CONCATENATE in Excel: combine text strings, cells and columns

In this article, you will learn various ways to concatenate text strings, numbers and dates in Excel using the CONCATENATE function and "&" operator. We will also discuss formulas to combine individual cells, columns and ranges.

In your Excel workbooks, the data is not always structured according to your needs. Often you may want to split the content of one cell into individual cells or do the opposite - combine data from two or more columns into a single column. Common examples are joining names and address parts, combining text with a formula-driven value, displaying dates and times in the desired format, to name a few.

In this tutorial, we are going to explore various techniques of Excel string concatenation, so you can choose the method best suited for your worksheets.

What is "concatenate" in Excel?

In essence, there are two ways to combine data in Excel spreadsheets:

  • Merging cells
  • Concatenating cells' values

When you merge cells, you "physically" join two or more cells into a single cell. As a result, you have one larger cell that is displayed across multiple rows and/or columns.

When you concatenate cells in Excel, you combine only the contents of those cells. In other words, concatenation in Excel is the process of joining two or more values together. This method is often used to combine a few pieces of text that reside in different cells (technically, these are called text strings or simply strings) or insert a formula-calculated value in the middle of some text.

The following screenshot demonstrates the difference between these two methods: Merge and concatenate in Excel

Merging cells in Excel is the subject of a separate article, and in this tutorial, we'll discuss the two main ways to concatenate strings in Excel - by using the CONCATENATE function and the concatenation operator (&).

Excel CONCATENATE function

The CONCATENATE function in Excel is used to join different pieces of text together or combine values from several cells into one cell.

The syntax of Excel CONCATENATE is as follows:

CONCATENATE(text1, [text2], …)

Where text is a text string, cell reference or formula-driven value.

The CONCATENATE function is supported in all versions of Excel 365 - 2007.

For example, to concatenate the values of B6 and C6 with a comma, the formula is:

=CONCATENATE(B6, ",", C6)

More examples are shown in the image below: Excel CONCATENATE function

Note. In Excel 365 - Excel 2019, the CONCAT function is also available, which is a modern successor of CONCATENATE with exactly the same syntax. Although the CONCATENATE function is kept for backward compatibility, Microsoft does not give any promises that it will be supported in future versions of Excel.

Using CONCATENATE in Excel - things to remember

To ensure that your CONCATENATE formulas always deliver the correct results, remember the following simple rules:

  • Excel CONCATENATE function requires at least one "text" argument to work.
  • In one formula, you can concatenate up to 255 strings, a total of 8,192 characters.
  • The result of the CONCATENATE function is always a text string, even when all of the source values are numbers.
  • Unlike the CONCAT function, Excel CONCATENATE does not recognize arrays. Each cell reference must be listed separately. For example, you should use CONCATENATE(A1, A2, A3) and not CONCATENATE(A1:A3).
  • If any of the arguments is invalid, the CONCATENATE function returns a #VALUE! error.

"&" operator to concatenate strings in Excel

In Microsoft Excel, the ampersand sign (&) is another way to concatenate cells. This method comes in very handy in many scenarios since typing an ampersand is much faster than typing the word "concatenate" :)

For example, to concatenate two cell values with a space in-between, the formula is:

=A2&" "&B2

How to concatenate in Excel - formula examples

Below you will find a few examples of using the CONCATENATE function in Excel.

Concatenate two or more cells without separator

To combine the values of two cells into one, you use the concatenation formula in its simplest form:

=CONCATENATE(A2, B2)

Or

=A2&B2

Please note that the values will be knit together without any delimiter like in the screenshot below.

To concatenate multiple cells, you need to supply each cell reference individually, even if you are combining contiguous cells. For example:

=CONCATENATE(A2, B2, C2)

Or

=A2&B2&C2

The formulas work for both text and numbers. In case of numbers, please keep in mind that the result is a text string. To convert it to number, just multiply CONCATENATE's output by 1 or add 0 to it. For instance:

=CONCATENATE(A2, B2)*1

Concatenating the values of two or more cells in Excel

Tip. In Excel 2019 and higher, you can use the CONCAT function to quickly concatenate multiple cells using one or more range references.

