How to add text or character to every cell in Excel

Wondering how to add text to an existing cell in Excel? In this article, you will learn a few really simple ways to insert characters in any position in a cell.

When working with text data in Excel, you may sometimes need to add the same text to existing cells to make things clearer. For example, you might want to put some prefix at the beginning of each cell, insert a special symbol at the end, or place certain text before a formula.

I guess everyone knows how to do this manually. This tutorial will teach you how to quickly add strings to multiple cells using formulas and automate the work with VBA or a special Add Text tool.

Excel formulas to add text/character to cell

To add a specific character or text to an Excel cell, simply concatenate a string and a cell reference by using one of the following methods.

Concatenation operator

The easiest way to add a text string to a cell is to use an ampersand character (&), which is the concatenation operator in Excel.

"text"&cell

This works in all versions of Excel 2007 - Excel 365.

CONCATENATE function

The same result can be achieved with the help of the CONCATENATE function:

CONCATENATE("text", cell)

The function is available in Excel for Microsoft 365, Excel 2019 - 2007.

CONCAT function

To add text to cells in Excel 365, Excel 2019, and Excel Online, you can use the CONCAT function, which is a modern replacement of CONCATENATE:

CONCAT("text", cell)

Note. Please pay attention that, in all formulas, text should be enclosed in quotation marks.

These are the general approaches, and the below examples show how to apply them in practice.

How to add text to the beginning of cells

To add certain text or character to the beginning of a cell, here's what you need to do:

  1. In the cell where you want to output the result, type the equals sign (=).
  2. Type the desired text inside the quotation marks.
  3. Type an ampersand symbol (&).
  4. Select the cell to which the text shall be added, and press Enter.

Alternatively, you can supply your text string and cell reference as input parameters to the CONCATENATE or CONCAT function.

For example, to prepend the text "Project:" to a project name in A2, any of the below formulas will work.

In all Excel versions:

="Project:"&A2

=CONCATENATE("Project:", A2)

In Excel 365 and Excel 2019:

=CONCAT("Project:", A2)

Enter the formula in B2, drag it down the column, and you will have the same text inserted in all cells.

Tip. The above formulas join two strings without spaces. To separate values with a whitespace, type a space character at the end of the prepended text (e.g. "Project: ").

Adding text to the beginning of cells

For convenience, you can input the target text in a predefined cell (E2) and add two text cells together:

Without spaces:

=$E$2&A2

=CONCATENATE($E$2, A2)

With spaces:

=$E$2&" "&A2

=CONCATENATE($E$2, " ", A2)

Please notice that the address of the cell containing the prepended text is locked with the $ sign, so that it won't shift when copying the formula down.

With this approach, you can easily change the added text in one place, without having to update every formula. Another way to add text to the beginning of a string

How to add text to the end of cells in Excel

To append text or specific character to an existing cell, make use of the concatenation method again. The difference is in the order of the concatenated values: a cell reference is followed by a text string.

For instance, to add the string "-US" to the end of cell A2, these are the formulas to use:

=A2&"-US"

=CONCATENATE(A2, "-US")

=CONCAT(A2, "-US")

Alternatively, you can enter the text in some cell, and then join two cells with text together:

=A2&$D$2

=CONCATENATE(A2, $D$2)

Please remember to use an absolute reference for the appended text ($D$2) for the formula to copy correctly across the column. Adding text to the end of cells

Add characters to beginning and end of a string

Knowing how to prepend and append text to an existing cell, there is nothing that would prevent you from using both techniques within one formula.

As an example, let's add the string "Project:" to the beginning and "-US" to the end of the existing text in A2.

="Project:"&A2&"-US"

=CONCATENATE("Project:", A2, "-US")

=CONCAT("Project:", A2, "-US")

With the strings input in separate cells, this works equally well: Inserting characters at the beginning and end of a string

Combine text from two or more cells

To place values from multiple cells into one cell, concatenate the original cells by using the already familiar techniques: an ampersand symbol, CONCATENATE or CONCAT function.

For example, to combine values from columns A and B using a comma and a space (", ") for the delimiter, enter one of the below formulas in B2, and then drag it down the column.

