by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
Is there any formula in this regard?
Hai,
During 37th week of 2018 [September], the first week of Hijri-1440 falls/starts.
How to arrive at Hijri [Islamic] week number equivalent to Gregorian week number.
Appreciate your valuable guidance, thanks,
Conditional Formatting Problem: I have made 8 Rules to color code certain words. 6 of the 8 Rules work great, but 2 do not. I have deleted the 2 Rules & reentered, but still no luck. HELP!
PLEASE FIND THE REQUIREMENT BELOW TO WRITE A FORMULA IN EXCEL,
IF THE AGE IS BETWEEN 1-35, PRINT 1000,
IF THE AGE IS BETWEEN 36-40, PRINT 2000,
IF THE AGE IS BETWEEN 41-45, PRINT 3000,
IF THE AGE IS BETWEEN 46-50, PRINT 4000
Cell L18 Cell L19
AGE VALUE
1 - 35 1000
36 - 40 2000
41 - 45 3000
46 - 50 4000
=IF(L18<36,"1000",IF(L18<41,"2000",IF(L18<46,"3000",IF(L18<51,"4000",""))))
Arif:
I think you are looking for something like this:
=IF(B55<=35,1000,IF(B55<=40,2000,IF(B55<=45,3000,IF(B55<=50,4000,"Out of Range"))))
Where the value being tested is in B55.
The "Out of Range" is needed to supply a display message if the value is above 50.
i hava two coloum in excel sheet A and B.
the value is different in both coloum.
i need a conditional formatting formula to change color of col B when col A value is lower then col B.
Single cell color change but when i select the coloum it is not working
please help..........
thank you.
How can I use conditional formatting in a single column?
For instance, using column A entering text in A1, then when text is entered in A2 and hit enter, A1 will have a strikethrough and A2 will not. Enter text in A3, A2 will strikethrough and A3 will not, so on and so forth.
I appreciate any help.
I have an Excel workbook with two sheets. I need to make column D in Sheet 2 format to fill the background a color if Sheet 1 has the exact same number in Column C. What is the function I type into Conditional Formatting New Rule on Sheet 2? Please and thank you!
Hello, Svetlana
I'm having some problems using "OR" function. What I need is something like this:
=OR($D1 = "TEXT 1" , SEARCH("TEXT 2",$D1) > 0)
"Translating" what I'm trying to do is "I want TRUE when either the D column has the exact value 'TEXT 1' or has 'TEXT 2' written with not necessarily exact match"
The problem I'm facing here is that if I add the SEARCH function, it only matches the result of the SEARCH function. If I remove it, it matches the "TEXT 1" one.
Am I missing something here? I'm a programmer and have to say Excel functions have a really terrible syntax. I'm sure it is a very simple issue, but I can't solve it.
Thanks in advance
Hi,
I Have a question regarding conditional formatting. I know how to apply a rule that if the value is under a certain amount, the cell value will equal this amount. I now want to apply a rule that if a cell is between a range, the value s equal to a certain formula. Example; if value is between 10000 and 20000, the result is 10000 plus 90% of the portion in excess to 10000.
Help?
hello
please I want the A1 and B1 to automatically give me an answer in cell C1
A1 20 + B1 20 = C1 40
please how do I format the cells
I really need your help
Emmanuel:
If I understand your question you need to enter this formula in C1:
=A1+B1
Hi
I have been trying to use AND formula in conditional formatting to change color of cell according to values but its not working.
i need to change the color of the cell depending on the change in the value of the cell (eg. difference between A2 and B2 should be highlighted in yellow if the difference is between 0 to 2.99%. if its more than 3% difference it should be highlighted in red.) can you please help me out in this
Hi,
I am have an excel budget sheet with three important rows at the bottom.
1. a sum of each column.
2. a row with the copied value of the sum-value above to hava as a control.
3. a formula that subtract the above values (I would like this value to be zero as a control).
To the first and third row I would like to have conditional formatting, coloring them red if they are not the right value (i.e: the 1st row to colour red if its not the same as thr 2nd row, and the 3rd row to colour red if its not zero).
This contitional formatting only applied correct to three of my columns, and three colours red even if the values are correct.
Please help!! Going nuts here :) Thanks!
In the,
****Excel formulas to work with text value****
section,
I found,
>0 selects a string containing and beginning with the specified word.
Whereas, >1 selects the string only containing and not beginning with the specified word.
Correct me if I misunderstood something.
Hello,
I was hoping you can help create a formula/condition rule. I need an entire column “O” to return a value based off a digit I put in it a cell IN COLULMN O.
For example:
If I type 1 in O5 I want O5 to return a value of 1.08
If I type 60 in O50 I want O50 to return a value of 65
Similarly in column Q- If I type “Y” in the cell, I want the cell to return a value of 65. For this I set a condition rule =If(Q1:Q25=“Y”,65,0) to be applied over Q1:Q25. Needless to say- it didn’t work!
Can you help me please???
Hello,
I was hoping you can help create a formula/condition rule. I need an entire column “O” to return a value based off a digit I put in it a cell IN COLULMN O.
For example:
If I type 1 in O5 I want O5 to return a value of 1.08
If I type 60 in O50 I want O50 to return a value of 65
Similarly in column Q- If I type “Y” in the cell, I want the cell to return a value of 65. For this I set a condition rule =If(Q1:Q25=“Y”,65,0) to be applied over Q1:Q25. Needless to say- it didn’t work!
Hello
I am trying to find a formula to find the greater value between two dates. between two columns in the same cell. I know I can use conditional formatting>Highlight Cells rule>Greater Than, however I am trying to do this on a spreadsheet with over 1000 lines. is there any way I can use a formula to help me to this in one go without having to do the above line by line
thank you
David:
You don't have to apply conditional formatting line by line. You can select all the cells that hold the calculation that you need formatted and apply the formatting to them all at once. The conditional formatting rule is the formula.
You can select all the cells in the column by clicking the column heading.
Hello,
I have two sheets in excel 2007, where I enter via barcode scanner serial numbers of devices, one sheet is for direct sales and the other sheet is for credit sales.
I need a way to validate for duplicate s/n between two sheets. At this moment I am using the formula =COUNTIF(sheet1!d5:sj30000), like conditional formatting highlighting the duplicated cell. The system find duplicates very good, but becomes very, very slow.
Now I want to validate at specific time, for example in the night, when the system is not used.
Can you help me to setup time driven validation formula to trigger at specific time.
Thank you very much for your time.
I am looking for help on creating a conditional format where I am color coding a row based on a # the user inputs. These color codes (1 - 6) are used to indicate the order is in a particular status as they determine.
Some cells on the row will already be highlighted in vbLavender. These are set by a different process to indicate something has changed with this data. I don't want the conditional formatting to cover this.
So for example cell BB44 has the lavender background.
Currently this is my VB code for the conditional formatting for color 5:
Selection.FormatConditions(1).StopIfTrue = False
Range("A2:BW99999").Select
Selection.FormatConditions.Add Type:=xlExpression, Formula1:="=$BT2 = 5"
Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
With Selection.FormatConditions(1).Interior
.ThemeColor = xlThemeColorAccent1
.TintAndShade = 0.399914548173467
End With
So if in cell BT44 I enter a 5 the row is shaded blue.
This also shades BB44 as blue. If I delete the 5 the lavender color is still there. How would I change the above to not color cells that have an existing color or vbLavender?
Any suggestions would be greatly appreciated :-)
John:
VBA help is beyond the scope of this blog, but there are many sites where you can find VBA help. Just Google "VBA Format Conditions" and you will find them.
I have some formatting set up so, if for example,I have cell B8 highlighted green with the letter "w" in it, any cell I put a W in will turn green as well. Where I am stuck is how do I get an adjacent cell to turn that same color without putting a "w" in it. For example. if I put a "w" in cell D8 and it turns green, how do I get cell D9 to turn green based on D8's value while leaving cell D8 blank?
Thanks!
Todd:
I think this will work. Select D9 then Conditional Formatting then New Rule then Use a formula to determine which cells to format then in the formula field enter =D8="W" then select the green formatting you'd like to see.
I really appreciate you posting this tutorial Svetlana. It has made my work (and others here) a lot easier, keep up the great work! I will consider subscribing to Ablebits, you guys rock!