by In this tutorial, you will lean a quick way to calculate percentages in Excel, find the basic percentage formula and a few more formulas for calculating percentage increase, percent of total and more.
Calculating percentage is useful in many areas of life, whether it is restaurant tipping, reseller commission, your income tax or interest rate. Say, you've been lucky enough to get a 25% off promotion code on a new plasma TV. Is this a good deal? And how much will you eventually have to pay?
In this tutorial, we are going to explore a few techniques that will help you efficiently calculate percent in Excel and learn the basic percentage formulas that will take the guesswork out of your calculations.
Percentage basics
The term "per cent" is derived from the Latin per centum, meaning "by the hundred". As you probably remember from high school math class, a percentage is a fraction of 100 that is calculated by dividing the numerator by the denominator and multiplying the result by 100.
The basic percentage formula is as follows:
For example, if you had 20 apples and you gave 5 to your friends, how much did you give, percentage wise? By performing a simple calculation =5/20*100 you get the answer - 25%.
This is how you normally calculate percentages in school and everyday life. Computing percentage in Microsoft Excel is even easier since Excel performs some operations for you automatically, in the background.
Regrettably, there is no universal Excel formula for percentage that would cover all possible scenarios. If you ask someone "Which percent formula do I use to get the result I want?", most likely, you will get an answer like "Well, that depends on what exactly result you want to achieve."
So, let me show you a few simple formulas for calculating a percent in Excel such as a percentage increase formula, a formula to get percentages of a total and more.
Basic Excel percentage formula
The basic formula to calculate percentage in Excel is this:
If you compare it to the basic math formula for percentage, you will notice that Excel's percentage formula lacks the *100 part. When calculating a percent in Excel, you do not have to multiply the resulting fraction by 100 since Excel does this automatically when the Percentage format is applied to a cell.
And now, let's see how you can use the Excel percentage formula on real-life data. Suppose, you have the number of "Ordered items" in column B and "Delivered items" in column C. To find out the percentage of delivered products, perform the following steps:
- Enter the formula
=C2/B2in cell D2, and copy it down to as many rows as you need. - Click the Percent Style button (Home tab > Number group) to display the resulting decimal fractions as percentages.
- Remember to increase the number of decimal places if needed, as explained in Percentage tips.
- Done! : )
The same sequence of steps shall be performed when using any other percentage formula in Excel.
In the following example, column D displays a rounded percent of delivered items, without any decimal places showing.
Calculating percentage of total in Excel
In fact, the above example is a particular case of calculating percentages of a total. Now, let's investigate a few more examples that will help you make quick work of calculating a percent of a total in Excel on different data sets.
Example 1. The total is at the end of the table in a certain cell
A very common scenario is when you have a total in a single cell at the end of a table. In this case, the percentage formula will be similar to the one we've just discussed with the only difference that a cell reference in the denominator is an absolute reference (with $).The dollar sign fixes the reference to a given cell, so that it never changes no matter where the formula is copied.
For example, if you have some values in column B and their total in cell B10, you'd use the following formula to calculate percentages of the total:
=B2/$B$10
You use a relative cell reference to cell B2 because you want it to get changed when you copy the formula to other cells of column B. But you enter $B$10 as an absolute cell reference because you want to leave the denominator fixed on B10 when auto-filling the formula down to row 9.
Tip. To make the denominator an absolute reference, either type the dollar sign ($) manually or click the cell reference in the formula bar and press F4.
The screenshot below demonstrates the results returned by the formula, the Percentages of Total column is formatted as percentage with 2 decimal places showing.
Example 2. Parts of the total are in multiple rows
In the above example, suppose you have several rows for the same product and you want to know what part of the total is made by all orders of that particular product.
In this case, you can use the SUMIF function to add up all numbers relating to a given product first, and then divide that number by the total, like this:
=SUMIF(range, criteria, sum_range) / total
Given that column A contains all product names, column B lists corresponding quantities, cell E1 is the name of the product you are interested in, and the total is in cell B10, your real-life formula may look similar to this:
=SUMIF(A2:A9 ,E1, B2:B9) / $B$10
Naturally, you can put the product name directly in the formula, like this:
=SUMIF(A2:A9, "cherries", B2:B9) / $B$10
If you want to find out what part of the total a few different products make, add up the results returned by several SUMIF functions, and then divide that number by the total. For example, the following formula calculates the percent of cherries and apples:
=(SUMIF(A2:A9, "cherries", B2:B9) + SUMIF(A2:A9, "apples", B2:B9)) / $B$10
For more information about the SUM function, please check out the following tutorials:
How to calculate percent difference in Excel
Of all formulas for calculating percentage in Excel, a percent change formula is probably the one you would use most often.
Excel formula for percent increase / decrease
To calculate the percentage of difference between two values A and B, the generic formula is:
When applying this formula to real data, it is important that you correctly determine which value is A and which is B. For example, yesterday you had 80 apples and how you have 100, meaning that now you have 20 apples more than before, which is 25% increase. If you had 100 apples and now you have 80, your number of apples has reduced by 20, which is 20% decrease.
Considering the above, our Excel formula for percentage change takes the following shape:
And now, let's see how you can use this formula for calculating percent difference in your spreadsheets.
Example 1. Calculating percent difference between 2 columns
Suppose you have the last month prices in column B and this month prices in column C. Then your percent change formula takes this form:
=(C2-B2)/B2
To calculate the percent difference between two numbers correctly, carry out these steps.
- Enter the formula in any blank cell in row 2, say D2. This will output the result as a decimal number.
- Select the formula cell and click the Percent Style button on the Home tab to convert the decimal number to percentage.
- Drag the formula down to copy it to the below cells.
As the result, the formula calculates the percentage of change in this month (column C) comparted to last month (column B). Positive percentages that show percentage increase are formatted in usual black, while negative percentages (percent decrease) are formatted in red. To have this done automatically, set up a custom format for negative percentages as explained in this tip.
Example 2. Calculating percentage difference between two numbers
In case you have one column of numbers, say column C that lists weekly or monthly sales, you can calculate the percentage change between the previous week/month and the current one using this formula:
=(C3-C2)/C2
Where C2 and C3 are the numbers you are comparing.
Note. Please pay attention that you should skip the first row with data and put your percent difference formula in the 2nd cell, which is D3 in this example.
To display decimals as percentages, apply the percent format to the cells containing your formula, and you will get the following result:
To calculate the percentage of change between a certain number and all other numbers, fix the address of that cell by using the $ sign, e.g. $C$2.
For instance, to calculates the percent increase / decrease for each month compared to January (C2), the formula in D3 is:
=(C3-$C$2)/$C$2
When copying the formula to the below cells, the absolute reference ($C$2) will remain the same, while the relative reference (C3) will change to C4, C5, and so on based on a relative position of the row where the formula is copied.
For more formula examples, please see How to calculate percentage change in Excel.
Calculating amount and total by percentage
As you've just seen, calculating percentages in Excel is easy, and so is calculating amounts and totals if you know the percentage.
Example 1. Calculate amount by total and percentage
Suppose you are buying a new laptop for $950 and they charge 11% VAT on this purchase. The question is - how much do you have to pay on top of the net price? In other words, what is 11% of $950?
The following formula will help:
Assuming that the total value is in cell A2 and percent in B2, the above formula turns into a simple =A2*B2 and returns 104.50.
Remember, when you type a number followed by the percent sign (%) in Excel, the number is interpreted as a hundredth of its value. For example, 11% is actually stored as 0.11 and Excel uses this underlying value in all formulas and calculations.
In other words, the formula =A2*11% is equivalent to =A2*0.11. Naturally, you are free to use the decimal number corresponding to the percentage directly in a formula if this works better for your worksheets.
Example 2. Calculating total by amount and percentage
For example, you friend offered you his old computer for $400, which is 30% off the original price. You want to know what the original price was.
Since 30% is the discount, you deduct it from 100% first to know what percentage you actually have to pay (100% - 30% = 70%). Now you need the formula to calculate the original price, i.e. to find the number whose 70% equals 400.
The formula goes as follows:
Applied to real data, it may take any of the following shapes:
=A2/B2
or
=A2/0.7
or
=A2/70%
Tip. To get an answer to a more difficult question - how to calculate the interest amount of a loan payment knowing an interest rate - check out the IPMT function.
How to increase / decrease a number by percentage
The holiday season is upon us and this indicates a change in your usual weekly spendings. You may want to consider different options to find out your optimum weekly allowance.
To increase an amount by a percentage, use this formula:
For example, to increase the value in cell A1 by 20%, the formula is:
=A1*(1+20%)
To decrease an amount by a percentage:
For instance, to reduce the value in cell A1 by 20%, the formula is:
=A1*(1-20%)
In our example, if A2 is your current expenditures and B2 is the percentage you want to increase or reduce that amount by, here are the formulas you'd enter in cell C2:
Increase by percentage:
=A2*(1+B2)
Reduce by percentage:
Suppose, you have a column of numbers that you want to increase or reduce by a certain percent, and you want to have the updated numbers in the same column rather than add a new column with the formula. Here are 5 quick steps to handle this task: Increase by percentage: Reduce by percentage: Naturally, you are free to replace 20% in the above formulas with the percentage you want. And here's the result - all the numbers in column B are increased by 20%:
In the same fashion, you can multiply or divide a column of numbers by a certain percentage. Simply enter the desired percentage in an empty cell and follow the steps above.=A2*(1-B2)
How to increase / reduce an entire column by a percentage
=1+20%=1-20%
This is how you calculate percentage in Excel. And even if working with percentages has never been your favorite kind of math, by using these basic percentage formulas you can get Excel to do the work for you. That's all for today, thank you for reading!
725 comments
How do I write a formula that determines that a number is equal to 60% of what number? I need a formula to account for 40% loss. The scenario involvers a withdrawal from a 401(k). I know that if I need $60,000, I must withdraw $100,000 to account for the 40% loss in taxes. How do I write that in a formula?
Hi Frank,
If my understanding is correct you know the amount (60,000) and percentage (60%) and you want to calculate the total. If so, use one of the following formulas:
=A1/0.6 or =A1/60% where A1 is $60,000
=A1/B1 where A1 is amount ($60,000) and B1 is percentage (60%)
I want to return a monthly value for fixed starting number that increases at a fixed percentage over a year. Let me show you the example:
Base number (we'll call it January) = 1,000 (B1)
Annual Increase = 40% (A1)
What is the increase in each month Feb- Dec (A2-A12) of the year (expressed as the base + one-twelfth of the percentage? When I do the .40/12 in the formula I come up with 1,434. I think it should be 1,400. (1000 *.4 +1000)
I'm missing something.
Thanks!
Hello,
I want to calculate the following:
6 = 2014 average (cell C23)
8 = Jan 15 total (cell D23)
5 = Feb 15 total (cell E23)
I need to calculate the % increase/decrease between the 2015 average (8+5/2=6.5) and the 2014 avg (6). Note, I will need to continually update the formula to include future months (cells F23-O23).
Thanks in advance,
Mark
How do I add 40% to the first 100 dollars and then 29% after the first 100??
Hello, I am Cambodian, Please help me, How to find average and what is the formula to find it? please :)
Hi!
You can use the AVERAGE function. For example the formula =AVERAGE(A1:A10) returns the average of values in cells A1 through A10.
Thank you for this article
I am struggling to find out the percentage of my quantitative data,
I had multiple choose questionnaires from (1 to 5)
1. I need to find out how many of participants chose number 1, 2, 3, 4,5 to put in table
2. I need the percentage of each number such is how many participants chose number 3
This is one example of my questionnaires
1 never 2 rarely 3 sometimes 4 very often 5 always
Q1.
Q2 .
Q3.
Thanks in advance
I calculate an agents effectiveness using this formula =(AHT/ agreed AHT)*100. results are either less than or equals to 100. but sometimes i get results over 100. how do i calculate for such agent over 100%?
Thanks for the article, it is very helpful! I am trying to show the percent change between two columns. I am ending up with the correct number, but there is not a '%' How do I get the percent sign to show up? This is the formula I am using; =((C5-B5)/B5)*100 Thanks!
how to know the percentage of a number from within
e.g 20% is 25% on top
or 150% is 60% from within what is the formula
My total amount is for example $3500,I want to know the amount of 5.5% including total amount in $3500.When I Add the amount + 5.5% amount it should come =$3500.
Hi Muralli,
If my understanding is correct, you want to calculate 5.5% of the total ammount and then add it to the total. If so, you can use any of the follwoing formulas:
=3500+(3500*5.5%)
=A1+(A1*5.5%)
=A1+(A1*0.055)
Where A1 is your total ammount.
In my spreadsheet "column C row 9 has $75.00" in column D row 9 I want it show 30% off of the $75.00 with the total being $52.50 in column D row 9. How do i enter that formula
Thank you
Hi Jeff,
It can be either =C9*70% or =C9*0.7
Thank you
How did you get that number because I also now have to but in that column in different rows 15% 25%.
Jeff
Just subtract it from 100%. For example, 100% - 15% = 85% or 0.85 in the decimal form.
how to use if i give 12 pieces of item to shop keeper so i put 12 item then auto it increase 1 item in scheme if i put 24 item then auto it increase 2 item in scheme.
%GE OF SERVICE TAX IN DIFFERENT PERIODS.
PLEASE HELP ME, HOW TO WRITE FORMULA IN EXCEL SHEET
REGARDS
T K MITRA
HOW TO CALCULATE SERVICE TAX IN THREE DIFFERENT PERIODS, E.G.
DATES : 31/12/13 = 31/12/13 : 12.36%, >= 01/04/2015 : 14%
PL. WRITE THE FORMULA IN EXCEL SHEET
REGARDS
How to use absolute cell references as necessary so that you can copy the formula, in cell G4, construct a formula to calculate the Percent of Total Sales for the first region. Copy the formula down for the remaining regions.
Please can you help?
I need an efficient workaround to discount a select group of products (given in a table with the percentage to reduce/increase price) from a huge database of products (given in a seperate list). the result should be updated prices for those products which should be discounted and all other product prices not affected by discount to remain the same.
=IF(ISERROR((($K7+$M7)/$I7)),0,(($K7+$M7)/$I7))
Please explain what this formula means.... I think my percentages are not calculating correctly.
it means you've put to many nested if's in your formula.
Hello ,
I need to make an excel sheet for my rate reference to update prices.
in the first column i would have the net rate ( different base rates) and next column i need to add say 10 % to the net rate of the first column and in the third column i need 15 % of the net rates given in the first column .
how can i do this ?? Hope u understand
I only need to get different percentage of the net prices fixed in column one .
Hello George,
Please enter these formulas into the 2nd cell of each column and then copy and paste them across the columns:
Second column
=A2*110%
Third column
=A2*115%
Insert these formulas and then copy/paste them down across columns.
Hie
Let say .. i have 10 customer. Total Sales : $1,000
Customer A : $100 ; Total contribution : 10%
Customer B : $200 ; Total contribution for A + B = 30%
Customer C : $100 ; Total contribution for A + B + C = 40%
How to do i do the % contribution in formula ?
Hi Kelly,
You can use the SUMIF() function to fulfill this task. Please see the following tutorial for more information:
https://www.ablebits.com/office-addins-blog/excel-sumif-function-formula-examples/
Hi there,
I want to calculate a percentage of the number of "Yes" response of the total given the option of three - yes, No amd Inappropriate.
How will I calculate the % of how many responses are "YES" out of the three responses
Please Help
Hi Priyanka,
I believe the COUNTIF function may help:
=COUNTIF(A1:A10, "yes")/10
Where A1:A10 are the cells with responses and 10 is the total number of cells.
After entering the formula, remember to click the Percent Style icon on the ribbon (Home tab > Number group) to display the result as percentage.
Svetlana,
How about if the column from which the formula is pulling continuously grows? the "/10" portion of the formula would have to be altered to match the ever-changing number of cells. Can the formula be set to match the total number of cells in the column?
I know you could do (A1:A99999), and that would take care of the first part of the formula, but if there's a way to make the "divide by" value equal the number of "active" cells, that would be great!
Hi Kyle,
You can use COUNTA to get the total count of non-blank cells, like this:
=COUNTIF(A1:A99999, "yes")/COUNTA(A1:A99999)
Hi Svetlana,
I am currently using the following percentage formula for calculating "Yes" vs "No" but not including the blanks.
=IFERROR(COUNTIF(C12:ZZ12,"Yes")/COUNTA(C12:ZZ12),"")
I am trying to add a third option of "Maybe" that I want to be counted as a "Yes" in the percentage. Any thoughts would be helpful as I am running out of ideas.
I need to formula to check if current "Yes" survey response is 71% for X number of responses how many more "Yes"survey responses will I need to get the score of 80%