by The tutorial explains the essence of Excel logical functions AND, OR, XOR and NOT and provides formula examples that demonstrate their common and inventive uses.
Last week we tapped into the insight of Excel logical operators that are used to compare data in different cells. Today, you will see how to extend the use of logical operators and construct more elaborate tests to perform more complex calculations. Excel logical functions such as AND, OR, XOR and NOT will help you in doing this.
Excel logical functions - overview
Microsoft Excel provides 4 logical functions to work with the logical values. The functions are AND, OR, XOR and NOT. You use these functions when you want to carry out more than one comparison in your formula or test multiple conditions instead of just one. As well as logical operators, Excel logical functions return either TRUE or FALSE when their arguments are evaluated.
The following table provides a short summary of what each logical function does to help you choose the right formula for a specific task.
| Function | Description | Formula Example | Formula Description |
| AND | Returns TRUE if all of the arguments evaluate to TRUE. | =AND(A2>=10, B2<5) |
The formula returns TRUE if a value in cell A2 is greater than or equal to 10, and a value in B2 is less than 5, FALSE otherwise. |
| OR | Returns TRUE if any argument evaluates to TRUE. | =OR(A2>=10, B2<5) |
The formula returns TRUE if A2 is greater than or equal to 10 or B2 is less than 5, or both conditions are met. If neither of the conditions it met, the formula returns FALSE. |
| XOR | Returns a logical Exclusive Or of all arguments. | =XOR(A2>=10, B2<5) |
The formula returns TRUE if either A2 is greater than or equal to 10 or B2 is less than 5. If neither of the conditions is met or both conditions are met, the formula returns FALSE. |
| NOT | Returns the reversed logical value of its argument. I.e. If the argument is FALSE, then TRUE is returned and vice versa. | =NOT(A2>=10) |
The formula returns FALSE if a value in cell A1 is greater than or equal to 10; TRUE otherwise. |
In additions to the four logical functions outlined above, Microsoft Excel provides 3 "conditional" functions - IF, IFERROR and IFNA.
Excel logical functions - facts and figures
- In arguments of the logical functions, you can use cell references, numeric and text values, Boolean values, comparison operators, and other Excel functions. However, all arguments must evaluate to the Boolean values of TRUE or FALSE, or references or arrays containing logical values.
- If an argument of a logical function contains any empty cells, such values are ignored. If all of the arguments are empty cells, the formula returns #VALUE! error.
- If an argument of a logical function contains numbers, then zero evaluates to FALSE, and all other numbers including negative numbers evaluate to TRUE. For example, if cells A1:A5 contain numbers, the formula =AND(A1:A5) will return TRUE if none of the cells contains 0, FALSE otherwise.
- A logical function returns the #VALUE! error if none of the arguments evaluate to logical values.
- A logical function returns the #NAME? error if you've misspell the function's name or attempted to use the function in an earlier Excel version that does not support it. For example, the XOR function can be used in Excel 2016 and 2013 only.
- In Excel 2007 and higher, you can include up to 255 arguments in a logical function, provided that the total length of the formula does not exceed 8,192 characters. In Excel 2003 and lower, you can supply up to 30 arguments and the total length of your formula shall not exceed 1,024 characters.
Using the AND function in Excel
The AND function is the most popular member of the logic functions family. It comes in handy when you have to test several conditions and make sure that all of them are met. Technically, the AND function tests the conditions you specify and returns TRUE if all of the conditions evaluate to TRUE, FALSE otherwise.
The syntax for the Excel AND function is as follows:
Where logical is the condition you want to test that can evaluate to either TRUE or FALSE. The first condition (logical1) is required, subsequent conditions are optional.
And now, let's look at some formula examples that demonstrate how to use the AND functions in Excel formulas.
| Formula | Description |
=AND(A2="Bananas", B2>C2) |
Returns TRUE if A2 contains "Bananas" and B2 is greater than C2, FALSE otherwise. |
=AND(B2>20, B2=C2) |
Returns TRUE if B2 is greater than 20 and B2 is equal to C2, FALSE otherwise. |
=AND(A2="Bananas", B2>=30, B2>C2) |
Returns TRUE if A2 contains "Bananas", B2 is greater than or equal to 30 and B2 is greater than C2, FALSE otherwise. |
Excel AND function - common uses
By itself, the Excel AND function is not very exciting and has narrow usefulness. But in combination with other Excel functions, AND can significantly extend the capabilities of your worksheets.
One of the most common uses of the Excel AND function is found in the logical_test argument of the IF function to test several conditions instead of just one. For example, you can nest any of the AND functions above inside the IF function and get a result similar to this:
=IF(AND(A2="Bananas", B2>C2), "Good", "Bad")
For more IF / AND formula examples, please check out his tutorial: Excel IF function with multiple AND conditions.
An Excel formula for the BETWEEN condition
If you need to create a between formula in Excel that picks all values between the given two values, a common approach is to use the IF function with AND in the logical test.
For example, you have 3 values in columns A, B and C and you want to know if a value in column A falls between B and C values. To make such a formula, all it takes is the IF function with nested AND and a couple of comparison operators:
Formula to check if X is between Y and Z, inclusive:
=IF(AND(A2>=B2,A2<=C2),"Yes", "No")
Formula to check if X is between Y and Z, not inclusive:
=IF(AND(A2>B2, A2<C2),"Yes", "No")
As demonstrated in the screenshot above, the formula works perfectly for all data types - numbers, dates and text values. When comparing text values, the formula checks them character-by-character in the alphabetic order. For example, it states that Apples in not between Apricot and Bananas because the second "p" in Apples comes before "r" in Apricot. Please see Using Excel comparison operators with text values for more details.
As you see, the IF /AND formula is simple, fast and almost universal. I say "almost" because it does not cover one scenario. The above formula implies that a value in column B is smaller than in column C, i.e. column B always contains the lower bound value and C - the upper bound value. This is the reason why the formula returns "No" for row 6, where A6 has 12, B6 - 15 and C6 - 3 as well as for row 8 where A8 is 24-Nov, B8 is 26-Dec and C8 is 21-Oct.
But what if you want your between formula to work correctly regardless of where the lower-bound and upper-bound values reside? In this case, use the Excel MEDIAN function that returns the median of the given numbers (i.e. the number in the middle of a set of numbers).
So, if you replace AND in the logical test of the IF function with MEDIAN, the formula will go like:
=IF(A2=MEDIAN(A2:C2),"Yes","No")
And you will get the following results:
As you see, the MEDIAN function works perfectly for numbers and dates, but returns the #NUM! error for text values. Alas, no one is perfect : )
If you want a perfect Between formula that works for text values as well as for numbers and dates, then you will have to construct a more complex logical text using the AND / OR functions, like this:
=IF(OR(AND(A2>B2, A2<C2), AND(A2<B2, A2>C2)), "Yes", "No")
Using the OR function in Excel
As well as AND, the Excel OR function is a basic logical function that is used to compare two values or statements. The difference is that the OR function returns TRUE if at least one if the arguments evaluates to TRUE, and returns FALSE if all arguments are FALSE. The OR function is available in all versions of Excel 2016 - 2000.
The syntax of the Excel OR function is very similar to AND:
Where logical is something you want to test that can be either TRUE or FALSE. The first logical is required, additional conditions (up to 255 in modern Excel versions) are optional.
And now, let's write down a few formulas for you to get a feel how the OR function in Excel works.
| Formula | Description |
=OR(A2="Bananas", A2="Oranges") |
Returns TRUE if A2 contains "Bananas" or "Oranges", FALSE otherwise. |
=OR(B2>=40, C2>=20) |
Returns TRUE if B2 is greater than or equal to 40 or C2 is greater than or equal to 20, FALSE otherwise. |
=OR(B2=" ", C2="") |
Returns TRUE if either B2 or C2 is blank or both, FALSE otherwise. |
As well as Excel AND function, OR is widely used to expand the usefulness of other Excel functions that perform logical tests, e.g. the IF function. Here are just a couple of examples:
IF function with nested OR
=IF(OR(B2>30, C2>20), "Good", "Bad")
The formula returns "Good" if a number in cell B3 is greater than 30 or the number in C2 is greater than 20, "Bad" otherwise.
Excel AND / OR functions in one formula
Naturally, nothing prevents you from using both functions, AND & OR, in a single formula if your business logic requires this. There can be infinite variations of such formulas that boil down to the following basic patterns:
=AND(OR(Cond1, Cond2), Cond3)
=AND(OR(Cond1, Cond2), OR(Cond3, Cond4)
=OR(AND(Cond1, Cond2), Cond3)
=OR(AND(Cond1,Cond2), AND(Cond3,Cond4))
For example, if you wanted to know what consignments of bananas and oranges are sold out, i.e. "In stock" number (column B) is equal to the "Sold" number (column C), the following OR/AND formula could quickly show this to you:
=OR(AND(A2="bananas", B2=C2), AND(A2="oranges", B2=C2))
OR function in Excel conditional formatting
=OR($B2="", $C2="")
The rule with the above OR formula highlights rows that contain an empty cell either in column B or C, or in both.
For more information about conditional formatting formulas, please see the following articles:
Using the XOR function in Excel
In Excel 2013, Microsoft introduced the XOR function, which is a logical Exclusive OR function. This term is definitely familiar to those of you who have some knowledge of any programming language or computer science in general. For those who don't, the concept of 'Exclusive Or' may be a bit difficult to grasp at first, but hopefully the below explanation illustrated with formula examples will help.
The syntax of the XOR function is identical to OR's :
The first logical statement (Logical 1) is required, additional logical values are optional. You can test up to 254 conditions in one formula, and these can be logical values, arrays, or references that evaluate to either TRUE or FALSE.
In the simplest version, an XOR formula contains just 2 logical statements and returns:
- TRUE if either argument evaluates to TRUE.
- FALSE if both arguments are TRUE or neither is TRUE.
This might be easier to understand from the formula examples:
| Formula | Result | Description |
=XOR(1>0, 2<1) |
TRUE | Returns TRUE because the 1st argument is TRUE and the 2nd argument is FALSE. |
=XOR(1<0, 2<1) |
FALSE | Returns FALSE because both arguments are FALSE. |
=XOR(1>0, 2>1) |
FALSE | Returns FALSE because both arguments are TRUE. |
When more logical statements are added, the XOR function in Excel results in:
- TRUE if an odd number of the arguments evaluate to TRUE;
- FALSE if is the total number of TRUE statements is even, or if all statements are FALSE.
The screenshot below illustrates the point:
If you are not sure how the Excel XOR function can be applied to a real-life scenario, consider the following example. Suppose you have a table of contestants and their results for the first 2 games. You want to know which of the payers shall play the 3rd game based on the following conditions:
- Contestants who won Game 1 and Game 2 advance to the next round automatically and don't have to play Game 3.
- Contestants who lost both first games are knocked out and don't play Game 3 either.
- Contestants who won either Game 1 or Game 2 shall play Game 3 to determine who goes into the next round and who doesn't.
A simple XOR formula works exactly as we want:
=XOR(B2="Won", C2="Won")
And if you nest this XOR function into the logical test of the IF formula, you will get even more sensible results:
=IF(XOR(B2="Won", C2="Won"), "Yes", "No")
Using the NOT function in Excel
The NOT function is one of the simplest Excel functions in terms of syntax:
You use the NOT function in Excel to reverse a value of its argument. In other words, if logical evaluates to FALSE, the NOT function returns TRUE and vice versa. For example, both of the below formulas return FALSE:
=NOT(TRUE)
=NOT(2*2=4)
Why would one want to get such ridiculous results? In some cases, you might be more interested to know when a certain condition isn't met than when it is. For example, when reviewing a list of attire, you may want to exclude some color that does not suit you. I'm not particularly fond of black, so I go ahead with this formula:
=NOT(C2="black")
As usual, in Microsoft Excel there is more than one way to do something, and you can achieve the same result by using the Not equal to operator: =C2<>"black".
If you want to test several conditions in a single formula, you can use NOT in conjunctions with the AND or OR function. For example, if you wanted to exclude black and white colors, the formula would go like:
=NOT(OR(C2="black", C2="white"))
And if you'd rather not have a black coat, while a black jacket or a back fur coat may be considered, you should use NOT in combination with the Excel AND function:
=NOT(AND(C2="black", B2="coat"))
Another common use of the NOT function in Excel is to reverse the behavior of some other function. For instance, you can combine NOT and ISBLANK functions to create the ISNOTBLANK formula that Microsoft Excel lacks.
As you know, the formula =ISBLANK(A2) returns TRUE of if the cell A2 is blank. The NOT function can reverse this result to FALSE: =NOT(ISBLANK(A2))
And then, you can take a step further and create a nested IF statement with the NOT / ISBLANK functions for a real-life task:
=IF(NOT(ISBLANK(C2)), C2*0.15, "No bonus :(")
Translated into plain English, the formula tells Excel to do the following. If the cell C2 is not empty, multiply the number in C2 by 0.15, which gives the 15% bonus to each salesman who has made any extra sales. If C2 is blank, the text "No bonus :(" appears.
In essence, this is how you use the logical functions in Excel. Of course, these examples have only scratched the surface of AND, OR, XOR and NOT capabilities. Knowing the basics, you can now extend your knowledge by tackling your real tasks and writing smart elaborate formulas for your worksheets.
567 comments
This helped. I wanted to give scores from result based on percentage. Thanks
=IF(AND(J5>=100%,J5=121%,J5=141%,J5200%,1,IF(J5<100%,5,"")))))
I need help using the IF function, to work out the score range
High =9-13
Moderate =5-8
Low 0-4
Thank you
=IF(AND(A1>=9,A1=5,A1<=8),"Moderate",IF(A1<=4,"Low","")))
Hello,
I need help with using the IF function. In the example that my instructor uses, it looks like this:
=IF([@[Billable Hours]]>4, "highly billable", "low billable"}
when he clicks on cell D2 (the title is called billable hours)it actually shows up like this, however when i click on the cell D2 its just coming up as D2 not as ([@[Billable Hours]]
If i leave the formula as saying D2 verses [@[Billable Hours]] i notice it doesnt come out right. How to I get the formula to recognize the title in the spreadsheet?
thank you
Hi!
the formula is if(and(d2="mkt",e2="manager"),20000,18000),if(and(d2="mkt",e2="officer"),15000,13000)where is worng plz help me.
shukriya
I'm stuck. I have a sheet with a cell, D7, that can have "HM", "WH", "CM" or "HOTH" in it. Then there is a second cell, F7 that can be blank or have an "x" in it. What I need is a formula, lets say in AA7, that will return a "1" if D7 has "HM" and there is an "x" in F7. But it needs to return "2" if D7 has "WH" and there is an "x" in F7. So on and so forth with "CM" returning "3" and "HOTH" returning "4", but remaining blank if there is no "x" in F7. Please help.
I am trying to get get a formula to work for the below can anyone help.
In column c I have either a yes or no answer I'm column d I want to have it that if any of these 5cells in column c have a no answer this cell shows 0% and only if all cells show a yes answer then it shows 25% for all cells together not individually.
Hello,
I want to find out a solution for a simple problem. my query is I have to find out a solution with if statement. the condition is i have one rows and three columns, in that first row only numeric values will be there, in 2nd row it has only either yes or no only, 3rd one will be empty one.In the 3rd column i have display if 2nd columns has yes means it has print numeric value of 1st or else it has to display zero in 3rd. please provide a solutions as soon as possible.
Thanks and Regards,
D.Rameshkumar
Column A includes customers who order in 2015, and column B customers who ordered in 2016. I want to have customers who ordered in 2015 but not in 2016. Is there a formula?
Dear All,
I want to combine the below formula in one formula, how do I do that?
IF(A1="Male", IF(B1>18, "Man", "Boy"), "Boy")
and
IF(A2="Female", IF(B2>18, "Woman", "Girl"), "Girl")
Thanks in advance :-)
create a table with 2 columns and 10 rows in excel and give the name to the first column "color" 2nd column "Green Or Red" .If the First Column Contains green or red value the second column should return true otherwise false.
[Hint:Use Logical Function]
Madam Plzzzzz Solve This One I just want know How Could You Will Do this
I can not see my yesterday post about if formula!
thanks
Hello Sevelana
there is a formula uses for blan means if(isblank( A2,"",..........but it calculate the 0 is nothing it does not shown as blank formula cell.
thanks for feedback
Hi
I want to use a formula like =if A2>01012017,A2<01022017,"Jan",...
thanks for your help
Hello all,
I have a requirement that I am not sure how to handle in Excel.
Here is my scenario
Total Price (this takes the # of Apartment Units and multiplies by the Per Unit Price) OR...I can manually enter in the Total Price and it will then automatically calculate the Per Unit Price.
I want to be able to enter in either field and have the other field calculated AND I don't want to lose the formulas I have in the cells. So, I could change one field and calculate the other field and then change the other field and have the other field calculated.
Hi Svetlana,
I have tried to find the many formula however i am not getting success, If you can help me out that is great.
I have a query I am an admin and i want to prepare an attendance however i am not able to figure out which formula to apply, If any one can help me it that would be great.
My company has a Rule that those who are coming before 10:00 we are giving levi, Those check in time between 10:01 to 10:30 are Late and after 10:30 it is halfday and same way those leaving in between 18:00 - 18:30 marked as early check out, Everyone has to check out after 18:31
Those who are meeting the criteria of coming before 10:00 and leaving after 18:30 will be marked present.
Those who are late by 10:00-10:30 and check out after 18:31 marked Late
Those who are coming after 10:31 and leaing after 18:31 marked as halfday.
Below is the biometric record from this i have to prepare attendance of more then 500 employee which is too tedious.
Help me out i will be greatful.
Att. Date InTime OutTime Shift S. InTime S. OutTime
01-Jan-2017 NS 00:00 00:00
02-Jan-2017 09:58 18:56 GS 09:30 18:30
03-Jan-2017 10:13 18:39 GS 09:30 18:30
04-Jan-2017 09:46 18:30 GS 09:30 18:30
05-Jan-2017 09:43 18:59 GS 09:30 18:30
As a Charity we have many clients. The spread sheet shows name and age in adjacent cells the next cells show catorgary of age spans ie 1-20, 21-40, 41-60, 61-80, 80-100. Our funder is asking us to show a score of 1 in appropriate catorgary cell corresponding to age. Do I use IF's & and's & or's and would be obliged if you can help...many thanks ...mike
Hi, want to check error in the formula: if(B5="High", if(C5="High",(5+5)/2,if(C5="Medium", (5+3)/2, (5+1)/2)), if(B5="Medium", if(C5="High", (3+5)/2, if(C5="Medium", (3+3)/2, (3+1)/2))), if (B5="Low", if(C5="High",(1+5)/2, if(C5="Medium", (1+3)/2, (1+1)/2)))
the purpose is to find out average of two values whose rating could be high, medium & low and weightage assigned in High = 5, Medium = 3 & Low = 1. Eg. if the combination of the two values if Medium & High, then the average should be (3+5) /2 = 4.
Kindly guide.
Hello!
I am trying to right a nested IF statement and no luck. Each of the below statements works individually, but when I try using them together I am getting the #Value error. Any help would be greatly appreciated!
=IF(AND(R4=Q4,T4=S4), "Match", "No Match"),IF(AND(T4=S4,R4Q4),"Campaign No Match",""),IF(AND(R4=Q4,T4S4),"Adgroup No Match","")
Context:
If values columns R and Q match as well as values in columns T and S, then the value should show "Match"
If values in columns T and S match, but values in columns R and Q do NOT match then the value should show "Campaign No Match"
If values in columns R and Q do match, but values in T and S do NOT match then the value should show "Adgroup No match"
thanks in advance
Hi there,
I have a student that is doing research and is looking for a formula with the following conditions:
Context: Each patient may have 3 or more rows of data. He has color coordinated rows that have date of knee surgery as one color and date of knee injection as another color in separate rows.
Looking for a function that will look at each patient and if either of the injection dates were before the surgery date, then generate result of TRUE.
I know the or statement is simple. But need the function to know to compare within the same patient and to compare the Injection fields that are in the white rows to the surgery fields in the green rows.
Thanks in advance
I sorted the holiday lookup problem out using the vlookup function. Now I face another problem, hopefully the last.
In my spreadsheet the information gives a final result of the hours worked. The company takes this figure and pays 195 hours as normal time and the remainder as overtime, i.e. 203:00 normal hours = 195:00 (threshold hours and 8:00 (overtime hours). So this 195 hours is like a threshold value - if 195:00 is reached then the remainder becomes overtime. But here is the thing that also throws problems my way, if the amount of hours worked is below 195:00 then that value needs to be displayed in the threshold hours cell as well as 0:00 in the overtime cell, i.e. Threshold hours 190:00 -- Overtime hours 0:00. I wish I could upload my spreadsheet.
Please help me
Nick