Add text from two cells with an ampersand:

=A2&", "&B2

Combine text from two cells with CONCAT or CONCATENATE:

=CONCATENATE(A2, ", ", B2)

=CONCAT(A2, ", ", B2)

When adding text from two columns, be sure to use relative cell references (like A2), so they adjust correctly for each row where the formula is copied. Combine two text cells

To combine text from multiple cells in Excel 365 and Excel 2019, you can leverage the TEXTJOIN function. Its syntax provides for a delimiter (the first argument), which makes the formular more compact and easier to manage.

For example, to add strings from three columns (A, B and C), separating the values with a comma and a space, the formula is:

=TEXTJOIN(", ", TRUE, A2, B2, C2) Combine text from multiple cells

How to add special character to cell in Excel

To insert a special character in an Excel cell, you need to know its code in the ASCII system. Once the code is established, supply it to the CHAR function to return a corresponding character. The CHAR function accepts any number from 1 to 255. A list of printable character codes (values from 32 to 255) can be found here.

To add a special character to an existing value or a formula result, you can apply any concatenation method that you like best.

For example, to add the trademark symbol (™) to text in A2, any of the following formulas will work:

=A2&CHAR(153)

=CONCATENATE(A2&CHAR(153))

=CONCAT(A2&CHAR(153)) Adding a special character to an Excel cell

How to add text to formula in Excel

To add a certain character or text to a formula result, just concatenate a string with the formula itself.

Let's say, you are using this formula to return the current time:

=TEXT(NOW(), "h:mm AM/PM")

To explain to your users what time that is, you can place some text before and/or after the formula.

Insert text before formula:

="Current time: "&TEXT(NOW(), "h:mm AM/PM")

=CONCATENATE("Current time: ", TEXT(NOW(), "h:mm AM/PM"))

=CONCAT("Current time: ", TEXT(NOW(), "h:mm AM/PM")) Inserting text before a formula

Add text after formula:

=TEXT(NOW(), "h:mm AM/PM")&" - current time"

=CONCATENATE(TEXT(NOW(), "h:mm AM/PM"), " - current time")

=CONCAT(TEXT(NOW(), "h:mm AM/PM"), " - current time") Adding text after a formula

Add text to formula on both sides:

="It's " &TEXT(NOW(), "h:mm AM/PM")& " here in Gomel"

=CONCATENATE("It's ", TEXT(NOW(), "h:mm AM/PM"), " here in Gomel")

=CONCAT("It's ", TEXT(NOW(), "h:mm AM/PM"), " here in Gomel") Inserting text on both sides of a formula

How to insert text after Nth character

To add a certain text or character at a certain position in a cell, you need to split the original string into two parts and place the text in between. Here's how:

  1. Extract a substring preceding the inserted text with the help of the LEFT function:
    LEFT(cell, n)
  2. Extract a substring following the text using the combination of RIGHT and LEN:
    RIGHT(cell, LEN(cell) -n)
  3. Concatenate the two substrings and the text/character using an ampersand symbol.

The complete formula takes this form:

LEFT(cell, n) & "text" & RIGHT(cell, LEN(cell) -n)

The same parts can be joined together by using the CONCATENATE or CONCAT function:

CONCATENATE(LEFT(cell, n), "text", RIGHT(cell, LEN(cell) -n))

The task can also be accomplished by using the REPLACE function:

REPLACE(cell, n+1, 0, "text")

The trick is that the num_chars argument that defines how many characters to replace is set to 0, so the formula actually inserts text at the specified position in a cell without replacing anything. The position (start_num argument) is calculated using this expression: n+1. We add 1 to the position of the nth character because the text should be inserted after it.

For example, to insert a hyphen (-) after the 2nd character in A2, the formula in B2 is:

=LEFT(A2, 2) &"-"& RIGHT(A2, LEN(A2) -2)

Or

=CONCATENATE(LEFT(A2, 2), "-", RIGHT(A2, LEN(A2) -2))

Or

=REPLACE(A2, 2+1, 0, "-")

