by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
hi dear
im using this formula =IF(AE4=""؛AD4؛AE4)
when there isnt formula inside those cells(ad4 nd ae4) it work perfect but when I use formula inside those cells it dont work .(im using xlookup for gathering data for these cells)
I want to use value of ae4 if its not empty other wise if its empty or blank or ziro i want to choice ad4 data
plz help me
Hi! If I understand correctly, you are trying to write this formula in cells AE4 and AD4. This creates circular references because the formula cannot reference itself. Choose a non-empty value inside the XLOOKUP formula.
Hello, I work for a company that has approximately 400 agents.
I am looking to create an Excel spreadsheet that can verify when an agent has gone past a certain time frame (when replying to a guest by email), and if possible, conditional formatting the time between receiving the email and responding to it.
The idea is to verify if the agents are replying on time and to check, as a quality assurance department, how often this happens during the month.
However, I am not sure how to create a formula for email threads that are in, for instance, outlook.
Hi! Try to use the recommendations described in this article: How to conditionally format dates and time in Excel with formulas and inbuilt rules. I hope it’ll be helpful.
I want to put a formula on an entire column without having to put that formula in a cell and dragging it down as I go.
I want to put the invoice amount in column A and have column B automatically put the amount without tax (5%). I tried highlighting column B and making a new rule with conditional formatting using a formula of =SUM($A1/1.05). If I put $105 in the cell in column A I want column B to autofill the adjacent cell with $100 (the amount without tax).
Right now nothing at all is coming up in column B when I put an amount in column A.
What am I doing wrong? How do I apply a formula to an entire column with out dragging it down as I go?
Thanks!
Hi! If I understand your task correctly, the following tutorial should help: How to copy formula in Excel with or without changing references.
Hi! I'm building a workbook that tracks employee performance which will (based on drop-down list selection) display a list of performance metrics/goals and subsequent ranges for achieving performance ratings (1, 2, 3, 4, and 5). I'm utilizing IF, VLOOKUP and IFS functions to identify which goals and ranges to display. The goals and ranges are housed in another sheet on the same workbook. For the metric, the reference formula looks like this: =IF($G$3="","",IF(VLOOKUP($G$3,Goals!$Z$3:$AG$9,5)=0,"",VLOOKUP($G$3,Goals!$Z$3:$AG$9,5))). For each cell returning the ranges for which performance results fall, I'm using: =IF($N$3="","",(IFS($G$3=Goals!$B$16,Goals!$I$17,$G$3=Goals!$B$2,Goals!$I$3,$G$3=Goals!$B$23,Goals!$I$24,$G$3=Goals!$B$30,Goals!$I$31,$G$3=Goals!$B$9,Goals!$I$10,$G$3=Goals!$B$44,Goals!$I$45,$G$3=Goals!$B$37,Goals!$I$38))).
Since each Metric may vary in Format (i.e., Number, Percentage, Custom ([h]:mm:ss)), I'm wanting to use Conditional Formatting to change the Number Format of the range of cells pulling back performance ranges. The only way I've had success in doing this is to create Conditional Formatting based the values returned from the IF/IFS formula above. My issue is that the performance ranges aren't necessarily static, so I would prefer a method that could simply apply the appropriate Number Format based on the goal type returned from the IF/VLOOKUP formula (which is located in a Merged cell above the two columns where the ranges return. This would allow for the appropriate formatting to match the source based on the header.
I'm not using an Inserted Table, because I need to Protect most of the document. Also, I've attempted using the "Use a formula..." Rule Type, but it isn't applying the desired Number Format. I've also tried applying General as the Format for the range of cells with which I'm having the issue.
Is there a way to build Conditional Formatting that controls only the Number Format of a desired range based upon a heading derived from a VLOOKUP in a separate row from the desired range?
Thank you!
Hi! Unfortunately, your explanation is not very clear. However, I recommend to pay attention to the CELL function. With info_type "format" you can get the format code of the cell.
I will read about the CELL function and see if I can use the format code to properly format the cells.
Apologies for the unclear explanation. Essentially, the range of cells I'm trying to Conditionally Format would return references based on a header. Depending on which header, the returned data should appear with the appropriate Number Format. For instance, one header should return data as a Percentage, another should return it as a Number with no decimals, and yet another should return as Customer [h]:mm:ss.
I hope that clears up what I'm trying to do. Thanks!
I'm going to guess that you can use the recommendations from the article above and, for example, this formula for each type of formatting:
=OR(A1="ABC",A1="DEF")
Specify in this formula all possible values at which the percentage format, for example, should be applied.
Hello,
I have the following formula to format cells in column E. Idea is that they are coloured red when the values in column D and E met the conditions as stated in the formula (both textual values):
=AND($D3="Noodzakelijk";$E3="Niet gestart")
I also tried many other ways, including:
=AND($D3="Noodzakelijk",$E3="Niet gestart")
but Excel doesn't recognise this as a formula because of the komma.
Any idea how to solve this?
Rows 1 and 2 contain headers btw.
Hi! Your conditional formatting formula works if you apply conditional formatting to a range of cells starting on row 3. For example, D3:E100
Pls I want to apply 3 different colour codes to an entire column based on their values but referencing from another particular cell. Using conditional formatting, it is getting only colour from the first cell of that column
When you create a conditional formatting rule, apply it to the entire range, not just one cell. Read more: Excel Conditional Formatting tutorial with examples.
Hope you can help....believe this is simple but still scratching my head.
Trying to format a column of cells based on another cell text value. For example; If B10="Higher" conditional format cells in range B15:B25 and highlight the cell (single) that has the highest numeric value in that range. And if B10="Lower", conditional format the cells in range B15:B25 and highlight the cell that has the lowest numeric value. Note; the range my contain more than one higher or lower cells and i would want them to format also.
thanks
-Mxc
Hi!
To do conditional formatting on two conditions, use the logical AND function. For the range B15:B25, apply this conditional formatting formula:
=AND($B$10="Higher",B15=MAX($B$15:$B$25))
I also recommend taking a look at this article: Relative and absolute cell references in Excel conditional formatting.
Hi there
I really hope you can help ... I'm trying to use conditional formatting to change text colour based on comparing the values in two columns. There are four rules I'll need to apply using different formulas for each:
FORECAST - NOT BOOKED: if the value in column C is higher than zero, and the value in column D is zero then make the text colour blue
FORECAST - UNDERBOOKED: if the value in column C is higher than zero, and the value in column D is less than the value in column C then make the text colour purple
FORECAST - OVERBOOKED: if the value in column C is higher than zero, and the value in column D is more than the value in column C then make the text colour red
NOT FORECAST - BOOKED: if the value in column C is zero, and the value in column D is higher than zero then make the text colour orange
Fingers and everything crossed you can help. Thank you so very much in advance!!
Best regards
Lynne
Hi! I hope you have studied the recommendations in the tutorial above. It contains answers to all your questions. Use the AND function to test both conditions. For example,
=AND(C1>0,D1=0)
Yeah, that's the formula I was using but I'd selected the actual row number i.e. C4 rather than C1 and it wasn't working. I've now changed it to C1 and it works!!
Thank you for your advice and clarity!!
Kind regards
Lynne
Hello,
I am trying to highlight column J values for the following condition:
If all cells on C1:I1 are blank highlight J1.
However, I want this applied to the whole table not just one row. Ex If C2:I2 cells are blank highlight J2.
Is there a way to do this through conditional formatting?
Hello!
Select the range of cells J1:J100 and use the conditional formatting formula
=PRODUCT(--ISBLANK(C1:I1))=1
For more information, please visit: Relative and absolute cell references in Excel conditional formatting.
Thank you so much!!! It worked!
Hi!
I have a two part question that may go beyond conditional formatting capabilities, but though I might give it a shot. Essentially, I am using Excel to track training records for our company. We have 25 documents we train to, each with a different revision (they are periodically updated). Every person has the date and the revision of each document input into this spreadsheet. I was able to get the revision column to conditionally format properly (highlighting red) by comparing their latest trained revision to the latest revision released through the formula "=D4D$3", where D4 (and D5, D6, etc.) is the employees latest training and D3 is the revision of the latest released version of the document. This formula will be repeated 25 times, hence the non-absolute values except for row 3. My questions are:
1. Next to these revision columns, I have the date the employees completed the training. Can I format these columns to highlight red based on the revision comparison? For example, in column C, I have the date of training for the document noted above (in column D). I made a formula the following formula to highlight cells red: "=D4D$3". However, nothing happens with this formula. Can you condition one cell based on comparison of values (in this case text) in two different cells?
2. The first column is the person names. Not super necessary, but it would be nice if I could highlight the person's name based on the outcome of the formatting in the subsequent columns as described in the first paragraph above. Essentially, at a quick glance I'd like to be able to look at a person's name, and know they are missing updated training to one of the documents. Not sure how I would make the formula, but maybe an IF statement with a bunch of ORs comparing the employee's revision to latest revision (as seen in row 3 as mentioned in the first paragraph above). Is this a possibility?
Let me know if there's anything I need to clarify in the query above.
Thanks,
Hi!
If I understood correctly, select the range C4:C29 and apply the conditional formatting rule =D4<>$D$3 to it.
I hope this will help.
Hello,
When I try to write the following conditional formatting with "Use a formula to determine which cells to format" I always get that standard warning message "There's a problem with this formula. Not trying to type a formula? ....."
=AND(G11=6,M11=1800)
I want to format M11 cell with green color by above conditional formatting.
Hi!
Check your regional settings and list separator.
Can i make a formula that if a digit is greater than my fixed digit one column text will be highlighted automatically?
Please re-check the article above since it covers your task.
Hi Alexander Trifuntov,
I want one entire row to show from among the drop downs based on the values entered in another cell.
I have drop downs 1. Below 100, 2. 100-110, Now I want an entire column cells to display the above result based on the values entered in another cell.
( ex. I have drops downs in H column with the above mentioned criteria, now I want these to come up automatically based on the values entered in Column G) If 89 is entered in Column G then Column H must show Below 100.
Kindly help, I would be highly obliged.
Hi! Unfortunately, you can only show one of the two drop-down lists by condition with a VBA macro.
Hello, I have a conditional formatting formula set in my data in which specific cells highlight in red based on input of another cell in another column, the formula is =$AB3"". I want the red highlight to be removed once data is entered in the cells. I think the isblank formula can be used in this case but I cant seem to find the way. Would anyone please advise? Thank you very much
Hi!
To check if a cell is not empty, you can use this formula:
=NOT(ISBLANK($AB3))
Hope this is what you need.
I am hoping you can help me! I have googled and even asked a friend that is good with excel but still can't get an answer. I have a pivotable that I am Conditional Formatting with "Highlight is equal to 0" and the second conditional formatting is fill in with black if it is Blank. I put both of these in and one worked and the other wouldn't save. I went to manage formatting rules and only one was there so I used the "New Rule" from that screen and when I clicked "OK" to go back to manage formatting rules screen from formatting screen, the rule disappears. I can't seem to get it to stay long enough to hit "Apply". This has happened before and now it is happening. I have noticed both times, I was only formatting 2 columns of the pivot table.
Also, I tried to format the top cell and copy it down and it will only use one of the rules and not both. The second disappears.
So my question is there a way to trick the system into keeping both rules? When I do other sheets that have 4 columns formatted it does fine.
Thanks for any insight!
Hi!
I can't see how you create a conditional formatting rule for the pivot table. Perhaps this article will be helpful: How to make a heat map in Excel PivotTable.
Hello,
I have three columns (G, H, & I) with drop down selection of 1-4. I want the cell in column J to be grey unless any of the cells in column G, H, or I are less than 2 but not blank. (i.e if column G & I are blank, and H is 3 or 4 column J is greyed out, but if H is 2 or 1, J is not greyed out.) Could you help me on this?
Hi!
If multiple conditions must be true at the same time, use the logical AND function.
Try this formula:
=AND((G1:I1>2),NOT(ISBLANK(G1:I1)))
That worked, THANKS!
Hello!
I have a table with list of Price of Chemicals by Month.
Some prices on particular month cells have been highlighted in Light Yellow.
I would like to know if can use Conditional Formatting to identify those cells highlighted in Light Yellow.
I managed to get a link and tried but it does not work, do you have a better one, please.
"This can be accomplished with a user-defined function. First, create the function to identify the fill color of the cell:
Function IdentifyColor(CellToTest As range)
'Returns R + (256 * G) + (65536 * B)
'IdentifyColor = 255 for red, 65280 for green, etc.
IdentifyColor = CellToTest.Interior.Color
End Function
Then create a conditional format formula for cell A5 based on this formula: =IdentifyColor(B5)=65280
It may be easier to use HEX2DEC to specify colors. Therefore, the formula would become: =IdentifyColor(B5)=HEX2DEC("00FF00")"
Hello!
In the article How to sum and count cells by color in Excel, you can find the VBA code for a custom functions GetCellColor and GetFontColor that return a color code. You may also find other functions and examples in this article useful.
Hi there,
I'm trying to condition individual cells ( that contain an average of another data set ) to be shaded/filled based on its amount compared to a single other cell.
Here's what I have so far, and it's doing nothing so far:
Formula= "$H$26 > $J$26"
If this statement is true, it should be shaded green - however, it is doing nothing! Help!!
Hi!
Your question is not very clear, but I'll try to guess.
If you want to compare multiple cells with a single cell, don't use absolute references for them.
H26 > $J$26
Read more: Relative and absolute cell references in Excel conditional formatting
How do I apply conditional formatting to show me if data in a cell is not in a specific format e.g. Time column should be in the Time format 13:30
Hi!
Unfortunately, Excel formulas cannot determine which date and time format applies.
Hi. I'm trying to apply a conditional format on a column based on another column's text; yes to the whole column. I saw that in that case you could use $B:$B (for example) for setting that column that you will use as reference. My conditional format looks like this:
Style: Classic
Use a formula to determine which cells to format
=$B:$B="Pago Tarjeta Credito Cash Rewards"
Format with: Custom Format. AaBbCcYyZz (text in red, no fill)
Applies to: $A:$A
Although I don't get any error notifications, I just can make it work. I already tried your way, checking first if I have headers or something in the first row that could interfere with the formula and based on that I changed the formula to (My data has headers and some notes on the first two rows):
Style: Classic
Use a formula to determine which cells to format
=$B3="Pago Tarjeta Credito Cash Rewards"
Format with: Custom Format. AaBbCcYyZz (text in red, no fill)
Applies to: $A:$A
But it still doesn't work...Can you try to tell me what I'm doing wrong?
Thanks.
Hi!
If you apply conditional formatting to an entire column, use a reference to the cell in the first row in the formula. For example:
=$B1="Pago Tarjeta Credito Cash Rewards"
I hope this will help.
How can I conditionally format a dependent drop down list level 2 when drop down list level 1 is selected that has values in level 2? I want for the level 2 dropdown cell to change background color when I've selected a value in level 1 dropdown, alerting me that there are further values to select.
Hi! You can conditionally format any cell whether or not it has a drop-down list. Conditional formatting uses the value of the cell.