by If you are a regular visitor of this blog, you've probably noticed a few articles covering different aspects of Excel conditional formatting. And now we will leverage this knowledge and create spreadsheets that differentiate between weekdays and weekends, highlight public holidays and display a coming deadline or delay. In other words, we are going to apply Excel conditional formatting to dates.
If you have some basic knowledge of Excel formulas, then you are most likely familiar with some of date and time functions such as NOW, TODAY, DATE, WEEKDAY, etc. In this tutorial, we are going to take this functionality a step further to conditionally format Excel dates in the way you want.
Excel conditional formatting for dates (built-in rules)
Microsoft Excel provides 10 options to format selected cells based on the current date.
- To apply the formatting, you simply go to the Home tab > Conditional Formatting > Highlight Cell Rules and select A Date Occurring.
- Select one of the date options from the drop-down list in the left-hand part of the window, ranging from last month to next month.
- Finally, choose one of the pre-defined formats or set up your custom format by choosing different options on the Font, Border and Fill tabs. If the Excel standard palette does not suffice, you can always click the More colors… button.
- Click OK and enjoy the result! : )
However, this fast and straightforward way has two significant limitations - 1) it works for selected cells only and 2) the conditional format is always applied based on the current date.
Excel conditional formatting formulas for dates
If you want to highlight cells or entire rows based on a date in another cell, or create rules for greater time intervals (i.e. more than a month from the current date), you will have to create your own conditional formatting rule based on a formula. Below you will find a few examples of my favorite Excel conditional formats for dates.
How to highlight weekends in Excel
Regrettably, Microsoft Excel does not have a built-in calendar similar to Outlook's. Well, let's see how you can create your own automated calendar with quite little effort.
When designing your Excel calendar, you can use the =DATE(year,month,date) function to display the days of the week. Simply enter the year and the month's number somewhere in your spreadsheet and reference those cells in the formula. Of course, you could type the numbers directly in the formula, but this is not a very efficient approach because you would have to adjust the formula for each month.
The screenshot below demonstrates the DATE function in action. I used the formula =DATE($B$2,$B$1,B$4) which is copied across row 5.
Tip. If you want to display only the days of the week like you see in the image above, select the cells with the formula (row 5 in our case), right-click and choose Format Cells…> Number > Custom. From the drop-down list under Type, select either dddd or ddd to show full day names or abbreviated names, respectively.
Your Excel calendar is almost done, and you only need to change the color of weekends. Naturally, you are not going to color the cells manually. We'll have Excel format the weekends automatically by creating a conditional formatting rule based on the WEEKDAY formula.
- You start by selecting your Excel calendar where you want to shade the weekends. In our case, it is the range $B$4:$AE$10. Be sure to start the selection with the 1st date column - Colum B in this example.
- On the Home tab, click Conditional Formatting menu > New Rule.
- Create a new conditional formatting rule based on a formula as explained in the above linked guide.
- In the "Format values where this formula is true" box, enter the following WEEKDAY formula that will determine which cells are Saturdays and Sundays:
=WEEKDAY(B$5,2)>5 - Click the Format… button and set up your custom format by switching between the Font, Border and Fill tabs and playing with different formatting options. When done, click the OK button to preview the rule.
Now, let me briefly explain the WEEKDAY(serial_number,[return_type]) formula so that you can quickly adjust it for your own spreadsheets.
- The
serial_numberparameter represents the date you are trying to find. You enter a reference to your first cell with a date, B$5 in our case. - The
[return_type]parameter determines the week type (square brackets imply it is optional). You enter 2 as the return type for a week starting from Monday (1) through Sunday (7). You can find the full list of available return types here. - Finally, you write >5 to highlight only Saturdays (6) and Sundays (7).
The screenshot below demonstrates the result in Excel 2013 - the weekends are highlighted in the reddish colour.
Tips:
- If you have non-standard weekends in your company, e.g. Fridays and Saturdays, then you would need to tweak the formula so that it starts counting from Sunday (1) and highlight days 6 (Friday) and 7 (Saturday) -
WEEKDAY(B$5,1)>5. - If you are creating a horizontal (landscape) calendar, use a relative column (without $) and absolute row (with $) in a cell reference because you should lock the reference of the row - in the above example it is row 5, so we entered B$5. But if you are designing a calendar in vertical orientation, you should do the opposite, i.e. use an absolute column and relative row, e.g. $B5 as you can see in the screenshot below:
How to highlight holidays in Excel
To improve your Excel calendar further, you can shade public holidays as well. To do that, you will need to list the holidays you want to highlight in the same or some other spreadsheet.
For example, I've added the following holidays in column A ($A$14:$A$17). Of course, not all of them are real public holidays, but they will do for demonstration purposes : )
Again, you open Conditional Formatting > New Rule. In the case of holidays, you are going to use either MATCH or COUNTIF function:
=COUNTIF($A$14:$A$17,B$5)>0=MATCH(B$5,$A$14:$A$17,0)
Note. If you have chosen a different color for holidays, you need to move the public holiday rule to the top of the rules list via Conditional Formatting > Manage Rules…
The following image shows the result in Excel 2013:
Conditionally format a cell when a value is changed to a date
It's not a big problem to conditionally format a cell when a date is added to that cell or any other cell in the same row as long as no other value type is allowed. In this case, you could simply use a formula to highlight non-blanks, as described in Excel conditional formulas for blanks and non-blanks. But what if those cells already have some values, e.g. text, and you want to change the background color when text is changed to a date?
The task may sound a bit intricate, but the solution is very simple.
- First off, you need to determine the format code of your date. Here are just a few examples:
- D1: dd-mmm-yy or d-mmm-yy
- D2: dd-mmm or d-mmm
- D3: mmm-yy
- D4: mm/dd/yy or m/d/yy or m/d/yy h:mm
You can find the complete list of date codes in this article.
- Select a column where you want to change the color of cells or the entire table in case you want to highlight rows.
- And now create a conditional formatting rule using a formula similar to this one:
=CELL("format",$A2)="D1". In the formula, A is the column with dates and D1 is the date format.If your table contains dates in 2 or more formats, then use the OR operator, e.g.
=OR(cell("format", $A2)="D1", cell("format",$A2)="D2", cell("format", $A2)="D3")The screenshot below demonstrates the result of such conditional formatting rule for dates.
How to highlight rows based on a certain date in a certain column
Suppose, you have a large Excel spreadsheet that contains two date columns (B and C). You want to highlight every row that has a certain date, say 13-May-14, in column C.
To apply Excel conditional formatting to a certain date, you need to find its numerical value first. As you probably know, Microsoft Excel stores dates as sequential serial numbers, starting from January 1, 1900. So, 1-Jan-1900 is stored as 1, 2-Jan-1900 is stored as 2… and 13-May-14 as 41772.
To find the date's number, right-click the cell, select Format Cells > Number and choose the General format. Write down the number you see and click Cancel because you do not really want to change the date's format.
That was actually the major part of the work and now you only need to create a conditional formatting rule for the entire table with this very simple formula: =$C2=41772. The formula implies that your table has headers and row 2 is your first row with data.
An alternative way is to use the DATEVALUE formula that converts the date to the number format is which it is stored, e.g. =$C2=DATEVALUE("5/13/2014")
Whichever formula you use, it will have the same effect:
Conditionally format dates in Excel based on the current date
As you probably know Microsoft Excel provides the TODAY() functions for various calculations based on the current date. Here are just a few examples of how you can use it to conditionally format dates in Excel.
Example 1. Highlight dates equal to, greater than or less than today
To conditionally format cells or entire rows based on today's date, you use the TODAY function as follows:
Equal to today: =$B2=TODAY()
Greater than today: =$B2>TODAY()
Less than today: =$B2<TODAY()
The screenshot below demonstrates the above rules in action. Please note, at the moment of writing TODAY was 12-Jun-2014.
Example 2. Conditionally format dates in Excel based on several conditions
In a similar fashion, you can use the TODAY function in combination with other Excel functions to handle more complex scenarios. For example, you may want your Excel conditional formatting date formula to color the Invoice column when the Delivery Date is equal to or greater than today BUT you want the formatting to disappear when you enter the invoice number.
For this task, you would need an additional column with the following formula (where E is your Delivery column and F the Invoice column):
=IF(E2>=TODAY(),IF(F2="", 1, 0), 0)
If the delivery date is greater than or equal to the current date and there is no number in the Invoice column, the formula returns 1, otherwise it's 0.
After that you create a simple conditional formatting rule for the Invoice column with the formula =$G2=1 where G is your additional column. Of course, you will be able to hide this column later.
Example 3. Highlight upcoming dates and delays
Suppose you have a project schedule in Excel that lists tasks, their start dates and durations. What you want is to have the end date for each task calculated automatically. An additional challenge is that the formula should also consider the weekends. For example, if the starting date is 13-Jun-2014 and the number of days of work (Duration) is 2, the ending date should come as 17-Jun-2014, because 14-Jun and 15-Jun are Saturday and Sunday.
To do this, we will use the WORKDAY.INTL(start_date,days,[weekend],[holidays]) function, more precisely =WORKDAY.INTL(B2,C2,1).
In the formula, we enter 1 as the 3rd parameter since it indicates Saturday and Sunday as holidays. You can use another value if your weekends are different, say, Fri and Sat. The full list of the weekend values is available here. Optionally, you can also use the 4th parameter [holidays], which is a set of dates (range of cells) that should be excluded from the working day calendar.
And finally, you may want to highlight rows depending on how far away the deadline is. For example, the conditional formatting rules based on the following 2 formulas highlight upcoming and recent end dates, respectively:
=AND($D2-TODAY()>=0,$D2-TODAY()<=7)- highlight all rows where the End Date (column D) is within the next 7 days. This formula is really handy when it comes to tracking upcoming expiration dates or payments.=AND(TODAY()-$D2>=0,TODAY()-$D2<=7)- highlight all rows where the End Date (column D) is within the last 7 days. You can use this formula to track the latest overdue payments and other delays.
Here are a few more formula examples that can be applied to the table above:
=$D2<TODAY() - highlights all passed dates (i.e. dates less than the current date). Can be used to format expired subscriptions, overdue payments etc.
=$D2>TODAY() - highlights all future dates (i.e. dates greater than the current date). You can use it to highlight upcoming events.
Of course, there can be infinite variations of the above formulas, depending on your particular task. For instance:
=$D2-TODAY()>=6 - highlights dates that occur in 6 or more days.
=$D2=TODAY()-14 - highlights dates occurring exactly 2 weeks ago.
How to highlight dates within a date range
If you have a long list of dates in your worksheet, you may also want to highlight the cells or rows that fall within a certain date range, i.e. highlight all dates that are between two given dates.
You can fulfil this task using the TODAY() function again. You will just have to construct a little bit more elaborate formulas as demonstrated in the examples below.
Formulas to highlight past dates
- More than 30 days ago:
=TODAY()-$A2>30 - From 30 to 15 days ago, inclusive:
=AND(TODAY()-$A2>=15, TODAY()-$A2<=30) - Less than 15 days ago:
=AND(TODAY()-$A2>=1, TODAY()-$A2<15)
The current date and any future dates are not colored.
Formulas to highlight future dates
- Will occur in more than 30 days from now:
=$A2-TODAY()>30 - In 30 to 15 days, inclusive:
=AND($A2-TODAY()>=15, $A2-TODAY()<=30) - In less than 15 days:
=AND($A2-TODAY()>=1, $A2-TODAY()<15)
The current date and any past dates are not colored.
How to shade gaps and time intervals
In this last example, we are going to utilize yet another Excel date function - DATEDIF(start_date, end_date, interval). This function calculates the difference between two dates based on the specified interval. It differs from all other functions we've discussed in this tutorial in the way that it lets you ignore months or years and calculate the difference only between days or months, whichever you choose.
Don't see how this could work for you? Think about it in another way… Suppose you have a list of birthdays of your family members and friends. Would you like to know how many days there are until their next birthday? Moreover, how many days exactly are left until your wedding anniversary and other events you wouldn't want to miss? Easily!
The formula you need is this (where A is your Date column):
=DATEDIF(TODAY(), DATE((YEAR(TODAY())+1), MONTH($A2), DAY($A2)), "yd")
The "yd" interval type at the end of the formula is used to ignore years and calculate the difference between the days only. For the full list of available interval types, look here.
Tip. If you happen to forget or misplace that complex formula, you can use this simple one instead: =365-DATEDIF($A2,TODAY(),"yd"). It produces exactly the same results, just remember to replace 365 with 366 in leap years : )
And now let's create an Excel conditional formatting rule to shade different gaps in different colors. In this case, it makes more sense to utilize Excel Color Scales rather than create a separate rule for each period.
The screenshot below demonstrates the result in Excel - a gradient 3-color scale with tints from green to red through yellow.
"Days Until Next Birthday" Excel Web App
We have created this Excel Web App to show you the above formula in action. Just enter your events in 1st column and change the corresponding dates in the 2nd column to experiment with the result.
If you are curious to know how to create such interactive Excel spreadsheets, check out this article on how to make web-based Excel spreadsheets.
Hopefully, at least one of the Excel conditional formats for dates discussed in this article has proven useful to you. If you are looking for a solution to some different task, you are most welcome to post a comment. Thank you for reading!
1237 comments
Dear Sir,
I have 2 issues.
1. Have XLs in which 3 colums idicate date of completion, how I can highlight earloest date in each raw?
2. In next column next action date written.
I want to compare it with above earliest date and if it is late , how can I highlight that cells?
Hi! Find the minimum value in column A using the MIN function. For column B, try the conditional formatting formula:
=AND(B1>A1,A1=MIN($A$1:$A$10))
Hi Alex,
It would so helpful if you could help me in sorting out the steps
A2= "=Today()" for ex. we can take it has 4/29/2023
B2(Start date) = 4/25/2023
C2(End Date) = 4/29/2023
D2 = I need to validate the formula which is
IF(A2= B2, it should "Delivering",
IF(A2> C2,"Completed")))),
Here am not getting the status as completed when date(C2) is actually completed
Hi! Combine these two conditions into one formula using these guidelines: Nested IF in Excel – formula with multiple conditions.
You all are so helpful! I am trying to create a spreadsheet to show past dates (completed) in green and today and future dates (not completed) in yellow. I currently have the following formatting: cell contains a blank value -no fill, =$G2>TODAY() -yellow fill, =$G2<TODAY() -green fill. The rules are in this order.
The blanks are correct, however anything I type a date in, regardless past or future, it fills in green. Any suggestions?
Hi! Unfortunately, I cannot check how you created the conditional formatting in your workbook. Note that the conditional formatting formula must match the conditional formatting range. In your case, the conditional formatting range should start on row 2. All the necessary information is in the article above.
I would like to create a yearly calendar (2023) month by month. I have completed this on my own manually, however, it took a long time. I am wondering if you have a template?
Hello! Your personal drop-down calendar and date calculator is Excel Date Picker. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
Hi,
I have a spreadsheet which records 2 different types of inspection date. Inspection 1 and Inspection 2, i would like a formula to automatically create the next inspection date which will be in 3 years time, on a week day, based on whichever inspection date was the latest,
Can this be done?
Thanks,
I am hoping you can help with a formula.
In column A, I have a date in which an account entered a work queue. In column L I have different statuses in a list. I want the status to automatically change to "Proceed with Write-off - Status Unchanged" if the account has remained unworked for 14 days.
Also, the statuses are pulling from another spreadsheet in this workbook "Column Options" and are located in Q2-Q7.
Hi! Without having your data, it is impossible to offer you a formula. To change the status after comparing dates, use these instructions: Excel IF between two dates. I hope it’ll be helpful.
Hi there,
Hope you can help.
I have a dynamic calendar excel template with drop down list of months. Need to highlight certain days of a particular months, but it keeps highlighting those same days across all months. How do I break the link so that it highlights what I choose in a month, not same day in every month?
Hope I am making sense.
Thanks,
Hi!
I can help with Excel formula. But can't help setting up a dynamic calendar, which I don't have.
I have a spread sheet that already has the autodate generated in cells A2 and A27. Now I'd like to have the deposit numbers in cell B1 and B26 increase by 2 digits automatically when the document opens just like the autdate. For example, let's say my deposit numbers for today April 13, 2023 are K105 (B1) and K108 (B26). I'd like to open the spreadsheet tomorrow, have the current date along with cells B1 and B26 showing K107 and K110, the day's deposit numbers.
Kindest Regards
Hi!
If I got you right, the formula below will help you with your task:
="K"&(105+(TODAY()-DATE(2023,4,13))*2)
Hi.
Please could you help with the following conditional formatting formula?
I have 2 columns.
Column D is headed 'Response Required By'. This column contains a date that I need a response from a supplier by.
Column E is headed ' Response Received'. This column remains blank until the supplier's response is received and the date is entered manually.
The conditional formatting I am trying to apply is as follows:
If the supplier has not responded within 5 days of the 'Response Required By' date (column D), then I want to highlight the blank cell in column E as AMBER
If the supplier has not responded within 1 day of the 'Response Required By' date (column D), then I want to highlight the blank cell in column E as RED
When the supplier has responded and their response date is entered manually into column E, I want the cell in Column E to be highlighted in GREEN
Many thanks
Have you tried the ways described in this blog post? If they weren't effective, please provide me with more details about your task.
So I work at a prison and have a worksheet that tracks dates for inmate reviews based on the date they entered our unit. They need to be reviewed once every 7 days for the first 2 months, then once per month after that (this part I have covered). We have our meetings to review on Tuesdays and Fridays. So the review periods go from Friday-Monday and from Tuesday-Thursday. So for this week the dates for review periods would be 04/07/23-04/10/23 and 04/11/23-04/13/23. Do you know how to have dates that fall into these review periods automatically highlighted as we are in them and when they will be the next review period. Thanks! :)
Hi!
I'm not quite sure what dates you want to be highlighted. The dates you specified are the entire week of 04/07/23 to 04/13/23. Please describe your problem in more detail.
OK. The dates I provided are just an example using the current week. I need dates that fall on Fridays-Mondays and Tuesdays-Thursdays separately highlighted, but also only highlighted when we are within that timeframe and when they will be the next period. So for example, today is Wednesday the 12th, so we would currently be in the Tuesday-Thursday period. So I would want any dates appearing in that period to be highlighted (in say green). And the next period would be Friday-Monday starting on the 14th. I would want dates that fall into that next period highlighted differently (say orange) to let me easily see that they are upcoming. Once we reach Friday, then the Friday-Monday period would then be green and the upcoming Tuesday-Thursday period would be orange. And so on.
Hi!
A conditional formatting formula to highlight the days Tuesday through Thursday:
=AND(WEEKDAY(A1,12)<4,ABS(TODAY()-A1)<3)
You can learn more about WEEKDAY function in Excel in this article on our blog.
Hello,
I am trying to format a cell once a date has expired. Specifically, on 10/1/2023 I need every date that was entered in a column, that has passed to change format. However, I am trying to avoid just writing a new conditional format rule on 10/1/2023. Instead I would prefer the formatting indicate what has passed. Also I would like to keep it moving forward for the end of each fiscal year.
Hi!
You can see all the possible ways for conditional date formatting above. You can use a reference to the cell with the desired date in the formula so that you don't have to change the formula manually.
Hi,
I am trying to set up a sheet with conditional formatting. Ex. B4 has a target date with B3 being -7 days and B5 being +7 days. I want B6 to turn green if it is between those two dates. I know how to do this for one cell, but I need to do it for C-P as well. Is there a way to do this?
Hi!
Select a range of cells (eg B6:P6) and apply your conditional formatting rule to it. Read more in this guide: Relative and absolute cell references in Excel conditional formatting.
Hi,
I hope you can assist. I am trying to create a rule that will highlight and strike through the cells value if another cells date displays a date of the 22nd day or before.
For example
if C1 is filled with 9/23/2023 the target cell will be unchanged
if C1 is filled with 9/21/2023 the target cell will turn red with text strike through.
The date in C1 will constantly be changing ranging from 1930's to current.
Hi!
Use the DAY function to determine the day of the month from a date. Create a conditional formatting rule for dates with this formula.
=DAY(C1)<23
Hi! Hoping you can help. I am trying to create a formula rule to highlight a cell range based on one cell but for multiple options.
E.g. Cell C4 has a date of 21/3/2021, and D4 has a date of 19/02/1998; I am trying to create a rule to highlight date ranges in different colours. 5 years.
Then I want to use that to highlight C4,5,6,7 etc., based on that range.
I have tried using an if and statement and a datedif statement, but it doesn't seem to want to work. Is this at all possible?
Thanks!
Sorry, date ranges would be Under 1 year, 1-2 years, 2-5 years and over 5 years.
Hi!
Select the range of cells for conditional formatting. For example, C4:C10. Create a conditional formatting rule with the formula
=DATEDIF(D4,C4,"y")>5
Note that the formula must refer to the first cell of the range.
You can learn more about DATEDIF function in this article: Excel DATEDIF to calculate date difference in days, weeks, months or years.
Thanks! I have tried to make the next selection of between 1 & 2 years, and 2 and 5 years, The formula works (no error) but it is not highlighting...
=AND((DATEDIF($G$4,$B$1,"Y")>1),(DATEDIF($G$4,$B$1,"Y")<2))
Have I used the right formula?
Thanks again
SORTED!
=AND((DATEDIF($G$4,$B$1,"M")>24),(DATEDIF($G$4,$B$1,"M")<60))
I changed it to months :)
Thanks!
The conditions in your formula cannot be met at the same time. Perhaps you should use >= and <=
Hello,
I have a set of dates for various personnel training attended, that expire within 1 year, 2 years, 3 years and so on. I would like to use conditional formatting to turn the cells yellow when they are 90 days out from expiry and red when the dates have expired. I can't seem to find the right combinations of rules to make this work, as most are based on the current date in excel rather than the given date in the cell. Please help!
Thank you.
Hi! Replace the TODAY() function in the conditional formatting date formulas you see above in the article with a cell reference. Instead of =TODAY()-$A2>30 write =$A1-$A2>30
Hi,
I’m trying to get the following formulas to work on the same table but they won’t work together, it’s like they cancel each other out
=AND($D2-TODAY()>=0,$D2-TODAY()=0,TODAY()-$D2<=7)
I also want to be able to get it to work for multiple end dates but it won’t allow the formula to work on more than one row.
Please help
Hi! The second condition repeats the first. The third condition contradicts the second. The formula will always return FALSE.
Ok so how do I get it to work to show both when it’s exceeded deadline and when it’s close to deadline?
And is it possible to have it work for multiple deadline dates
You want me to use your wrong formula to guess what you want to do. Pay attention to the following paragraph of the article above: How to highlight dates within a date range.
Now can I formulate a date that actually says the month. "January 2" instead of 1/2 or 2 Jan or the others?
Hi!
If a cell has a date in it, you can change its format as described in this article: How to change Excel date format and create custom formatting. For example, "mmmm d".
Hi, I'm trying to set up an employee directory that has the weekdays and times they're available. I currently have two cells that have the formula =NOW() (with one having the custom format to display "Fri" and the other to display hh:mm:ss am/pm). I would like to change the cells change colour to red if the day is Friday and they are not working (ie if they only work Mon-Thu etc). How would I go about conditionally formatting this?
Hi!
To define the number of the day of the week, use the WEEKDAY formula.
Here's an example of a conditional formatting formula for Friday:
=WEEKDAY(A1,2)=5
Hello -
I'm trying to set up an inspection record template with separate Receipt Date and Expiration Date cells, where the Expiration Date cell will be automatically highlighted if the value entered there is <12 months from the Receipt Date. The Receipt Date will not always be the same date that the record is getting filled out, which is where I'm running into trouble. Please help?
Hello!
I'm not sure what the problem is with the Receipt Date and why you can't use the recommendations in the article above. I think this tutorial will help you calculate the difference between Receipt Date and Expiration Date in months: Calculate number of months between two dates in Excel.
Hi I have the following:
Sheet 1
Column A: list of employee names
Column B: employee title
Column C: hire date
Column D: # of years with company
I am trying to sort this list on a new sheet so that all employees and their info from each column on sheet 1 is populated according to their anniversary date for 2023, but also separated by month. So if the employee anniversary date is in January, the employee and their info would be pulled from sheet 1 and listed under January 2023...and do this for each month. Is there a way to do this?
Hi! To get data from the table according to the criterion, use the FILTER function.
=FILTER(A2:D10,MONTH(C2:C10)=1)
To sort the resulting data, use the SORT function.
=SORT(FILTER(A2:D10,MONTH(C2:C10)=1),3,1)
This should solve your task.
What formula can I use if I want a row to fill with color after the date is typed into a cell? Example: 3/15/2023 is typed into E3, how can I have A3:E3 turn green?
Hello!
Here is the article that may be helpful to you: Highlight row if cell is not blank.