Concatenate cells with a space, comma or other delimiter

In your worksheets, you may often need to join values in a way that includes commas, spaces, various punctuation marks or other characters such as a hyphen or slash. To do this, simply put the desired character in your concatenation formula. Remember to enclose that character in quotation marks, as demonstrated in the following examples.

Concatenating two cells with a space:

=CONCATENATE(A2, " ", B2)

or

=A2 & " " & B2

Concatenating two cells with a comma:

=CONCATENATE(A2, ", ", B2)

or

=A2 & ", " & B2

Concatenating two cells with a hyphen:

=CONCATENATE(A2, "-", B2)

or

=A2 & "-" & B2

The following screenshot demonstrates how the results may look like: Concatenating cells with a space, comma or other delimiter

Tip. In Excel 2019 and higher, you can use the TEXTJOIN function to merge strings from multiple cells with any delimiter that you specify.

Concatenating text string and cell value

There is no reason for the Excel CONCATENATE function to be limited to only joining cells' values. You can also use it to combine text strings to make the result more meaningful. For example:

=CONCATENATE(A2, " ", B2, " completed")

The above formula informs the user that a certain project is completed, as in row 2 in the screenshot below. Please notice that we add a space before the word " completed" to separate the concatenated text strings. A space (" ") is also inserted between the combined values, so that the result displays as "Project 1" rather than "Project1".

With the concatenation operator, the formula can be written this way:

=A2 & " " & B2 & " completed"

In the same manner, you can add a text string in the beginning or in the middle of your concatenation formula. For example:

=CONCATENATE("See ", A2, " ", B2)

="See " & A2 & " " & B2 Concatenating a text string and cell value

Join text string and another formula

To make the result returned by some formula more understandable for your users, you can concatenate it with a text string that explains what the value actually is.

For example, you can use the following formula to return the current date in the desired format and specify what kind of date that is:

=CONCATENATE("Today is ",TEXT(TODAY(), "mmmm d, yyyy"))

="Today is " & TEXT(TODAY(), "dd-mmm-yy") Concatenating a text string and a formula-driven value

Tip. If you would like to delete the source data without affecting the resulting text strings, use the "Paste special - values only" option to convert formulas to their values.

Concatenate text strings with line breaks

Most often, you would separate the resulting text strings with punctuation marks and spaces, as shown in the previous example. In some cases, however, there may be a need to separate the values with a line break, or carriage return. A common example is merging mailing addresses from data in separate columns.

A problem is that you cannot simply type a line break in the formula like a usual character. Instead, you use the CHAR function to supply the corresponding ASCII code to the concatenation formula:

  • On Windows, use CHAR(10) where 10 is the character code for Line feed.
  • On Mac, use CHAR(13) where 13 is the character code for Carriage return.

In this example, we have the address pieces in columns A through F, and we are putting them together in column G by using the concatenation operator "&". The merged values are separated with a comma (", "), space (" ") and a line break CHAR(10):

=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2

The CONCATENATE function would take this shape:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", E2, " ", F2)

Either way, the result is a 3-line text string: Concatenating cells with line breaks

Note. When using line breaks to separate the combined values, you must have Wrap text enabled for the result to display correctly. To do this, press Ctrl + 1 to open the Format Cells dialog, switch to the Alignment tab and check the Wrap text box.

