Google Spreadsheet COUNTIF function with formula examples

Google Sheets COUNTIF is one of the easiest functions to learn and one of the handiest to use.

It's time to pick up some knowledge on how COUNTIF is used in Google Spreadsheet and learn why this function makes a true Google Spreadsheet companion.

What is the COUNTIF function in Google Sheets?

This short helper allows us to count how many times a certain value appears within a specified data range.

COUNTIF syntax in Google Sheets

The syntax of our function and its arguments are as follows:

=COUNTIF(range, criterion)
  • range — a range of cells where we want to count a certain value. Required.
  • criterion or searching criterion — a value to find and count across the data range indicated in the first argument. Required.

Google Spreadsheet COUNTIF in practice

It may seem that COUNTIF is so simple that it doesn't even count as a function (pun intended), but in truth its potential is quite impressive. Its searching criteria alone is enough to earn such a description.

The thing is that we can decide to look for not only concrete values but also those that meet certain criteria.

It's high time to try and build a formula together.

Google Spreadsheet COUNTIF for text and numbers (exact match)

Let's suppose your company sells various types of chocolate in several consumer regions and works with many clients.

This is how your sales data look like in Google Sheets: Sales data in Google Sheets.

Let's begin with the basics.

We need to count the number of "Milk Chocolate" sold. Place the cursor in the cell where you want to get the result and enter the equality sign (=). Google Sheets immediately understands that we are going to enter a formula. As soon as you type the letter "C", it will prompt you to choose a function that begins with this letter. Select "COUNTIF". COUNTIF for text.

The first argument of COUNTIF is represented by the following range: D6:D16. By the way, you don't have to enter the range manually — mouse selection is enough. Then enter a comma (,) and specify the second argument — searching criteria.

The second argument is a value that we're going to look for across the selected range. In our case it's going to be the text — "Milk Chocolate". Remember to finish the function with a closing bracket ")" and press "Enter".

Also, don't forget to enter double quotes ("") when using text values.

Our final formula looks as follows:

=COUNTIF(D6:D16,"Milk Chocolate")

As a result, we get three sales of this type of chocolate.

Tip. To count words and characters in Google Sheets, visit this tutorial.

Note. COUNTIF function works with a single cell or neighboring columns. In other words, you can't indicate a few separate cells or columns and rows. Please see the examples below.

Incorrect formulas:

=COUNTIF(C6:C16, D6:D16,"Milk Chocolate")

=COUNTIF(D6, D8, D10, D12, D14,"Milk Chocolate")

Correct usage:

=COUNTIF(C6:D16,"Milk Chocolate")

=COUNTIF(D6,"Milk Chocolate") + COUNTIF(D8,"Milk Chocolate") + COUNTIF(D10,"Milk Chocolate") + COUNTIF(D12,"Milk Chocolate") + COUNTIF(D14,"Milk Chocolate")

You may have noticed that it's not really convenient to set the searching criteria in the formula — you have to edit it every time. The better decision would be to write the criteria down other Google Sheets cell and reference that cell in the formula.

Let's count the number of occurred sales in the "West" region using the cell reference in COUNTIF. We'll get the following formula:

=COUNTIF(C6:C16,A3)

The function uses the content of A3 (the text value "West") in its calculations. As you can see, it's a lot easier now to edit the formula and its searching criteria. Using cell reference in COUNTIF.

Of course, we can do the same thing with numerical values. We can count the number of occurrences of the number "125" by indicating the number itself as a second argument:

=COUNTIF(E6:E16,125)

or by replacing it with a cell reference:

=COUNTIF(E6:E16,A3) COUNTIF for numbers.

Google Spreadsheet COUNTIF function and wildcard characters (partial match)

What is great about COUNTIF is that it can count whole cells as well as parts of the cell's contents. For that purpose, we use wildcard characters: "?", "*".

For instance, to count the sales in some particular region we can use only part of its name: enter "?est" into A2. A question mark (?) replaces one character. We are going to look for the 4-letter words ending with "est", including spaces.

Use the following COUNTIF formula in B2:

=COUNTIF(C6:C16,A2)

As you already know, the formula can easily take the next form:

=COUNTIF(C6:C16, "?est")

And we can see 6 sales in the "West" region.

Now let us employ the B3 cell for another formula:

=COUNTIF(C6:C16,A3)

What is more, we'll change the criteria to "??st" in A3. It means that now we are going to look for 4-letter words ending with "st". Since in this case two regions ("West" and "East") satisfy our criteria, we will see 9 sales: COUNTIF partial match.

Similarly, we can count the number of sales of the goods using an asterisk (*). This symbol replaces not just one, but any number of characters: Asterisk and COUNTIF.

=COUNTIF(D6:D16,A2)

"*Chocolate" in A2 to count all the products ending with "Chocolate".
=COUNTIF(D6:D16,A3)
"Chocolate*" in A3 to count all the products starting with "Chocolate".

And, as you may have guessed, if you enter "*Chocolate*", you're going to look for all the products that contain the word "Chocolate".

Note. If you need to count the number of words that contain an asterisk (*) and a question mark (?), then use tilde sign (~) before those characters. In this case, COUNTIF will treat them as simple signs rather than searching characters. For example, to look for the values that contain "?", the formula will be:

=COUNTIF(D6:D16,"*~?*")

COUNTIF Google Sheets for less than, greater than or equal to

The COUNTIF function is able to count not only how many times some number appears, but also how many of the numbers are greater than/less than/equal to/not equal to another specified number.

For that purpose, we use corresponding mathematical operators: "=", ">", "<", ">=", "<=", "<>".

Check out the table below to see how it works:

Criteria Formula example Description
The number is greater than =COUNTIF(F7:F16,">100") Count cells where values are greater than 100.
The number is less than =COUNTIF(F7:F16,"<100") Count cells where values are less than 100.
The number equals to =COUNTIF(F7:F16,"=100") Count cells where values equal to 100.
The number is not equal to =COUNTIF(F7:F16,"<>100") Count cells where values are not equal to 100.
The number is greater than or equal to =COUNTIF(F7:F16,">=100") Count cells where values are greater than or equal to 100.
The number is less than or equal to =COUNTIF(F7:F16,"<=100") Count cells where values are less than or equal to 100.

Note. It's very important to enclose the mathematical operator along with a number in the double quotes.

If you want to change the criteria without altering the formula, you can reference the cells as well.

Let me reference A2 and put the formula in B2, just as I did before:

=COUNTIF(F7:F16,A2)

To create more sophisticated criteria, use an ampersand (&).

For example, B3 contains a formula which counts the number of values greater than or equal to 100 in the E7:E16 range:

=COUNTIF(E7:E16,">="&A3)

B4 has the very same criteria, but we reference not only the number in that cell but also a mathematical operator. This makes it even easier to adapt COUNTIF formula if necessary:

=COUNTIF(E7:E16,A4&A3) COUNTIF variations.

Tip. We've been asked a lot about counting those cells that are greater than or less than values in another column. If that's what you're looking for, you will need another function for the job — SUMPRODUCT.

For example, let's count all rows where sales in column E are bigger than in the same row of column F:

=SUMPRODUCT(--(E6:E17>F6:F17)) Count all rows where the value in column E is greater than the value from column F.

  • The part at the core of the formula — E6:E17>F6:F17 — compares values in columns E and F. When the number in column E is greater, the formula takes it as TRUE, otherwise — FALSE.

    You'll see that if you enter the same into the ArrayFormula:

    =ArrayFormula(E6:E17>F6:F17) Verify the range from the SUMPRODUCT.

  • Then the formula takes this TRUE/FALSE result and turns it into 1/0 numbers with the help of the double unary operator (--).
  • This lets SUM do the rest — total the number of when E is greater than F.

Google Spreadsheet COUNTIF with multiple criteria

Sometimes it's necessary to count the number of values that answer at least one of the mentioned conditions (OR logic) or multiple criteria at once (AND logic). Based on that, you can use either a few COUNTIF functions in a single cell at a time or the alternate COUNTIFS function.

Count in Google Sheets with multiple criteria — AND logic

The only way I’d advise you to use here is with a special function that is designed to count by multiple criteria — COUNTIFS:

=COUNTIFS(criteria_range1, criterion1, [criteria_range2, criterion2, ...])

It is normally used when there are values in two ranges that should meet some criteria or whenever you need to get the number falling between a specific range of numbers.

Let’s try and count the number of total sales between 200 and 400:

=COUNTIFS(F5:F16,">=200",F5:F16,"<=400") COUNTIFS function in Google Sheets.

Count uniques in Google Sheets with multiple criteria

You can go further and count the number of unique products between 200 and 400.

Nope, it's not the same as above! :) The above COUNTIFS counts each occurrence of sales between 200 and 400. What I suggest is to also look at the product. If its name occurs more than once, it won't be included in the result.

There's a special function for that — COUNTUNIQUEIFS:

COUNTUNIQUEIFS(count_unique_range, criteria_range1, criterion1, [criteria_range2, criterion2, ...])

Compared to COUNTIFS, it's the first argument that makes the difference. Count_unique_range is that range where the function will count unique records.

Here's how the formula and its result will look:

=COUNTUNIQUEIFS(D5:D16,F5:F16,">=200",F5:F16,"<=400") Count unique products that meet your criteria.

Look, there are 3 rows that meet my criteria: the sales are 200 and greater and at the same time are 400 or less.

However, 2 of them belong to the same product — Milk Chocolate. COUNTUNIQUEIFS counts the first mention of the product only.

Thus, I know that there are only 2 products that meet my criteria.

Count in Google Sheets with multiple criteria — OR logic

When only one of all criteria is enough, you’d better use several COUNTIF functions.

Example 1. COUNTIF + COUNTIF

Let's count the number of sales of black and white chocolate. To do that, enter the following formula in B2:

=COUNTIF(D6:D16,"*Milk*") + COUNTIF(D6:D16,"*Dark*")

Tip. I use asterisk (*) to ensure that the words "dark" and "milk" will be counted no matter where they are in the cell — at the beginning, in the middle, or at the end.

Tip. You can always introduce cell references to your formulas. See how it looks on the screenshot below in B3, the result remains the same:
=COUNTIF(D6:D16,A2) + COUNTIF(D6:D16,A3) COUNTIF with multiple criteria.

Example 2. COUNTIF — COUNTIF

Now, I am going to count the number of total sales between 200 and 400: Sales between 200 and 400.

I take the number of totals under 400 and subtract the number of total sales under 200 using the next formula:

=C0UNTIF(F6:F16,"<=400") — COUNTIF(F6:F16,"<=200")

The formula returns the number of sales more than 200 but less than 400.

If you decide to reference A2 and A3 that contain the criteria, the formula will be a bit simpler:

=COUNTIF(F6:F16, A3) — COUNTIF(F6:F16, A2)

A3 cell will have "<=200" criteria, while A4 — "<=400". Put formulas into B2 and B3 and make sure that the result doesn't change — 3 sales over the needed range.

COUNTIF Google Sheets for blank and non-blank cells

With the help of COUNTIF, we can also count the number of blank or non-blank cells within some range.

Let's suppose that we successfully sold the product and marked it as "Paid". If the customer declined the goods, we write zero (0) in the cell. If the deal wasn't closed, the cell remains empty.

To count non-blank cells with any value, use the following:

=COUNTIF(F6:F16,"<>")

or

=COUNTIF(F6:F16,A2)

To count the number of empty cells, make sure to put the COUNTIF formula in the following way:

=COUNTIF(F6:F16,"")

or

=COUNTIF(F6:F16,A3)

The number of cells with a textual value is counted like this:

=COUNTIF(F6:F16,"*")

or

=COUNTIF(F6:F16,A4)

Screenshot below shows that A2, A3, and A4 cells include our criteria: How to count blank or non-blank cells.

Thus, I have 4 closed deals, 3 of which were paid for and 7 of which have no markings yet and, consequently, are not closed.

COUNTIF and conditional formatting

There is one interesting opportunity that Google Sheets offer — to change the cell's format (like its color) depending on some criteria. For example, we can highlight the values that appear more often in green.

COUNTIF function can play a small part here as well.

Select the range of the cells that you want to format in some special way. Click Format -> Conditional formatting...

In the Format cells if... drop-down list choose the last option Custom formula is, and enter the following formula into the appeared field:

=COUNTIF($B$8:$B$38,B8)/COUNTIF($B$8:$B$38,"*")>0.3

It means that the condition will be answered if the value from B8 appears within B8:B38 in more than 30% of cases: Changing formatting with COUNTIF.

In a similar way, we add two more formatting rule criteria — if the cell value appears more often than in 25% of cases and more often than in 20%:

=COUNTIF($B$8:$B$38,B8)/COUNTIF($B$8:$B$38,"*")>0.25

=COUNTIF($B$8:$B$38,B8)/COUNTIF($B$8:$B$38,"*")>0.2

Keep in mind that the first criterion will be checked beforehand, and if it's met, the rest won't apply. That is why you'd better start with the most unique values moving to the most common ones. If the cell value doesn't meet any criteria, its format will remain intact. Conditional format rules and COUNTIF.

You can see that the colour of the cells has changed according to our criteria.

To make sure, we also counted the frequency of some values in C2:C5 using the COUNTIF function. The results confirm that COUNTIF in formatting rule was applied correctly.

Tip. Find more examples on how to count & highlight duplicates in Google Sheets.

All these function examples give us a clear understanding of how Google Spreadsheet COUNTIF offers multiple opportunities to work with the data in a most efficient way.

COUNTIF color in Google Sheets

One task that gains popularity is counting cells by their color. Though there's no native Google Sheets function to do that, you can still achieve the result without coding. All you need is an add-on from the Google Workspace Marketplace: Function by Color.

Google Workspace Marketplace badge

Using the add-on, you will:

Video: How to count colored cells in Google Sheets


Install Function by Color from Google Store to follow the examples along or to try it on your own cases. Let me know how it goes in the comments section below! :)

Google Workspace Marketplace badge

Table of contents

