by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
what is the correct function or format to utilize if i want to have an up arrow if value in one cell is greater than value in another cell
down arrow if less than
wanting to track if rate is trending up or down each week
Hi!
Please check the formula below, it should work for you:
=IF(A1>B1,"↑",IF(A1<B1,"↓","="))
For more information, please visit: How to insert a special symbol in Excel.
Or you can compare two columns using conditional formatting Icon Set arrows as explained in this example.
Hi, I am trying to conditionally format some test results. I have a table with columns for each question and the marks that each student got. I have made it an actual table within excel and added in the 'total row' option within the table editing. Within this bottom row I have put the maximum values for each mark. I wanted to then use these as the references for conditional formatting.
However, it is not working. And it is something to do with using the 'total row', it is as though excel will not recognise values in this row for conditional formatting.
Any ideas?
PS I would prefer to have them in the total row at the bottom for visual purposes, I know I could move them elsewhere and make it work, but I want this to work (and also to find out why it isn't working!)
Hi!
I kindly ask you to have a closer look at the article above. Perhaps you are not using an absolute reference to the total row.
For example,
=A1>$A$10
OK, so I hope someone can help me figure this out. I have two columns, first one is year of purchase and the second is end of life (EOL). So, column one will have year 2019, column two has a formula in it that adds 5 years to the first column, (2019+5). So, purchase date will be 2019 and EOL is 2024. I'd like to use conditional formatting to show when the device is getting closer to replacement. This way the EOL column turns green as long as the device is 3 years old or younger, 3-4 years old would be yellow, 4-5+ years turns red.
Thanks for any help that can be given.
Aaron
Hi!
Here is the article that may be helpful to you: How to conditionally format dates and time in Excel.
The conditional formatting formula might look like this:
=(YEAR(today())-YEAR(A1))<3
We have somethings with expiration dates and want to make a spreadsheet that will show us (in yellow) when they are 30-60 days from expiring and (in red) when they are <30 days as well as past the due date, and all other cells are to remain white. We want the color in column C and the date in column B. We also only need the month and year and can't figure out how to set it to only show mm/yy (as in 09/22). Excell used to not be this complicated but we sure can't figure it out now-can anyone help with this?
Thank you!
Hello!
To show only the month and year, use a custom date format mm/yy , as described in this guide: How to change date format in Excel and create custom formatting.
To change the color of cells with a date by a condition, use this instruction: Conditionally format dates in Excel based on the current date.
Create 2 conditional formatting rules with formulas like this:
=A1-TODAY()<30
=AND(A1-TODAY()>30,A1-TODAY()<60)
I have column A with days and dates listed. I then have five columns (B:F) with a drop down menu of "Yes", "No", "Maybe".
What formula should I use in the Column A cells to turn just that cell in Column A to green if all other 5 columns (B:F) are "Yes" OR to turn the date cell in Column A to red if all other 5 columns (B:F) are "No". Those rows with a mix of yes, no, maybe could remain uncoloured in Column A.
Thanks in advance.
Hello!
To count the number of cells with a specific value, use the COUNTIF function.
An example of a conditional formatting formula:
=COUNTIF(B1:F1,"Yes")=5
Hi, I am trying to compare two table in two different sheets for duplicate values. Can i please ask what is your opinion in regards of what should i use for that ? Thank you in advance.
Hello!
Please have a look at this article - How to compare two Excel files or sheets for differences. I hope this will help.
I love your tools and they make my life much easier. I would like to format a cell based on the following:
If a cell in column L contains "N0" and I would like to format the corresponding cell in Colum A the same color as the format in Column L.
Hi!
In conditional formatting, you must specify the exact color of the cell. You cannot copy a color from another cell.
MY mac does have "new rules type" under "New format". What can I do ? TIA
Hi!
To create a new conditional formatting rule on mac, follow Home - Conditional formatting - New rule - Style: Classic - Use a formula (or other options of your choice).
Hi Alexander Trifuntov, it worked like charm , nice and appreciate you help and this portal
Sire, i trying to lookup 4 cells if any of the Cell contains text "Yes" than it should give a ouptu in a new cell with a text "Match found". How can i achieve this . Thanks
Hello!
Combine cell values into one string using the concatenation operator &. Search for "Yes" in this text string using the SEARCH function.
Please try the following formula:
=IF(ISNUMBER(SEARCH("Yes",A1&A2&A3&A4)),"Match found","")
Hi Alexander Trifuntov, it worked like charm , nice and appreciate you help and this portal
PLEASE HELP
I've tried everything. I have a formula that I know works in another excel sheet I already have. I have followed it exactly- to the the T again (and even copied and pasted) and copied and pasted the format only too. It goes like this
I have A4 Cell that will either contain 100% (or other varying percentages) (I've put this in text, general, numbers, percentages, etc. - still no fix). I want the B4 Cell to turn gray if A4 has 100%.
I select "Use a formula to determine which cells to format"
Format where this formula is true:
=$A4=''100" (I've also put "100%)
In my other excel where this formula works the formula is true when =$A4="Yes" but I'm guessing there is a problem because its a percentage or number? Please let me know
Hello!
A percentage is just a number. 100% is a percentage format for the number 1. So use the formula A4=1.
Read more how to display numbers as percentages.
Hello,
Thank you for the above post, I learnt a lot and have been able to conditionally format some cells I need but I am still stuck on a particular one.
I would like AE11 to turn yellow if greater than AE4 or green if less than AE4.
I have formatted these rules with no luck:
Rule 1: =AE11 >= $AE$4 (yellow)
Rule 2: =AE110,SUM(AE5:AE10),"") and the value of AE4 is generated based on the formula =IF($C$11 = 1,"1",IF($C$11 = 2,"3",IF($C$11 = 3,"5",IF($C$11 = 4,"6",IF($C$11 = 5,"8",IF($C$11 = 6,"9","")))))). Is the fact both cells contain a formula affecting my ability to conditionally format?
Please excuse my messy rules, just starting out.
Sorry, something has gone wrong with my post and now it doesn't make sense.
The crux of my problem is AE11 and AE4 both contain formulas. How do I conditionally format cells when the cells already contain a formula?
Hello!
Conditional formatting works on a value that is written in a cell or returned by a formula. Make sure that the formula doesn't return an error.
Hey,
I have checked my formulas in both AE11 and AE4 and they are both working.
The formula for AE11 is =IF(AD5>0,SUM(AE5:AE10),"")
While the formula for AE4 is =IF($C$11 = 1,"1",IF($C$11 = 2,"3",IF($C$11 = 3,"5",IF($C$11 = 4,"6",IF($C$11 = 5,"8",IF($C$11 = 6,"9",""))))))
They are both returning what is expected of them. I want to conditionally format AE11 so it turns yellow if greater than AE4 or stays white if less than or equal to AE4.
Hi!
Your second formula returns numbers as text. You cannot compare text and number. Do not use double quotes in it. Instead of "3" write 3.
Thank you, thank you, thank you! It is working perfectly now.
You are very generous in sharing your expertise.
Dear Alex,
I need to fill the current cell with some colour if the font colour of the matching data from another sheet is red. Kindly tell us the syntax ?
Thanks in advance
Hi!
To determine the color of a cell in a conditional formatting formula, use the GetCellColor custom function. The following tutorial should help: How to get the color code of a cell.
I hope my advice will help you solve your task.
Thank you so much
Dear Sir/Mam,
Need support for excel formula.
I want to show aging report to management.
if last three days not single qty dispatch showing colour Yellow, if not dispatched last 5 days showing colour Red.
please supoort.
I have data
Date wise FG in qty & date wise dispatch qty,
Regards,
Indrajit Raut
Hello!
You can find the examples and detailed instructions here: How to conditionally format dates and time in Excel - built-in rules and formulas.
I am using conditional formatting on a calendar. I created a scheduler where I enter appointments and the appointments then appear on the calendar using a vlookup. The scheduler is just a pivot table that is very rudimentary, but it really looks nice when it is moved to the calendar. The problem I am having is that when I try to search the pivot table for the condition it is highlighting everyday on my calendar because it is picking up the formulas in the pivot table rather than the results of the formulas. How do I get the conditional formatting to search for the value/results that the formulas give rather than the formula itself?
Hi!
Unfortunately, I can't understand your question. I don't know what formula you're using, but conditional formatting works with values.
Hello, hoping you can help me! I have a spreadsheet with column headings:
BUDGET - these are $ values
ACTUAL - these are $ values
VARIANCE - this is a % difference
I want to use conditional formatting in the ACTUAL cell BUT based on the result in the VARIANCE cell, eg:
If the VARIANCE is >90%, then format ACTUAL green
If the VARIANCE is between 76%-89%, then format ACTUAL orange
If the VARIANCE is <75%, then format ACTUAL red
Hoping you can help! Thanking you in anticipation!
Hi!
Have you tried the ways described in this blog post? Pay attention to the following paragraph of the article above – Formulas to compare values. Create a separate rule for each color.
I want to highlight the corresponding values of Y axis with X axis. I have about 3000 units.
V lookup can find only 1 data at a time. I am looking for the way where i can find all 3000 values in X axis and their corresponding Y axis value (it is in text format)
Hi!
Your explanations are not very clear, but maybe this guide will help you to find several values at once: Vlookup multiple matches in Excel with one or more criteria.
If this is not what you wanted, please describe the problem in more detail.
I am creating a spreadsheet where I have a drop-down with numbers 1, 2, and 3 in column C. I want to associate a different set of locker combinations to each number in column D depending on which number I select in column C... how can I best accomplish this?
Thank you!
Hello!
The dropdown list writes numbers 1, 2, or 3 to the cell. Use the IF function or the CHOOSE function to associate different locker combinations with this number.
I hope it’ll be helpful.
Hello,
I'm having trouble getting my conditional formatting to work. I have a column formatted to turn red, yellow, or green, based on how far out the date is. That part is working fine, however, I also have formatting set to grey the cell out if a separate column is marked "yes". This is working on some cells but not others and I see no reason why it shouldn't work. I have tried completely deleting all formatting and starting over. I have tried using just the grey format and it still only applies to the same cells and not the others. My formula is simple and reads =R2="yes". Do you know why this works on some cells and not others?
Hello!
Unfortunately, without seeing your data it is difficult to give you any advice. Check if other conditional formatting rules apply to these cells. Also, check the values in column R. There may be extra spaces or other characters.
I have a spreadsheet (spreadsheet 1) with all addresses in our county (about 140,000). Those addresses have latitude and longitude assigned to them.
I have another spreadsheet (spreadsheet 2) of about 300 people who signed up and gave their address to participate in a program to pick up material at their home for free. I want to conditionally match those addresses with addresses in spreadsheet 1 so I can locate people that signed up on a map using their latitude and longitude (this method is more accurate than other methods available).
Using the following formula I got about 80 of the 300 addresses in spreadsheet 2 to match with addresses in spreadsheet 1 =COUNTIFS(Address, $O2)
(Address in that formula is a Named Range in spreadsheet 2, which I read enables me to compare columns from two different spreadsheets, and it worked.)
The failed matches is because people who signed up did not always write their street name the same way the county has it in its records. But they almost always get their street number correct, and the first word of the street name, so I am guessing matching about the first 12 characters will capture many more matches.
So, I want to conditionally format a match of the first 12 characters in the address column on spreadsheet 1 with the first 12 characters in the address column on spreadsheet 2.
I have tried =COUNTIFS(LEFT(Address,12),LEFT($O2,12)) and a number of other formulas, but all have been rejected by Excel. Help getting the correct formula would be greatly appreciated.
Hello!
COUNTIFS function cannot use formula instead of a range of values. If you want to count the number of matches, use the SUMPRODUCT function.
=SUMPRODUCT(--(LEFT(Address,12)=LEFT($O2,12)))
You can also use the SEARCH function to search for matches.
=SUM(--ISNUMBER(SEARCH(LEFT($O2,12),Address)))
I hope it’ll be helpful. If something is still unclear, please feel free to ask.
Thank you Alexander for your swift response! I apologize for my long-delayed Thank You.
I wish I could say your answer worked. It is entirely possible your answer would work if I had more knowledge on how to apply it.
Bottom line is after trying your formulas (probably wrongly) I gave up and used a geocoding website (not perfect results, but appears to be pretty good). Even if I were able to use your formulas properly, this kind of problem really needs a fuzzy match, because of the mistakes people make when they write their address. From what I have read that is far trickier than what I asked about and beyond my very basic Excel skills, so rather than try to become an Excel expert for this one problem I decided to give up.
Thank you again for trying to help me, and for helping others here!