by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
Hi Svetlana, Can I use conditional formatting on one sheet and monitor a cell on another sheet? So I want a cell on one sheet to change colors when the cell on another sheet has specific text or numbers.
Hi Todd,
Sure, you just need to add the name of the sheet to the reference in your formula, e.g. if you want to monitor the value in A2 in Sheet 2, here is how it should look:
=Sheet2!$A$2="Value"
Good afternoon,
Can you please assist me with the following:
If cell B4 contains the two letter code v6, reflect in
cell R4: September 15th.
Hello Gerardo,
You need to enter an IF statement into R4:
=IF($B4="v6","September 15th","")
You can read more about the IF function in this blog post:
https://www.ablebits.com/office-addins-blog/if-function-excel/
If cell J8 value is 5 and cell K8 value is 2 and I want cell G8 to list the value from J8 when K8 is 2...how do I formulate that?
Hello Todd,
If you want to display the value from J8 when K8 is 2, then you need a simple IF statement in G8:
=IF(K8=2,J8,"")
If you want to get the value from J8 if both conditions are true: K8 contains 2 AND J8 contains 5, then you need the following formula in G8:
=IF(AND(J8=5,K8=2),J8,"")
Hi, can you please help me find a formula for my query. I want to conditional format and show me where a figure reduces to zero in a column. I'm checking leave audits and need to identify where someone's balance has been taken off them. So basically just identifying zeros isn't enough, I need to show where the preceding cell above had a figure and then in the next it is zero.
Hello Svetlana
Following your formula suggestion which should conditionally format a date in column E based on the open or closed status appearing in column H, I am finding the same results despite the status.
I am attempting to use the following formula:
=AND($E6<TODAY(), $H6="O")
As certain as can be, I have checked all your listed reasons why this may not work. The result I am getting is exactly the same as it would be for, =$E6<TODAY()
Any help you can give would be immensely appreciated. Please!
20
30
40
50
20
sum = 160 my query is i want sum 190 then i am having freedom to change the cell value (30) what is option of reverse caluclation
I have two columns containing sub totals. In the first column I have number and text mixed like ' 1 count ',' 2 count ' etc. In the second column there are values corresponding to sub totals. I tried to find out the highest value in column B. However the secondary sub totals had to be ignored as they were nothing but sum of first set of sub totals. The formula I used in the new rule, was =and(isnumber(search("count",$A1)),$B1=max($B:$B)). But nothing gets highlighted. Please help
I am trying to create a formula for the following
I want the number 2 to be generated in the selected cell when all the values in three separate cells are below a specific number, if this statement is not true than I want a value of 0 generated.
I have tried several formulas and none seem to work, my latest try was with the following:
=IF(AND(NOT(C5<85),NOT(R5<85)NOT(S5<85)),2,0)
This returns this error message: #ERROR, Formula Parse Error
Hi,
I wants to apply like if i will update A1 as Apple, B1 suppose to show Red automatically, how to do that
please explain.
I have a spreadsheet for work where I have figures based on where our console is for the morning and then the afternoon so we can check the difference in numbers which is spread across 3 sheets named - AM, PM, DIFFERENCE.
I am looking to format this so that is there is a difference in the numbers then the cell would either change colour or show a symbol.
I would need it so that if we have a number in the morning, for example 10, and at the end of the day it showed 15 it would need to turn red or have a symbol to say the figure increased?
Any help would be greatly appreciated!
Hi,
I was wondering whether there is a way in which you can change a cell value according to the fill of that cell or of other cells. For example, if I have A2 filled with red, I want to write inside of it the word "DENIED" and if I put green, I would like to write "GRANTED". Thank you in advance!
Hi
I have a problem. i like to link one cell to another in the same format.
I'm Bold & Italic. I'm with under line Bold is Bold & Italic is Italic.
i try many formulas but its not working.
can you help me.
In spreadsheet, I need to link two cells
For example, If I click on a1 then c1 cell automatically get highlighted.
It is possible is google spreadsheet?
If yes means, How to do that?
how do i highlight (change background color) for a row in multiple tables based on a cell having similar values?
for ex if i have multiple tables measuring the performance of tv channels and i want to highlight certain channels in different market tables..how can i do it..
was trying conditional formatting but not getting the answer
(all the tables are in the same page/sheet)
The conditional formatting based on another cell's value was exactly what I wanted, but it isn't working and I have checked all 6 of your troubleshooting items - but still no joy. I have prepared a worksheet to calculate savings for an energy customer based on a particular (user input) value that would determine the rate structure for each client meter. The client has 5 meters, so I have 5 sections to calculate their potential savings under different input scenarios. There are 3 potential rate structures for each meter and the savings from their (current) rate structure will depend upon the transformer capacity chosen. I want to be able to highlight the actual savings calculation lines for each meter based on the rate structure elected by the transformer capacity chosen. If the capacity chosen is 100% of the transformer capacity, then the rate qualifier is zero and there is no rate change. I would not have any lines highlighted. If the capacity chosen is 50-99% of the transformer capacity, then the rate qualifier is 1 and there would be cost changes/potential savings associated with the new rates. I would want the appropriate lines associated with the calculations for rate 1 to be highlighted if the rate qualifier were 1, but NOT highlighted for any other value. Similarly, if the capacity were less than 50% of the transformer capacity, the rate qualifier would calculate as a 2 and the cost/potential savings lines associated with the 2nd rate structure would calculate and I would want them to be highlighted - but not highlighted for any other value than 2. So far I have been unsuccessful in getting the conditional highlighting to work. In manage rules, I used an absolute cell address for my reference cell to check the value and the cells to be highlighted were correct, but still no highlighting. What else could be wrong? I don't need the highlighting for myself, but I am giving this workbook to my boss, who won't know how it is built and will need the highlighting to help him understand how the workbook is calculating when he makes input changes to the transformer values. Thanks for any help you can give!
Just to clarify on my last comment....
I cant use the option to highlight dates between a certain range as i need the dates and highlighting to be relative to todays date. so if i chose to use a "between" formula i would have to change the date range daily which defeats the object
Good Day
Please may you assist. I am working on a call report and i need my formulas to produce the following two results:
1) Highlight all dates prior to 30 days from today in RED BOLD
Highlight all dates prior to 15 days from today in PURPLE BOLD
Highlight all dates in the last 14 days NORMAL BLACK
2)Highlight all dates which fall 2 weeks from today in PURPLE BOLD
Highlight all dates which fall one week from today in RED BOLD
highlight all dates which fall on future dates in BLACK BOLD WITH RED BACKGROUND
I've worked out the formulas for one of the above but i cant get them to work together simultaneously without affecting eachother. so in other words problem (1) will be applicable to one column so i need all those formulas to work together and not affect eachother.... i cant seem to get excel to give preference to the formulas with the lowest date, it seems to be working on the 30days first, then the 15 and then the 7 so my 7 days will not highlight because it is already highlighted from the formula of 30 days.
PLEASE ASSIST - THIS IS BOGGLING MY BRAIN
I need to highlight a cell if:
it contains a specific text
AND
it is not duplicated in the same column
Thank you
Hello
I need a formula for the following:
Cell A2 returns a result of 16, I need to classify this result into one of 6 groups
if A2 90, I want cell B2 to display GROUP 1
Thanks very much
T
I need to set a whole column of information not to be lesser than $X, if it's lesser than the amount it should just show 0. What should I do?
So, this is a straight line depreciation project and I need to divide my depreciation expense in half for the first year and the disposal/last year. However, the problem is that we do not know when would the disposal/last year be, it might vary from year 3-20. How should I put it in excel?