Drag the formula down, and you will have the same character inserted in all the cells: Add text after Nth character

How to add text before/after a specific character

To insert certain text before or after a particular character, you need to determine the position of that character in a string. This can be done with the help of the SEARCH function:

SEARCH("char", cell)

Once the position is determined, you can add a string exactly at that place by using the approaches discussed in the above example.

Add text after specific character

To insert some text after a given character, the generic formula is:

LEFT(cell, SEARCH("char", cell)) & "text" & RIGHT(cell, LEN(cell) - SEARCH("char", cell))

Or

CONCATENATE(LEFT(cell, SEARCH("char", cell)), "text", RIGHT(cell, LEN(cell) - SEARCH("char", cell)))

For instance, to insert the text (US) after a hyphen in A2, the formula is:

=LEFT(A2, SEARCH("-", A2)) &"(US)"& RIGHT(A2, LEN(A2) - SEARCH("-", A2))

Or

=CONCATENATE(LEFT(A2, SEARCH("-", A2)), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2))) Adding text after a specific character

Insert text before specific character

To add some text before a certain character, the formula is:

LEFT(cell, SEARCH("char", cell) -1) & "text" & RIGHT(cell, LEN(cell) - SEARCH("char", cell) +1)

Or

CONCATENATE(LEFT(cell, SEARCH("char", cell) - 1), "text", RIGHT(cell, LEN(cell) - SEARCH("char", cell) +1))

As you see, the formulas are very similar to those that insert text after a character. The difference is that we subtract 1 from the result of the first SEARCH to force the LEFT function to leave out the character after which the text is added. To the result of the second SEARCH, we add 1, so that the RIGHT function will fetch that character.

For example, to place the text (US) before a hyphen in A2, this is the formula to use:

=LEFT(A2, SEARCH("-", A2) -1) &"(US)"& RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)

Or

=CONCATENATE(LEFT(A2, SEARCH("-", A2) -1), "(US)", RIGHT(A2, LEN(A2) -SEARCH("-", A2) +1)) Inserting text before a specific character

Notes:

  • If the original cell contains multiple occurrences of a character, the text will be inserted before/after the first occurrence.
  • The SEARCH function is case-insensitive and cannot distinguish lowercase and uppercase characters. If you aim to add text before/after a lowercase or uppercase letter, then use the case-sensitive FIND function to locate that letter.

How to add space between text in Excel cell

In fact, it is just a specific case of the two previous examples.

To add space at the same position in all cells, use the formula to insert text after nth character, where text is the space character (" ").

For example, to insert a space after the 10th character in cells A2:A7, enter the below formula in B2 and drag it through B7:

=LEFT(A2, 10) &" "& RIGHT(A2, LEN(A2) -10)

Or

=CONCATENATE(LEFT(A2, 10), " ", RIGHT(A2, LEN(A2) -10))

In all the original cells, the 10th character is a colon (:), so a space is inserted exactly where we need it: Adding space at the same position in all cells

To insert space at a different position in each cell, adjust the formula that adds text before/after a specific character.

In the sample table below, a colon (:) is positioned after the project number, which may contain a variable number of characters. As we wish to add a space after the colon, we locate its position using the SEARCH function:

=LEFT(A2, SEARCH(":", A2)) &" "& RIGHT(A2, LEN(A2)-SEARCH(":", A2))

Or

=CONCATENATE(LEFT(A2, SEARCH(":", A2)), " ", RIGHT(A2, LEN(A2)-SEARCH(":", A2))) Insert space after a specific character

How to add the same text to existing cells with VBA

If you often need to insert the same text in multiple cells, you can automate the task with VBA.

Prepend text to beginning

The below macros add text or a specific character to the beginning of all selected cells. Both codes rely on the same logic: check each cell in the selected range and if the cell is not empty, prepend the specified text. The difference is where the result is placed: the first code makes changes to the original data while the second one places the results in a column to the right of the selected range.

If you have little experience with VBA, this step-by-step guide will walk you through the process: How to insert and run VBA code in Excel.

Macro 1: adds text to the original cells