In the same manner, you can separate final strings with other characters such as:

  • Double quotes (") - CHAR(34)
  • Forward slash (/) - CHAR(47)
  • Asterisk (*) - CHAR (42)
  • The full list of ASCII codes is available here.

How to concatenate columns in Excel

To join two or more columns, just enter your concatenation formula in the first cell, and then copy it down to other cells by dragging the fill handle (the small square that appears in the lower right hand corner of the selected cell).

For example, to combine two columns (column A and B) delimiting the values with a space, the formula in C2 copied down is:

=CONCATENATE(A2, " ", B2)

Or

= A2 & " " & B2 Concatenating two columns in Excel

Tip. A quick way to copy the formula down the column is to select the cell with the formula and double-click the fill handle.

For more information, please see How to merge two columns in Excel without losing data.

Combine text and numbers keeping formatting

When concatenating a text string with a number, percentage or date, you may want to keep the original formatting of a numeric value or display it in a different way. This can be done by supplying the format code inside the TEXT function, which you embed in a concatenation formula.

In the beginning of this tutorial, we have already discussed a formula that concatenates text and date.

And here are a few more formula examples that combine text and number:

Number with 2 decimal places and the $ sign:

=A2 & " " & TEXT(B2, "$#,#0.00")

Number without insignificant zeros and the $ sign:

=A2 & " " & TEXT(B2, "0.#")

Fractional number:

=A2 & " " & TEXT(B2, "# ?/???")

To concatenate text and percentage, the formulas are:

Percent with two decimal places:

=A12 & " " & TEXT(B12, "0.00%")

Rounded whole percent:

=A12 & " " & TEXT(B12, "0%") Concatenating numbers in various formats

How to concatenate a range of cells in Excel

Combining values from multiple cells might take some effort because the Excel CONCATENATE function does not accept arrays.

To concatenate several cells, say A1 to A4, you need to use one of the following formulas:

=CONCATENATE(A1, A2, A3, A4)

or

=A1 & A2 & A3 & A4

When combining a fairly small group of cells, it's no big deal to type all the references. A large range would be tedious to supply, typing each individual reference manually. Below you will find 3 methods of quick range concatenation in Excel.

Method 1. Press CTRL to select multiple cells

To quickly select several cells, you can press and hold the Ctrl key while clicking on each cell you want to include in the formula. Here are the detailed steps:

  1. Select a cell where you want to enter the formula.
  2. Type =CONCATENATE( in that cell or in the formula bar.
  3. Press and hold Ctrl and click on each cell you want to concatenate.
  4. Release the Ctrl button, type the closing parenthesis, and press Enter.
To concatenate a range of cells, press CTRL to select multiple cells.
Note. When using this method, you must click each individual cell. Selecting a range with the mouse would add an array to the formula, which the CONCATENATE function does not accept.

Method 2. Use TRANSPOSE function to get all cell values

When a range consists of tens or hundreds of cells, the previous method may not be fast enough as it requires clicking on each cell. In this case, you can use the TRANSPOSE function to return an array of values, and then merge them together in one fell swoop.

  1. In the cell where you want the result to appear, enter the TRANSPOSE formula, for example:

    =TRANSPOSE(A1:A10)

  2. In the formula bar, press F9 to replace the formula with calculated values. As a result, you will have an array of values to be concatenated.
  3. Delete the curly braces surrounding the array. Use the TRANSPOSE function to get the range
  4. Type =CONCATENATE( before the first value, then type the closing parenthesis after the last value, and press Enter. Concatenate the values.

Note. The result of this formula is static as it concatenates the values, not cell references. If the source data changes, you will have to repeat the process.

Method 3. Use the CONCAT function

In Excel 365 and Excel 2021, this simple formula will concatenate a range of cells in a blink:

=CONCAT(A1:A10)

Method 4. Use the Merge Cells add-in

A quick and formula-free way to concatenate any range in Excel is to use the Merge Cells add-in with the "Merge all areas in selection" option turned off, as demonstrated in Combining values of several cells into one cell.

Excel "&" operator vs. CONCATENATE function

Many users wonder which is a more efficient way to join strings in Excel - CONCATENATE function or "&" operator.

The only real difference is the 255 strings limit of the CONCATENATE function and no such limitation when using the ampersand. Other than that, there is no difference between these two methods, nor is there any speed difference between the CONCATENATE and "&" formulas.

And since 255 is a really big number and you will hardly ever need to combine that many strings in real work, the difference boils down to comfort and ease of use. Some users find CONCATENATE formulas easier to read, I personally prefer using the "&" method. So, simply stick with the technique you feel more comfortable with.

Opposite of CONCATENATE in Excel (splitting cells)

The opposite of concatenate in Excel is splitting the contents of one cell into multiple cells. This can be done in a few different ways:

You can also find useful information in this article: How to unmerge cells in Excel.

Concatenate in Excel with Merge Cells add-in

With the Merge Cells add-in included in Ultimate Suite for Excel, you can efficiently do both:

  • Merge several cells into one without losing data.
  • Concatenate the values of several cells into a single cell and separate them with any delimiter of your choosing.

The Merge Cells tool works with all Excel versions from 2016 to 365 and can combine all data types including text strings, numbers, dates and special symbols. Its two key advantages are simplicity and speed - any concatenation is done in a couple of clicks.

Combine values of several cells into one cell

To combine the contents of several cells, you select the range to concatenate and configure the following settings:

  • Under What to merge, select Cells into one.
  • Under Combine with, type the delimiter (a comma and a space in our case).
  • Choose where you want to place the result.
  • Most importantly, uncheck the Merge all areas in the selection box. It is this option that controls whether the cells are merged or their values are concatenated.
Combine the values of several cells into one cell.

Combine columns row-by-row

To concatenate two or more columns, you configure the Merge Cells' settings in a similar way but choose to merge columns into one and place the results in the left column.

Concatenating columns into one.

Join rows column-by-column

To combine data in each individual row, column-by-column, you choose:

  • Merge rows into one.
  • Use a line break for the delimiter.
  • Place the results in the top row.

The result may look similar to this: Concatenating multiple rows into one.

To check how the Merge Cells add-in will cope with your data sets, you are welcome to download a fully functional trial version of our Ultimate Suite for Excel below.

That's how to concatenate in Excel. I thank you for reading and hope to see you on our blog next week!

Available downloads

Concatenation formula examples (.xlsx file)
Ultimate Suite 14-day trial version (.exe file)

Table of contents

447 comments

  1. I have a cell (B2). cell value is: SAHANSRA,NAVJOT This is Lastname,Firstname
    I am using: LEFT(B2,FIND(",",B2)-1) and MID(B2,FIND(",",B2)+1,10) respectively to pull the name apart and place them into separate cells.
    What I need to do is place the LASTNAME into a static array with spaces to fill for 30 characters total. The results of the Lastname formula is now in cell N25
    REPLACE(N25,(LEN(N25)+1),(30-(LEN(N25)))," ")
    I need the result of the last formula to look like "SAHANSRAbbbbbbbbbbbbbbbbbbbbbb"
    where "b" is a space (22 of them) I thought this would give me my 22 spaces, but it only gives me 1.
    HELP!! thank you in advance.

  2. hi, how i can use concatenate with condition?
    for example i have 2 columns A & B and the condition is if we have same number in column B with different name in column A, and i need to add them in same cell (C).
    do we have i formula?
    A B C
    elie 1 elie,Rita
    Rita 1 elie,Rita
    Joseph 2 Joseph,Noha
    Noha 2 Joseph,Noha

  3. I have a question with what I am finding is a difficult if/then situation.
    Say I have a column with 3 separate values over hundreds of rows: AA BB or CC
    AA is unique but BB and CC ultimately will be the same.
    I need to concatenate 3 cells based off of the above breakdown.
    The first part will be DEF: (with the colon) which is common for all of the outputs.
    The next part will be either GHI:: or JKL:: depending on AA, BB or CC with JKL:: being associated with BB & CC designations.
    Then the last part is a unique number that will be on its own ######.
    The end result will need to be DEF:GHI::###### (AA value) or DEF:JKL::###### (BB or CC value) all depending on the values AA BB CC.

    Keep hitting a wall with figuring out the IF AA then GHI:: portion.

    Thanks,

    Mike

  4. How do I format after using concatentate using a formula for the two values?
    For example: =concatenate((d3/d4)," / " (d5/d4)) gives values like:
    1.425212521521 / 1.4526265654
    But, I only want these values to be 3 numbers after the decimal. Is this possible if the returned value is a text string?

  5. Hello I want to use concatenate function
    0000 1 /15-16

    I want 00001/15-16

    I am not getting

    • Set Number Format to General.
      =CONCATENATE(A1,B1,C1)

      Regards,
      Taimoor

      • Also Set Number format for your; 0000 to Text.

        Regards,
        Taimoor

  6. Hi there, I've been trying to combine these into one cell without losing the zeros infront of columns C & D but have failed. Can you please help?
    A1 B1 c1 d1
    P HHL 0007040 0114876823
    Thank you!

  7. 1 A Banana Closed
    2 B Apple Closed
    3 B Banana
    4 A Apple Closed
    5 A Apple Closed

    Dear Friend, Kindly help me out in above i want a formula in which excel itself concatenate values of column 1 in which all other values are same, like i want answer in one cell like (4,5) , because its other column values A Apple Closed are same.

  8. how to concatenate different characters within a cell???

  9. How can I combine values from different cells in one column?
    Eg.
    A B C D
    20 50 80 A = 20, B = 50, C = 80

  10. How do one sum up a value like this 75+17+46+05+28 already in a single cell.

    you find a lot of value like this in a single excel cell, how do one add it up 83+24+32+79+74

    53+21+59+82+65

    02+54+33+84+16

    86+22+59+34+04

    57+03+27+39+54

    • Just add a + sign at the beginning

  11. Hi,

    I want to limit the content of a cell to the following format:

    XX YY 00-ZZZZ-EDWW

    How can i do it using Data Validation or any other way?

    thanks,

  12. I've used the Concat function and joined three cells successfully. Now, how can I cut and paste the "merged" cells into a word document?

    • Hi Barbara,

      In Excel, select the cell with your CONCAT formula, and press Ctrl+C to copy it. Switch to your Word document, place the mouse pointer to where you want the merged text to appear and press Ctrl+V to paste it.

  13. Hi,
    I had a Excel sheet which has many columns . Let say A1,D1 and G1 are has to be concatenated.

    A1 has value 134574935
    D1 has date in 03/05/2018
    G1 has date in 05/05/2018

    I want result as
    insert into tablename values('134564935','03-May-2018','05-May-2018');

    Note:- date format has changed and the delimeter in the format has also changed.

    Please help me to solve this . Thanks in advance .

  14. I'm trying to concatenate two columns of data. One contains area codes for phone numbers, and the second column contains the numbers themselves. The problem is that when the phone number begins with a zero, this isn't included in the final concatenated value, resulting in nonviable phone numbers. How can I go about fixing this?
    Thanks

    • Hanelise:
      If you want to keep the leading zeros, you just need to format the cells as Text before entering the data. This should be OK for you because when you concatenate the cells they will go to text anyway.

  15. Thank You - Wonderful article - its exactly what i wanted.

  16. Hi,

    I need to concatenate a few cells but A2 it's a number 08 and I need the zero in front, but for some reason it's only showing the number 8 alone, same with all the single digits like 4 it should be 04. For the 2018 I need only the 18 but it's giving me the complete year.

    8_4_2018_

    =CONCATENATE(A3,"_",B3,"_",C3,"_",S3,"",Z3,"_",K3,"_")

    Correct way should be:

    08_04_18 It's the date but in this format.

    Thanks

  17. Is there a quick way to build a formula:
    =concatenate(a1,a2,a3,a4 .... a1024)
    or
    =concatenate(a1,b1,c1,d1, ... amj1)
    without typing the addresses one by one ?

    Please note, that the cells a1..a1024, or a1..amj1, contain results of other formulas, so their content varies, and the TRANSPOSE trick seems not to work :-(

    BTW, most of the above internal results will be just empty strings, and the rest will be just one or two letters, so the actual result of the above concatenate will be only 100-200 characters.

    Bests,
    Mike

  18. What is my text has a "READY TO LET" text, and I like to join text and formulas like :

    ="INFLATION TO [READY TO LET YEAR] @ 4% ("&I64&" years)", I get this:

    INFLATION TO [READY TO LET YEAR] @ 4% (4 years), but I need this:

    INFLATION TO "READY TO LET YEAR" @ 4% (4 years)

    Would you please let me know how to write this formula?

    Please advise,

  19. Hi there,
    How to concatenate two columns that mimic this (N'Doe, John', N'Doctor') where Doe, John is the first column and Doctor is the second column. This (N'Doe, John', N'Doctor') has to be used in SQL and XML. Thanks

  20. Thanks. This is what I really wanted

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)