by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
hi
i want to create a conditional formatting for following
Column 1 Contains Date of shipment
Column 2 Contains contains a (tick) which confirm if the shipment is sailed.
Column 1 should turn red when Shipment date occurs
and Column 1 thr should be no formate if Column 2 contains a Tick
Please help
hi everyone,
i want to create conditional formatting for the following:
Column 1 contains due date
Column 2 contains actual date
Column 3 would contain conditional formatting if Column 1 > Column 2
please help
Thanks in advance
Hi all,
I was wondering if anyone could help me with a conditional formatting formula for the following information?
I want to compare a 'Grade(1-9)' column with a 'Tgt' column and have it showing as red if it the 'Grade(1-9)' column is less than the 'Tgt'.
Here is an example of the information in both columns:
Tgt: 8D 7D 6S 7D
Grade(1-9): 8D 6A 6E 6E
Therefore, the 6A 6E and 6E in the 'Grade(1-9)' column I would like to highlight as red as it is less.
Is this possible?
The current grading from highest to lowest is:
9A 9S 9D 9E 8A 8S 8D 8E 7A 7S 7D 7E 6A 6S 6D 6E 5A 5S 5D 5E 4A 4S 4D 4E 3A 3S 3D 3E 2A 2S 2D 2E 1A 1S 1D 1E U
Would the formula change for each different Tgt value or is there an one fits all formula?
Thanks for any support or even just a no it wouldn't be possible!
Sorry I forgot to mention that the 'Grade(1-9)' values start at cell E6 and 'Tgt' values start at B6.
Restating my previous question for better clarity -
I want to format cells in column based on two different conditions applying to the cell in the same row in column A, but the conditions are complicated and I don't know they would look like in a formula. The two conditions are:
1. If the value in column A is the highest value in column A
2. If the value in column A is a duplicate value with another value in column A
...in other words, if there is "a tie at first place" in column A, I want to make the cells in the NEXT column (column B)for those rows yellow.
I know my formula for the conditional formatting has to include =AND($A1,)but I am at a loss as to how to describe my two conditions in the formula.
Thank you for any help you can provide with this knotty problem!
I want to format cells in column J based on two different conditions in applying to the cell in the same row in column I, but the conditions are complicated and I don't know they would look like in a formula. The two conditions are:
1. If the value in column I is the highest value in column I
2. If the value in column I is a duplicate value with another value in column I
...in other words, if there is "a tie at first place" in column I.
I know my formula for the conditional formatting has to include =AND($I1,)but I am at a loss as to how to describe my two conditions in the formula.
I am trying to apply conditional formatting based on the following and am getting very confused!
I want column A to change colour based on the following:
Col D has a date – YELLOW
Col E has "Y" – ORANGE
Col F has a date – PINK
Col G has a date – DARK BLUE
Col H has a date – DARK GREEN
Col I has a value – LIGHT GREEN
The process should be, as each column has a value or date entered it changes to that corresponding colour, can you help?
Hello
I am creating a vehicle fleet inspection chart. Vehicles are required to be serviced within every six weeks.
I have plotted a row of six weekly reference dates for the year based on the last service date from the previous year (E18:N18). Giving me ten dates. The dates in this row indicate that the vehicle must be serviced by each of these dates.
I have also added a todays date cell (C17)
I have conditionally formatted these cells to:
> change to orange if a date is entered that was later than the reference cell.
> change to green if a date is entered that is less than or equal to the reference cell.
> no formatting for blank cells and stop if true.
However, I still require the cells (E21:N21) to change to red if the cell is blank and the reference dates above (E18:N18) are less than todays date. This would show me that no service took place. How can I do this please?
Hi,
I would like to know the formula for the following.
Plan Submission Overdue Actual Submit Date
9-Feb-18 13 13/2/2018
8-Feb-18 14 13/2/2018
5-Feb-18 17 5/2/2018
5-Feb-18 17 5/2/2018
1-Mar-18 -7
Condition as follows :
>>If Actual submit date is blank and overdue (due previous week) , Plan submission date highlight grey.
>>If actual Submit date is blank and overdue this week, plan submission date highlight grey.
>>If actual submit date not blank, no need to highlight.
Hope you can help with this. thanks!
Thanks so much, This article was very much helpful.
My spreadsheet has a last revision date column with a date and a "Date of next review" column next to it with the formula of =S114+365. I would like to have the "Date of next..." to be highlighted if it is within 30-60 days yellow and less than 30 days in the future as red
formula =AND($A2-TODAY()>=30, $A2-TODAY()=1, $A2-TODAY()<30)
isn't cooperating, any help is much appreciated
Hello,
i m trying t create an auto border with conditional formatting, since my cells are havign formulas, the border are getting displayed, even though the cells are empty.
i have to make the cells between B21 to h35, whenever my results there in the rows the border should be auto
the following formula i have tried, with various methods, formats etc...
=OR($B21"",C21"",D21"",E21"",F21"",
Please guide me
thanks in advance
Hi,
I am trying to format cells that are a formula =(A1/B1) with percentage as a result in the C-column.
I am using Icon sets and have put in;
red 80-100%
yellow 50-79%
red 0-49%
I have tried both with Number, Percentage, Percentile and Formula.
It works only when I have one cell that has become 100%, otherwise it will not show the right color. It is like the colours only works in relation to the highest amount put into the column? I do not always have the 100% but I still wish it to work according to the colors.
Please help, I hope I have made this clear enough.
Sofie
Need to colour based on other cell value like.
If B2 value has a maximum valie in range of B1:B5 then only A2 cell colour with yellow.
What formula i use in conditional formatting?
Hello,
Please create a custom Conditional Formatting rule for cell A2 using this formula:
=B2=MAX($B$1:$B$5)
Hope it will help you.
Hello,
I have this
=OR(O16=$AB$23;O16=$AC$23;O16=$AD$23;O16=$AE$23;O16=$AF$23;O16=$AG$23)
apply for O16:AH21
I want to apply for AB23:AG23 from range O16:AH21... little help.
Hello,
For me to understand the problem better, please send me a small sample workbook with your source data and the result you expect to get to support@ablebits.com. Please don't worry if you have confidential information there, we never disclose the data we get from our customers and delete it as soon as the problem is resolved.
Please also don't forget to include the link to this comment into your email.
I'll look into your task and try to help.
Is there any way for me to apply conditional formatting to a column that highlights only specific cells in that column that have blanks in the row that the cell is in? Such as highlighting cells only in column B where there are blanks in specific rows in column A.
Hi Dan,
Simply, make a rule for column B with this formula:
=$A1=""
Where A1 is the top-most cell of the applied range.
For example, if you are setting up a rule for B2:B100, then use the formula =$A2=""
I'm trying to format a cell on a separate sheet to be highlighted based on if multiple cells have at least a value of 1 in it. For example, I have 4 cells and each cell needs to to have at least a value of 1 for the cell on the other sheet to be highlighted. Can this be done? If so, how? Thanks.
Hello, Matthew,
Try the following:
Supposing that your 4 cells are in Sheet2, you need to create a rule for conditional formatting like this:
=AND(NOT(ISBLANK(Sheet2!A1)),NOT(ISBLANK(Sheet2!A2)),NOT(ISBLANK(Sheet2!A3)),NOT(ISBLANK(Sheet2!A4)))
Hope it will help you!
Hi!
Would explain more about the part below that how the function works in order to ignore the 1st occurrences and not highlight it?
"Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1"
Thank you in advance.
I have an excel sheet where the county is listed in one column. I would like it to say "yes" in the column next to the County" column if the county is considered economically distressed. How do you write a formula to say "if this cell says Lake, Lauderdale, Haywood, Hardeman, McNairy, Perry, Wayne, Grundy, VanBuren, Bledsoe, Pickett, Scott, Campbell, Union, Claiborne, Hancock, Cocke, then the adjacent cell should say YES"?
Hi
Desperately Need your help :)
I have a dates column AC2:AC37 and i also have a price column M2:M37. Once a date in the AC column has got to today date i want the matching price cell in column M to be highlighted.
looking forward to your response.
Hi Danial,
Select cells M2:M37 and make a rule based on this formula:
=AC2=TODAY()
This will highlight only the prices that have today's date in column AC.
If you want to highlight the prices matching today's date as well as all previous dates, then use this formula:
=AC2<=TODAY()
Hello,
I have conditional formatting in a cell that turns red when it passes a certain date. In the cell next to it I have Status'. I want to shade the cell with the date in it when the cell next to it says "Completed" so I don't still think it's Red/past due. How would this work? Thank you in advance.