Sub PrependText() Dim cell As Range For Each cell In Application.Selection If cell.Value <> "" Then cell.Value = "PR-" &amp; cell.Value Next End Sub

This code inserts the substring "PR-" to the left of an existing text. Before using the code in your worksheet, be sure to replace our sample text with the one you really need. Macro to add text to the beginning of multiple cells

Macro 2: places the results in the adjacent column

Sub PrependText2() Dim cell As Range For Each cell In Application.Selection If cell.Value <> "" Then cell.Offset(0, 1).Value = "PR-" &amp; cell.Value Next End Sub

Before running this macro, make sure there is an empty column to the right of the selected range, otherwise the existing data will be overwritten. Macro to prepend text and place the results in another column

Append text to end

If you are looking to add a specific string/character to the end of all selected cells, these codes will help you get the work done quickly.

Macro 1: appends text to the original cells

Sub AppendText() Dim cell As Range For Each cell In Application.Selection If cell.Value <> "" Then cell.Value = cell.Value &amp; "-PR" Next End Sub

Our sample code inserts the substring "-PR" to the right of an existing text. Naturally, you can change it to whatever text/character you need. Macro to add text to the end of all selected cells

Macro 2: places the results in another column

Sub AppendText2() Dim cell As Range For Each cell In Application.Selection If cell.Value <> "" Then cell.Offset(0, 1).Value = cell.Value &amp; "-PR" Next End Sub

This code places the results in a neighboring column. So, before you run it, make certain you have at least one empty column to the right of the selected range, otherwise your existing data will be overwritten. Macro to append text and place the results in the adjacent column

Add text or character to multiple cells with Ultimate Suite

In the first part of this tutorial, you've learned a handful of different formulas to add text to Excel cells. Now, let's me show you how to accomplish the task with a few clicks :)

With Ultimate Suite installed in your Excel, here are the steps to follow:

  1. Select your source data.
  2. On the Ablebits tab, in the Text group, click Add.
  3. On the Add Text pane, type the character/text you wish to add to the selected cells, and specify where it should be inserted:
    • At the beginning
    • At the end
    • Before specific text/character
    • After specific text/character
    • After Nth character from the beginning or end
  4. Click the Add Text button. Done!

As an example, let's insert the string "PR-" after the "-" character in cells A2:A7. For this, we configure the following settings: Inserting the same text in multiple cells

A moment later, we get the desired result: The text is added to all selected cells.

These are the best ways to add characters and text strings in Excel. I thank you for reading and hope to see you on our blog next week!

Available downloads

Add text to cell in Excel - formula examples (.xlsm file)
Ultimate Suite - trial version (.exe file)

Table of contents

