by The tutorial demonstrates different ways to convert time to decimal in Excel. You will find a variety of formulas to change time to hours, minutes or seconds as well as convert text to time and vice versa.
Because Microsoft Excel uses a numeric system to store times, you can easily turn hours, minutes and seconds into numbers that you can use in other calculations.
In general, there are two ways to convert time to decimal in Excel - by changing the cell format and by using arithmetic calculations or Excel time functions, such as HOUR, MINUTE and SECOND. Further on in this tutorial, you will find the detailed explanation of the first way and formula examples demonstrating the other technique.
How to convert time to decimal number in Excel
Overall, there are three ways to change a time value to a decimal number: arithmetic operation, CONVERT function or a combination of three different Time functions.
The easiest way to convert time to decimal in Excel is to multiply the original time value by the number of hours, seconds or minutes in a day:
- To convert time to a number of hours, multiply the time by 24, which is the number of hours in a day.
- To convert time to minutes, multiply the time by 1440, which is the number of minutes in a day (24*60).
- To convert time to seconds, multiply the time time by 86400, which is the number of seconds in a day (24*60*60 ).
In the following sections, you will learn the other methods of converting times to a decimal number in Excel.
How to convert time to hours in Excel
This section demonstrates 3 different formulas to convert hours from the standard time format (hh:mm:ss) to a decimal number.
Formula 1: Arithmetic calculation
You already know the fastest way to convert a time value to a number of hours in Excel - multiplying by 24, i.e. by the number of hours in one day:
=A2*24
Where A2 is the time value.
To get the number of compete hours, embed the above formula in the INT function that will get rid of the fractional part:
=INT(A2*24)
Formula 2: CONVERT function
Another way to perform the "time > hours" conversion is to use the following Convert formula:
=CONVERT(A2, "day", "hr")
Formula 3: HOUR, MINUTE and SECOND functions
Finally, you can use a bit more complex formula, whose logic, however, is quite obvious. Extract the individual time units by using the HOUR, MINUTE and SECOND functions, then divide minutes by 60 (the number of minutes in an hour) and seconds by 3600 (the number of seconds in an hour), and add up the results:
=HOUR(A2) + MINUTE(A2)/60 + SECOND(A2)/3600
How to convert time to minutes in Excel
The same three methods can be used to convert minutes from the standard time format to a decimal number.
Formula 1: Arithmetic calculation
To convert time to total minutes, you multiply time by 1440, which is the number of minutes in one day (24 hours * 60 minutes = 1440):
=A2*1440
If you want to return the number of compete minutes, utilize the INT function like in the previous example:
=INT(A2*1440)
You can view the results in the screenshot below:
Formula 2: CONVERT function
To do the "time > minutes" conversion with the CONVERT(number, from_unit, to_unit) function, supply "day" as the unit to convert from and "mn" as the unit to convert to:
=CONVERT(A2, "day", "mn")
Formula 3: HOUR, MINUTE and SECOND functions
One more way to get the number of minutes is to multiply hours by 60 and divide seconds by the same number:
=HOUR(A2)*60 + MINUTE(A2) + SECOND(A2)/60
How to convert time to seconds in Excel
Converting time to total seconds in Excel can be done in a similar fashion.
Formula 1: Arithmetic calculation
Multiply the time value by 86400, which is the number of seconds in a day (24 hours * 60 minutes * 60 seconds = 86400):
=A2*86400
Formula 2: CONVERT function
The formula is basically the same as in the above examples with the only difference that you convert the "day" unit to "sec":
=CONVERT(A2, "day", "sec")
Formula 3: HOUR, MINUTE and SECOND functions
Use the HOUR, MINUTE and SECOND functions like in the two previous examples (I believe at this point you don't need any further explanation of the formula's logic :)
=HOUR(A2)*3600 + MINUTE(A2)*60 + SECOND(A2)
Tips:
- If any of the above formulas returns a value formatted as time, simply change the cell's format to Generalto display it as a number.
- To convert time to a decimal number that represents the time in the internal Excel system, apply the General format to the cell. With this approach, 23:59:59 will be converted to 0.99999, 06:00 AM to 0.25, and 12:00 PM to 0.5. If an integer part of the converted number is greater than zero, it means that your cell contains both date and time values.
How to split date and time in Excel
As is often the case, your Excel worksheet may contain dates and times in one cell, while you want to split them into two separate cells.
Remembering that in the internal Excel system the date value is stored as a whole part and the time value as a fractional part of a decimal number, you can extract the date using the INT function, which rounds the cell value down to the nearest integer.
Supposing your original dates and times are in column A, the following formula will accomplish the separation:
=INT(A2)
To extract the time portion, subtract the date returned by the above formula from the original date and time value:
=A2-B2
Where column A contains the original date & time values and column B contains the dates returned by the INT function.
If you'd rather not have time values linked to the separated dates (for example, you may want to remove the date column in the future), you can use the following MOD formula that refers to the original data only:
=MOD(A2,1)
Tip. If the separated date and time values are not displayed properly, change the format of the new columns to Date and Time, respectively.
This is how you split date and time in Excel. If you want to further separate hours, minutes and seconds into individual columns, then use the HOUR, MINUTE and SECOND functions, as demonstrated in How to get hours, minutes and seconds from a timestamp.
How to spell time in Excel
Sometimes, you may need to convert time into the format that reads something like "# days, # hours, # minutes and # seconds". A good thing is that you already know all the ingredients of the formula:
- Extract days using the INT function;
- Extract time units with HOUR, MINUTE and SECOND functions, and
- Concatenate all parts in a single formula.
Having difficulties with figuring out a proper formula for your worksheet? The following example will make things easy!
Supposing you have the dates of upcoming events in column B beginning in cell B4, and the current date and time returned by the NOW() function in cell B1.
The formula to calculate the time difference is as simple as =B4-$B$1. Of course, nothing prevents you from subtracting the current date and time directly with =B4-NOW().
And now, let's make a countdown timer that would show how many days, hours, minutes and seconds are left until each event.
The formula to enter in cell D4 is as follows:
=INT(C4) & " days, " & HOUR(C4) & " hours, " & MINUTE(C4) & " minutes and " & SECOND(C4) & " seconds"
If you wish to get rid of 0 values, like in cells D6 and D7 in the screenshot above, then include the following IF statements:
=IF(INT(C4)>0, INT(C4)&" days, ","") & IF(HOUR(C4)>0, HOUR(C4) & " hours, ","") & IF(MINUTE(C4)>0, MINUTE(C4) & " minutes and ","") & IF(SECOND(C4)>0, SECOND(C4) & " seconds","")
All zeros are gone!
Note. When either of the above formulas refers to a negative number, the #NUM! error will appear. This may happen when you subtract a bigger time from a smaller one.
An alternative way to write time in words in Excel is to apply the following custom time format to the cell: d "day," h "hours," m "minutes and" s "seconds". No formulas and no calculations are required! For more information, please see Creating a custom time format in Excel.
Convert text to time in Excel
If your time formulas and calculations do not work right, time values formatted as text is often the cause. The fastest way to convert text to time in Excel is using the TIMEVALUE function.
The Excel TIMEVALUE function has just one argument:
Time_text is a text string in any of the time formats that Excel can recognize. For example:
=TIMEVALUE("6:20 PM")
=TIMEVALUE("6-Jan-2015 6:20 PM")
=TIMEVALUE(A2) where A2 contains a text string
As you see, the formulas with cell references and corresponding text strings deliver identical results. Also, please notice the left alignment of time strings (text values) in cells A2 and A6 and right-aligned converted time values in column D.
Convert time to text in Excel
Supposing you have an Excel file full of times formatted to look like "8:30:00 AM" and you want to convert them to the text format. Simply changing the cell's format to TEXT won't work because this would change your time values to underlying numeric representation of the time. For example, 8:30:00 AM will be converted to decimal 0.354166666666667.
So, how do you convert cells to the text format so that your cells still have the time in them? The answer is to use the TEXT function that converts a numeric value to text with the display formatting that you specify, for example:
=TEXT($A2,"h:mm:ss")
The screenshot below demonstrates other possible formats:
How to convert numbers to time format in Excel
If you have a list of numbers such as 1, 2, 3.5 and you want to convert them to a time format, for example 1:00:00, 2:00:00 or 3:30 AM, perform the following steps.
- Divide the numbers by 24 (there are 24 hours in a day). The formula can be as simple as =A2/24.
- Select the cell(s) with the formula result, right-click and select Format Cells from the context menu or press Ctrl+1. Either way, the Format Cells dialog will appear, you select Time on the left pane under Category, and choose the format you want on the right pane under Type. Please see How to format time in Excel for more details.
If your time exceeds 24 hours, 60 minutes, 60 seconds, use these guidelines to correctly show it.
That's all for today. If someone wants to get the first-hand experience with the formulas discussed in this article, you are most welcome to download the sample workbook below.
If you want to learn a few more useful formulas to calculate times in Excel, please check out the related tutorials at the end of this page. I thank you for reading and hope to see you again next week!
Practice workbook for download
Converting time in Excel - examples (.xlsx file)
462 comments
Can I please have 1 days 4 hours 21 mins converted to 28.21 in Excel
Hi,
Please describe your problem in more detail. How is your original data written as 28:21:00 or as the text "1 days 4 hours 21 mins"?
Hi There,
I need to convert 08:30:24 into hours and minutes only. tried with above but failed, Kindly help
THanks
Stay safe.
Hello!
If I understand your task correctly, you can use custom time format —
"hh:mm"
I hope it’ll be helpful.
How to convert 56 to 056:00 in Excel
Thnx
Hello!
If I understand your task correctly, the following formula should work for you:
=TIME(0,56,0)
Use a custom date format
[hh]:"0"mm:ss
I hope this will help
Hi there,
Is it possible to convert time 08:30 to 08.30 instead of 08.5
Thanks,
Hello!
Time cannot be shown using a point. But you can convert it to text
=TEXT(A1,"hh.mm")
I hope my advice will help you solve your task.
Hi,
How could i convert shift times in to hours as a formula.
For example, if someone is working from 6am - 2 pm 5 days a week, how can I get the total hours worked calculated?
Hello!
This question has been asked many times. For example, here.
I hope it’ll be helpful.
I am trying to keep track of my employees hours worked in Excel. I do not need to calculate their "In" and "Out" times, but instead calculate their bi-weekly total hours to ensure they do not go over their allotted 69 hours per month.
Example:
Debra worked 31.45 hours for pay period 1 of 2.
Right now I have =69-31.45 to show me how many hours she has leftover for the month. However, it is giving me 37.55 - which is incorrect.
How can I change the whole number in Excel from 100 to 60 so it will calculate her remaining hours?
I hope this makes sense! I have been on a hunt to figure this out - YouTube, Google, my Excel book and I cannot figure this out.
Any help with this is SOOOO appreciated :)
I'm trying to take a Start Time and add 1 minute per question being answered to calculate an end time.
What I currently have:
(F13) Time Format (HH:MM) Start Time: Manually enter Time "example. 21:00"
(G13) Number Format Total Questions: =(Results!K3) "example. 153"
(H13) End Time: =SUM(TIMEVALUE(F13:G13)) "Result: Error Value"
Could someone help me resolve the error?
Hello!
If the number of minutes is written in cell G13, then you can add minutes to all of them with the formula
=F13 + G13/1440
I hope I answered your question.
How do you do the first example you shared if the time is greater than 12? for example, I have time 23:56
and I would like to convert it to minutes. When I use this formula =(R11*1440) I am getting 14396 - this should be 1436. Why is this happening? Thanks!
Hello!
My result is 1436. Check cell R11, you may have entered the date and time, not just time.
I want to convert minutes in HH:MM:SS format but condition is minute showing in General
For Example
Total min 200 is nothing but 03:20:00
Is there any formula to convert like mentioned above?
I need to get the year, month, and day as separate integer values from a date such as 7/13/2014.
How do I do that?
Hello!
Please check out the following articles that show how to use YEAR and MONTH functions in Excel. Hope they'll help you with your task.
am try to convert actual minutes to decimals such as 4.11 hours worked to equal 4.18 hours and 3.32 hours to 3.53 and so forth so it works like a time clock where 15 minutes =.25 -30 min =.5 45 minutes =.75 thank you in advance
Hello!
I don't understand what the phrase means "4.11 hours worked to equal 4.18 hours". Pay attention to the following paragraph of the article above How to convert time to decimal number in Excel
I am also having a problem like this. Due to a disability i need to do my my timesheet in excel. we use 24 hour time (military) but they want the difference expressed as a decimal. For example, Start Time 11:30 End Time 16:45 = 05:15 but they want the time sheet to say 5.25 (don't trust my math) I'm sure you addressed it earlier but if you did I didn't get it. I would appreciate your guida
Hello!
Pay attention to the following paragraph of the article above How to convert time to decimal number in Excel
It covers your case completely.
bonsoir,
j'ai un petit problème sur excel, c'est que j'ai besoin de créer des colonnes avec ces donnée
- column 1: Julianne day (1 to 365)
- column 2: Solar time in decimal format (00:00:00) with interval of 5 min (from 1 to 12 for each hour))
mon problème c'est que j'arrive pas a trouver une formule pour gérer l'intervalle de 5min sur un ans.
merci
August 1, 2020 3:52:15 PM AST
how to change this one as date format , tried a lot, can you please guide me.
Hello!
You haven't written which format you want to change. You can do this if you read this manual on date formats.
2 days 19 hours 40 minutes
Its convert to 67.40 Dec... Can u plz send the excel formula
Hello!
What does 67.4 mean? What are these units of measurement?
2 * 24 + 19 + 40/100? This number doesn't make sense.
i have 261 minute. needs to be convert as HH:MM
Hello!
The formula below will do the trick for you:
=CONVERT(D1,"mn","hr")/24
Set the cell time format hh:mm
Hello;
Can you please help convert decimal 37.5 to hours and minutes.
When converting a number under 24 hours the formula number/24 works but if totalling hours over a week, the formula does not work if the total goes over 1 day or 24 hours.
Thank you
I am looking for the excel formula please :0)
Hello!
To be able to show more than 24 hours in a cell, please use this time format: "37:30:55". You can find it in the list of Excel time formats.
Hi,
How to convert 9,30 in decimal 9,50 or 8,45 in 8,75.
The times I receive in Excel are the effective times marked with a comma (none :)
tnx
Hello!
The rounding of numbers in your examples occurs according to different rules. Therefore, I can not offer you a general formula for your two tasks. I recommend paying attention to the MROUND function. For your first example, the formula is suitable
=MROUND(A1,0.5)
I would like to convert time to a numerical number to add up total hours.
Example:
6:00AM-2:00PM=8 hours
Hello Erica!
Specify what you want to calculate. Your formula counts the time from 2 PM to 6 AM. And this is not 8, but 16 hours. If you want to calculate the time from 6 AM to 2 PM, then the formula is necessary
= 2: 00 PM-6: 00AM
To convert a result from time to number, use the formula
= (2:00 PM-6:00AM) * 24
And set the number format in this cell
Hello dear..
I am from Indonesia..
How to stop auto convert number from general to custom
ex.
from 1. auto convert to 01.00
from 10. auto convert to 10.00
from 100. auto convert to 100.00.00
How do you convert 06:55 into 0655 in Excel. I want to to eliminate the colon.
Thank you.
Hello Santiago!
You can convert time to text.
Please try the following formula:
=TEXT(A1,"[hh]mm")
Learn more about the TEXT function on our blog.