by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
I have a problem that I need help with. I am trying to use Conditional Formatting to highlight one cell against another cell using greater than, equal to, and less than. The cell I want highlighted gets its value using a formula that gathers data from multiple areas in the spreadsheet. This seems to be the cause of my trouble. The cell I want to compare it to is a static number. For some reason no matter what I do I cannot get the cell containing the formula to highlight correctly.
Ive tried all variations of =g3h3 but for some reason it will not work. (G3 is the cell that has a value obtained from a formula)
What I am looking for is when G3 is less than H3 then G3 gets highlighted red. When G3 is greater than H3 then G3 gets highlighted green. When they are equal G3 stays white.
PLEASE HELP! I've spent 3 hours on this already.
1. I have a spreadsheet that data starts at A19:AS100. I want to change font color to "red" for text VA only. In using conditional formatting, Format only cells that contain...I enter VA and have tried entering VA~ also to only change text for VA but it is also changing text color for VAC. Please let me know how I can change text color of VA only not everything that has VA in it or starts with VA.
2. In the same spreadsheet I am needing to get a total for the following "SUR,HSC,COS,HP" that are listed in cells beginning in column B19:AS100 by name. Names are located beginning A19:A100. There are times that the above list is entered in a cell with other text ex. HSC/CON, DP/SUR and I am needing it to count 1. When it is entered in a cell with two of the criteria listed above ex. SUR/HSC, HP/COS I still need it to count it as 1. I am needing it to count only once regardless if there are two of the criteria to count listed in a cell.
I would truly appreciate any and all help you can give me on this.
THANK YOU.
I have 12 columns with turnover and a column with total turnover, would like to highlight, the total as follows;
if col.1 and col.2 are empty and col.3 and col.4 have data and rest of columns are empty, fill with colour.
Thanks
What I wanted to achieve is cell formatting depending on the comparison of another two fields that have a date in them (one is a straight date, the other calculated date). If the month in those two dates matches (its equal) then to trigger the formatting (shading) of the third cell.
A formatting rule of something like
=MONTH($K21)=MONTH($R12)
But because this is not a valid formula it doesn't work. I have added this invalid formula here for making my question easier to understand.
Thank you
Hello, Jack,
actually, your formula for is correct, if it doesn't work, most likely there's something wrong in your table or you apply the conditional formatting incorrectly.
If you still require our assistance, please send us your workbook with the data and the result you expect to get to support@ablebits.com. Please don't worry if you have confidential information there, we never disclose the data we get from our customers and delete it as soon as the problem is resolved.
Don't forget to include the link to this comment into your email.
We'll look into your task and try to help.
How would I create a conditional formatting rule based on the below formula. This formula is counting (then averaging in a separate, similar formula) worked hours but excludes login and logout times outside of the given range. I’d like to highlight the cells in another column (H:H) that meet the below criteria so that it’s easy to tell which times were actually used in calculating the final formula. For example. If 40 days were “worked” during the selected period, but only 34 days were used to create the result, I want to highlight those 34 cells.
=COUNTIFS(F:F,">"&M2,F:F,""&M4,G:G,"<"&N4,A:A,"<6")&" days"
Where:
F:F = Log in time
M2 = min log in time
N2 = max log in time
M4= min log out time
N4 = max log out time
A:A= day of the week in numeric form
"&M2,F:F,""&M4,A:A,"<6")
H:H=sum of hours worked (Logout-Login).
Thank you in advance,
Anthony
I have a sheet that has various colors based on the cell character:
"A" = Color Green font
"R" = Color Purple font
"C" = Color Blue font
"I" = Color Red font
etc..
But in the sheet there are some cells that identify as "C/R"
So the cell would have to be C in Blue / R in Purple.
Two colors in the same cell separated by the "/"...
I want to a cell to default to a text / value if another cell contains specified text/ value
If cell a1 = text then cell b1 = 135,
or similar scenarios.
Thanks
Pad
Hello,
I have a spreadsheet with 4 individual columns, then 15 column pairs. Each pair of columns is a set of data from two different sources, sorted by a common key value. What I need to do is highlight the value in the second column (of the pair) of a row that has inequal values.
I know I can use, for example, =$E2$F2, applied to column $F:$F to highlight values in F that don't match corresponding value in E. But, how do I do this properly over 14 more pairs? Do I need 15 rules?
Thanks
Hi!
I desesperally need your precious help please: i have a worksheet with about 70 rows and 52 columns. Each row represents a store/client, the column represents the weekly quantity ordered. Most of the time the quantity doesnt change – except for certain periods. I need to see clearly when the number change. i though conditional formatting could help me but i cannot make it works. I need to compare all the cells to their adjacent cells. I tried the formula = B$3C$3, then i tried = $B3$C3, then without dollar signs … nothing worked (it highlight entire columns rather than cells). I need to automatically highlight the cell that is not equal to the cell to its right.
Many many thanks in advance!
hi
this Mohammad Dawood . i from Afghanistan . when i change an alphabeth it have to give a color in the Excell . please gave me Information thanks
Hi,
I am using few rules for conditional formatting for .csv file. But after the closing the file all rules get deleted. why this is happing? Can we apply this rules for .csv file.
Thanks in advance
Hi, Rangrao,
I'm sorry but there's no way to apply the formatting rule to the .csv file. It's impossible due to some peculiarities of this format.
Please check this help page from Microsoft to see all the restrictions to the file.
Hello,
I have a issue that I need help with.
Basically I have two sheets, one sheet that lists All Items and another that list the Items Sold from the all items sheet. I've used vlookup to pull all the relevant data from All Items for each item on the Items Sold Sheet. Now I want to highlight the SKU that appears in Items Sold in All Items. At the same time All items Sheet has more than one SKU whereas The Items sold has only one. I have used the below formula with Conditional Formatting on the All Items Sheet to try to accomplish this however it highlights all the Skus with a corresponding value from the SKU's column in Items Sold =COUNTIF(SKU, $B2)=1. I want it to highlight all the items sold but only one of the items. Can this be done?
Hello,
I have one issue,from a selected raw how I can highlight the whole column or selected portion if it identify a preset text or number?
Hello
Can anyone plz help me for following:
I have 4 Columns A,B,C,D
A= Customer Name
B= Invoice Amount
C= Due Date
D= Formula to insert?
In (Column D) I would like to sum the Invoice Amount(Column B) according to individual Customer(Column A) if due date is today or already past(Column C).
Example: Today is "29th Aug 2017"
A(Customer) B(Invoice Amount) C(Due Date) D(Due Amount)
John $15 29th Aug 17 John= $15+50=65
Smith $10 25th Aug 17 Smith=$10(Only 1 invoice due)
Smith $13 10th Sep 17 Obama=No Due
Obama $18 18th Sep 17
John $50 28th Aug 17
Please help.
I'm sorry my question is not coming over correct, 2nd try: I have a spreadsheet with 10,000 rows and 10 columns. Data starts in Row 2, Row 1 are headers. I want all of Row 2 to turn Red if the value in column G, row 2 is =1 then the whole row is Green. I then have to repeat this for the next 9,998 rows.
Hello I have a spreadsheet with 10,000 rows and 10 columns. Data starts in Row 2, Row 1 are headers. I want all of Row 2 to turn Red if the value in column G, row 2 is =1 then the whole row is Green. I then have to repeat this for the next 9,998 rows. Each row should look to it's own row's value in column G. But when I do conditional formatting in row 2 and drag down it will only look to G2 even if I'm in row 3,200 etc. I've tried $G2, and G2 but it will only look at the G2 no matter what row. In closing row 3543 needs to look at G3543's value to decide format. What am I missing? Thank you!
HI
I want to create a drop down menu that would carry out 5 rows of data.
ie
Cash
100
200
300
400
500
How would I achieve this?
Thanx.
Thanks that formula worked.
=MIN(IF(A4:A94,B4:B9)) =0
=MIN(IF(A4:A9>4,B4:B9)) = 30.92
Can you help me with this simple problem.I can't get the top
formula to work it returns 0.The bottom formula works
ok.Can't seem to get the 4 to work together.Can you help
me with this
A B
5 30.92
4 31.29
2 31.11
3 31.17
6 31.29
7 31.29
=MIN(IF(A4:A9>4,A4:A94,B4:B9)) = 30.92
Can you help me with this simple problem.I can't get the top
formula to work it returns 0.The bottom formula works
ok.Can't seem to get the >4<6 to work together.Can you help
me with this, I used ctrl,shift,enter
A B
5 30.92
4 31.29
2 31.11
3 31.17
6 31.29
7 31.29
=MIN(IF(A4:A9>4,A4:A9<6,B4:B9)) = 0 .This is the formula i cant get to work.
Hi, Harold,
as far I can see, you're trying to use IF function incorrectly. Please take a look at this article of ours to learn more about the syntax of the function.
You may want to check out this one as well, since it explains how to use IF and MIN together. You fill find a bunch of examples that'll help you to build your own formula properly :)
thanks i'll take a look
I didn't make my example ,clear. I have column "A" with these numbers 5 4 2 3 6 7 - In column "B" I have these numbers 30.92 31.29 31.11 31.17 31.29 31.07 If i select a number in column A or an adjacent number I want the minimum corresponding number in column "B" I need a formula for this. I tried this formula but all i get is zero.=MIN(IF(A4:A9>4,A4:A9<8,B4:B9)). i used control, shift, enter.
I didn't make my example ,clear. I have column "A" with these numbers 5 4 2 3 6 7 - In column "B" I have these numbers 30.92 , 31.29 , 31.11 ,31.17, 31.29, 31.07 If i select a number in column A or an adjacent number I want the minimum corresponding number in column "B" I need a formula for this. I tried this formula but all i get is zero.=MIN(IF(A4:A9>4,A4:A9<8,B4:B9)). i used control, shift, enter.I added some commas between some of the numbers to make it clearer.
Thank you very much for the clarification, Harold.
First of all, please take a look at this part of the article, to learn how to use AND and OR operators in array formulas (* for AND, + for OR)
Then please try this formula:
=MIN(IF((A4:A9<8)*(A4:A9>4),B4:B9))
However, if you're using Excel 2016, the following should do as well:
=MINIFS(B4:B9,A4:A9,"<8",A4:A9,">4")
Hello,
How to make formula for the following:
if A1=8 then answer is 2
if A1=10 then answer is 4
if A1=12 then answer is 6
Thanks
Hello,
You need to use IF function. Please read the article devoted to it here, you will find lots of examples :)
For newer editions you can use =IFS(A1=8;2;A1=10;4;A1=12;6) .. That would save you from nested IFs. But it requires 2016 or newer.
Old method, =IF(A1=8;2;IF(A1=10;4;IF(A1=12;6;""))) .. It can be shorter if there's no other option than these three, 8,10 and 12. If so use;
=IF(A1=8;2;IF(A1=10;4;6))
try this formula
=IF(A1=8,2,IF(A1=10,4,IF(A1=12,6,"No Value")))