by If you are a regular visitor of this blog, you've probably noticed a few articles covering different aspects of Excel conditional formatting. And now we will leverage this knowledge and create spreadsheets that differentiate between weekdays and weekends, highlight public holidays and display a coming deadline or delay. In other words, we are going to apply Excel conditional formatting to dates.
If you have some basic knowledge of Excel formulas, then you are most likely familiar with some of date and time functions such as NOW, TODAY, DATE, WEEKDAY, etc. In this tutorial, we are going to take this functionality a step further to conditionally format Excel dates in the way you want.
Excel conditional formatting for dates (built-in rules)
Microsoft Excel provides 10 options to format selected cells based on the current date.
- To apply the formatting, you simply go to the Home tab > Conditional Formatting > Highlight Cell Rules and select A Date Occurring.
- Select one of the date options from the drop-down list in the left-hand part of the window, ranging from last month to next month.
- Finally, choose one of the pre-defined formats or set up your custom format by choosing different options on the Font, Border and Fill tabs. If the Excel standard palette does not suffice, you can always click the More colors… button.
- Click OK and enjoy the result! : )
However, this fast and straightforward way has two significant limitations - 1) it works for selected cells only and 2) the conditional format is always applied based on the current date.
Excel conditional formatting formulas for dates
If you want to highlight cells or entire rows based on a date in another cell, or create rules for greater time intervals (i.e. more than a month from the current date), you will have to create your own conditional formatting rule based on a formula. Below you will find a few examples of my favorite Excel conditional formats for dates.
How to highlight weekends in Excel
Regrettably, Microsoft Excel does not have a built-in calendar similar to Outlook's. Well, let's see how you can create your own automated calendar with quite little effort.
When designing your Excel calendar, you can use the =DATE(year,month,date) function to display the days of the week. Simply enter the year and the month's number somewhere in your spreadsheet and reference those cells in the formula. Of course, you could type the numbers directly in the formula, but this is not a very efficient approach because you would have to adjust the formula for each month.
The screenshot below demonstrates the DATE function in action. I used the formula =DATE($B$2,$B$1,B$4) which is copied across row 5.
Tip. If you want to display only the days of the week like you see in the image above, select the cells with the formula (row 5 in our case), right-click and choose Format Cells…> Number > Custom. From the drop-down list under Type, select either dddd or ddd to show full day names or abbreviated names, respectively.
Your Excel calendar is almost done, and you only need to change the color of weekends. Naturally, you are not going to color the cells manually. We'll have Excel format the weekends automatically by creating a conditional formatting rule based on the WEEKDAY formula.
- You start by selecting your Excel calendar where you want to shade the weekends. In our case, it is the range $B$4:$AE$10. Be sure to start the selection with the 1st date column - Colum B in this example.
- On the Home tab, click Conditional Formatting menu > New Rule.
- Create a new conditional formatting rule based on a formula as explained in the above linked guide.
- In the "Format values where this formula is true" box, enter the following WEEKDAY formula that will determine which cells are Saturdays and Sundays:
=WEEKDAY(B$5,2)>5 - Click the Format… button and set up your custom format by switching between the Font, Border and Fill tabs and playing with different formatting options. When done, click the OK button to preview the rule.
Now, let me briefly explain the WEEKDAY(serial_number,[return_type]) formula so that you can quickly adjust it for your own spreadsheets.
- The
serial_numberparameter represents the date you are trying to find. You enter a reference to your first cell with a date, B$5 in our case. - The
[return_type]parameter determines the week type (square brackets imply it is optional). You enter 2 as the return type for a week starting from Monday (1) through Sunday (7). You can find the full list of available return types here. - Finally, you write >5 to highlight only Saturdays (6) and Sundays (7).
The screenshot below demonstrates the result in Excel 2013 - the weekends are highlighted in the reddish colour.
Tips:
- If you have non-standard weekends in your company, e.g. Fridays and Saturdays, then you would need to tweak the formula so that it starts counting from Sunday (1) and highlight days 6 (Friday) and 7 (Saturday) -
WEEKDAY(B$5,1)>5. - If you are creating a horizontal (landscape) calendar, use a relative column (without $) and absolute row (with $) in a cell reference because you should lock the reference of the row - in the above example it is row 5, so we entered B$5. But if you are designing a calendar in vertical orientation, you should do the opposite, i.e. use an absolute column and relative row, e.g. $B5 as you can see in the screenshot below:
How to highlight holidays in Excel
To improve your Excel calendar further, you can shade public holidays as well. To do that, you will need to list the holidays you want to highlight in the same or some other spreadsheet.
For example, I've added the following holidays in column A ($A$14:$A$17). Of course, not all of them are real public holidays, but they will do for demonstration purposes : )
Again, you open Conditional Formatting > New Rule. In the case of holidays, you are going to use either MATCH or COUNTIF function:
=COUNTIF($A$14:$A$17,B$5)>0=MATCH(B$5,$A$14:$A$17,0)
Note. If you have chosen a different color for holidays, you need to move the public holiday rule to the top of the rules list via Conditional Formatting > Manage Rules…
The following image shows the result in Excel 2013:
Conditionally format a cell when a value is changed to a date
It's not a big problem to conditionally format a cell when a date is added to that cell or any other cell in the same row as long as no other value type is allowed. In this case, you could simply use a formula to highlight non-blanks, as described in Excel conditional formulas for blanks and non-blanks. But what if those cells already have some values, e.g. text, and you want to change the background color when text is changed to a date?
The task may sound a bit intricate, but the solution is very simple.
- First off, you need to determine the format code of your date. Here are just a few examples:
- D1: dd-mmm-yy or d-mmm-yy
- D2: dd-mmm or d-mmm
- D3: mmm-yy
- D4: mm/dd/yy or m/d/yy or m/d/yy h:mm
You can find the complete list of date codes in this article.
- Select a column where you want to change the color of cells or the entire table in case you want to highlight rows.
- And now create a conditional formatting rule using a formula similar to this one:
=CELL("format",$A2)="D1". In the formula, A is the column with dates and D1 is the date format.If your table contains dates in 2 or more formats, then use the OR operator, e.g.
=OR(cell("format", $A2)="D1", cell("format",$A2)="D2", cell("format", $A2)="D3")The screenshot below demonstrates the result of such conditional formatting rule for dates.
How to highlight rows based on a certain date in a certain column
Suppose, you have a large Excel spreadsheet that contains two date columns (B and C). You want to highlight every row that has a certain date, say 13-May-14, in column C.
To apply Excel conditional formatting to a certain date, you need to find its numerical value first. As you probably know, Microsoft Excel stores dates as sequential serial numbers, starting from January 1, 1900. So, 1-Jan-1900 is stored as 1, 2-Jan-1900 is stored as 2… and 13-May-14 as 41772.
To find the date's number, right-click the cell, select Format Cells > Number and choose the General format. Write down the number you see and click Cancel because you do not really want to change the date's format.
That was actually the major part of the work and now you only need to create a conditional formatting rule for the entire table with this very simple formula: =$C2=41772. The formula implies that your table has headers and row 2 is your first row with data.
An alternative way is to use the DATEVALUE formula that converts the date to the number format is which it is stored, e.g. =$C2=DATEVALUE("5/13/2014")
Whichever formula you use, it will have the same effect:
Conditionally format dates in Excel based on the current date
As you probably know Microsoft Excel provides the TODAY() functions for various calculations based on the current date. Here are just a few examples of how you can use it to conditionally format dates in Excel.
Example 1. Highlight dates equal to, greater than or less than today
To conditionally format cells or entire rows based on today's date, you use the TODAY function as follows:
Equal to today: =$B2=TODAY()
Greater than today: =$B2>TODAY()
Less than today: =$B2<TODAY()
The screenshot below demonstrates the above rules in action. Please note, at the moment of writing TODAY was 12-Jun-2014.
Example 2. Conditionally format dates in Excel based on several conditions
In a similar fashion, you can use the TODAY function in combination with other Excel functions to handle more complex scenarios. For example, you may want your Excel conditional formatting date formula to color the Invoice column when the Delivery Date is equal to or greater than today BUT you want the formatting to disappear when you enter the invoice number.
For this task, you would need an additional column with the following formula (where E is your Delivery column and F the Invoice column):
=IF(E2>=TODAY(),IF(F2="", 1, 0), 0)
If the delivery date is greater than or equal to the current date and there is no number in the Invoice column, the formula returns 1, otherwise it's 0.
After that you create a simple conditional formatting rule for the Invoice column with the formula =$G2=1 where G is your additional column. Of course, you will be able to hide this column later.
Example 3. Highlight upcoming dates and delays
Suppose you have a project schedule in Excel that lists tasks, their start dates and durations. What you want is to have the end date for each task calculated automatically. An additional challenge is that the formula should also consider the weekends. For example, if the starting date is 13-Jun-2014 and the number of days of work (Duration) is 2, the ending date should come as 17-Jun-2014, because 14-Jun and 15-Jun are Saturday and Sunday.
To do this, we will use the WORKDAY.INTL(start_date,days,[weekend],[holidays]) function, more precisely =WORKDAY.INTL(B2,C2,1).
In the formula, we enter 1 as the 3rd parameter since it indicates Saturday and Sunday as holidays. You can use another value if your weekends are different, say, Fri and Sat. The full list of the weekend values is available here. Optionally, you can also use the 4th parameter [holidays], which is a set of dates (range of cells) that should be excluded from the working day calendar.
And finally, you may want to highlight rows depending on how far away the deadline is. For example, the conditional formatting rules based on the following 2 formulas highlight upcoming and recent end dates, respectively:
=AND($D2-TODAY()>=0,$D2-TODAY()<=7)- highlight all rows where the End Date (column D) is within the next 7 days. This formula is really handy when it comes to tracking upcoming expiration dates or payments.=AND(TODAY()-$D2>=0,TODAY()-$D2<=7)- highlight all rows where the End Date (column D) is within the last 7 days. You can use this formula to track the latest overdue payments and other delays.
Here are a few more formula examples that can be applied to the table above:
=$D2<TODAY() - highlights all passed dates (i.e. dates less than the current date). Can be used to format expired subscriptions, overdue payments etc.
=$D2>TODAY() - highlights all future dates (i.e. dates greater than the current date). You can use it to highlight upcoming events.
Of course, there can be infinite variations of the above formulas, depending on your particular task. For instance:
=$D2-TODAY()>=6 - highlights dates that occur in 6 or more days.
=$D2=TODAY()-14 - highlights dates occurring exactly 2 weeks ago.
How to highlight dates within a date range
If you have a long list of dates in your worksheet, you may also want to highlight the cells or rows that fall within a certain date range, i.e. highlight all dates that are between two given dates.
You can fulfil this task using the TODAY() function again. You will just have to construct a little bit more elaborate formulas as demonstrated in the examples below.
Formulas to highlight past dates
- More than 30 days ago:
=TODAY()-$A2>30 - From 30 to 15 days ago, inclusive:
=AND(TODAY()-$A2>=15, TODAY()-$A2<=30) - Less than 15 days ago:
=AND(TODAY()-$A2>=1, TODAY()-$A2<15)
The current date and any future dates are not colored.
Formulas to highlight future dates
- Will occur in more than 30 days from now:
=$A2-TODAY()>30 - In 30 to 15 days, inclusive:
=AND($A2-TODAY()>=15, $A2-TODAY()<=30) - In less than 15 days:
=AND($A2-TODAY()>=1, $A2-TODAY()<15)
The current date and any past dates are not colored.
How to shade gaps and time intervals
In this last example, we are going to utilize yet another Excel date function - DATEDIF(start_date, end_date, interval). This function calculates the difference between two dates based on the specified interval. It differs from all other functions we've discussed in this tutorial in the way that it lets you ignore months or years and calculate the difference only between days or months, whichever you choose.
Don't see how this could work for you? Think about it in another way… Suppose you have a list of birthdays of your family members and friends. Would you like to know how many days there are until their next birthday? Moreover, how many days exactly are left until your wedding anniversary and other events you wouldn't want to miss? Easily!
The formula you need is this (where A is your Date column):
=DATEDIF(TODAY(), DATE((YEAR(TODAY())+1), MONTH($A2), DAY($A2)), "yd")
The "yd" interval type at the end of the formula is used to ignore years and calculate the difference between the days only. For the full list of available interval types, look here.
Tip. If you happen to forget or misplace that complex formula, you can use this simple one instead: =365-DATEDIF($A2,TODAY(),"yd"). It produces exactly the same results, just remember to replace 365 with 366 in leap years : )
And now let's create an Excel conditional formatting rule to shade different gaps in different colors. In this case, it makes more sense to utilize Excel Color Scales rather than create a separate rule for each period.
The screenshot below demonstrates the result in Excel - a gradient 3-color scale with tints from green to red through yellow.
"Days Until Next Birthday" Excel Web App
We have created this Excel Web App to show you the above formula in action. Just enter your events in 1st column and change the corresponding dates in the 2nd column to experiment with the result.
If you are curious to know how to create such interactive Excel spreadsheets, check out this article on how to make web-based Excel spreadsheets.
Hopefully, at least one of the Excel conditional formats for dates discussed in this article has proven useful to you. If you are looking for a solution to some different task, you are most welcome to post a comment. Thank you for reading!
1237 comments
Hi,
I have a question - i have a sheet with multiple columns, now for example if i put a date in column R then i would like the entire row to be orange, later once i decide to put a date in column S then the same row should turn Green. How do i do this.
Hi, Bosco,
are you going to put only dates in these columns? If so, you can create two formatting rules that will check if those are blank or not. The formulas for the rules are:
=$S1<>"" and =$R1<>""
If your data begins from the second or the third row (and so on), change the number in the formula accordingly.
Hi...
Lets suppose we have set particular values corresponding to date of the month
How can i apply a formula i which the value of current date reflect in separate cell
I am trying to format one cell to highlight when the year isn't current. The names listed must complete a task at any date during the current year. After December 31st of each year, the task is overdue. The cell currently has only the year, but it would be nice to have the actually date they completed the task and still have December 31st of the current year as the condition. Thanks for your assistance.
Hello, Sherry,
if the cell to format is A1 and it contains a full date, use the next formula in conditional formatting:
=YEAR($A1)<YEAR(TODAY())
If there's only a year entered into the cell, the formula will be:
=$A1<YEAR(TODAY())
Hello Juli,
I am doing an sprint calendar for agile. We have 2 week sprints that start on a Tuesday. I need to highlight the 2 weeks for the current date.
For example today is March 21 and my sprint is from March 14 to March 25. I like to have those dates highlighted.
I try to use your DATEIF example but I guess the excel I have does not support that function.
I Try =AND(TODAY()-B35>=1,TODAY()-O35<=10) but is not giving me the result I need.
Hello,
I need help, I want to change the dates font color to be black in cell A, if cell B is "done", else keep the due date in red in cell B.
For exmp:
Cell A1 =today()
Cell A4 due date is 4 March 2017 (it is in red if expired)
Cell B4 is keep counting the over due days
Cell C4 is where the payment is still in debt. But once the payment is fully paid, cell B turned to "done" automatically. When cell B is "done", the due date in cell A is black again instead of red.
up to now i am using the format as below
cell B with: =IF(C4<=0,"selesai ",(A4-A$1)
For Cell A4 I am using Conditional formatting rules manager
I am using windows 10
Thank you
cell B with: =IF(C4<=0,"done",(A4-A$1)
HI .
I M WORKING AS MAINTENANCE CORDINATOR IN MULTINATIONAL COMPANY. & AS CORDINATOR I HAVE TO PREPARE SCHEDULE FOR THE FIRE FIGHTING EQUIPMENTS BY THE GIVEN DATE & DETAILS OF EQUIPMENTS. BUT I FOUND HARD TO MAKE SCHEDULE WITH EXCEL AS I M FILLING DATES MANUALLY.
E.G. IF THERE IS ANNUAL CONTRACT FOR ABC CO.
START DATE-END DATE-TYPE OF EQUIPMENT-SCHEDULED-01ST VISIT - 02ND VISIT -03 VISIT -04 VISIT
02/02/2017 - 02/02/2018-FIRE ALARM-MONTHLY-?DATE-?DATE-?DATE-?DATE
02/02/2017 - 02/02/2018-FIRE HYDRANT-QUARTERLY-?DATE-?DATE-?DATE-?DATE
PLEASE HELP ME IN CREATING THE DATES IF WE PLAN THE MAINTENACE MONTHY OR QUARTERLY
Any help will be greatly appreciated.
Hi!
I have a sheet in which I track the status of containers based on their ETA's.
Currently I have a formula set so that if the dates in the ETA column are in the past (or today), the entire row turns green.
This allows us to easily identify which containers have already arrived.
Is there a way to change the cell in the Status column to say "Arrived" based on the ETA column?
Thanks in advance!
hii.. I have a spreadsheet containing report reciept data.
we have a deadline of particular date to submit monthly report.
i want to highlight the dates for reports received after the particular deadline date.
Can you please guide?
Sir/Ma'am-
I've tried manipulating the example formula that was used to show how to "conditionally format a cell when a value is changed to a date", however, I don't want the program to highlight a separate row when a date is input, I want it to highlight each specific cell that has a date. I tried using the formula that was indicated as an example just out of curiosity, but it's also highlighting any cell that has "period 1", "period 2", "period 3", "period 4"- and it's also not highlighting some cells that do have dates? Is there any assistance that you could provide? I would truly appreciate it!
Hi!
I would like to get some idea how to put the conditional formatting in my case;
If I have many columns with full of dates, and every columns has the required expiration dates. I want to highlight every dates reaching (3 months, 2 months, and 1 month) before expiration so that I can inform the Training Officer for the next schedule for the refresher or retraining course.
Lets say column A (A1:A50) with different dates and with 2 years validity. I would like to highlight the dates reaching 3 months prior the expiration.
Hoping to received for your kind response.
Hi, Please help. Is it possible to change font of column F to green if the date in column Q is greater or equal to 01-JAN-17 and have column F in red font of the date in Q is 31DEC16 or less.
PLease help if its possible
I have a due date and Date Completed column, thanks to this page, I was able to format my due dates with past due and coming up with in a week. Is there a way to format, so that once I add a date to my Completed column, that it will un-fill my due date column, to show as being complete and not past due?
Or would it be easier to just remove the formatting from a particular cell, once I have completed it?
Hi,
I have the following conditioning problem
Column A is a target date, DD/MM/YYYY.
Column B is the completion date, DD/MM/YYYY
If a cell in column B is within 5 days of A I would like the cell to turn GREEN.
5-10 days AMBER
10+ days RED.
Is that possible???
I have an interesting problem. I have a spreadsheet that has 3 sheets, one as an overview that the workbook opens to, and 2 with expiration dates.
The expiration dates are on Emp_Data sheet and Vehicle_Data respectively, I use the formula on the main page to calculate remaining time before expiry:
=IF(DATEDIF(B2,Emp_Data!B4,"y")=0,"",DATEDIF(B2,Emp_Data!B4,"y")&" years,")
&IF(DATEDIF(B2,Emp_Data!B4,"ym")=0,"",DATEDIF(B2,Emp_Data!B4,"ym")&" month(s), ")
&IF(DATEDIF(B2,Emp_Data!B4,"md") = 0,"",DATEDIF(B2,Emp_Data!B4,"md")&" Days")
This formula removes the year/month/day if it returns a 0. B2 is the current date, and Emp_Data!B4 is the expiration date.
What I want to do is have conditional formatting for dates that go below 15 days remaining, and another for fields that are above 15 days. Because I use separate sheets, it does not seem to be possible. I have attempted to use condition formatting for numbers, text, and dates for the field, to no avail.
I have attempted to use a formula to convert the remaining time to days, in a separate field, however, I cannot apply conditional formatting with just one field, as they are all different dates.
You can actually do this. When you are in the conditional formatting screen, you click on the button at the end of the text box and you can change the sheet that it is pulling the information from.
I have a spreadsheet that documents the date when our students respond to questions and I would like to highlight only the first cell of the new date so that when I enter a new date, it will change to same color.
example:
student name question date
john question1 02/15/16 (highlighted)
Abraham 02/15/16
elina 02/15/16
sarah 02/15/16
lorry 02/15/16
phil 02/15/16
phil 02/16/16 (highlighted)
Hello,
I am trying to conditionally format on dates. With expired dates (which would be over 1 year past current date) turning red, no date being yellow and any date that is current(within 1 year of current date)green.
Is there a way to format that?
Dear Team,
I have created excel work book for hotel reservation.There are two sheets named Reservation sheet and I have put dates horizontally & Room numbers vertically into it.In the other sheet (Named Guest booking list) I have put
Guest Name,ID,arrival date, departure date and room number respectively.I want to fill in reservation sheet cell according to the dates stay when I put the room number into guest booking list.
Therefore please let me know the If function or relevant method to make this easy.
Thank you.
This was super, super helpful. Thanks so much for putting together this guide!
=AND(M2>=TODAY(), M2<TODAY()+3) - whats wrong with this formula
Hi,
I have an excel file in which I am trying to change the cell color(red, yellow, or green) based on the date in the cell minus 0 days (red), 5 days (yellow), and 10 days green. Is that possible? THis is an award tracker and I want to the cell to change color based on proximity to the due date.