by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
Hello,
I have conditional formatting on my dates and they turn color based on 30, 60 90 days past due date. What i need next is to change my status column to match the date colors. I have status' of Open and Closed. If they are open they should match the color of the date, red, orange or green if over certain days, if it is closed it can remain black. Any help is appreciated.
I forgot to mention I was using this formula with no luck - just turns everything red for open =IF($K2>30,$C2="open","")
Hi Michelle,
I'm not sure I completely understand the task, so let me check. You have a status column C that contains words "Open" or "Closed", this is absolutely clear. You have another column K with what kind of entries - numbers or dates?
If numbers, you can change the color of your Status column by creating 3 conditional formatting rules with a simple formula like this:
=AND(C2="open",K2>30)
If dates, then please provide more details on how you determine the past due date. If you can send me your sample workbook at support@ablebits.com, this will be a faster way : )
Hello,
they are dates. They turn color based on 30, 60 and 90 days past the due date. I need the status column to do the same if they are Open and Closed so that we can monitor what is not done on time. Maybe there is another way?
Hello,
If I have a set of numbers is there a way I can use conditional formatting to highlight the number in that set that is closest to zero?
Hello Jessica,
Thank you for your interesting question!
If your data set consists of positive numbers only, you can use this simple way:
- Select your data set.
- Click Conditional formatting > New Rule... > Format only top or bottom ranked values.
- Under "Format values that rank" section, select "Bottom" from the drop-down list and put 1 in the box next to it.
If your data consists of both positive and negative values, then a solution is a bit more complex. I've added a couple of examples to the post because this is really a very interesting question and other users may find the examples helpful. Please see How to highlight the nearest value in a data set for full details.
Hi,
I have conditional formatting set so that the fill turns green if it equals a certain number. There are 5 numbers that meet that criteria in a row, 4 of them turn green and the 5th one does not. They all have the same formats and formulas. Do you know why it is leaving out that one number?
Thanks!
Hi Mike,
The most obvious reason that comes to mind is that the format of the problematic number is different from all others. You can try to copy the format from some other cell where the rule works well to that problematic cell using Excel's Format Painter. Also, make sure your formatting rule applies to the entire rows. If neither is the case, you can send us your workbook at support@ablebits.com and we'll try to figure it out.
Nevermind...figured it out. I'm dumb
Hi Jared,
As I see in the comments timestamps, it took you just 16 min to figure out the solution. So, you definitely are not : )
I am making a spreadsheet and want to highlight specific duplicates. Like if a name pops up 3 times I want it green...4-9 times I want yellow. and 10+ times to be in red or something. What rule do I want to set up for this? Do I have to find the first instance of a name and create each rule based on that?
Svetlana,
Thank you very much for your time on this. That was helpful and again informative. I will use this suggestion.
You have an awesome blog here. Thanks.
Make it a great day !
I have a situation in which I'm applying conditional formatting to data that can be in three different ranges. For example if a cell has a value below a certain number, it colors green, if it is between two values, it colors yellow and if it is higher than a value, it colors red. I have this part down with three separate rules.
However, these ranges will change based on gender, which I have in an earlier column. Therefore, there are two different sets of three rules I want to apply to a row of data. What I want is that if C3, for example, reads female, then three specific conditional formatting rules will be applied to J3 which would be different than if C3 read male.
I would love any help you could give me.
Thanks!
Hi Carl,
It is not possible to create a conditional formatting rule that would force another rule or set of rules to apply to a certain range of cells. Instead, you can create 6 separate rules combining both conditions in one formula, e.g.:
=AND($D3>0, $C3="male")
If you are looking for something different, please send me your sample data at support@ablebits.com and we will try to figure out the proper formulas.
Thanks for this awesome blog !!!
Yet i could not crack this.
I have value in cell a1 to a5 and b1 to b5. Column a is output of path1 and column b is path2. Now i need to compare value of column b with column a and color column c with 3 colors using data bars to show the magnitude.
1) green : if column b value is lesser than a
2) yellow: if column b value is equal to column a
3) red : if column b value is lesser than column a
Now the c column should have a data bar to indicate how good or bad the value in column b is compared to column a. I spent too much but i eventually end up forgetting my location !
Can you shed some magic on this please
Hi Amarnath,
3 data bars of different colors cannot be displayed at the same time in one column. But you can try this way:
- Enter the following formula to cell C2 that will calculate the difference: =B2-A2
- Copy the formula across the entire column C.
- Apply the Green Data Bar to column C (negative values will be colored in red).
To hide the values and leave only the data bar visible, click 'Manage Rules' under Conditional Formatting, double-click your Data Bar rule and select the option "Show Bar Only".
As an alternative, you can consider using sparklines.
I am trying to do some Dynamic highlighting bas on a data validation list. My issue is when I create my conditional formatting formula =$J45=$E$40, the dynamic is only work for 1 value. When I switch values in the dropdown, the formula no longer works for the table range. Why is this?
Hello Bethany,
It's very difficult to say what the problem may be without seeing your data. Your formula works for column J only since you use an absolute column reference. Is this correct? Anyway, if you can send me your sample workbook at support@ablebits.com, I think we will be able to help better.
How do I test for the value of a cell color? I have a spread sheet where my customer combined rows of the same kind with a cell color. They did this manually. However I need to export this to a publishing program so is there a search for this? In the past, before the customer used color fill, I tested the data (=IF(F319=F320,"","{RULE}") and then I was able to place a rule below each group. Now with the cells filled with color, I'm at a loss.
Thanks!
Hi Steve,
You can use a user-defined function to count color-codes cells, we provide the ready-to-use code in this article - How to count and sums cells by color in Excel. You will need only the GetCellColor function that returns the background color code of the specified cells. You can use this function within your IF formula like this: =IF(GetCellColor(F319)=GetCellColor(F320), "","{RULE}").
Hi! I'm having a problem figuring out how to get conditional formatting to work in the following scenario.
I have a 3 column table. A and B will either have "Yes" or "No" as values. If both A and B = Yes, I want to highlight that row green. If both A and B = No, I want to highlight that row red. And if A and B have differing values from each other (e.g. A=No, B=Yes), I want to highlight that row yellow.
I'm pretty sure I need to have 3 different rules, but other than that, I'm not sure where to start. I feel like this must be easier than I'm making it but I'm not sure how absolute and relative cell references work, and I think maybe that's part of my problem. Any help you can provide would be greatly appreciated! Thanks so much!
Hi Jen,
Right, you will need 3 rules with the following formulas:
Green: =AND($A2="Yes", $B2="Yes")
Red: =AND($A2="No", $B2="No")
Yellow: =$A2<>$B2 (in plain English, the <> operator means "not equal to")
As for the cell references, I will try to explain in more detail:
- Absolute cell references (with the $ sign) always remain constant, no matter where they are copied. Because you always compare values in columns A and B, you should use an absolute column reference. As you can see, the dollar sign ($) appears before all column letters in the above formulas.
- Relative cells references (without the $ sign) change based on the relative position of rows and columns, when copied across multiple cells. Since you need to compare values in each row individually, you use relative row references in the formulas.
In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, you can simply pretend as if you are writing a formula for the top-left cell only, A2 in our case.
Absolute and relative references in conditional formatting formulas behave in the same way as in usual Excel formulas (as described above). So, because you use relative row references, your formulas will "get changed" for each row and compare the values in columns A and B in each individual row. I hope this makes sense :)
Svetlana,
Thank you so much for explaining the absolute and relative cell references. I looked it up more after I posted my question, but you've explained it better than anything else I've found!
As for the conditional formatting formulas -- I had the red and green rules correct, except for the mixed references; the yellow formual I did not have correct and I'm not sure why I failed to find such an easy solution. The not equal to operator makes perfect sense.
Thanks so much!
Jen
I have columns with dates in them. Each row is a different activity and the columns represent different schedule versions. If column C has one date and then a different date in column D, I want column to highlight in a color depending on if it occurs before or after the date in column C. I want to carry this down across several rows, but for some reason the conditional formatting is based only on the first row of data. How can I get the conditional formatting to apply to each individual row?
You just need to use an absolute column and a relative row in your formulas. Please try these ones (assuming that row 2 is your first row with data):
=$C2>$D2
=$C2<$D2
Hello,
I am wondering if there is a way to apply icons to words and not just numbers.
For example the icons are in column B and I would like the "green check" icon to display when column J reads "YES".
Is that possible?
Hi Kathleen,
You can do this with the help of this formula =IF(J2="YES",1,""). Copy the formula all across column B, starting from cell B2.
Then create an icon set rule and set a green flag for values >=1. Remember, to select the option "Show icon only".
Can you do this for more than one cell? I need to do this for my spreadsheet but I have many many rows and would like to use one general rule rather than a rule for each line. But I also want to be sure that it's looking at each line to format and not just the first one and carrying that cell's value forward for the formatting of the rest.
For example, Column B contains either a "Yes" or a "No" for each row and I want the corresponding cell in column P to have red fill if Column B for that row is "No."
I figured out a workaround. Ideally I wanted my Column P to be filled but for now I've inserted a column that puts a Red X as you suggested in your reply to Kathleen.
Hi Mallory,
The beauty of Excel conditional formatting is that you don't need to create a rule for each row! Just apply the rule to as many rows as you want to color, write the formula for the first row using a relative cell reference (like A1) or mixed cell reference (like $A1), and Excel will compare the values in each row, like it does when you copy a formula down a column.
In your case, you could create 2 rules, say for P2:P1000 (where P2 is the first row of data), with these formulas:
=$B2="yes" and =$B2="no"
For more information, please see Relative and absolute cell references in Excel conditional formatting rules.
Hello,
This already looks like an oracle now. I have an other challenge with duplicates. I have a file with different sheets. In Sheet D there is a cell that fills automaticly with information from the other sheets. I use this to generate Meta data for my website which I can import.
Some of the data in Sheet D are duplicate. I like to make a rule which will change the data in this sheet/cell automaticly if the outcom of the formula used in Sheet D , Cell A is a duplicatie with a cell above in the same column.
I hope you can help me with this info.
Thanks
Rutger
Hi Rutger,
Try creating a rule with this simple formula =A2=A1 where A2 is the top-left most cell in the range where you want to color the duplicates and A1 is a cell above. This rule will color the second duplicate occurrence. If you need to highlight the first one as well, create one more rule with this formula =A2=A3.
This solution works fine for one and several columns, except for the case if you have data in row 1. Hopefully this is not the case and you have column headers there : )
Hi Svetlana,
First what an amazing blog, I only occasionally use excel I had no idea it could do so much!!
My problem is that when I use the formula =D3=C3 to highlight duplicates (where the first cell of data is c3) it highlights the first occurrence of the duplicate, not the second. I don't need the first highlighting but I do need the second. I don't know what I am doing wrong.
Please help and keep up being the excel fairy!
John
Hi John,
Thank you so much for your kind words.
The formula I suggested for Rutger is purposed for highlighting duplicates in the same column. As far as I understand, your formula is comparing cells in columns D and C, in the same rows. So, if you want to highlight only duplicate values in column D, the formula will work, just make sure the rule applies solely to this column.
If you are looking for something different, please provide a bit more details.
Hi Svetlana,
Thanks for the response. Yes it does highlight the duplicates but it highlights the first example not the last. I don't want the first highlighting. So I need to know if a value has been repeated on the same row. So imagine 3b, 3a, 3a, 4c on a row of data I would only want the 2nd 3a highlighting not the first one. Using the formula you gave it highlights just the first ie: 3b, 3a, 3a, 4c. I don’t want this.
Also I need it to highlight multiple duplicates and non consecutive duplicates. I need it to 2b, 2b, 2b, 2a . I also need it to do 2b, 2a, 2b, 3c,. So in all the examples I need only the second repeat to be highlighted. Hope you can help.
Yours
John
Hi John,
Got it, please try this one:
=COUNTIF($A3:A3,A3)=2
Where 3 is the first row and column A is the left-most column with data. The rule shall be applied to all columns (not including the header row), though only the left-most column is included in the formula.
Wonderful Svetlana,
You are a genius and a true excel fairy. Many thanks indeed.
John
Hello,
My conundrum is this:
Cell I13 has zero formulas nested and only represents whatever number i type into it. I need the text or fill in cell I13 to be green if it's value is greater than or equal to the value in cell I14 and I need the color to be red if its value is less than the value represented in cell I14. I14 has a nested formula which represents a numerical value from cell D4. I have tried the Conditional Formating rules to no avail; is this algorithm even possible?
Hello PH,
I've just tried creating 2 rules for cell I13 with the following formulas, and they worked just fine:
Red: =$I$13<$I$14 Green: =$I$13>=$I$14 My cell I14 has a simple formula =D4, though in theory this should not make any difference. If the above formulas do not work for you, please specify which exactly formula you have in I14 so that I can test on the same data.
similar to the question above, i want a conditional formula that i can apply to multiple cells in a range. if a cell contains a number > the number in the cell above, i want green; if the cell contains a number < the number in the cell above, i want red. i would like to drag this condition all the way down the column. is this possible?
nevermind. i think i figured it out. you can delete my thread.
I am trying to find a formula to highlight the entire row based on the conditional formatting of one column.
I formatted column 1 to highlight duplicates, and I want excel to highlight the entire row if there is a duplicate.
Is this possible?
Hello Sarah,
Of course, this is possible. You just need to extend the range for the formula to get applied to the entire table rather than 1 column. Simply open the Conditional Fromatting Rules Manager and change the range in the "Applies to" box.
As an example, please see "Check for duplicates across multiple columns" in this article. As you see in the screenshot, the formula applies to the range A2:C9, and as a result the entire rows are highlighted based on cell value in column C.
Thank you! The second suggestion worked!
I am having an issue with using conditional formatting on my excel project. I want to highlight each number in a row that is different from each other in one single conditional formatting formula. How would I do that?
If my understanding is correct, you need to highlight unique values in each row. If so, the following formula will work a treat, where A is the first column and H is the last column with values:
=COUNTIF($A2:$H2,"="&A2)=1
Hi, i want to format a cell based value of different cell. Please let me know how to do it.
Ex: If value in Cell E2="Yes" the F2 cell needs to be in date format.
Hi Naveen,
I'm sorry, I do not have any idea on how to do this. I'm not even sure this is possible in principle.
=OR($E2="Yes")
Use the Formula for conditional formatting E2="Yes" and set the format section to date format you want, but you do that in the cell you want to format. You still have to enter the date in that cell.
Hi,
I have an answer for this if you can explain in brief..
Thanks,
Hitesh
Hi! was wondering if you can help me with something on the similar subject.
Column A + Column B = $F$5
A Basic example is Column A has 2.70, 5.40, 8.10 Column B has 10.80, 21.60, 32.40 if I put 13.50 in the box I'd like the 2.70 in Column A and 10.80 to be highlighted in Column B etc.
I've tried different ways like =A3+B$3=$F$5 and/or =B3+A$3=$F$5 but nothing seems to work can you help me.?
Thanks
Hi Derek,
You were almost there : ) You need to create a separate rule for column A and column B with this formula: =$A3+$B3=$F$5 Please note, it will work for Column A + Column B = $F$5, only if values in columns A and B are in the same row.
If you want to highlight values in different rows that make a sum, you will need a bit more complex formulas:
For Column A: =ISERROR(MATCH(ROUND($F$5-$A1,10),$B$1:$B$10,0))=FALSE
For Column B: =ISERROR(MATCH(ROUND($F$5-$B1,10),$A$1:$A$10,0))=FALSE
Wow that's a lot more complex than I thought it would be lol
Ok last question I promise if I wanted to add one more column later what would I input?
Thanks so much for your help I couldn't have worked that out for myself
Hi Derek,
I'm glad to know the formulas have worked for you : )
If you are asking about the 2nd case (sum in different rows), regrettably it's not possible to do in 3 columns (i.e. A + B + C = $F$5) using conditional formatting formulas, at least I do not know any way. This would require 2 nested loops, which can be done as a macro only.
Hi! I have a bit particular case. I have to find duplicates (max 5) in column A worksheet_1 and copy only one of each duplicate in column A worksheet_2. Then I have to copy values from B worksheet_1 that correspond to each duplicate in B1:F1 of worksheet_2.
For example:
worksheet_1 worksheet_2
A B A B C D E F
1 kl5f 1 k15f ozpp
2 l9j8 2 l9j8 kol
6 yu60
2 kol
1 ozpp
Thank you in avance
Normally the exemple was suppposed to be with spaces...
Hi Jelena!
It's a bit difficult to understand what exactly result you are trying to achieve without seeing your data. If you can send me (support@ablebits.com) your sample workbook and the result you are looking for, I will try to help.
what i m trying to do is that, if i enter value in single cell of a row the clour of that row or the selected cells should be changed by entering the data in the cell
If you want to color the entire row based on the data in a certain column, then select all the rows and columns with your data and create a rule using this formula:
=$C2><""
Where C is your column, 2 is the first row with data.
If you want to highlight a row when at least one column contains data, use this formula:
=countif($A2:$G2,"><"&"")>0
Where A and G are correspondingly the first and the last columns you want to check.
i have a work sheet, many column,in a column many date are 14/15/16/17 if 15> then total row move to another sheet automatic
In this case Excel formulas cannot help, this task can be fulfilled using a macro.
Hi,
Can you please give an answer of conditional formatting which is compared above for two columns where in countif formula has been used. Can you please brief. Because that scenarion is exactly with my question but in that i found one querry which is -
Products are mentioned in column a and sales vales are mentioned in the other column. The conditional formatting which is used in that is not exactly giving the actual reaults.
Because i hv seen and practically applied..
scenario-
Product1 2
Product2 4
Product3 6
Product4 3
Product1 2
Here if product is matching and if the aale value that is matching then it should highlight both with the help of cnditional formatting however its still highlighting incase product one is mentioned two times and sale value ia differerent. So in that case it shiuld not highlight but its highlighting.
Plz assist to resolve this scenario.
Thanks in advance...
Hi Hitesh,
There are two ways to fulfill your task: using a helper Column or our Duplicate Remover add-in.
If you choose the former, do the following:
- Add a helper column to your table, e.g. column C, and enter the following formula in cell C2:
=concatenate(A2,B2)
Where A and B are the columns you want to compare, 2 is the first row with the data.
- Select columns A and B and create a conditional formatting rule using this formula:
=countif($C$2:$C2,$C2)>1
If you use the Duplicate Remover, you won't need to create a helper column and mess around with formulas. Just pick the "Fill with color" option on the final step of Duplicate Remover Wizard.
Hi Svetlana,
Thanku so much. Its really awsome. My question has been reaolved. But there is a small thing which i wanted to add in.
The scenarion which i discussed below related to conditional formatting by using countif formula.
But the first product no. And sales value is not highlighting except that its highlighting from the below duplicate.ex-
Below is tge scenario resolved with sugesstions provided by you. But firat plan is highlighting with by using countif formula and the next plan no. Which is 12345 and the same amount i.e.:-200 is highlighting
Plan no. Name amount column d
12345 a 200 =concatenate
(A,b,c)
135937 b 300
847474 C 400
92828 d 500
12345 a 200
95850 e 600
12345 a 100
Please assist and advise if i can through these duplicate plans in another or sheet 2 without help of macro...
Thanks in advance....
Hi svetlana,
Can you please provide an update on above question..
Thanks,
Hitesh