by If you are a regular visitor of this blog, you've probably noticed a few articles covering different aspects of Excel conditional formatting. And now we will leverage this knowledge and create spreadsheets that differentiate between weekdays and weekends, highlight public holidays and display a coming deadline or delay. In other words, we are going to apply Excel conditional formatting to dates.
If you have some basic knowledge of Excel formulas, then you are most likely familiar with some of date and time functions such as NOW, TODAY, DATE, WEEKDAY, etc. In this tutorial, we are going to take this functionality a step further to conditionally format Excel dates in the way you want.
Excel conditional formatting for dates (built-in rules)
Microsoft Excel provides 10 options to format selected cells based on the current date.
- To apply the formatting, you simply go to the Home tab > Conditional Formatting > Highlight Cell Rules and select A Date Occurring.
- Select one of the date options from the drop-down list in the left-hand part of the window, ranging from last month to next month.
- Finally, choose one of the pre-defined formats or set up your custom format by choosing different options on the Font, Border and Fill tabs. If the Excel standard palette does not suffice, you can always click the More colors… button.
- Click OK and enjoy the result! : )
However, this fast and straightforward way has two significant limitations - 1) it works for selected cells only and 2) the conditional format is always applied based on the current date.
Excel conditional formatting formulas for dates
If you want to highlight cells or entire rows based on a date in another cell, or create rules for greater time intervals (i.e. more than a month from the current date), you will have to create your own conditional formatting rule based on a formula. Below you will find a few examples of my favorite Excel conditional formats for dates.
How to highlight weekends in Excel
Regrettably, Microsoft Excel does not have a built-in calendar similar to Outlook's. Well, let's see how you can create your own automated calendar with quite little effort.
When designing your Excel calendar, you can use the =DATE(year,month,date) function to display the days of the week. Simply enter the year and the month's number somewhere in your spreadsheet and reference those cells in the formula. Of course, you could type the numbers directly in the formula, but this is not a very efficient approach because you would have to adjust the formula for each month.
The screenshot below demonstrates the DATE function in action. I used the formula =DATE($B$2,$B$1,B$4) which is copied across row 5.
Tip. If you want to display only the days of the week like you see in the image above, select the cells with the formula (row 5 in our case), right-click and choose Format Cells…> Number > Custom. From the drop-down list under Type, select either dddd or ddd to show full day names or abbreviated names, respectively.
Your Excel calendar is almost done, and you only need to change the color of weekends. Naturally, you are not going to color the cells manually. We'll have Excel format the weekends automatically by creating a conditional formatting rule based on the WEEKDAY formula.
- You start by selecting your Excel calendar where you want to shade the weekends. In our case, it is the range $B$4:$AE$10. Be sure to start the selection with the 1st date column - Colum B in this example.
- On the Home tab, click Conditional Formatting menu > New Rule.
- Create a new conditional formatting rule based on a formula as explained in the above linked guide.
- In the "Format values where this formula is true" box, enter the following WEEKDAY formula that will determine which cells are Saturdays and Sundays:
=WEEKDAY(B$5,2)>5 - Click the Format… button and set up your custom format by switching between the Font, Border and Fill tabs and playing with different formatting options. When done, click the OK button to preview the rule.
Now, let me briefly explain the WEEKDAY(serial_number,[return_type]) formula so that you can quickly adjust it for your own spreadsheets.
- The
serial_numberparameter represents the date you are trying to find. You enter a reference to your first cell with a date, B$5 in our case. - The
[return_type]parameter determines the week type (square brackets imply it is optional). You enter 2 as the return type for a week starting from Monday (1) through Sunday (7). You can find the full list of available return types here. - Finally, you write >5 to highlight only Saturdays (6) and Sundays (7).
The screenshot below demonstrates the result in Excel 2013 - the weekends are highlighted in the reddish colour.
Tips:
- If you have non-standard weekends in your company, e.g. Fridays and Saturdays, then you would need to tweak the formula so that it starts counting from Sunday (1) and highlight days 6 (Friday) and 7 (Saturday) -
WEEKDAY(B$5,1)>5. - If you are creating a horizontal (landscape) calendar, use a relative column (without $) and absolute row (with $) in a cell reference because you should lock the reference of the row - in the above example it is row 5, so we entered B$5. But if you are designing a calendar in vertical orientation, you should do the opposite, i.e. use an absolute column and relative row, e.g. $B5 as you can see in the screenshot below:
How to highlight holidays in Excel
To improve your Excel calendar further, you can shade public holidays as well. To do that, you will need to list the holidays you want to highlight in the same or some other spreadsheet.
For example, I've added the following holidays in column A ($A$14:$A$17). Of course, not all of them are real public holidays, but they will do for demonstration purposes : )
Again, you open Conditional Formatting > New Rule. In the case of holidays, you are going to use either MATCH or COUNTIF function:
=COUNTIF($A$14:$A$17,B$5)>0=MATCH(B$5,$A$14:$A$17,0)
Note. If you have chosen a different color for holidays, you need to move the public holiday rule to the top of the rules list via Conditional Formatting > Manage Rules…
The following image shows the result in Excel 2013:
Conditionally format a cell when a value is changed to a date
It's not a big problem to conditionally format a cell when a date is added to that cell or any other cell in the same row as long as no other value type is allowed. In this case, you could simply use a formula to highlight non-blanks, as described in Excel conditional formulas for blanks and non-blanks. But what if those cells already have some values, e.g. text, and you want to change the background color when text is changed to a date?
The task may sound a bit intricate, but the solution is very simple.
- First off, you need to determine the format code of your date. Here are just a few examples:
- D1: dd-mmm-yy or d-mmm-yy
- D2: dd-mmm or d-mmm
- D3: mmm-yy
- D4: mm/dd/yy or m/d/yy or m/d/yy h:mm
You can find the complete list of date codes in this article.
- Select a column where you want to change the color of cells or the entire table in case you want to highlight rows.
- And now create a conditional formatting rule using a formula similar to this one:
=CELL("format",$A2)="D1". In the formula, A is the column with dates and D1 is the date format.If your table contains dates in 2 or more formats, then use the OR operator, e.g.
=OR(cell("format", $A2)="D1", cell("format",$A2)="D2", cell("format", $A2)="D3")The screenshot below demonstrates the result of such conditional formatting rule for dates.
How to highlight rows based on a certain date in a certain column
Suppose, you have a large Excel spreadsheet that contains two date columns (B and C). You want to highlight every row that has a certain date, say 13-May-14, in column C.
To apply Excel conditional formatting to a certain date, you need to find its numerical value first. As you probably know, Microsoft Excel stores dates as sequential serial numbers, starting from January 1, 1900. So, 1-Jan-1900 is stored as 1, 2-Jan-1900 is stored as 2… and 13-May-14 as 41772.
To find the date's number, right-click the cell, select Format Cells > Number and choose the General format. Write down the number you see and click Cancel because you do not really want to change the date's format.
That was actually the major part of the work and now you only need to create a conditional formatting rule for the entire table with this very simple formula: =$C2=41772. The formula implies that your table has headers and row 2 is your first row with data.
An alternative way is to use the DATEVALUE formula that converts the date to the number format is which it is stored, e.g. =$C2=DATEVALUE("5/13/2014")
Whichever formula you use, it will have the same effect:
Conditionally format dates in Excel based on the current date
As you probably know Microsoft Excel provides the TODAY() functions for various calculations based on the current date. Here are just a few examples of how you can use it to conditionally format dates in Excel.
Example 1. Highlight dates equal to, greater than or less than today
To conditionally format cells or entire rows based on today's date, you use the TODAY function as follows:
Equal to today: =$B2=TODAY()
Greater than today: =$B2>TODAY()
Less than today: =$B2<TODAY()
The screenshot below demonstrates the above rules in action. Please note, at the moment of writing TODAY was 12-Jun-2014.
Example 2. Conditionally format dates in Excel based on several conditions
In a similar fashion, you can use the TODAY function in combination with other Excel functions to handle more complex scenarios. For example, you may want your Excel conditional formatting date formula to color the Invoice column when the Delivery Date is equal to or greater than today BUT you want the formatting to disappear when you enter the invoice number.
For this task, you would need an additional column with the following formula (where E is your Delivery column and F the Invoice column):
=IF(E2>=TODAY(),IF(F2="", 1, 0), 0)
If the delivery date is greater than or equal to the current date and there is no number in the Invoice column, the formula returns 1, otherwise it's 0.
After that you create a simple conditional formatting rule for the Invoice column with the formula =$G2=1 where G is your additional column. Of course, you will be able to hide this column later.
Example 3. Highlight upcoming dates and delays
Suppose you have a project schedule in Excel that lists tasks, their start dates and durations. What you want is to have the end date for each task calculated automatically. An additional challenge is that the formula should also consider the weekends. For example, if the starting date is 13-Jun-2014 and the number of days of work (Duration) is 2, the ending date should come as 17-Jun-2014, because 14-Jun and 15-Jun are Saturday and Sunday.
To do this, we will use the WORKDAY.INTL(start_date,days,[weekend],[holidays]) function, more precisely =WORKDAY.INTL(B2,C2,1).
In the formula, we enter 1 as the 3rd parameter since it indicates Saturday and Sunday as holidays. You can use another value if your weekends are different, say, Fri and Sat. The full list of the weekend values is available here. Optionally, you can also use the 4th parameter [holidays], which is a set of dates (range of cells) that should be excluded from the working day calendar.
And finally, you may want to highlight rows depending on how far away the deadline is. For example, the conditional formatting rules based on the following 2 formulas highlight upcoming and recent end dates, respectively:
=AND($D2-TODAY()>=0,$D2-TODAY()<=7)- highlight all rows where the End Date (column D) is within the next 7 days. This formula is really handy when it comes to tracking upcoming expiration dates or payments.=AND(TODAY()-$D2>=0,TODAY()-$D2<=7)- highlight all rows where the End Date (column D) is within the last 7 days. You can use this formula to track the latest overdue payments and other delays.
Here are a few more formula examples that can be applied to the table above:
=$D2<TODAY() - highlights all passed dates (i.e. dates less than the current date). Can be used to format expired subscriptions, overdue payments etc.
=$D2>TODAY() - highlights all future dates (i.e. dates greater than the current date). You can use it to highlight upcoming events.
Of course, there can be infinite variations of the above formulas, depending on your particular task. For instance:
=$D2-TODAY()>=6 - highlights dates that occur in 6 or more days.
=$D2=TODAY()-14 - highlights dates occurring exactly 2 weeks ago.
How to highlight dates within a date range
If you have a long list of dates in your worksheet, you may also want to highlight the cells or rows that fall within a certain date range, i.e. highlight all dates that are between two given dates.
You can fulfil this task using the TODAY() function again. You will just have to construct a little bit more elaborate formulas as demonstrated in the examples below.
Formulas to highlight past dates
- More than 30 days ago:
=TODAY()-$A2>30 - From 30 to 15 days ago, inclusive:
=AND(TODAY()-$A2>=15, TODAY()-$A2<=30) - Less than 15 days ago:
=AND(TODAY()-$A2>=1, TODAY()-$A2<15)
The current date and any future dates are not colored.
Formulas to highlight future dates
- Will occur in more than 30 days from now:
=$A2-TODAY()>30 - In 30 to 15 days, inclusive:
=AND($A2-TODAY()>=15, $A2-TODAY()<=30) - In less than 15 days:
=AND($A2-TODAY()>=1, $A2-TODAY()<15)
The current date and any past dates are not colored.
How to shade gaps and time intervals
In this last example, we are going to utilize yet another Excel date function - DATEDIF(start_date, end_date, interval). This function calculates the difference between two dates based on the specified interval. It differs from all other functions we've discussed in this tutorial in the way that it lets you ignore months or years and calculate the difference only between days or months, whichever you choose.
Don't see how this could work for you? Think about it in another way… Suppose you have a list of birthdays of your family members and friends. Would you like to know how many days there are until their next birthday? Moreover, how many days exactly are left until your wedding anniversary and other events you wouldn't want to miss? Easily!
The formula you need is this (where A is your Date column):
=DATEDIF(TODAY(), DATE((YEAR(TODAY())+1), MONTH($A2), DAY($A2)), "yd")
The "yd" interval type at the end of the formula is used to ignore years and calculate the difference between the days only. For the full list of available interval types, look here.
Tip. If you happen to forget or misplace that complex formula, you can use this simple one instead: =365-DATEDIF($A2,TODAY(),"yd"). It produces exactly the same results, just remember to replace 365 with 366 in leap years : )
And now let's create an Excel conditional formatting rule to shade different gaps in different colors. In this case, it makes more sense to utilize Excel Color Scales rather than create a separate rule for each period.
The screenshot below demonstrates the result in Excel - a gradient 3-color scale with tints from green to red through yellow.
"Days Until Next Birthday" Excel Web App
We have created this Excel Web App to show you the above formula in action. Just enter your events in 1st column and change the corresponding dates in the 2nd column to experiment with the result.
If you are curious to know how to create such interactive Excel spreadsheets, check out this article on how to make web-based Excel spreadsheets.
Hopefully, at least one of the Excel conditional formats for dates discussed in this article has proven useful to you. If you are looking for a solution to some different task, you are most welcome to post a comment. Thank you for reading!
1237 comments
Hello, I have a sheet where it highlights a products expiry date if it is within 30-60 days of todays date Yellow, Red for 1-30 days Etc. This is set up as a conditional format based on another cell calculating the days. How do I get the formula within the conditional format rules so I can entirely remove the Column doing the calculations to improve the speed of my document? Thank you.
Hello!
I hope you have studied the recommendations in the tutorial above. It contains answers to your question.
Pay attention to the following paragraph of the article above
Hope you’ll find this information helpful.
I have a spreadsheet that keeps track training. One requirement is to complete certain parts within 2 years of employees hire date. I have the start date in one cell, under the employee's name and I have a column for date complete. Want to fill the date complete cell with colors depending on if they have gone over their 24 month due date, if they are within 6 months of their due date and when they have a year left on their complete date. I believe I need and If AND formula where I can say if the date complete cell is blank and the hire date is either greater than or equal to the 730 days, 550 days or the 365 days, it fills with the appropriate color. Unable to get my formulas correct to do so. Can you help?
Hello!
I hope you have studied the recommendations in the above tutorial.
Pay attention to this section.
Please specify what formula you used and what problem or error occurred.
Hello,
I'm trying to have the cells for column G turn green if there are dates entered in columns E and F. If there are no dates entered I want the cells in column G to be red. If there is one date entered in either cell E or F, I want the cells in column G to yellow.
Thank you for your help.
Hello!
To conditionally format a cell with a date, you can use the formula
=LEFT(@CELL("format",A1),1)="D"
It returns TRUE if any of the standard date and time formats are applied in the cell.
Hi
I need help!
I'm trying to come up with an Excel dashboard whereby the end result will be traffic light.
The input for this traffic light which to be displayed on the dashboard will be project completion (%) vs it's Go-Live/Handover date.
The traffic light on the dashboard is meant to tell you whether you are on track or not when the project completion is measured against the time you have left.
I've tried using several formulas but none worked and I'm no expert in Excel. Hope some of you can help me out here!
Thanks!
Hello! I am creating a calendar in excel (and trying to avoid using vba, since I know nothing about the programming side of things!). What I am trying to do now, is use conditional formatting to highlight(/grey out) dates not in the current month. I saw on another site this formula:=MONTH(B5)MONTH($B$6), where B5 is the month dropdown list.
Currently, my spreadsheet has this in it:
1. dropdown lists for year in B2, and month in C2.
2. A formula to change the dates based on the selected year and month, which is copied to all the "calendar boxes":
=DATE($B$2,MATCH($C$2,{"January";"February";"March";"April";"May";"June";"July";"August";"September";"October";"November";"December"},0),1)-WEEKDAY(DATE($B$2,MATCH($C$2,{"January";"February";"March";"April";"May";"June";"July";"August";"September";"October";"November";"December"},0),1),2)
3. I also have this rule:
=B6=TODAY() which applies to my "calendar boxes", range B6:H41. It highlights the current day in blue.
Any help would be much appreciated!
Hello Katie!
If I understand your task correctly, the following formula conditional formatting should work for you:
=IF(AND(MONTH(B1)=MONTH(TODAY()),YEAR(B1)=YEAR(TODAY())),TRUE,FALSE)
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hi! Can anyone help me with this concern? :) I was trying to find the formula where the cell will be highlighted in the specified colors below when the ff conditions are met:
EG: The exact date or deadline is July 24, 2020.
2 days before deadline (Jul 22) = yellow
1 days before deadline (Jul 23) = light red
deadline (Jul 24) = red
overdue (Jul 25 onwards) = dark red
Is there any way we can do that in googlesheets? Thank you for the help!
Hello!
I hope you have studied the recommendations in the above tutorial.
There are answers to all your questions.
Describe in detail what problem you have, and I will try to help you
DATE :15/07/2020
S.NO DATE DC NO FINANCE DC NO CUSTOMER NAME VEHICLE MODEL CASH MODE DOWNPAYMENT CHEQUE AMT DO NUMBER
please help one this. i have mentioned colums in excelsheet. for me if date is more than 5 days if cheque amount not received then it should be popup in red colour otherwise in green color. please send me formula in my email id.
Thanks
Hello!
Check out the recommendations in the article above. Also read about using formulas in conditional formatting. If after that you have specific questions, I will try to answer them
Hi Alexander, Thanks for the guide, Really Helpful!!
I have a question regarding conditional formatting dates which have passed due, only if the the task is not close or not completed.
For Info Start Date - Column C, End date - Column D, Task Status Column H, Today's Date - Cell J1, Date format dd.mm.yy.
Many Thanks In Advance
Becki
Hello Becki!
I’m sorry but your task is not entirely clear to me.
Please describe your problem in more detail. Include an example of the source data and the result you want to get. It’ll help me understand your request better and find a solution for you. Thank you.
Hi Alexander,
Apologies for the vagueness in the original post.
please see below sample data:
Task Name Start Date End date Status today's date =TODAY()
task 1 29.06.20 29.06.20 completed
task 3 23.06.20 25.06.20 closed
task 4 01.07.20 04.07.20 at risk
task 5 04.07.20 06.07.20 in progress
I want to highlight the end date when it is passed today's date, but only if the task status is not Completed or closed.
Many Thanks
Becki
Hello Becki!
Use this formula for conditional formatting
=IF(AND($D1 < TODAY(),$H1 <> "closed",$H1 <> "completed"),TRUE,FALSE)
I hope my advice will help you solve your task.
HI Alexander,
Is there more formula?
Many Thanks
Becki
HI Alexander, If there more to the formula than posted?
Thanks
Becki
Hello Becki!
Use this formula for conditional formatting
=IF(AND($D1 < TODAY(),$H1 <> "closed",$H1 <> "completed"),TRUE,FALSE)
I hope my advice will help you solve your task.
Hello,
I am a case manager and complete needs assessments on a certain example 6/22/2020. I then have to bill on that date each month. How would I create a formula to become red 5 Days before that date each month. As I would want that cell to become red on 7/17/2020, 8/17/2020 and 9/17/2020. But then be a normal color the rest of the month? Does this make sense. Any assistance would be helpful. Thanks- Stacey
Hello Stacey!
If I understand your task correctly, to make the cell turn red every 17th day of the month, use the formula in the conditional formatting rule
=IF(DAY(TODAY())=17,TRUE,FALSE)
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hello Alexander,
i have that has column C as start date and column D as end date. i want to highlight the cells from G12 to AD12 which is a two year span but divided in months.
so based on the day i input in column C start, and D end. it highlights the cell under the month. Note, i am not using days in the highlight section, only months. but using days in C and D.
i used this formula for days only, but i need days to work with months.
=AND($G$10>=$C12, $G$10<=$D12)
C12 and D12 is where i input the start and end dates (days) G10 to AD10 is where the months are located (01-January-2020, 01-February-2020, 01-March-2020, etc.)
Appreciate the support and thank you in advance.
i figured it out, after days of troubleshooting. i made a simple mistake in the code. instead of this =AND($G$10>=$C12, $G$10=$C12, G$10<=$D12)
and now it works the way i wanted it.
Hello!
I’m sorry but your task is not entirely clear to me. Поясните подробнее, что означает: "i used this formula for days only, but i need days to work with months."
Please describe your problem in more detail. Include an example of the source data and the result you want to get. It’ll help me understand your request better and find a solution for you. Thank you.
Hello, I have a spreadsheet with forklift certificate training and expiry dates in two adjacent columns. The first column is the date of the training and the second column is the date that the training needs to be refreshed. I would like the second column to highlight 30 days before the date in the cell, every date in this column is different as no two training sessions occur on the same day, so I have 22 rows of different dates in the second column, it is these I would like to highlight 30 days before the date I am an excel beginner so any help would be greatly appreciated
Hello John!
I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Explain: "I would like the second column to highlight 30 days before the date in the cell". Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you. Thank you.
Hi Alexander, thanks for the reply,
so i have two columns with 22 rows and each row has a different date in it, the date in the first column is when the training occurred,
the second column has the dates that the training expires, so in column 2 it is the same date as column one + three years (training is valid for three years)
e.g 1st column has 01/02/19 in the cell
and the second column has 01/02/22
What i'd like to have is the date in the second column to highlight one month before the date shown e.g on 01/01.22 i'd like the cell in column two to turn red.
Basically id like the dates in column two to turn red one month before the dates in the cells to remind me that the date of expiry of the training is approaching!
I hope that makes more sense!
Thank you
Hello John!
I hope you have studied the recommendations in the above tutorial. You'll need to set the conditional formatting rule for column B with the following formula applied:
=AND(TODAY() > EDATE(B1,-1),TODAY()<B1)
And choose red as a color to fill the cell with.
I hope this is exactly what you need.
Hi guys,
Could you please help with conditional formation for a day occuring (for example 26th) of each month to be highlighted. Well appreciated.
Also if some one knows how to sort date in pivot table for the Invoice period from 26th of each month. As everymonth is a different number of days, I can't use the period with fixed number of days. Kind of desparate to complete my task.
Eddy
Hello Eddy!
If I understand your task correctly,use a formula for conditional formatting
=DAY($B2)=26
B2 - the first cell of the date range to be highlighted.
I need a spreadsheet to highlight cells in column c if the cell is greater than 16 and if column a is a Monday, Wednesday or Friday
Hello Melanie!
If I understand correctly, you can use the formula for conditional formatting
=IF(AND(C1 > 16,OR(A1="Monday",A1="Friday",A1="Wednesday")),TRUE,FALSE)
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hi - I have 2 date columns (E baseline date) (F revised date) how can I set formatting that if (F) is equal to (E) green; if (F) is 15 days over then amber; if (F) is 30 days over then red;
I have used 'AND' and 'IF' formula and I get partly cells in (F) green and nothing else.
Help please!
Thank you
Sara.
Hello Sara!
You need to create a separate rule for each condition. I recommend that you study the instructions on the order in which conditional formatting rules are followed.
I hope this will help, otherwise please do not hesitate to contact me anytime.
Please help! I have a sheet where a particular item expires every 2 year. What I'm trying to do is have the conditional formatting come into effect when the 23 month marks hits; and I have no idea if this is even possible. The original date is in the format dd-mmm-yy and is starts in the F4 spot. Any help would be much appreciated. Thanks!
Hello Jeff!
Please go to Conditional Formatting- > New Rule -> Use a formula to determine which cells to format and set the following formula for column A:
=EOMONTH($A1,23) > TODAY()
Hope this is what you need.
Thank you, I was able to combine and redefine your formulas! You made my life much easier.
I would appreciate it if someone can assist me with a date formula :
I have 2 cells A1 and A5
In cell A1 is todays date then Cell A5 should shows current month and Year if todays date is between the 1st and the 15 of current month but if todays date is between the 16 and end of month Cell A5 should change to next month and related year.
For instance
A1 20/04/2020 then A5 should be
May20
If A1 14/04/2020 then A5 should be Apr20
Any help would be highly appreciated
Leon
Hello Leon!
If I understand your task correctly, the following formula in cell A5 should work for you:
=IF(DAY(A1)<=15,A1,DATE(YEAR(A1),MONTH(A1)+1,DAY(A1)))
If it is necessary to change the date format without changing the date itself, Custom Format in A5 should be used. Please go to Format Cells, choose Number -> Custom Format and set "mmmyy"
I hope this will help, otherwise please do not hesitate to contact me anytime.
i have a table for security report with date 1 as starting date and the whole month is triggered by change of month. i used date value and EOMONTH FORMULAS TO ESTABLISH THE CALENDAR. So each date relies on previous date because there is a formula. above the cells is names of days from Monday to Sunday which changes when i change the month because the boxes have formulas too but i format them to "ddd" only to show day name. for this am unable to highlight weekends with conditional formatting for "sun" & "sat". how can i make it.
Hello Peter!
Please check out the second paragraph of this article https://www.ablebits.com/office-addins-blog/excel-conditional-formatting-dates/#highlight-weekends
I hope this will help, otherwise please do not hesitate to contact me anytime.
I need help. I have a start date in column B and end date in column C. Column E to P are the months of the year. I want column E to P to reflect the start and end date with colour blue, for eg if i hv January in column B, and June in column C, then only columns E to J turn blue. How should I do it? Am totally new with Excel!
Hello Flora!
You may use Conditional Formatting- > New Rule -> Use a formula to determine which cells to format and set the following formulas:
For column E:
=$C1 > DATE(2020,1,1)
For column F:
=$C1 > DATE(2020,2,1)
For column G
=$C1 > DATE(2020,3,1)
etc.
I have a spreadsheet with a column that is a date format. I am needing a way to set a conditional rule for invalid dates ie 09/31/2020 to highlight the cell red.
With this I need it to trigger if the data is copied and pasted from one sheet to another or a way once I have all the data in the new sheet that I can run a macro to trigger all the rules on all the cells.