by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
Hi,
I have a timetable where I want several cells to change color if something is written in one cell.
So in row 1 are the days and in column A are the times.
Each cell in the table corresponds to one hour.
I would like someone to be able to write their name + 3h or 6h etc and have the cell written in plus the cells below change color.
So for example if someone writes name + 6h in D4. D4 to D9 will change color.
If someone writes name + 3h in F10. F10 to F12 will change color. And so on.
Is that possible?
Thanks in advance
Hi! The conditional formatting rule is set for each cell separately. I'm really sorry, looks like this is not possible with the standard Excel options.
Good day,
I tried to apply your tutorial to my situation, but my brain is not connecting the dots. I want to format a cell in column H if cell D is "Yes" and the time in H is > 00:01:20. See my summary with the or condition below. I'm getting errors on the variations that I'm attempting.
Format cell:
If D2 is Yes, and H2 > 00:01:20
or
D2 is No, and H2 > 00:05:00
I assume two different conditions with stop if true, but I can't even get one to work.
Thanks for any guidance you can provide.
Hi! Use the AND function to check if two conditions are met at the same time. Determine the time using the TIME function. Try this conditional formatting formula:
=AND(D2="Yes",H2>TIME(0,1,20))
I work a lot with conditional formatting, sometime up to 100's at a time.
Since the excel is more and more used in the cloud, and VBA is not possible anymore, I stumble across this, which maybe, very maybe, can be resolved by conditional formatting:
I change a value in a matrix, let's keep it simple $A$2:$E$2
By a formula I can change the date in $F$2 to today
Is it possible to do the following with conditional formatting (it is NOT possible with a formula):
I want $G$3 to display the date of the last change in the matrix.
Since everything is always updated, I think it must be impossible however, there is a menu 'review/show latest changes', is there way to access those values, then we are saved.
thanks for any response
Johan
Hi! Unfortunately, if you can't do it with a formula, you can't do it with conditional formatting either. I think this instruction will not work in the cloud either: How to insert today date & current time as unchangeable time stamp.
Compare 2 columns for duplicates
for this part I used this formula
for column A:=COUNTIFS($B1$:$B$5,A1)>=1
for column B:=COUNTIFS($A1$:$A$5,B1)>=1
Hi!
This is very helpful. I do have a question, though: I'm trying to set up a formula for a material list in Excel at work. The material list tab has a column for Quantities, Materials, and Unit Prices. The Unit Prices for each material item are auto-generated into each cell on Column I based on a material cost database located on a separate tab in the workbook. The material cost database is pretty comprehensive, but it does not provide a unit cost for all material items, so if an item is selected on the Material List tab that does not have a unit price in the database, Column I will show pricing for that item as $0.00 on the Material List tab. I would like to set up a formula that highlights that cell so that it flags attention to the missing cost.
Example: Let's say I want to price a quantity of five pieces of wood that are 2x4x16'. I first enter a quantity of "5" in cell A5. I then select "2x4x16'" in the drop-down menu in cell D5. The unit price for this item will automatically appear in cell I5 and the extended price for the total cost of five pieces will appear in cell J5. Now, let's say I want to change the length of the boards from 16' to 14'. So I use the drop-down menu to select "2x4x14'". However, let's say that a price does not yet exist for the 14' boards in the cost database, so the unit price in cell I5 shows $0.00 instead of a unit cost. In this scenario, since I'm asking it for a price on a quantity (five boards), I want cell I5 to highlight itself so that it shows a missing unit cost for this item. At the same time, I also don't want the cell to turn red if the quantity listed in A5 is set to zero. Does this make sense? I've tried using the formula =AND(A5>0, I5>=0), but it did not work as I was hoping because it is now turning cell I5 red whenever a quantity greater than zero is entered into A5. Any suggestions would be appreciated!
Hi! If I understand your task correctly, the following formula should work for you:
=AND(A5>0,I5=0)
can you please help in manage the following formatting:
They should be conditionally formatted so X days to 20 days have a no background, 30-15 days are in a yellow background, and 15-0 days are in Red. Once it goes into active status, +1 days, the conditional formatting background should become green.
As for the end date time delta:
The conditional formatting should be green until 4 months from contract end, at three months the background should be conditionally formatted to be shaded yellow, and then at 1 month, the background should be red.
Also, please use the start date, end date or extension dates in the tracker and not ones that are two weeks out. We need real countdown to when the call order goes live.
Hi! I can't offer you conditional formatting formulas without having your data and a more complete description of the task. All the information you need is in the article above. In addition, this guide may also be helpful: Excel conditional formatting for dates & time: formulas and rules.
This is all beyond me however, I am trying to learn. I want to change the colour of the font in a cell when 2 other cells have text in the cell. i.e. B2=when C2 and D2 have text. Is this something that is possible? Any help would be greatly received.
Hi! To validate text in cells, use the ISTEXT function in a conditional formatting formula.
=AND(ISTEXT(C1),ISTEXT(D1))
Hi,
Fascinating examples and too complicated for me. I have only used conditional formatting for finding duplicates in different columns. It works fine for most item but some items that appear to be identical are not marked in red. My case is addresses. I am very carful about spacing, spelling, and punctuation all of which if not identical will fail to fail two items as identical. Any idea why Excel refuses to recognize visually identical items in isolated instances? After copying one oveer the other they do turn red (obviously). This is frustrating in trying to elimiate duplicate addresses. Any? idea what is going on.
Charles
Hi! Maybe this guide will be helpful: Remove non-printable characters in Excel.
Hi,
I wonder if you can help me as I am tearing my hair out. I am trying to highlight a cell when the date becomes overdue but then change say from red overdue to green done. My column with the wording overdue and done does not show in the formula. The cell I want to highlight (J4) has the formula
=IF(AND([@[Status ]]="Complete",[@Complete]=1),1,IF(ISBLANK([@[Due Date ]]),-1,IF(AND([@[Status ]]"Complete",TODAY()>[@[Due Date ]]),0,-1)))
I cannot see where these words are fetched from unless they are hidden somewhere.
Hi! It is very difficult to understand a formula that contains unique references to your workbook worksheets. Hence, I cannot check its work. However, the conditional formatting formula must return TRUE or FALSE (1 or 0), not -1. For conditional formatting, your formula cannot work.
I am trying to replicate a conditional format. For each new cell the conditional value changes. So for example the result in A2 is /= to A1 but the result in B2 is /= B1. So far I can only get the results for A2-F2 to be conditional on A1 and not change for each new cell. I hope I'm explaining this right! Apart from just doing over 100 cells individually is there a way to easily replicate. Thanks
Hi! If I understand your task correctly, this article may be helpful: Relative and absolute cell references in Excel conditional formatting.
I am trying to highlight duplicated if column A and column B are the same. I am creating a spreadsheet with book and page Column A is the Book and Column B is the page I want the duplicates of the same book and page. So if book 135 and page 2 repeats I want that highlighted. Is there a way to do this?
Hi! If I understand your task correctly, this article may be helpful: How to identify duplicates in Excel: find, highlight, count, filter.
Hi, I am trying to highlight a cell if the value of one cell id not equal to AND the value of a cell is equal to.
I tried this but is not working
=IF(AND($C44"#N/A",$D44="#N/A"),TRUE,FALSE)
Hi! If you want to define an error in a cell, use the ISERROR function. Try this formula:
=IF(AND(NOT(ISERROR($C44)),ISERROR($D44)),TRUE,FALSE)
Hope this is what you need.
Hi, I have a list of dates for deliverables and want to highlight those that are due today; due this week; due next week; etc. I used the 'Date Occurring' prebuilt criteria which is great for highlighting the date (in column C), BUT I want to also highlight the task description (in column A) the same colour as the date. I can use the formula, but I cannot see a formula that has the concept of "This week" (I can do 'between TODAY() and TODAY()+7' but this is not the same concept as 'This week' which is the Sun-Sat week (or Mon-Sun).
Do you have any suggestions? Otherwise I will just have to rebuild it using the 'between' formula which doesn't quite do what I wanted (with people being able to see those tasks due this working week, next working week, etc. and would instead be due in the next 7days, or the next 7-14 days.
Any suggestions? Thanks :)
I have solved it, though there may be a more efficient way.
I ended up using the "WEEKNUM" function. So, if the due date is in cell C1, then:
This week is WEEKNUM(TODAY())=WEEKNUM($C1)
Next week is WEEKNUM(TODAY()+1=WEEKNUM($C1)
If there is a better way, I'd be happy to hear it. As it is, this is my IF statement for the due date descriptor column:
=IF(ISNUMBER($C1),IF($C1TODAY(),$C1TODAY(),$C1<TODAY()+31),"This month",""))))))),"")
This may be a bit overdone with too many options so may be refined (removing the next fortnight for example), but for now it's what I was after.
Happy to hear any feedback/criticism/ideas!
Keep up the great work :)
It cut off my IF statement as it doesn't like some of the syntax. Not sure how to get around that. Needless to say, that formula is not correct! :)
I am trying to figure out how to use conditional formatting so that if I have a group of five cells the fifth cell is red unless there is text in any of those five cells. So I would like A5 to be the color red but if there is text in any cell A1:A5 then the color of the A5 cell would be gray. Is this possible?
Hi! To check the text in a cell, try the ISTEXT function. For example,
=SUM(--ISTEXT(A1:A5))>0
Hello! Im looking to create a conditional format rule to highlight when a commission was not paid, but was supposed to.
I have "Yes" or "No" values where the column is the month, and the row is a policy that commission should have been paid to.
I also have another field in a separate column the date the commission should have started
For example:
Commission start: 10/22
Payment status:
10/22 No
11/22 Yes
12/22 NO
I want it to basically highlight the 12/22 field because a commission was NOT received even though it should have been (after that commission start date)
Any advice?
Hi! I hope you have studied the recommendations in the tutorial above. Unfortunately, this information is not enough to recommend a formula to you. It is not clear how your data is written. However, "12/22" and "12/22 NO" are text. You cannot compare the text "10/22" to the text "12/22".
I have been struggling with conditional formatting for weeks trying to crack this code! I have a spreadsheet that is tracking Personnel (Column A), with a completion date (Column C) within a time frame of 6 months. I have set up 3 cells with current date (E44), start date (E47), due date (E48) separate from the table.
I need a formula that will highlight cells in column A, based on whether Column C is blank AND a specific Cell (E44) is within 60/30/15 days of the due date listed in Cell (E48). Each increment will be formatted to a different color (i.e.60=blue, 30=yellow, 15=red).
Hi! If I understand your task correctly, the following conditional formatting formula should work for you:
=AND(ISBLANK(C1),$E$48-$E$44<60)
Combine the conditions using the AND function.
Hi All - I'm not sure if this is possible but would like to pick your experience and knowledge to see what could be done...
I'm trying to apply a conditional formatting on a column.. to change the cell color when it meets the below conditions:
1. Cells in the column where we have conditional formatting applied should be more than 0
AND
2. Value in the adjacent cell in the same row should be a fixed text
AND
3. Value in a fixed cell anywhere in the file should be a fixed text.
Example:
I have texts in cell A3, A6, A7, A9.... = Deployed
I have text in cell B2 = Not Deployed
I have text in cell C2 and D2 = Deployed
I need to have conditional formatting applied in column D, the conditions should be as mentioned above... If I'm looking at Cell D3, if the value is more than 0, if the value in D2 = Deployed and if the value in A3 is Deployed, then the cell D3 should be colored green..
I have tried a lot of combinations and formulae and its not working... any help would be highly appreciated.
Hi! You have given two different descriptions of the task. The sample data does not match these descriptions. It is not clear to which data range you want to apply conditional formatting. If you need help, please describe your problem accurately.
Hi there! I'm having quite a bit of difficulty with conditional formatting. I've been trying to figure this out for weeks now! I would appreciate any amount of help!
Here's an example of what I'm working with:
Column A has dates and Column B has rooms. I want a duplicate value in Column B to be highlighted only if there is also a duplicate date in Column A of the same rows. Basically, if Room 1 is being listed twice on the one date, I'd like it to be highlighted.
For example: I would like to have a formula that formats B2 and B3 if A2 and A3 are the same, but not include B4, because the room is different, and not B5 because the date is different.
A2 B2
01 January Room 1 - Highlight
A3 B3
01 January Room 1 - Highlight
A4 B4
01 January Room 2
A5 B5
02 January Room 1
Hi! We have a special tutorial that can help to solve your problem. Read: How to highlight duplicate rows in Excel.
You can select duplicate rows in Excel in a couple of clicks and without formulas using Duplicate Remover tool. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
Hi everyone!
I'm having a hard time working with conditional formattig on Excel Online. I don't know if the logics are different from the desktop version, but I feel like the formulas are very simple and straight-forward, however they are not working as I expect them to. I have a fill with multiple data validations in place but unfortunately this data validations do not work because we usually copy and paste data from other sheets and paste it on this one, which seems to bypass the validations. So I have been trying to use conditional formatting to highlight the cells instead.
Here are two examples:
1. For a column (F) with data validation list, I want to highlight the cells it if the text is not Proper case. I'm using the following conditional formatting rule: Apply to range F2 and Highlight cells with cell value not equal to =EXACT($F2,PROPER($F2)). The issue is that this highlights all the cells. My expectations is that it should highlight "this example" but not "This Example". I also tried changing range to F2:F, F2:F2 and changing the formula to =EXACT(F2,PROPER(F2)) | =AND(EXACT(F2,PROPER(F2)),ISTEXT(F2))
2. For a column (B) with data validation based on length, I want to highlight the cells if the value is not equal to exactly 10 characters. I'm using the following conditional formatting rule: Apply to range B2 and Highlight cells with cell value not equal to =LEN(B2)=10. The issue is that this highlights all the cells as well. My expectations is that it should highlight "123" or "123456789012345" but not "1234567890".
I'd appreciate any help with this. Thanks in advance!
Hello,
I have a conditional formatting for a file and was wondering if you could help.
I will use | to show how the file columns are set up with 1 set of headers in row 3.
|Current|Comparison|New|Special1|Special2|Current|Comparison|New|Current|Comparison|New|Special1|Current|Comparison|New|
The conditional formatting looks at the data under Current and New to highlight is based on the values. (like if Current is 5 and New is 0, then fill color is Red. If Current is 5 and New is 10, then fill color is Orange)
With the Conditional Formatting Rules Manager, Applies To:
Currently I have to add the range for every column I need it applied to. (like this, =$O$4:$O$12,$T$4:$T$12,$W$4:$W$12,$AA$4:$AA$12)
How I can apply to a whole range ($O$4:$AA$12), but if the column header row 3 = "New"?
Hi! I’m sorry, but your description doesn’t give me a complete understanding of your task. Maybe this article will be helpful: How to change background color in Excel based on cell value. If this does not help, explain the problem in detail.