by If you are a regular visitor of this blog, you've probably noticed a few articles covering different aspects of Excel conditional formatting. And now we will leverage this knowledge and create spreadsheets that differentiate between weekdays and weekends, highlight public holidays and display a coming deadline or delay. In other words, we are going to apply Excel conditional formatting to dates.
If you have some basic knowledge of Excel formulas, then you are most likely familiar with some of date and time functions such as NOW, TODAY, DATE, WEEKDAY, etc. In this tutorial, we are going to take this functionality a step further to conditionally format Excel dates in the way you want.
Excel conditional formatting for dates (built-in rules)
Microsoft Excel provides 10 options to format selected cells based on the current date.
- To apply the formatting, you simply go to the Home tab > Conditional Formatting > Highlight Cell Rules and select A Date Occurring.
- Select one of the date options from the drop-down list in the left-hand part of the window, ranging from last month to next month.
- Finally, choose one of the pre-defined formats or set up your custom format by choosing different options on the Font, Border and Fill tabs. If the Excel standard palette does not suffice, you can always click the More colors… button.
- Click OK and enjoy the result! : )
However, this fast and straightforward way has two significant limitations - 1) it works for selected cells only and 2) the conditional format is always applied based on the current date.
Excel conditional formatting formulas for dates
If you want to highlight cells or entire rows based on a date in another cell, or create rules for greater time intervals (i.e. more than a month from the current date), you will have to create your own conditional formatting rule based on a formula. Below you will find a few examples of my favorite Excel conditional formats for dates.
How to highlight weekends in Excel
Regrettably, Microsoft Excel does not have a built-in calendar similar to Outlook's. Well, let's see how you can create your own automated calendar with quite little effort.
When designing your Excel calendar, you can use the =DATE(year,month,date) function to display the days of the week. Simply enter the year and the month's number somewhere in your spreadsheet and reference those cells in the formula. Of course, you could type the numbers directly in the formula, but this is not a very efficient approach because you would have to adjust the formula for each month.
The screenshot below demonstrates the DATE function in action. I used the formula =DATE($B$2,$B$1,B$4) which is copied across row 5.
Tip. If you want to display only the days of the week like you see in the image above, select the cells with the formula (row 5 in our case), right-click and choose Format Cells…> Number > Custom. From the drop-down list under Type, select either dddd or ddd to show full day names or abbreviated names, respectively.
Your Excel calendar is almost done, and you only need to change the color of weekends. Naturally, you are not going to color the cells manually. We'll have Excel format the weekends automatically by creating a conditional formatting rule based on the WEEKDAY formula.
- You start by selecting your Excel calendar where you want to shade the weekends. In our case, it is the range $B$4:$AE$10. Be sure to start the selection with the 1st date column - Colum B in this example.
- On the Home tab, click Conditional Formatting menu > New Rule.
- Create a new conditional formatting rule based on a formula as explained in the above linked guide.
- In the "Format values where this formula is true" box, enter the following WEEKDAY formula that will determine which cells are Saturdays and Sundays:
=WEEKDAY(B$5,2)>5 - Click the Format… button and set up your custom format by switching between the Font, Border and Fill tabs and playing with different formatting options. When done, click the OK button to preview the rule.
Now, let me briefly explain the WEEKDAY(serial_number,[return_type]) formula so that you can quickly adjust it for your own spreadsheets.
- The
serial_numberparameter represents the date you are trying to find. You enter a reference to your first cell with a date, B$5 in our case. - The
[return_type]parameter determines the week type (square brackets imply it is optional). You enter 2 as the return type for a week starting from Monday (1) through Sunday (7). You can find the full list of available return types here. - Finally, you write >5 to highlight only Saturdays (6) and Sundays (7).
The screenshot below demonstrates the result in Excel 2013 - the weekends are highlighted in the reddish colour.
Tips:
- If you have non-standard weekends in your company, e.g. Fridays and Saturdays, then you would need to tweak the formula so that it starts counting from Sunday (1) and highlight days 6 (Friday) and 7 (Saturday) -
WEEKDAY(B$5,1)>5. - If you are creating a horizontal (landscape) calendar, use a relative column (without $) and absolute row (with $) in a cell reference because you should lock the reference of the row - in the above example it is row 5, so we entered B$5. But if you are designing a calendar in vertical orientation, you should do the opposite, i.e. use an absolute column and relative row, e.g. $B5 as you can see in the screenshot below:
How to highlight holidays in Excel
To improve your Excel calendar further, you can shade public holidays as well. To do that, you will need to list the holidays you want to highlight in the same or some other spreadsheet.
For example, I've added the following holidays in column A ($A$14:$A$17). Of course, not all of them are real public holidays, but they will do for demonstration purposes : )
Again, you open Conditional Formatting > New Rule. In the case of holidays, you are going to use either MATCH or COUNTIF function:
=COUNTIF($A$14:$A$17,B$5)>0=MATCH(B$5,$A$14:$A$17,0)
Note. If you have chosen a different color for holidays, you need to move the public holiday rule to the top of the rules list via Conditional Formatting > Manage Rules…
The following image shows the result in Excel 2013:
Conditionally format a cell when a value is changed to a date
It's not a big problem to conditionally format a cell when a date is added to that cell or any other cell in the same row as long as no other value type is allowed. In this case, you could simply use a formula to highlight non-blanks, as described in Excel conditional formulas for blanks and non-blanks. But what if those cells already have some values, e.g. text, and you want to change the background color when text is changed to a date?
The task may sound a bit intricate, but the solution is very simple.
- First off, you need to determine the format code of your date. Here are just a few examples:
- D1: dd-mmm-yy or d-mmm-yy
- D2: dd-mmm or d-mmm
- D3: mmm-yy
- D4: mm/dd/yy or m/d/yy or m/d/yy h:mm
You can find the complete list of date codes in this article.
- Select a column where you want to change the color of cells or the entire table in case you want to highlight rows.
- And now create a conditional formatting rule using a formula similar to this one:
=CELL("format",$A2)="D1". In the formula, A is the column with dates and D1 is the date format.If your table contains dates in 2 or more formats, then use the OR operator, e.g.
=OR(cell("format", $A2)="D1", cell("format",$A2)="D2", cell("format", $A2)="D3")The screenshot below demonstrates the result of such conditional formatting rule for dates.
How to highlight rows based on a certain date in a certain column
Suppose, you have a large Excel spreadsheet that contains two date columns (B and C). You want to highlight every row that has a certain date, say 13-May-14, in column C.
To apply Excel conditional formatting to a certain date, you need to find its numerical value first. As you probably know, Microsoft Excel stores dates as sequential serial numbers, starting from January 1, 1900. So, 1-Jan-1900 is stored as 1, 2-Jan-1900 is stored as 2… and 13-May-14 as 41772.
To find the date's number, right-click the cell, select Format Cells > Number and choose the General format. Write down the number you see and click Cancel because you do not really want to change the date's format.
That was actually the major part of the work and now you only need to create a conditional formatting rule for the entire table with this very simple formula: =$C2=41772. The formula implies that your table has headers and row 2 is your first row with data.
An alternative way is to use the DATEVALUE formula that converts the date to the number format is which it is stored, e.g. =$C2=DATEVALUE("5/13/2014")
Whichever formula you use, it will have the same effect:
Conditionally format dates in Excel based on the current date
As you probably know Microsoft Excel provides the TODAY() functions for various calculations based on the current date. Here are just a few examples of how you can use it to conditionally format dates in Excel.
Example 1. Highlight dates equal to, greater than or less than today
To conditionally format cells or entire rows based on today's date, you use the TODAY function as follows:
Equal to today: =$B2=TODAY()
Greater than today: =$B2>TODAY()
Less than today: =$B2<TODAY()
The screenshot below demonstrates the above rules in action. Please note, at the moment of writing TODAY was 12-Jun-2014.
Example 2. Conditionally format dates in Excel based on several conditions
In a similar fashion, you can use the TODAY function in combination with other Excel functions to handle more complex scenarios. For example, you may want your Excel conditional formatting date formula to color the Invoice column when the Delivery Date is equal to or greater than today BUT you want the formatting to disappear when you enter the invoice number.
For this task, you would need an additional column with the following formula (where E is your Delivery column and F the Invoice column):
=IF(E2>=TODAY(),IF(F2="", 1, 0), 0)
If the delivery date is greater than or equal to the current date and there is no number in the Invoice column, the formula returns 1, otherwise it's 0.
After that you create a simple conditional formatting rule for the Invoice column with the formula =$G2=1 where G is your additional column. Of course, you will be able to hide this column later.
Example 3. Highlight upcoming dates and delays
Suppose you have a project schedule in Excel that lists tasks, their start dates and durations. What you want is to have the end date for each task calculated automatically. An additional challenge is that the formula should also consider the weekends. For example, if the starting date is 13-Jun-2014 and the number of days of work (Duration) is 2, the ending date should come as 17-Jun-2014, because 14-Jun and 15-Jun are Saturday and Sunday.
To do this, we will use the WORKDAY.INTL(start_date,days,[weekend],[holidays]) function, more precisely =WORKDAY.INTL(B2,C2,1).
In the formula, we enter 1 as the 3rd parameter since it indicates Saturday and Sunday as holidays. You can use another value if your weekends are different, say, Fri and Sat. The full list of the weekend values is available here. Optionally, you can also use the 4th parameter [holidays], which is a set of dates (range of cells) that should be excluded from the working day calendar.
And finally, you may want to highlight rows depending on how far away the deadline is. For example, the conditional formatting rules based on the following 2 formulas highlight upcoming and recent end dates, respectively:
=AND($D2-TODAY()>=0,$D2-TODAY()<=7)- highlight all rows where the End Date (column D) is within the next 7 days. This formula is really handy when it comes to tracking upcoming expiration dates or payments.=AND(TODAY()-$D2>=0,TODAY()-$D2<=7)- highlight all rows where the End Date (column D) is within the last 7 days. You can use this formula to track the latest overdue payments and other delays.
Here are a few more formula examples that can be applied to the table above:
=$D2<TODAY() - highlights all passed dates (i.e. dates less than the current date). Can be used to format expired subscriptions, overdue payments etc.
=$D2>TODAY() - highlights all future dates (i.e. dates greater than the current date). You can use it to highlight upcoming events.
Of course, there can be infinite variations of the above formulas, depending on your particular task. For instance:
=$D2-TODAY()>=6 - highlights dates that occur in 6 or more days.
=$D2=TODAY()-14 - highlights dates occurring exactly 2 weeks ago.
How to highlight dates within a date range
If you have a long list of dates in your worksheet, you may also want to highlight the cells or rows that fall within a certain date range, i.e. highlight all dates that are between two given dates.
You can fulfil this task using the TODAY() function again. You will just have to construct a little bit more elaborate formulas as demonstrated in the examples below.
Formulas to highlight past dates
- More than 30 days ago:
=TODAY()-$A2>30 - From 30 to 15 days ago, inclusive:
=AND(TODAY()-$A2>=15, TODAY()-$A2<=30) - Less than 15 days ago:
=AND(TODAY()-$A2>=1, TODAY()-$A2<15)
The current date and any future dates are not colored.
Formulas to highlight future dates
- Will occur in more than 30 days from now:
=$A2-TODAY()>30 - In 30 to 15 days, inclusive:
=AND($A2-TODAY()>=15, $A2-TODAY()<=30) - In less than 15 days:
=AND($A2-TODAY()>=1, $A2-TODAY()<15)
The current date and any past dates are not colored.
How to shade gaps and time intervals
In this last example, we are going to utilize yet another Excel date function - DATEDIF(start_date, end_date, interval). This function calculates the difference between two dates based on the specified interval. It differs from all other functions we've discussed in this tutorial in the way that it lets you ignore months or years and calculate the difference only between days or months, whichever you choose.
Don't see how this could work for you? Think about it in another way… Suppose you have a list of birthdays of your family members and friends. Would you like to know how many days there are until their next birthday? Moreover, how many days exactly are left until your wedding anniversary and other events you wouldn't want to miss? Easily!
The formula you need is this (where A is your Date column):
=DATEDIF(TODAY(), DATE((YEAR(TODAY())+1), MONTH($A2), DAY($A2)), "yd")
The "yd" interval type at the end of the formula is used to ignore years and calculate the difference between the days only. For the full list of available interval types, look here.
Tip. If you happen to forget or misplace that complex formula, you can use this simple one instead: =365-DATEDIF($A2,TODAY(),"yd"). It produces exactly the same results, just remember to replace 365 with 366 in leap years : )
And now let's create an Excel conditional formatting rule to shade different gaps in different colors. In this case, it makes more sense to utilize Excel Color Scales rather than create a separate rule for each period.
The screenshot below demonstrates the result in Excel - a gradient 3-color scale with tints from green to red through yellow.
"Days Until Next Birthday" Excel Web App
We have created this Excel Web App to show you the above formula in action. Just enter your events in 1st column and change the corresponding dates in the 2nd column to experiment with the result.
If you are curious to know how to create such interactive Excel spreadsheets, check out this article on how to make web-based Excel spreadsheets.
Hopefully, at least one of the Excel conditional formats for dates discussed in this article has proven useful to you. If you are looking for a solution to some different task, you are most welcome to post a comment. Thank you for reading!
1237 comments
need to apply conditional formatting with time.thanks
i want to know as below :
i have marked a conditional formatting on a particular cell , if the value in the cell exceeds a particular amount then it turns red , i want to know the date when the cell is showing red , so that it becomes an alertness
good day
Could you please assist me I have a spreadsheet with one culm for date and I want each cell to be automatic highlighted with red when it is 3 month old from the current date, yellow when it is 2 month old than current date and green when it is 1 month old from the current date
Thanks in advance for your assist
I have a Spreadsheet where i have to populate the cells for the arrival date of guests.
At the top of the Sheet is the Date the report is for. i.e 7 June
Then further down the columns I populate the names of guests / membership number and arrival date 7 June- which is the same as the date of the report.
what is the code I can use so that when I change the date of the report it auto populates the arrival date of the fields beside all the guests who are arriving on the same date?
Chris:
If all the guests' arrival date will be the same date as the date for the report, you can enter the cell address of the cell from the top of the sheet, let's call it cell A2.
So, in cell B12 where you want to enter a guests' arrival date the formula would look like:
=A2.
If you want to enter this address in the first cell that holds names and dates and then copy it down the column lock that address like this:
=$A$2
Incidentally, enter the names and dates in separate cells. Don't enter different data types in the same cell.
You may even want to enter the first name and last name in two separate cells. This way you can search and analyze the records easier.
Many of the questions here on AbleBits have to do with different data types having been entered in the same cell and now it has to be untangled. All that extra work and aggravation can be avoided by setting up the data entry correctly.
If you want to get fancy you could create a Master List of all the members' names and then use a drop down or lookup field to enter their names. It should be faster and less prone to error. Oh, yeah, there are several options for lots of possible fun with this data.
Hello,
I am working with a spreadsheet with multiple columns that are mainly dates/milestones (for construction projects).
Most of these dates are set at the beginning of a project and these dates can change. One very important date is the "completion date". For all columns/milestones, there is a column right next to it that has the option of A (actualized), P (pending) or N (non-applicable). Because these dates are for the most part entered manually, sometimes a date will get entered (zoning or building permits let's say) will get pushed past the "completion date".
Is there a way to highlight cells that occur after the date of another cell? Additionally, can a rule be entered that only applies to dates with a corresponding P (pending) that occurs after the "completion date" and highlights those specific cells?
Hello,
I have a date (only month and year) let's say in cell A1 and I'm trying to have the cell highlight yellow if it's the month before the date entered and highlight red if it's the same month or later than the month entered. Could you tell me how to do that?
Hi,
I have a spreadsheet with start dates (A2) and end dates (B2) (manually entered). All end dates SHOULD be within 40 days of the start date, so C2 is '40 day date' (using A2+40). I now need to highlight all rows in which the end date falls outside of the 40 day limit. I've tried everything I can think of and all sorts of the ones on here, but nothing is working. Please can someone help?
I have a question. So I have a spreadsheet with start day first column anniversary date second column, I need for third column to be 6 month to round up. so say I was at my job 1 year and 7 months I need it to round to 2 years.
Hi,
I have a spreadsheet with the week commencing dates going across the top of the sheet starting in cell H4.
Is it possible to have a whole column highlighted when the current date is within that week commencing?
Have been able to get just the date cell to highlight but not the rest of the column.
Cheers
Hi,
I'm trying to format actual dates a task was performed vs when it was targeted to be performed.
my formatting is:
cells that contain blank is "white"
cell value less than/equal target is "green"
cell value greater than target is "red"
the formatting worked well until I entered the July dates. Example: I have a target date of 01July18. the actual date performed was 01July18 so the cell should have turned green but it turned red instead. Am I missing something?
Hi,
I'm trying to format actual dates a task was performed vs when it was targeted to be performed.
my formatting is:
cells that contain blank is "white"
cell value target is "red"
the formatting worked well until I entered the July dates. Example: I have a target date of 01July18. the actual date performed was 01July18 so the cell should have turned green but it turned red instead. Am I missing something?
I am trying to conditionally format cells to change colour when a time exceeds 17:00. I think that my problem may be that the cells containing the times I want to conditionally format are derived from another cell containing a date and time.
Could someone please offer up some help, thank you.
Dears
I would like to make date ranges = Some text or month.
Example : 5/01/2018 - 4/01/2018 = January
5/02/2018-4/02/2018=February
Kindly help me.
Input two date ranges - Out put required "Text" (Bill of the month of)
Sorry Date Column Singe only.
Example
01/01/2018 = December 17
02/01/2018 = December 17
03/01/2018 = December 17
04/01/2018 = December 17
05/01/2018 = January 18
upto to
04/02/2018 = January 18
Khursheed:
Where 4/1/2018 is in cell K25 and the date you want to compare it to is in L26 the formula looks like this:
=IF(L26<=$K$25,"December 17","January 18")
You can change the cell addresses to suit your needs.
Note the cell that holds the 4/1/2018 is in K25 and in the formula is an absolute reference indicated by the $. This means that as you copy the formula up or down the column the cell to compare the dates to will always be 4/1/2018.
The formula reads like this, If the value in L26 is equal to or less than the value in K25, then display December 17 otherwise display January 18.
Hi,
Need Help
I want to know the expire date of the certificate is the following formula for conditional formatting is correct?
=AK4>EDATE(TODAY(),3)
Pradnya:
I think it would work better if you put the value for TODAY in another cell and referenced that cell. For example: =AK4>EDATE(AK3,3) would work better. Where the cell AK3 holds the formula TODAY().
Hi team,
I have a query. How do I go about conditional formatting (highlight a whole row) based on the last working day of every month in a data set - loan amortization schedule. For example, if the date is the last working day in a particular month, the whole row is highlighted a particular background colour.
Thank you for your assistance.
Hello,
Thank you for your blog.
I would like to format a column of dates to highlight any date < or + to TODAY, if there is a particular text present in another column of the same row.
Said another way.
I would like the date in Column H to highlight when < or + to TODAY, only if Column D has an "a" or "na" text in it.
I've tried numerous different formulas without success.
Any insight would be greatly appreciated!!!
Thank you.
Please can someone help?
I am wanting to add some formulas to my spreadsheet.
I have column L (which has a date inserted into it) and column M which will also have a date inserted manually once work is completed, BUT I want Column M to turn red if it has been 7 days after the date inserted into column L, only if a date hasn't been entered into column M. Any solutions?
Hi,
I have a column with tenant names, a column with move in dates, and a column with Lease expiration dates.
Without adding an additional column, is it possible to have the column with the move date turn yellow 2 months before the 3 years anniversary without the actual move in date changing? I also would like this to happen every 3 years.
Becky:
Yes, you can do this and some other date related things, too.
To highlight the move date:
Select the cell(s) containing the signing date(s)
Select Conditional Formatting from the ribbon or wherever it is in your version of Excel
Choose New Rule based on formula
enter =TODAY()+60 in the field
Choose the formatting of your choice then OK out and you're finished.
If you want to see in another cell what the status of your tenant's dates are, enter this in another cell where A42 contains the signing date of the lease:
=IF(A42<TODAY()+60,"2 Mos","OK")
If you want to see the day and date their lease expires, enter this in another cell:
=EDATE(A42,36) where "36" is the number of months from the signing date.
When you enter all of this in the various cells, your lease sheet should display a lot of info.
Hi,
I have a column with tenant names, a column with move in dates, and a column with Lease expiration dates.
Without adding an additional column, is it possible to have the column with the move date turn yellow 2 months before the 3 years anniversary without the actual move in date changing? I also would like this to happen every 3 years.
Is this possible?
Is this possible?
im having an issue where i want the date in column B to go red when the date entered has passed but will only change color when column A contains a specific word.