by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
How would I apply color bar formatting to a range of cells, but with that formatting based on the value of a DIFFERENT range of cells?
I have several cells containing text, and I want to highlight those cells by color from best to worst to make it easy for people to see which is better without needing intimate knowledge of the field. However there is no way for Excel to know which string of text should be 'best' and 'worst'. So for example, if I was comparing the material a tool was made from and wanted to highlight the cells showing which material was better or worse than others:
A
1 Titanium
2 Plastic
3 Wood
4 Stainless Steel
I can't just highlight column A and say Conditional Formatting > Color Bars, because Excel can't know which one is better or worse. What I imagine I would need is another column (Column B) containing numbers from 1-4 which indicate what I determine to be best to worse, and that the conditional formatting applied to the text cells in Column A is based on the values in Column B.
How can I do this please? Bear in mind that it's possible that the data source I've put into Column B would not necessarily be in a neighboring column or not necessarily even in the same row.
Thanks!
Need a conditional Formatting Formula
I have a Excel sheet colour in Orange Colour When i Feed the Data in the Cell Days wise
When i enter the Data or Text it should be changed to Green Colour
If the Data is Not entered Totay The next day the filed not Entered Value or Data should be Changed to Red Colour
Kindly provide a solution
I'm looking to have conditional formatting that looks for duplicates between a set of cells on one sheet and the set of cells on another sheet, both sheets are in the same workbook. I already know how to pull data from one sheet to another but would like to format the data pulled to look for duplicate from a set of cells on the same sheet it is pulling data from.
For example I have a sheet that pulls a drivers name from a specific cell using formula:
='DAY PLAN'!H10
but I would like to have it where if the driver is also working a PM shift listed in another sheet I would like the name to show up with the conditional formatting. I have tried using "Format only unique or duplicate values" Rule is set to Format all duplicate values in the selected range. I want the applies to formula to be:
=$D$11:$F$21:='DAY PLAN'!$R$2:$S$32
but when I hit apply, it changes to:
=$D$11:$F$21
I have also tried to enter it with these formulas with no luck:
=$D$11:$F$21:'DAY PLAN'!$R$2:$S$32
-or-
='195'!$D$11:$F$21:='DAY PLAN'!$R$2:$S$32
-or-
='195'!$D$11:$F$21:'DAY PLAN'!$R$2:$S$32
-or-
='DAY PLAN'!$R$2:$S$32:='195'!$D$11:$F$21
-or-
='DAY PLAN'!$R$2:$S$32:'195'!$D$11:$F$21
Thanks in advance!
Hello!
Perhaps this tutorial will be helpful to you: How to highlight duplicate cells and rows in Excel.
However, we have a solution that will solve your problem in a couple of clicks. I recommend the Compare tables tool, which helps you find duplicates and unique values in any two data sets: tables, columns, or lists.
It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
Thanks, got it figured out
how can we get the top 1 record for more than 100 rows (each top 1 record for each row need to be highlighted)
I am not sure I fully understand what you mean.
I have setup rules format the fill in cell B4 based on values of K4 and L4 and want to quickly copy that to the lower rows so "B" cell references the corresponding "K" and "L" cells. I tried to format paint but it kept everything referencing K4 and L4.
Hi!
Select the entire conditional formatting range and apply the rule. I also recommend that you read this: Relative and absolute cell references in Excel conditional formatting.
Thank you for your amazing blog and excel knowledge. The answer may already be in here but I'm still struggling. I am trying to hightlight cells where the employee made less than $1000.00 but not if there is a "s/f " in the comments section or "not available" in hte4 comments section or alternatively it can be if the word "ok" is in the comment section. So less than $1000.00 and have been "ok'd" by management:
TOTAL GROSS PAY OVER/UNDER FLEET MGR COMMENTS
1,112.51 112.51 Kevin
749.44 -250.56 Kevin ok
963.38 -36.62 Corey ok
1,027.34 27.34 Corey
884.58 115.42 Corey ok
825.84 -174.16 Corey ok
854.60 -145.40 Corey not available
997.32 -2.68 Corey S/F 84319
Hi!
If I understand your task correctly, use logical AND function:
=AND(A2<1000,D2<>"s/f",D2<>"not available",D2="ok")
Hope this is what you need.
I hope you can help me, I am having trouble getting the formula correct.
I want to use conditional formatting to change the color of the cell if for example cell J61 is todays date and J61 contains the text investigation. Can you please help me get the formula correct? I tried the below formula but it does not work
=AND($J61=TODAY(), $L61="Lab Assessment – Phase I Investigation")
Hello!
Use SEARCH and ISNUMBER functions to search for partial text matches.
=AND($J61=TODAY(),ISNUMBER(SEARCH("Investigation",$L61)))
Hope this is what you need.
Is it Possible to do this in tandem with a color scale formatting? For example, I'd like to use a color scale based on the values in column A, but I'd like to highlight the entire row based on those values. The one way I can see is by manually making a color scale saying if the value in A is 1 use dark grey, if 2 use a lighter grey, if 3 an even lighter gray, etc... But that's one rule for each possible value in column A. Anyway to do it in maybe two formatting conditions?
Hi!
Perhaps this guide will be helpful to you: Color scales in Excel: how to add, use and customize.
Unfortunately I've tried that forum and haven't had luck. Do you know if there's a way to set the formatting of one cell equal to the formatting of another? Or at least the coloring?
Hi!
All standard tools for copying cell format are described in this article: Excel Format Painter and other ways to copy formatting. For everything else, you need to use VBA.
Hello Team,
I am using Excel 2010. I want to know if it is possible to highlight multiple columns (same row) if cell values in sequential order (e.g numbers 1, 2, 3, 4 and so on. The numbers follow an increasing pattern (1, 2, 3…).
Sample
2 11 12 13 14 15 29 33 48 55
8 9 10 17 26 27 28 32 43 50
5 9 18 24 30 31 32 42 54 58
Need outcome result (in Highlight as following)
11 12 13 14 15
8 9 10 26 27 28
30 31 32
I have tried following conditional formatting formula (outcome : this formula only Highlight certain values)
=A1+1=B1
Please assist me with the correct conditional formatting formula? Thank you!
Hello!
Please try the following conditional formatting formula:
=(A1=OFFSET(A1,0,-1)+1)+(A1=OFFSET(A1,0,1)-1)
You can learn more about OFFSET function in Excel in this article on our blog.
Hello Alex,
Thank you so much for the reply!
The formula worked like a charm.
OFFSET function was awesome.
Thank you for making such informative website!
I am using the graded 3-color scale with percentages, 0 50, and 100. For some reason, the color will not change when entering a percentage. This is a long running spreadsheet, and it always worked in the past. I copy the cells to a new cell, as I always have done but I can't see why now it isn't working. In this example, the cell location is $M$505. The formatting is the same for the previous cells, but it won't work.
Hi!
When you copy a cell, its formatting is copied too. You can remove the conditional formatting where you copy the values.
I have an issue, I have a data field that goes up mostly 1 number at a time which is the delivery drop numbers and I'm trying to fill every other drop with a coloured background. Complex bit is it may go 1, 2, 3, 5,6,8,10 as certain things don't pull through. So would be looking at Column C. each number would have multiple rows.
Do you have any advice as still self teaching Excel.
Hi!
Please clarify your specific problem or provide additional details to highlight exactly what you need. As it's currently written, it's hard to tell exactly what you're asking.
So in column B we have delivery drop numbers.
1
1
1
1
2
2
2
3
3
5
5
5
6
8
The rows are populated with info related to the delivery, but the drop numbers above as an example go up each time but not always by 1. I'm trying to make every row of each number fill with light grey to seperate each delivery on the paperwork when printed as a visual aid.
Hello!
If your data starts with row 2, use this conditional formatting formula:
=$B2<>$B1
For more information, please visit: How to change the row color based on a cell's value.
I hope it’ll be helpful.
Amazing, it works really well. You sir are an Excel Genius :)
Hi! I'm using Conditional Formatting to highlight ranges of cells using different colors based on age range, for example I want to highlight cells between 6months,0days to 8months,31days red; 9months,0days to 11months,31days orange, and 12months,0days to 14months,31days yellow; etc.
In doing so, a couple issues are presenting:
1. Not all cells within the age range are highlighting, and
2. Ages that fall in different ranges are highlighting in the incorrect color.
Will you be able to help me with this please? Thank you.
Hi!
I do not have your data so I cannot answer these questions. I think this guide will be helpful: Excel conditional formatting for dates & time: formulas and rules.
Hello, I have a spreadsheet with conditional formatting formulas that has been working well, but the last few sets of data I have built the formatting has stopped working correctly.
For example, one row of data I have the following =C23<=30 (highlights green), then =AND(C23=45) (highlights yellow), then =C23>45 (highlights red). Applies to cells =$C$23:$N$23
The green and red formatting is fine, but the cells that should be yellow are just white.
Appreciate any help, cheers
Hello! The logical AND function is used for several conditions. Try =C23=45 If the value in C23 is obtained using a formula, the result is probably a decimal number, for example 45.0005 Then use rounding.
First, your explanations and samples are fantastic. Very concise. Thank you.
I am having an issue using conditional formatting and cell contents vs cell results.
In cell E2, I have a formula referencing a cell in another worksheet. =Mandatory!C2 Result is "PASS". In cell F2, I have a different cell reference =Mandatory!F2 Result is also "PASS".
I would like to use conditional formatting to highlight both cells in E and F based on this true statement -- if E2 = F2 . My range is set to =$E$3:$F$100.
How do I reference the cell result of "PASS" and not the formula.
Thanks for your time.
Hello!
If I understand your task correctly, for the range $E$3:$F$100 use the conditional formatting condition E3=F3.
Hello!
I have data in cells C3 and D3, in C3 I have a Start Date and in D3 an End Date. Once I populate these two cells with dates another block of cells will format in Yellow in between these corresponding dates to show that there is provisional booking. This part works fine.
Now I want to add a date into cell F3, this is to confirm a booking, once this is populated I want the same block of cells to turn Green to show that the booking is confirmed.
At the moment I have this formula =AND($F3"", $P$2>=$C$3,$P$2<=$D$3), but it is highlighting everything in the row where I only want it to highlight the same specific dates.
Any ideas how I can do this?
To select only one cell and not a row, apply conditional formatting to the column. Also note the sequence in which you apply the rules by following these instructions: Apply multiple conditional formatting rules to same cells.
I hope it’ll be helpful. If something is still unclear, please feel free to ask.
Good morning, I hope you can help me please.
I have estimated costs in 1 column, and actual costs in the next. I would like the actual costs to change colour when they get to 70% of the estimated. And then change colour again when they go over the estimated.
Is it possible to do this with conditional formatting please?
Thank you in advance, Hayley x
Hello!
Create two conditional formatting rules with formulas =B1>A1*0.7 and =B1>A1
All the necessary information is in the article above.
Hi there,
is there a way to autofill text based on duplicates?
Let's say I have worksheet made like this:
Data 1: Data2:
A1 = car = B1 = vehicle
A2 = banana = B2 = food
A3 = B3
If A1 have a text with let's say "car" and then B1 have a text "vehicle" so when I copy paste "car" from other notebook to the cell A3 is it possible for B3 to automatically fill the row with "vehicle" text?
I often have to paste 10+ various IDs and sometimes they are duplicated for different Special IDs so I thought it would be nice if the value could be automatically filled with the same text for the same value if the other cell is already filled somewhere in the worksheet.
Hi!
Maybe this article will be helpful: How to use AutoFill in Excel - all fill handle options.
Hi I have a small problem with my Conditional Formatting.
So the formula itself works, the color changes to gray whenever any text I type manually contains letters SD (it's only example).
However it only works, whenever I type the text manually - let's say if I type SD12345 the text will turn gray.
If I copy and paste the text from notepad or somewhere else, it suddenly doesn't work.
However my other, normal formula (not CF) to autofill text in another cells, based on text with letters SD works perfectly fine.
So if B2 for example contains text SD12345, C2 will autofill text with text "Apple" for example. I wanted B2 to also turn gray however it doesn't work whenever I copy this text from other source and having 500+ values it's getting pretty time consuming to type everything.
I can't post a CF formula right now as it's on my work computer but I hope you get the idea.
Hi!
When you copy and paste, you are also copying the formatting of the cell from which you are pasting the value. This cell is excluded from conditional formatting rules. If you use Paste Special - Values then conditional formatting will work.
I am trying to create a formula for out of date training. So basically if someone has completed a training course within 2 years the cell remains green. If they completed the training over 2 years ago the cell turns red letting us know straight away that the person needs re-training asap.
Hi!
Here is the article that may be helpful to you: How to highlight dates within a date range. This should solve your task.
Nice explanation with examples.