by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
Whats formula in format cell to conver gujrati number to english
To understand what you want to do, give an example of the source data and the expected result.
Hi Abelbits Team
I'm attempting to create a formula rule that will change a cell fill colour if the 5 digit number entered in that cell is at a later date entered on another sheet in the workbook.
Is this possible?
Hi! This can be done by specifying in a conditional formatting formula the exact cell on the other sheet where this 5-digit number can be written. Or, write a formula in that cell that returns TRUE if the value is found on another sheet. For a more precise answer, your question contains no data.
Hello,
I have to highlight duplicates Values in Column A, If value in the column is "No". Also, duplicate value is equal to "Yes" I dont want to highlight that cell.
ID Received
12 No
12 No
13 Yes
13 No
Also i dont want to consider ID's for duplicate values if its equal to "Yes".
Hello! I’m not sure I got you right since the description you provided is not entirely clear. However, it seems to me that the formulas below will work for you:
=IF(COUNTIFS($A$1:$A$8,$A1,$B$1:$B$8,"No")>1, "Duplicate", "")
or
=IF(AND(COUNTIF($A$1:$A$8, $A1)>1,B1="No"), "Duplicate", "")
Read more: How to find duplicates in Excel: identify, highlight, count, filter.
Hello there!
I have a budgeting template I'm using and I can't really get the conditional formatting to work.
I have columns in a table labeled: Amount, Budget, and Difference. I'm trying to use conditional formatting on the Difference column with Icon Sets. Whenever I clicked on the Icon Sets button and selected the one I wanted, it would place the icon in the column, but it wouldn't be accurate for what I was wanting it to do.
I'll put an example below:
Amount Budget Difference
$25.00 $50.00 (Up Arrow Icon) $25.00
$75.00 $25.00 (Up Arrow Icon) ($50.00)
$100.00 $20.00 (Right-facing Arrow Icon) ($80.00)
That's just a small example of what keeps happening to me. I wanted to see how much more negative I was compared to the amount I budgeted for; however, the icons are misleading. It'd put a green/good arrow where the number was negative and should have had a red down arrow. I hope this makes sense. I'd include a snippet of my screen for more clarity, but it won't let me paste the image here. Please help!
Hi! Try to use the recommendations described in this article: Excel Icon Sets conditional formatting: inbuilt and custom. Set different icons for positive and negative numbers as described in this article.
Hello,
I have a data set that contains text in the 1st cell of a row and then numbers in the next contiguous cells, depending on number of samples taken.
I want to format the numbers based on the specific text in the 1st cell as a 3 colour scale.
Each 3 colour scale would be different based on the text in the 1st cell.
eg:
bananas,3 8,2,6,9 --> highlight cells red if bananas value <4, Yellow if 6
oranges,30, 80,50 --> highlight cells red iv value <4, Yellow if 6
I cant figure from this tutorial, how this may be achieved.
Any help would be greatly appreciated
Hi! If you want to know how to use Color Scale correctly, have a look at this article: Excel conditional formatting Color Scales.
Because Color Scale cannot use another cell's value for formatting, I don't think it can be used in your case.
You need to create a separate conditional formatting rule for each condition, as described in the article above.
Hi,
Thanks for your time.
I am after a formula for conditional formatting that relies on data from 4 other cells.
Basically, I want cell A4 to switch colour based off whether the values in B1, B2, B3 and B4 all equal "Pass". If they all don't equal pass, then the colour doesn't change.
The conditions for B1:B4 equal: Pass, Fail or "blank"
I'm thinking a formula something like: =(B1="pass"+B2="pass"+B3="pass"+B4="pass")
Thanks for your assistance.
Hi! Use the AND logical function to check that all conditions return TRUE.
Try this conditional formatting formula:
=AND(B1:B4="pass")
Thanks Alexander, that worked great.
I want a simple calculation, of one value divided by the value in the next column, to highlight the first column where the value exceed a limit, e.g. =$C2/$D2>3600, but it is highlighting cells that do not meet this condition and missing cells that do. I am baffled as to why this doesn't work - there are other conditional formatting rules on the worksheet, but they only apply to different columns. Do you have any advice as to what I could be missing please?
Hi! Unfortunately, you don't write what errors you are getting. If you apply the conditional formatting rule to the whole column, do the formula for the first row =$C1/$D1>3600
If this does not help, explain the problem in detail.
I am trying to format a single cell based on the contents of two other cells in the same row as each other. The cell that I need to format is J9. The cells in the other rows are C11 and J11. The rows end at 61. I can get my formula to apply the formatting to J9, but not in all scenarios.
What I need to be true in order for my main cell (J9) to be formatted is the following:
C11 or J11 must be empty.
C11 and J11 must be empty (or not)
Thank you for your help!
Hi! Have you tried the methods described in this blog post? If you are not satisfied, please let me know and I will try to help you. Based on your description of the problem, I can't help you because the condition "C11 and J11 must be empty (or not)" doesn't make sense.
=AND($L2>365,$M2<18)
I am using this formula to get rows from L row which has greater than 365 and M row has less than 18. The M row contains % values. It highlighting this data - 5584 112.95.
Hi! L and M are columns, not rows. However, I can't understand what result you want.
Hello,
I want a formula that formats my cell based on a range value in another cell.
Example: I want my cell to be coloured if the number in another cell is between 20,02 and 50.
I can't make it work with ("and") and ("or") formulas. I don't know why.
Can anyone help me?
Hi! Please re-check the article above. Pay attention to the following paragraph: Formulas to compare values (numbers and text). For example: =AND($B2>5, $B2<10)
I haven't used Excel in years. I'm using Excel 360's Year Calendar template. Column A has numbers 1-31, columns B-M are months that contain text of when a project is due. I used Conditional Formatting to change the cells color to yellow when text is entered into a cell. I want to use Conditional Formatting to change the cell color to orange when the due date is 14 days from today and red when 7 days from today. Can you help?
I've used =$A3=TODAY()+7 nothing happens
Thank you very much for your time
Hi! If I understand your task correctly, this article may be helpful: How to conditionally format dates and time in Excel with formulas and inbuilt rules.
For the range A3:A34, try this conditional formatting formula:
=$A3>TODAY()+7
Hello! I am trying to format cells based on a formula. In a row, I need to find the tree adjacent cells with maximum cumulative value and format them with a color. Here's an example of my data:
A B C D E F
1 120 42 201 207 210 111
2 19 109 91 63 33 25
In the first row, cells C1-D1-E1 make up the higest total value (i.e., 618). I find it by using a formula =MAX(A1:D1+B1:E1+C1:F1), then pressing Ctrl-Shift-Enter. In the second row, the respective cells will be B2-C2-D2 (263). Now I just need to color-mark these cells based on the above formula, and then spread this condition onto next rows downwards.
When I am trying to do so, I keep getting color-marked all cells which are selected, not only those which are true based on my condition. I tried this also with other formulas, but ended up with the same result (all selected cells become marked).
Would greatly appreciate your help.
Hello! Your maximum value formula does not match the problem description. However, I think it is impossible to highlight these cells using conditional formatting. I'm really sorry, we cannot help you with this issue.
I am trying to conditionally format column A or based on a values in column B. However, it does not do anything.
Contact Information (A) Key (B)
Contact Name 100
Nickname / Preferred Name 2
Relationship Name 100
Title 72
Department 5
Rule
=$B$2<20 applied to =$A$2:$A$6 (Trying to Conditionally highlight Column A values when its column B value is less than 20)
The rule works when individually applied on each row. Example $B$3<20 applied to $A$3 works.
Hello! If you are applying the rule to a range of cells, use references to the first row in the conditional formatting formula. And don't use absolute cell references in the rule. For example, =$B1<20 applied to =$A$2:$A$6
The following tutorial should help: Relative and absolute cell references in Excel conditional formatting.
Sorry i also need this formatting to only happen if the response date cell is still blank...
Hi this has been really helpful but I am trying to do a conditional formatting formula - I have a cell with a date when a complaint is received and have a cell where the response date is put
I want to highlight the response date cell amber if it is 7 days or more from the received date and highlight the response date cell red if it is 15 days from the received date to show when responses are due, can you help at all? thank you
Hi! You can find the answer to your question in this article: Excel conditional formatting for dates & time: formulas and rules. For example, 7 days or more from the received date:
=AND(ISBLANK(B1),TODAY()-A1>=7)
many thanks
i need to use condition formatting to highlight the colour of D Column if the value of D is greater than 1.1 times of B Column.
Please re-check the article above since it covers your case.
Hello, I'm trying to format a pivot table that says if $B15="(blank)" then format the font on that entire row 'white'. This pivot table will be using different size data sources, so how do I need to use the applies to section. Every time I enter a range it automatically changes to absolute values.
Hi! The answer to your question can be found in this article: How to change the row color based on a cell value in Excel.
Hi, what formula must i use if i want to carry over a value/data from once cell to another if that value is greater than an zero. I want to say: =A2, if the value in A2 is greater than 0, otherwise 0
Hi! The answer to your question can be found in this article: IF function in Excel: formula examples for text, numbers, dates, blanks.
Hi, I'm trying to set up a sheet to compare pricing from 3 different vendors. I have over 400 rows and I want the cheapest one in each row to be highlighted. I set up a formula to look like this. =AB6=MIN($AB:$AD6) and I applied to all the rows. It went and highlighted each row, the problem is, in some rows it did not highlight the cheapest one and in some rows it highlighted more than one cell. Can you help me?
Hi! If I understand your task correctly, try the following conditional formatting formula:
=A1=MIN($A1:$C1)
The following tutorial should help: Relative and absolute cell references in Excel conditional formatting.
Hi, I commented earlier. The formula you provided is the formula that I used, and did not work. Is there a way to fix it?
If you look carefully, I suggested a different formula. MIN($AB:$AD6) - it's wrong and it's impossible. If you apply it to the entire range, e.g. A1:C4000, the minimum number in each row will be highlighted. I may have guessed wrong, as I am having trouble understanding your question: "I want the cheapest one in each row to be highlighted".
Hi! I am trying to format a column if the conditions below are both met.
U2 is less than or equal to Y1
F1 is less than or equal to Y1
All values are dates and F1 and Y1 are fixed.
Hi! Read carefully the recommendations in the article above. Pay attention to the following paragraph: Compare values based on several conditions (OR and AND formulas). There is an answer to your question there. To have both conditions true, use the logical function AND.
In one sheet there are ITEM#, QTY, PRICE, CAT#. In another sheet there are ITEM# & CAT# which is populated. I have to enter the ITEM# in the first sheet and using vlookup CAT# will be fetched from the 2nd sheet. Now I want to apply conditional formatting in the 1st sheet on ITEM# column so that if anything outside the range of ITEM# entered from 2nd sheet then the cell will be colored in sheet 1 on ITEM# cell. Please advise what formula should I apply in the conditional formatting here.
Hi! The answer to your question can be found in this article: How to change background color in Excel based on cell value.