387 comments

  1. Hi!

    Thank you very much for this resource and the amazing job you are doing!

    I need your help. I would like to count a number of words in a cell (or a range of cells) but I need to exclude the counting of certain words that are irrelevant (say "a", "the", "and", "an"). The range is the same (say B2:B16), but the criteria of exclusion are multiple. How can I do it without repeating the range every time (in fact, there are a lot more the criteria of exclusion than the four in the example above).

    Thank you in advance.

    • Hi Helen,

      Thank you for your lovely words!

      As for your task, please share an editable copy of your spreadsheet with us: support@apps4gs.com

      I'll check the data you have and see where your criteria are and how many of them you may have. This will help me find the best solution.

      • Dear Natalia,

        Thank you for your reply. I have sent you an example of a neutral text in a Google Spreadsheet and a little comment. Looking forward to reading your comment. Thank you in advance,
        Helen

        • Dear Helen,

          Thank you for sharing your spreadsheet. Here's a formula to count all those special words you mentioned:
          =COUNT(ArrayFormula(FIND("#", REGEXREPLACE(SPLIT(B3, {" ", ",", ";"}), "^(and|the|a|at|in)$", "#"))))

          Subtract this from your total word count and you're good to go :)

          I entered the resulting formulas to column E in your spreadsheet, have a look.

  2. In the example below, how would I count the number of shirts of each style, size and color?

    Style Size Color
    Women's XL Black
    Women's XL Black
    Men's XL White
    Men's 2XL White
    Women's XL Green
    Men's L Green
    Men's 3XL Black
    Mens XL Green
    Men's XL Black
    Women's M Yellow
    Women's M Black
    Women's XL White
    Women's XL Green
    Men's XL Black
    Women's L Green
    Women's XL Green
    Men's 3XL Green

    • So trying to add the agent from Column A (9 agents total) to this formula: =ARRAYFORMULA(sum(COUNTIFS(AS2:AS11,{"Yes","VM","No"})))

  3. Hi,

    I have calculated how many completed tasks are done in the current day or current month. See below:

    =COUNTIFS('Completed Cases'!K2:K5000,">"&TODAY()-1,'Completed Cases'!K2:K5000,"="&EOMONTH(TODAY(),-1)+1,'Completed Cases'!K2:K5000,"<"&EOMONTH(TODAY(),0)+1)

    I now need to work out how to break that down and count if the outcome was option A or option B from a different column. What is the best way to do this please?

    • Hi Ben,

      Am I getting it right that some results from K belong to option A from another column and some results belong to B? If so and you'd like to get two different results based on that another column as well, you just neet to have two COUNTIFS formulas where one of the conditions will be for that another column:
      =COUNTIFS('Completed Cases'K2:K5000, ">"&TODAY()-1, 'Completed Cases'!K2:K5000, "="&EOMONTH(TODAY(),-1)+1, 'Completed Cases'!K2:K5000, "<"&EOMONTH(TODAY(),0)+1, 'Completed Cases'!ANOTHER_COLUMN, "option A")

      If that's not really what you need, please try to describe the desired outcome in more detail.

    • Hi Jack,

      you should use COUNTIFS for your task. I've put an example formula in E2 since it's the only row from your task I understand clearly. Please adjust this formula to use in other rows as you need.

      • Hi, I had managed it just before your replies and had sent my solution but it appears it did not go through?

        Thanks anyway

  5. Hi, I have a sheet with actions on.

    On another sheet, I want the number of actions where, on the actions sheet:
    - value in column C is the value in column C of the count sheet (e.g. where C9 = C9)
    - value in column H of the action sheet is "Strike"
    - value in column J of the action sheet is "Active"

    How would I achieve this?
    Thanks

    • Did it now, thanks anyway.

      =COUNTIFS('Log Sheet'!C9:C,C9,'Log Sheet'!H9:H,"Strike",'Log Sheet'!J9:J,"Active")

  6. Hi,
    I'm trying to do something similar. Let's pretend on your sample sheet that you had in Column E another list of products. Some said Dark Chocolate, Milk Chocolate, Extra Dark Chocolate, but you also had just plain Chocolate. etc.
    I want to be able to count all of the occurrences of Dark Chocolate where (plain) Chocolate would not be counted.

    (In my sheet, I need to count all of the occurrences of English 1 separately from all of the occurrences of Honors English 1.
    I can get an exact count of all of the "Honors English 1", but anytime I try to count "English 1", because those words also appear in "Honors English 1", it counts both "English 1" and "Honors English 1".

    I've linked to a sample sheet: https://docs.google.com/spreadsheets/d/10x13hlqSthvxByNrAqbMSOIM_-VLU6KZ4MdVHkSWa_k/edit?usp=sharing

    • Hi Elizabeth,

      Thank you for sharing the sample right away. I entered the formulas into column J, please take a look. Here's a sample formula:
      =COUNTIF($B$2:$E$11,G2)

  7. Hi, is there any possiblitiy for me to use COUNTIFS to count specific text from cell that has Data Validation : drop down list.

    • Hi Firdauz,

      Do you want to take cells with data validation into account or do you want to count text in all items within one data validation in a cell?

  8. How to make a countif to find out amount more than 0:03:00 but lower than 0:04:00

  9. Hi! I created a self-assessment in Google Forms that I'm trying to score with a simple formula. All questions on the assessment have checkbox options for each item, so multiple options can be selected. For example...

    For question 1, I choose Options A, B, and D. Option A is worth 1 point, Option B is worth 2 points, and option D is worth 4 points. What formula will take a cell that says 'A, B, D' and calculate 7?

    Thanks in advance!

    • I figured it out this morning. I was overthinking it.

      I used =(COUNTIF(cell,"*A*")*1)+(COUNTIF(cell,"*B*")*2)+(COUNTIF(cell,"*C*")*3)+(COUNTIF(cell,"*D*")*4)...

  10. How do i do countif with the power formula?

  11. Hi there,
    I am struggling with conditional formatting using custom formula. I want to do a simple formatting into red for all cells in one column that are duplicates (excluding the first occurrence). Following some instructions on the Internet, I select the column (it's formatted as plain text and it only contains numbers) - the range would be A3:A500 (A1 nad A2 are headers) and then Format cells if -> custom formula -> =countif($A$3:$A$500,A3)>1. I also try without $ sign. I also try with (A:A, A3)>1. The problem is that after I have written =countif, no matter what I put there - be it the bracket or whatever - the system highlight this in red and always shows "Invalid formula". Literally, into the custom formula field I can put only: =countif .
    I am puzzled and desperate. I have tried on different data in different sheets - same issue everywhere... I would appreciate any help on this matter.

    • Hi Ela,

      First please try to format your data as numbers, not text, before trying to apply the conditional formatting.

      If this doesn't help, for me to be able to help you, please share an editable copy of your spreadsheet with us (support@apps4gs.com) with 2 sheets: (1) a shortened copy of your source data (2) the result you expect to get. I kindly ask you to shorten the tables to 10-20 rows. If you have confidential information there, you can replace it with some irrelevant data, just keep the format.

      Note. We keep that Google account for file sharing only and don't monitor its Inbox. Please do not email there. Once you share the file, just confirm by replying to this comment.

  12. I have multiple conditional formatting in a google spreadsheet. An example is: =AND($B2="In",COUNTIFS($D:$D,$D2,$B:$B,"In")=6)
    This will look at multiple cells and highlight a row based upon the criteria. Each conditional formatting is the same just the number at the end changes which, in turn, highlights the cell a different color. I need to add in another factor to this formatting that if something is column E is indicated as either MEDICAL APPOINTMENT or ILLNESS that is does not count as one of the quantities.
    For example is someone has 5 that are marked "In" generally it would highlight all that person's lines purple; however, if 1 of those "INs" are due to a medical appointment or illness it needs to not be counted as 5 INs". but 4 "INs" and highlighted a different color

    • Hello Shawna,

      For me to be able to help you, please share an editable copy of your spreadsheet with us (support@apps4gs.com) with 2 sheets: (1) a shortened copy of your source data (2) the result you expect to get. I kindly ask you to shorten the tables to 10-20 rows. If you have confidential information there, you can replace it with some irrelevant data, just keep the format.

      Note. We keep that Google account for file sharing only and don't monitor its Inbox. Please do not email there. Once you share the file, just confirm by replying to this comment.

  13. Hello.

    I have a series of cells each containing a 0 or a 1. I would like to count the number of cells containing a 1, but would the count to stop when the first 0 is encountered.

    For example, this row:
    1 1 1 1 0 1 1 0 0 1 0 0 0
    should produce the count 4.

    And this one:
    1 1 0 1 1 1 1 1 0 1 1 0
    should produce the count 2.

    Can this be done with COUNTIF (or perhaps with some other function)?

    Best wishes

    • Hello DB,

      Assuming your numbers are in A1:M1, here's a formula to try:
      =IFERROR(LEN(LEFT(JOIN("",A1:M1),FIND("0",JOIN("",A1:M1))-1)),COUNT(A1:M1))

  14. Hello!

    I am trying to count how many values in a column are bigger than the corresponding values in another. Specifically, I have one column that lists the scores of a pre-test that students take at the beginning of class and a list of the student's scores on the test they take at the end of the class. I want to count how many of those scores improved, how would I do that?

    Thank you!

  15. Hi! Can you help in writing a countif function where the cell does not contain "---"

  16. I wonder whether the following is possible.

    In TAB1, column A has a number of people's names. Column B onwards is then made up of dates and each column records attendance the attendance of the names in column A

    In TAB2, column A has the same names. I want Column B to then repeat whatever is in the cell of today's column in TAB1, so if H1 has today's date, then it will give me the attendance of the named person (in A9) in B9 in TAB2.

    How do I get column B in Tab2 to pick up the relevant cell from today's column? Is there an appropriate formula?

    Thanks in advance for anyone who is able to help!

    • Hello Jon,

      If I understand you correctly, you can try to use IF along with the VLOOKUP function.

      In case you're not sure how to use them exactly, please share a small sample spreadsheet with us (support@apps4gs.com) with your sheets and the example you want to get (the result sheet is of great importance and often gives us a better understanding than any text description). I kindly ask you to shorten the tables to 10-20 rows.

      Note. We keep that Google account for file sharing only, please do not email there. Once you share the file, just confirm by replying to this comment.

      I'll look into your task and do my best to help.

  17. I was wondering given your example sheet above.

    If I want to count the amount of Dark Chocolate sold fx.

    so sum up all numbers in column total sales where column Product = "Dark Chocolate"

  18. Thank you for monitoring this channel and helping us out.

    How can I use COUNTIFS and OR

    =COUNTIFS(E35:T35, "Z" OR COUNTIFS(E35:T35, "1" )

  19. Hi I want to count only if two criteria are met.
    EG Cells in Range A14:A35 = A and Cells in range C:14:C35 = W

    I only want a count of 1 if both conditions are met

    Thanks

    James

  20. Hi there,

    I was wondering if there was a way to count if one cell is greater than another range. For example I have a set of scores for students in P column (say range P3:P80) and a second set of score in Q column (Q3:Q80). I want to count the scores in Q column IF they are greater than the initial scores, e.g. I want to count the number of students who got a higher score in the second set of results.

    Cheers,
    Emma

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)