by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
I have a list of names in cells C5:C14. For each name there is data that goes till Column G. I want the name to turn Green indicating all the data is done for that name.
Example:
C5 says Jane Doe. I want C5 to turn green if D5:G5 all individually contain "Yes."
Thanks in advance.
Hello!
Use the conditional formatting formula:
=AND(C5="Jane Doe",SUM(--(D5:G5="Yes"))=4)
Hope this is what you need.
Hi there,
I have a spreadsheet with 2 columns which contain start dates, and each row is a different contract. Column A I've used a vlookup to pull the date from a different worksheet. Column B has just the date in the cell (ie no formula). I've changed the cell type to be 'short date' on both columns.
I would like to use conditional formatting to highlight when these dates are not the same as each other on each row.
I've tried using conditional formatting - new rule - formula : =$A1=$B1 but it highlights all of the cells, I think this is because it is comparing the formula in column A to the value in column B and saying it is different, even if the date value in column A and B are the same.
I also tried using a formula =IF(EXACT(A2,B2),"Match","Mismatch") but again it pulls everything as a mismatch, I think because it's reading the formula rather than the value.
Is it possible to use conditional formatting based on the cell value rather than cell formula?
Thank you very much in advance for any advice you can give
Hello!
If you want to highlight cells where dates don't match, use the formula
=$A1<>$B1
Please note that dates do not include time as well. It doesn't matter what format they are in.
Hello,
I am trying to highlight a row if a column (J) says finished. I used =$J2=Finished and changed the formating to standard green. For some reason this doesn't work. Why?
Hello!
We have a special tutorial on this. Please see - How to change the row color based on a cell's value in Excel.
Hello,
I am hoping someone can help me ... I have been looking for hours on how to solve this issue but cannot find the answer. I have tried using the examples given but I still cannot get the conditional formatting to work.
My spreadsheet has column A with an issue date and column B with a contractual date. The contractual date is 35 days out in the future from the issue date. I want the contractual date cell to turn blue when the contractual date is (issue date +30) and stay blue until date 35 when I would like it to change to red.
eg. Issue date is Jan 1/22 (Column A) and the contractual date is Feb 4/22 (Column B). I would like Column B to turn blue on Jan 31st and stay blue until Feb 4th and then turn red from Feb 4th going forward. I hope that makes sense. I have tried what I think should work but it turns the cell red right away. Not sure what to do to get this spreadsheet looking like I want to. I am hoping you can give me direction. Thank you
Hello!
Create two conditional formatting rules with the desired colors for these conditions
=((B1-A1) > 29)*((B1-A1) < 35)
=(B1-A1) > 34
This should solve your task.
Hello,
I'm trying to set 3 scale colors to highlight how much money from the budget has been spent until now.
I want cell K2 to change color (K2 is corresponding to the remaining balance).
I want it to be based on the percentage or percentile of cell D3 (D3 is corresponding to the total assigned amount of money for the year).
I want the color change to be divided into:
- Green, when remaining amount is between 100% - 66%
- Yellow, when remaining amount is between 65% - 33%
- Red, when remaining amount is between 32% - 0%
I do not find the correct way to add D3 as base reference amount cell.
Thank you in advance!!
C.
Hello!
Here is the article that may be helpful to you: Excel conditional formatting Icon Sets, Data Bars and Color Scales.
I hope I answered your question. If something is still unclear, please feel free to ask.
Hello,
I am trying to format the cells of a column based on different words that the cells might contain.
The following rule works great:
Format only cells that contain>Specific text>Containing>="text1"
But if i try to add multiple text strings, then it does not highlight anything. I used the following condition:
=OR("text1";"text2).
Note that a cell can either contain "text1" or "text2" but not both.
Hello!
You can create two rules. There is a separate rule for each word. For multiple conditions, also use a conditional formatting formula. For instance,
=OR(A1="text1",A1="text2")
Read the second paragraph in the article above.
Hello,
Are you able to assist with a google sheets conditional formatting question?
If so: my spreadsheet has column B, which contains the driver names for the market I am working in, and column C, which contains the starting location numbers for each driver. I would like to apply formatting to column B to change the color for the driver based on the value in column C for that driver. I have tried several formulas and they aren't working for me. Some of the formulas I've tried are C2="5859" or $C2="5859" or C$2="5859". Applied to range B1:B1032.
Hi!
I recommend reading this guide: Google Sheets conditional formatting based on another cell.
Hello,
I'm trying to have a conditional format that hides certain cells if a specific word is in another cell, Now the rule works for 4 of the 5 words but the word Supervisor is doesn't like, However, If I use a drop-down list even fewer words will allow the format but if I then type the same word over the top of that dropdown list word it works. I am very confused.
The formula I am using is =$C4="Supervisor" This would then block out C4 and U4, the word is then changed to Store Manager, Barista Etc.
Any ideas?
Many Thanks
Martin
Hi!
I am not sure I fully understand what you mean. Conditional formatting cannot hide cells or change their content. Are you using a filter to hide some values? What is the dropdown used for? Explain your problem more precisely.
Question, I want to see if its possible to do something,
Im doing a mileage spreadsheet for my bussiness, I want to know if this is possible. If the driver wrote that its L ( loaded) I want to add those mileages at the end of the document, and if its E (empty) then add it in another box. like weekly he is typing the mileage and then it just add up the ones that are L in a box and the ones that says E in another.
Hello,
As I understand your task, you must find the amount by condition. Use the SUMIF function for this.
Hi, compliments of the season to you, and thank you for your help in advance. My apologies if you've answered this elsewhere,
I have a reference cell with a number value that is the average ( =AVERAGE(X:Y) ) of the same cells I wish to apply conditional formatting to. The conditional formatting rules I am trying to apply to the cells are;
Format only cells with: Cell Value | less than | =reference cell
Format only cells with: Cell Value | greater than or equal to | =reference cell
The result I am trying to achieve is for cells with a value 'less than' the reference cell to fill with light green, and those 'greater than or equal to' fill with a light red. Some cells fill correctly, some don't. Those that don't fill correctly are the other (wrong) colour, or have no colour at all.
All cells (including the reference cell) are formatted as numbers with no decimal places. All numbers in the data cells are whole numbers. If I click on any of the data cells, the number displays in the formula bar correctly. If I check the rules for any of the cells that are filled incorrectly, both rules are correct. I would love to get this working properly as it will reveal some very interesting information.
Many thanks in advance for your help,
Paul.
Hi!
The information you provided is not enough to understand your case and give you any advice. I can’t guess what values you have painted incorrectly, what values are written in these cells and what exact formula is used.
Hi, I have a workbook where I keep record of our orders. I want to put in a conditional format to check if column F & G is empty and make Column C Red Bold. I have tried the following formulas
=OR(ISBLANK($F2),ISBLANK($G2))
=OR($F2=0),$G2=0))
=OR(if($F2=0,1),($G2=0,1))
I also used the and in front as well as changed the 0 to "", and I did your troubleshooting but the problem remain. Some calculate correctly i.e. if either cell F or G has information in it does not change the format, and some if both is empty it change the format. But for most of these it does not do the conditional formatting correctly. I have - for the empty cells - gone and select them and pressed delete as well to ensure there is nothing in the cells.
Hello!
Unfortunately, I was unable to reproduce your error in my workbook. Try this formula:
=OR($F2="",$G2="")
I hope it’ll be helpful.
Hello, Hope you are all well. I need help in what formula to use in conditional formatting. I would like that a cell will display an N/A value if the word/text in another cell is Enrolled. I use the =IF($G6="Enrolled","N/A"). The formula works in a cell but if I apply it as a formula in the conditional formatting it does not work. Kindly help. Thank you very much.
Hello!
Unfortunately, conditional formatting can change the format of a cell, but it cannot change the value in a cell. Your task can be accomplished with a VBA macro.
I want to highlight cells in a column that have repeated words in it. How do I do this?
Hello!
To select cells with repeated words, you need to use a VBA macro. Sorry, I cannot help you.
Hi I would like to:
Search every cell in column B for the string "supplier"
Where the string "supplier" is found, I want to format the corresponding cell in column K to be curreny and red text. Can someone help with this?
Thanks
Hello!
Use the SEARCH function to find the desired word in the text. Conditional formatting formula:
=ISNUMBER(SEARCH("supplier",B1,1))
I hope it’ll be helpful.
Sir if the column A has name
A
shailesh singh
column b has name
B
shailesh
I want to search column B in column A and remove from A
SO column A should have only name as singh
Pls guide me
Hello!
Please try the following formula in column C:
=SUBSTITUTE(A1,B1,"")
You can change the text in column A only with a VBA macro.
I hope my advice will help you solve your task.
Qns. I have an Excel sheet containing 2 columns of various number. I would like to change the first column cell format based on second column value in such way, if first column number second column number then cell fill with Green color and with other rows I would like to apply the same format. I have tried many times and many ways but I could not do. This condition is applied only one row. If I would like to apply it on other rows it takes the value of first row's second column value. How can I apply the whole formatting on other rows(Change the color based on their containing second column's value.) If anybody have the answer please share.
How do I highlight ONLY the single LOWEST number in a column? B3 to B20 has a value in each cell and if there are 2 or more numbers that match then nothing should be highlighted. I want to copy this formula to the next 17 columns beside the "B" column.
Hi!
For column A, you can use a conditional formatting formula like this:
=(COUNTIF($A$1:$A$100,MIN($A$1:$A$100))=1)*(MIN($A$1:$A$100)=A1)
How can I conditionally format for if B = Yes, then A, B, C, and D should be green fill?
Hi!
Your question is not clear. Clarify - are A, B, C, and D columns or individual cells in these columns?
Thank you. If column B is Yes or Y, then I would like Columns A, B, C, and D to green fill. If column B is No or N, I would like Columns A, B, C, and D to red fill.
Thank you so much for doing this.
I would like all the individual cells in those columns to turn green.
For instance B 2 is Y then I want A, B, C, D, 2 to be green, If B3 is N, I want A, B, C, D 3 to be red
Hi!
You can read all the recommendations you need in the article above. For range A2:D2 use the formula =B2="Y".
hi
i want D18 only to generate its specific formula if text is entered in B18?
if not, to leave D18 blank
any help would be apprieciated
thanks!
Hi!
If I understood the problem correctly, you can use the IF function:
=IF(B18<>"",A1+B1,"")
I there a log of errors generated by custom formatting formula? The formula below is not working but I don't see any error messages.
=AND(MOD(ROW(),3)=1,INDIRECT(ADDRESS(ROW(),COLUMN(),TRUE,TRUE))<0)
The intent is that if the current row number is 4,7,10,13... and the value in the current cell is less than zero, the cell should have a red fill colour. There is a specific range applied and correctly shown (moving border) during editing of the format. I have tested the "indirect" technique in a single cell and that seem to work but the conditional formatting is not. Any help very much appreciated
Hello!
The conditional formatting formula must contain cell references in the range to be formatted. For example, for the range D1:H1000, you can use the formula
=AND(MOD(ROW(D1),3)=1,D1<0)
This formula will be applied to every cell in the selected range.
Hope I understood your question correctly.
Bingo. Thanks a ton.