93 comments

  1. Hi,
    May I seek your help. what is the possible for this
    Given data:
    in Cell1A contains : apple, orange, banana
    the result I want in Cell1A: 1.) apple 2.) orange 3.) banana

    • Hi! You can change the text in the cell in which it is written using a VBA macro. You can also do it using Ultimate Suite as described in the article above.

  2. Hi, is it possible to concatenate two cells into separate paragraphs in a third cell? Something I would typically do using Alt+Enter?

    For example,

    A1: "Hi, "
    B1: "Hope you're doing well"
    C1 shows:
    "Hi,
    Hope you're doing well"

    Thanks

  3. I'm trying to auto fill a column with the word "COMPLETED" if duplicate entries occur in two other, separate columns.
    I.e. Column A contains a variety of numbers. Column B contains specific numbers that can also be found in Column A. Column C should show the word "COMPLETED" if the number is found in both Columns A & B

  4. Hi Team,
    I want to replace 3 special character like "*" in the end of sentence

    Jimy saputra = jimy sapu***
    Asep surasep = Asep sura***
    Alexander Trifuntov = Alexander Trifun***

    thanks a lot in advance:-

  5. Dear Team,
    I want to add spaces like the expected results,
    thanks a lot in advance:-
    C2160feetRoad
    C41OPP240B
    C284981C12
    G14sunderIndustrialstate
    Their expected results should be as:-
    c2 160 feet Road
    c41 OPP 240 B
    c2 84981 c12
    G14 sunder industrial state

    • Hi! To make a formula and add spaces, you need to see some kind of regularity or pattern in your data. Unfortunately, I don't see that.

      • Thanks Sir,
        possible to formula to add space ist after two character,then three character,then three character in a single cell please

          • Thanks Sir,
            This is only for ist three character, but i need a single formula to make space in a cell after every two or three spaces
            e,g:C2160feetRoad should be as c2 160 feet Road.

  6. Hello,

    I'm attempting to extract the text from many cell notes. The form of the text in each cell note is:
    ABC
    DEF
    GHI

    I setup the following function:

    Function getComment(incell As Range) as String
    On Error Resume Next
    getComment = incell.Comment.Text
    End Function
    ----------------
    When I call the function on a cell, the result is:
    ABCDEFGHI

    How to insert a delimiter such as 'space' or 'comma' in between each line so it looks like:
    ABC,DEF,GHI
    or
    ABC DEF GHI

    Thanks!

  7. Hi
    Grateful if you could please help. I have one cell AB and another cell C. How to add C between AB please?

    • Hi! If I understand your task correctly, try the following formula:

      =REPLACE(A1,2,0,B1)
      or
      =LEFT(A1,1)&B1&RIGHT(A1,1)
      where
      A1="AB"
      B1="C"
      You can learn more about REPLACE function in Excel in this article on our blog.

  8. I have data from a mainframe and the date fields do not have a / separator to separate the month/day/year. I can use a formula you provided. When I use =LEFT(E2, 4) &"/"& RIGHT(E2, LEN(E2) -4) this works perfectly to put a separator before the 4-character year, if the date is 8 characters in length. example: 11162002 will be 1116/2002 but if the date is 7 characters in length I get this - 6162002 will be 6162/002. If I move the left and right functions ( =RIGHT(E2, 4) &"/"& LEFT(E2, LEN(E2) -4) ) I get this result 2002/1116. This is very confusing to me. I need to count 4 characters starting from the right and insert a / and then count 7 characters from the right again to insert another / to all dates will look like this. 11/16/2002 for a 8 character date string or 6/16/2002 for a 7 character string but I am unable to find a solution. What would these 2 formulas look like. Please provide 1st formula to separate the year and 2nd formula to separate the month/day.

    thank you in advance

  9. This does not address inserting from the right.

    I have a series of digits I wand to insert a decimal into from the right by 2 places. Every guide I find only addresses inserting from the left.

      • I might have overlooked something, and sorry if I did, but I'm not understanding how I would add a "." into an existing string, 2 places from the right.

        562357 > 5623.57

        • Well I managed somehow.
          Still don't see how the section you referred to is relevant to my question.
          =RIGHT(REPLACE(M2,LEN(M2)-3+2,LEN(M2),""), 10) & "." & RIGHT(M2,2)

  10. It is not helpful, in order to use this tutorial you have to already be an expert. You need to do the explanation for dummies as well.

  11. Hello. How can I add brackets to all cells. For instance, the cell reads "$Stop1" and I want "{$Stop1}."

  12. If the cell I'm drawing in with CONCAT is currency which ends in ".00" or, say, ".10", it truncates the zero so I get $2 or $2.2 without the remaining zeros. How do I force the 2 space decimal?

  13. Function SplitWords(Txt As Range) As String
    Dim Out$
    If Len(Txt) = 0 Then Exit Function
    Out = Mid(Txt, 1, 1)
    For i = 2 To Len(Txt)
    If Mid(Txt, i, 1) Like "[a-z]" And Mid(Txt, i + 1, 1) Like "[A-Z]" Then
    Out = Out & Mid(Txt, i, 1) & " "
    Else
    Out = Out & Mid(Txt, i, 1)
    End If
    Next i
    SplitWords = Out
    End Function

  14. HI! I need help.

    I want a serial number entered on one sheet to automatically populate within a sentence on another sheet.

    For instance:

    A user enters the serial number on Sheet 1 in Cell B5 as 1234-Q.

    I want Sheet 2 to have a sentence within a cell that says "the service for serial number '1234-Q' is complete". How can I do this? Paste special doesn't exactly work.

    Appreciate any help, thanks!

  15. A B
    1000403 DRUGS ALLOPURINOL
    (ALLOPURINOL USP)
    1000448 TRI ETHYL
    ALUMINUM
    1000465 TRI ETHYL
    ALUMINUM
    1000552 DRUGS: LOSARTAN
    POTASSIUM USP
    (LOSARTANPOTASSIUM)
    1000916 COMBED
    COTTON CORESPUN SEWING THREAD
    70%POLYESTER FILAMENT YARN
    42%
    1001356 BOPP FILMS
    BIAXIALLY ORIENTED POLYPROPYLENE FILM

    in this database, I want to add texts spread over 2-3-4-n nos of Cells at Cl-B against individual entry(first column) in a single cell. Considering the database is huge and number of cell over which text is spread is not limited, use of concatenate may not be helpful.

  16. How can I add text to a formula like =SUM(224/12) so the result would be 18.6 days

  17. How do I add a comma and a space between characters? My cells return multiple characters in one cell (I want that) and I would like to add a comma and space between each character.
    Thank you for your help!!
    Elyse

    • Hello!
      What formula do you use to get the characters in a cell? We need to change this formula. To write text with commas in another cell you can use the TEXTJOIN function

      =TEXTJOIN(",",TRUE,MID(A1,ROW(A1:A50),1))

  18. I want to add "Address" but can not put as =""Address"" since it does not take it as text. how I can add this ?

  19. how do you enter name, and letter by letter it goes to each next Cell,
    for example : JOHN RAMBO,
    J O H N R A M B O in each cell

      • i need to copy data from other form and put in an excel sheet, which read each letter for each cell, kind of hard adding list of name to it by using arrow keys, as names from my country had kind of long names...

          • okay, the sheet than i had was make by the printing company and some how if edited it will be printed differently, im suppose to fill in the name from a physical form into the sheet, in which read each letter of the name in each cell, the problem was it become a hassle each time for me to enter the name for example :
            JOHN DOE
            i had to enter the name
            J "ARROW KEY" O "ARROW KEY" H "ARROW KEY" N "ARROW KEY" *BLANK* "ARROW KEY" D "ARROW KEY" O "ARROW KEY" E

            so in the sheet it will be [ J ][ O ][ H ][ N ][ ][ D ][ O ][ E ]

            its okay to type in like this, but if you had 300 names with 21 letter, well... poop..
            it will be helpful if you can solve this silly problem of mine... thank you

  20. Good day.
    Please which formula in excel can ad space after 2nd upper case character.. e.g. "JohnDavis" to appear as "John Davis"

    Thank you

    • Hello!
      To insert a space before the second uppercase letter, use the formula:

      =LEFT(A1,MATCH(TRUE,EXACT(MID(A1,ROW(2:50),1), UPPER(MID(A1,ROW(2:50),1))),0))&" "&MID(A1,MATCH(TRUE,EXACT(MID(A1,ROW(2:50),1), UPPER(MID(A1,ROW(2:50),1))),0)+1,50)

      I hope it’ll be helpful.

      • Hi! can ask if this formula is possible to this
        Macaraeg,ChristopherLabanaBautista
        thank you

        • Hello!
          To split sticky text and insert spaces into it, you need to use VBA. You can try to apply a user defined function

          Function SplitWords(Txt As Range) As String
          Dim Out$
          If Len(Txt) = 0 Then Exit Function
          Out = Mid(Txt, 1, 1)
          For i = 2 To Len(Txt)
          If Mid(Txt, i, 1) Like "[a-z]" And Mid(Txt, i + 1, 1) Like "[A-Z]" Then
          Out = Out & Mid(Txt, i, 1) & " "
          Else
          Out = Out & Mid(Txt, i, 1)
          End If
          Next i
          SplitWords = Out
          End Function

          To insert a space after a comma, use the SUBSTITUTE function.
          I hope it’ll be helpful. If something is still unclear, please feel free to ask.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)