by Microsoft Excel provides several functions purposed for counting different kinds of cells, such as blanks or non-blanks, with number, date or text values, containing specific words or character, etc.
In this article, we will focus on the Excel COUNTIF function that is purposed for counting cells with the condition you specify. First, we will briefly cover the syntax and general usage, and then I provide a number of examples and warn about possible quirks when using this function with multiple criteria and specific types of cells.
In essence, COUNTIF formulas are identical in all Excel versions, so you can use the examples from this tutorial in Excel 365, 2021, 2019, 2016, 2013, 2010 and 2007.
COUNTIF function in Excel - syntax and usage
Excel COUNTIF function is used for counting cells within a specified range that meet a certain criterion, or condition.
For example, you can write a COUNTIF formula to find out how many cells in your worksheet contain a number greater than or less than the number you specify. Another typical use of COUNTIF in Excel is for counting cells with a specific word or starting with a particular letter(s).
The syntax of the COUNTIF function is very simple:
As you see, there are only 2 arguments, both of which are required:
- range - defines one or several cells to count. You put the range in a formula like you usually do in Excel, e.g. A1:A20.
- criteria - defines the condition that tells the function which cells to count. It can be a number, text string, cell reference or expression. For instance, you can use the criteria like these: "10", A2, ">=10", "some text".
And here is the simplest example of Excel COUNTIF function. What you see in the image below is the list of the best tennis players for the last 14 years. The formula =COUNTIF(C2:C15,"Roger Federer") counts how many times Roger Federer's name is on the list:
Note. A criterion is case insensitive, meaning that if you type "roger federer" as the criteria in the above formula, this will produce the same result.
Excel COUNTIF function examples
As you have just seen, the syntax of the COUNTIF function is very simple. However, it allows for many possible variations of the criteria, including wildcard characters, the values of other cells, and even other Excel functions. This diversity makes the COUNTIF function really powerful and fit for many tasks, as you will see in the examples that follow.
COUNTIF formula for text and numbers (exact match)
In fact, we discussed the COUNTIF function that counts text values matching a specified criterion exactly a moment ago. Let me remind you that formula for cells containing an exact string of text: =COUNTIF(C2:C15,"Roger Federer"). So, you enter:
- A range as the first parameter;
- A comma as the delimiter;
- A word or several words enclosed in quotes as the criteria.
Instead of typing text, you can use a reference to any cell containing that word or words and get absolutely the same results, e.g. =COUNTIF(C1:C9,C7).
Similarly, COUNTIF formulas work for numbers. As shown in the screenshot below, the below formula perfectly counts cells with quantity 5 in Column D:
=COUNTIF(D2:D9, 5)
In this article, you will find a few more formulas to count cells that contain any text, specific characters or only filtered cells.
COUNTIF formulas with wildcard characters (partial match)
In case your Excel data include several variations of the keyword(s) you want to count, then you can use a wildcard character to count all the cells containing a certain word, phrase or letters as part of the cell's contents.
Suppose, you have a list of tasks assigned to different persons, and you want to know the number of tasks assigned to Danny Brown. Because Danny's name is written in several different ways, we enter "*Brown*" as the search criteria =COUNTIF(D2:D10, "*Brown*").
An asterisk (*) is used to find cells with any sequence of leading and trailing characters, as illustrated in the above example. If you need to match any single character, enter a question mark (?) instead, as demonstrated below.
Tip. It is also possible to use wildcards with cell references with the help of the concatenation operator (&). For example, instead of supplying "*Brown*" directly in the formula, you can type it in some cell, say F1, and use the following formula to count cells containing "Brown": =COUNTIF(D2:D10, "*"&F1&"*")
Count cells beginning or ending with certain characters
You can use either wildcard character, asterisk (*) or question mark (?), with the criterion depending on which exactly result you want to achieve.
If you want to know the number of cells that start or end with certain text no matter how many other characters a cell contains, use these formulas:
=COUNTIF(C2:C10,"Mr*") - count cells that begin with "Mr".
=COUNTIF(C2:C10,"*ed") - count cells that end with the letters "ed".
The image below demonstrates the second formula in action:
If you are looking for a count of cells that start or end with certain letters and contain the exact number of characters, you use the Excel COUNTIF function with the question mark character (?) in the criteria:
=COUNTIF(D2:D9,"??own") - counts the number of cells ending with the letters "own" and having exactly 5 characters in cells D2 through D9, including spaces.
=COUNTIF(D2:D9,"Mr??????") - counts the number of cells starting with the letters "Mr" and having exactly 8 characters in cells D2 through D9, including spaces.
Tip. To find the number of cells containing an actual question mark or asterisk, type a tilde (~) before the ? or * character in the formula. For example, =COUNTIF(D2:D9,"*~?*") will count all cells containing the question mark in the range D2:D9.
Excel COUNTIF for blank and non-blank cells
These formula examples demonstrate how you can use the COUNTIF function in Excel to count the number of empty or non-empty cells in a specified range.
COUNTIF not blank
In some Excel COUNTIF tutorials and other online resources, you may come across formulas for counting non-blank cells in Excel similar to this one:
=COUNTIF(A1:A10,"*")
But the fact is, the above formula counts only cells containing any text values including empty strings, meaning that cells with dates and numbers will be treated as blank cells and not included in the count!
If you need a universal COUNTIF formula for counting all non-blank cells in a specified range, here you go:
Or
This formula works correctly with all value types - text, dates and numbers - as you can see in the screenshot below.
COUNTIF blank
If you want the opposite, i.e. count blank cells in a certain range, you should adhere to the same approach - use a formula with a wildcard character for text values and with the "" criteria to count all empty cells.
Formula to count cells not containing any text:
Since an asterisk (*) matches any sequence of text characters, the formula counts cells not equal to *, i.e. not containing any text in the specified range.
Universal COUNTIF formula for blanks (all value types):
The above formula correctly handles numbers, dates and text values. For example, here's how you can get the number of empty cells in the range C2:C11:
=COUNTIF(C2:C11,"")
Please be aware that Microsoft Excel has another function for counting blank cells, COUNTBLANK. For instance, the following formulas will produce exactly the same results as the COUNTIF formulas you see in the screenshot above:
Count blanks:
=COUNTBLANK(C2:C11)
Count non-blanks:
=ROWS(C2:C11)*COLUMNS(C2:C11)-COUNTBLANK(C2:C11)
Also, please keep in mind that both COUNTIF and COUNTBLANK count cells with empty strings that only look blank. If you do not want to treat such cells as blanks, use "=" for criteria. For example:
=COUNTIF(C2:C11,"=")
For more information about counting blanks and not blanks in Excel, please see:
COUNTIF greater than, less than or equal to
To count cells with values greater than, less than or equal to the number you specify, you simply add a corresponding operator to the criteria, as shown in the table below.
Please pay attention that in COUNTIF formulas, an operator with a number are always enclosed in quotes.
| Criteria | Formula Example | Description |
|---|---|---|
| Count if greater than | =COUNTIF(A2:A10,">5") | Count cells where value is greater than 5. |
| Count if less than | =COUNTIF(A2:A10,"<5") | Count cells with values less than 5. |
| Count if equal to | =COUNTIF(A2:A10,"=5") | Count cells where value is equal to 5. |
| Count if not equal to | =COUNTIF(A2:A10,"<>5") | Count cells where value is not equal to 5. |
| Count if greater than or equal to | =COUNTIF(C2:C8,">=5") | Count cells where value is greater than or equal to 5. |
| Count if less than or equal to | =COUNTIF(C2:C8,"<=5") | Count cells where value is less than or equal to 5. |
You can also use all of the above formulas to count cells based on another cell value, you will just need to replace the number in the criteria with a cell reference.
Note. In case of a cell reference, you have to enclose the operator in quotes and add an ampersand (&) before the cell reference. For example, to count cells in the range D2:D9 with values greater than a value in cell D3, you use this formula =COUNTIF(D2:D9,">"&D3):
If you want to count cells that contain an actual operator as part of the cell's contents, i.e. the characters ">", "<" or "=", then use a wildcard character with the operator in the criteria. Such criteria will be treated as a text string rather than a numeric expression. For example, the formula =COUNTIF(D2:D9,"*>5*") will count all cells in the range D2:D9 with contents like this "Delivery >5 days" or ">5 available".
Using Excel COUNTIF function with dates
If you want to count cells with dates that are greater than, less than or equal to the date you specify or date in another cell, you proceed in the already familiar way using formulas similar to the ones we discussed a moment ago. All of the above formulas work for dates as well as for numbers. Let me give you just a few examples:
| Criteria | Formula Example | Description |
|---|---|---|
| Count dates equal to the specified date. | =COUNTIF(B2:B10,"6/1/2014") | Counts the number of cells in the range B2:B10 with the date 1-Jun-2014. |
| Count dates greater than or equal to another date. | =COUNTIF(B2:B10,">=6/1/2014") | Count the number of cells in the range B2:B10 with a date greater than or equal to 6/1/2014. |
| Count dates greater than or equal to a date in another cell, minus x days. | =COUNTIF(B2:B10,">="&B2-"7") | Count the number of cells in the range B2:B10 with a date greater than or equal to the date in B2 minus 7 days. |
Apart from these common usages, you can utilize the COUNTIF function in conjunction with specific Excel Date and Time functions such as TODAY() to count cells based on the current date.
| Criteria | Formula Example |
|---|---|
| Count dates equal to the current date. | =COUNTIF(A2:A10,TODAY()) |
| Count dates prior to the current date, i.e. less than today. | =COUNTIF(A2:A10,"<"&TODAY()) |
| Count dates after the current date, i.e. greater than today. | =COUNTIF(A2:A10,">"&TODAY()) |
| Count dates that are due in a week. | =COUNTIF(A2:A10,"="&TODAY()+7) |
| Count dates in a specific date range. | =COUNTIF(B2:B10, ">=6/1/2014")-COUNTIF(B2:B10, ">6/7/2014") |
Here is an example of using such formulas on real data (at the moment of writing today was 25-Jun-2014):
Excel COUNTIF with multiple criteria
In fact, Excel COUNTIF function is not exactly designed to count cells with multiple criteria. In most cases, you'd use its plural counterpart, the COUNTIFS function to count cells that match two or more criteria (AND logic). However, some tasks can be solved by combining two or more COUNTIF functions in one formula.
Count values between two numbers
One of the most common applications of Excel COUNTIF function with 2 criteria is counting numbers within a specific range, i.e. less than X but greater than Y. For example, you can use the following formula to count cells in the range B2:B9 where a value is greater than 5 and less than 15.
=COUNTIF(B2:B9,">5")-COUNTIF(B2:B9,">=15")
How this formula works:
Here, we use two separate COUNTIF functions - the first one finds out how many values are greater than 5 and the other one gets a count of values greater than or equal to 15. Then, you subtract the latter from the former and get the desired result.
Count cells with multiple OR criteria
In situations when you want to get several different items in a range, add 2 or more COUNTIF functions together. Supposing, you have a shopping list and you want to find out how many soft drinks are included. To have it done, use a formula similar to this:
=COUNTIF(B2:B13,"Lemonade")+COUNTIF(B2:B13,"*juice")
Please pay attention that we've included the wildcard character (*) in the second criterion, it is used to count all kinds of juice on the list.
In the same manner, you can write a COUNTIF formula with several conditions. Here is an example of the COUNTIF formula with multiple OR conditions that counts lemonade, juice and ice cream:
=COUNTIF(B2:B13,"Lemonade") + COUNTIF(B2:B13,"*juice") + COUNTIF(B2:B13,"Ice cream")
For other ways to count cells with OR logic, please see this tutorial: Excel COUNTIF and COUNTIFS with OR conditions.
Using COUNTIF function to find duplicates and unique values
Another possible usage of the COUNTIF function in Excel is for finding duplicates in one column, between two columns, or in a row.
Example 1. Find and count duplicates in 1 column
For example, this simple formula =COUNTIF(B2:B10,B2)>1 will spot all duplicate entries in the range B2:B10 while another function =COUNTIF(B2:B10,TRUE) will tell you how many dupes are there:
Example 2. Count duplicates between two columns
If you have two separate lists, say lists of names in columns B and C, and you want to know how many names appear in both columns, you can use Excel COUNTIF in combination with the SUMPRODUCT function to count duplicates:
=SUMPRODUCT((COUNTIF(B2:B1000,C2:C1000)>0)*(C2:C1000<>""))
We can even take a step further and count how many unique names there are in Column C, i.e. names that do NOT appear in Column B:
=SUMPRODUCT((COUNTIF(B2:B1000,C2:C1000)=0)*(C2:C1000<>""))
Tip. If you want to highlight duplicate cells or entire rows containing duplicate entries, you can create conditional formatting rules based on the COUNTIF formulas, as demonstrated in this tutorial - Excel conditional formatting formulas to highlight duplicates.
Example 3. Count duplicates and unique values in a row
If you want to count duplicates or unique values in a certain row rather than a column, use one of the below formulas. These formulas might be helpful, say, to analyze the lottery draw history.
Count duplicates in a row:
=SUMPRODUCT((COUNTIF(A2:I2,A2:I2)>1)*(A2:I2<>""))
Count unique values in a row:
=SUMPRODUCT((COUNTIF(A2:I2,A2:I2)=1)*(A2:I2<>""))
Excel COUNTIF - frequently asked questions and issues
I hope these examples have helped you to get a feel for the Excel COUNTIF function. If you've tried any of the above formulas on your data and were not able to get them to work or are having a problem with the formula you created, please look through the following 5 most common issues. There is a good chance that you will find the answer or a helpful tip there.
1. COUNTIF on a non-contiguous range of cells
Question: How can I use COUNTIF in Excel on a non-contiguous range or a selection of cells?
Answer: Excel COUNTIF does not work on non-adjacent ranges, nor does its syntax allow specifying several individual cells as the first parameter. Instead, you can use a combination of several COUNTIF functions:
Wrong: =COUNTIF(A2,B3,C4,">0")
Right: =COUNTIF(A2,">0") + COUNTIF(B3,">0") + COUNTIF(C4,">0")
An alternative way is using the INDIRECT function to create an array of ranges. For example, both of the below formulas produce the same result you see in the screenshot:
=SUM(COUNTIF(INDIRECT({"B2:B8","D2:C8"}),"=0"))
=COUNTIF($B2:$B8,0) + COUNTIF($C2:$C8,0)
2. Ampersand and quotes in COUNTIF formulas
Question: When do I need to use an ampersand in a COUNTIF formula?
Answer: It is probably the trickiest part of the COUNTIF function, which I personally find very confusing. Though if you give it some thought, you'll see the reasoning behind it - an ampersand and quotes are needed to construct a text string for the argument. So, you can adhere to these rules:
If you use a number or a cell reference in the exact match criteria, you need neither ampersand nor quotes. For example:
=COUNTIF(A1:A10,10)
or
=COUNTIF(A1:A10,C1)
If your criteria includes text, wildcard character or logical operator with a number, enclose it in quotes. For example:
=COUNTIF(A2:A10,"lemons")
or
=COUNTIF(A2:A10,"*") or =COUNTIF(A2:A10,">5")
In case your criteria is an expression with a cell reference or another Excel function, you have to use the quotes ("") to start a text string and ampersand (&) to concatenate and finish the string off. For example:
=COUNTIF(A2:A10,">"&D2)
or
=COUNTIF(A2:A10,"<="&TODAY())
If you are in doubt whether an ampersand is needed or not, try out both ways. In most cases an ampersand works just fine, e.g. both of the below formulas work equally well.
=COUNTIF(C2:C8,"<=5")
and
=COUNTIF(C2:C8,"<="&5)
3. COUNTIF for formatted (color coded) cells
Question: How do I count cells by fill or font color rather than by values?
Answer: Regrettably, the syntax of the Excel COUNTIF function does not allow using formats as the condition. The only possible way to count or sum cells based on their color is using a macro, or more precisely an Excel User-Defined function. You can find the code working for cells colored manually as well as for conditionally formatted cells in this article - How to count and sum Excel cells by fill and font color.
4. #NAME? error in the COUNTIF formula
Issue: My COUNTIF formula throws a #NAME? error. How can I get it fixed?
Answer: Most likely, you have supplied an incorrect range to the formula. Please check out point 1 above.
5. Excel COUNTIF formula not working
Issue: My COUNTIF formula is not working! What have I done wrong?
Answer: If you have written a formula which is seemingly correct but it does not work or produces a wrong result, start by checking the most obvious things such as a range, conditions, cell references, use of ampersand and quotes.
Be very careful with using spaces in a COUNTIF formula. When creating one of the formulas for this article I was on the verge of pulling my hair out because the correct formula (I knew with certainty it was right!) wouldn't work. As it turned out, the problem was in a measly space somewhere in between, argh... For instance, look at this formula:
=COUNTIF(B2:B13," Lemonade").
At first sight, there is nothing wrong about it, except for an extra space after the opening quotation mark. Microsoft Excel will swallow the formula just fine without an error message, warning or any other indication, assuming you really want to count cells containing the word 'Lemonade' and a leading space.
If you use the COUNTIF function with multiple criteria, split the formula into several pieces and verify each function individually.
And this is all for today. In the next article, we will explore several ways to count cells in Excel with multiple conditions. Hope to see you next week and thanks for reading!
1067 comments
Hi, Please see the following chart.
A B C D E
HOUSE 4 4 - HOUSE 4 4 - HOUSE
HOUSE 4 4 - HOUSE 3 - BOX
TOY 1 1 - TOY 1 2 - SHOE
HOUSE 4 4 - HOUSE 1 - TOY
SHOE 2 2 - SHOE 2
SHOE 2 2 - SHOE
SOCK 1 1 - SOCK
HOUSE 4 4 - HOUSE
BOX 3 3 - BOX 3
BOX 3 3 - BOX
BOX 3 3 - BOX
Column A is the item, column B is the count for each reoccurrence in column A, column C is =CONCATENATE(B1," - ",A1), column D counts and removes duplicates =IF(COUNTIF($B$1:B1,B1)=1,B1,"") and column E sorts and shows how many of each. The problem I am having is it only seems to count an item with a count of "1", only once so if there is more than 1 item with one occurrence, it only counts the first one. Can you tell me what I'm doing wrong?
My formulas are as follows:
Column A (no formula)
Column B =COUNTIF($A$1:$A$11,A1)
Column C =CONCATENATE(B1," - ",A1)
Column D =IF(COUNTIF($B$1:B1,B1)=1,B1,"")
Column E =IF(ROW(A1)>COUNT($D$1:$D$11),"",INDEX($C$1:$C$11,MATCH(LARGE($D$1:$D$11,ROW(A1)),$D$1:$D$11,0)))
Thanks!
Scott
Svetlana,
I am trying to use COUNTIF to count the output of a formula, e.g. a cell that contains a formula. The formula is a nested =IF() function.
COUNTIF however doesn't seem to see the output. For example, if other cells meet certain criteria, the output is "D". When I then use COUNTIF to count the "D"s it returns 0.
I'm familiar with COUNTIFS but I am using COUNTIF in this way to measure time and create a Gantt chart that doesn't overlap processes. If one process is going on, the cell returns "D" (for delay) and I can count that delay, via COUNTIF.
So, can I count formula outputs via COUNTIF, or is there another way to count formula outputs and/or display them differently?
Thanks!!
Lucas
Hello, Lucas,
COUNTIF should work in your case perfectly, I'm afraid the problem lies in something else. Perhaps, it is the spaces around "D". We could suggest you better, if you sent us your file with the formula to support@ablebits.com. Don't forget to include the link to this comment in your email.
Please don't worry if you have confidential information in your document, we never disclose the data we get from our customers and delete it as soon as the problem is resolved.
I am trying to count certain text in a range of cells from another tab. I need to count "status" and "status date" as separate formulas for counts. I tried this but didn't work: =COUNTIF('690-JHC3 Ven 600-699'!F4:F10001,"*STATUS*")and the other =COUNTIF('690-JHC3 Ven 600-699'!F4:F10001,"*STATUS DATE*")
Appreciate the help - thanks
Hi Kim,
Try this
=COUNTIF('690-JHC3 Ven 600-699'!F4:F10001,"*"&"STATUS"&"*")
This should ensure that STATUS is counted no matter what is before or after the word.
HI THERE ,
I WANT TO CALCULATE NO OF UNIQUE ALPHANUMERIC CHARACTER(EXMP.I-INKOL17000522 OR IN17000523) MONTH WISE REMOVING DUPLICATE .NEED TO USE ONE DROP DOWN LIST OF MOTHS TO GET MONTH WISE TOTAL NO OF OCCURRENCE.
PLS HELP
Hi, Sammie,
I'm sorry, it's difficult to help you with a formula since we don't know how your data is stored.
However, If I understand your task correctly, first of all you need to sum unique values. You can do that by following the instructions from this article.
And then, using these results, you create a drop-down list.
Hope you'll find this information helpful!
Hello Svetlana,
I have been reading through your website and can't see the answer to what I thought would be a fairly common question. Can you please help?
I have a created a spreadsheet of people from 10 different work teams. The team names are in column E. Columns J through AG are a range of competencies people are required to complete.
For each person’s row, where they have completed the competencies matching the column heading I would like to record the date they completed that particular competency.
For example:
. A B C D
1 Name Team Competency 1 Competency 2
2 John Red 10/08/17 16/07/17
3 James Red 16/07/17
4 Bob Red 16/07/17
5 Sara Blue 16/07/17
6 Gale Blue 11/07/17
7 Alice Blue
8 Dave Blue 16/07/17
9 Jane Green 11/07/17
10 Blair Green
What I cannot work out is how to create a formula to count the number of people from the Blue team (or any specific team) who have completed Competency 1.
Ideally the results of these formulas will be used to create a table similar to this:
Team Com 1 completed Com 2 completed
Red 2 2
Blue 3
Green 1
Thank you for your assistance.
CS
Hi,
I want to know from you that how can I count the two cell data at a time like:
colA
OC TC
OC SC
OC SC
OC EC
OC TC
OC ST
R1 SC
R1 TC
R1 SC
R1 TC
I want to know for OC how many TC of SC and for R1 how many TC or SC Like ------------
TANK YOU.
BR,
Achira
Hi there , I have a simple table I did not set it up as pivot table. First row are dates and under each date there are columns with stock symbols( 10-50 symbols under each date average ). I am using a count if formula in conditional formatting to determine how many times each stock symbol appears in my table =COUNTIF($A$2:$Z$100,A2)=5 it is a relative reference and I ask a certain color for cells that meet criteria . I set up the range to be same as in formula A2:Z100 Every day I add up symbols and some times I delete columns that are dated more than 2 months ago. The problem is that every day after I add up a new column the range that formula apply to is changing so I have to manually set it up ( conditional formatting/manage rule /this worksheet/applies to )
How can I overcome this problem ? Basically I was looking to add up every day a column and symbols that meet criteria of countif formula to be highlighted let say green
Hello,
I am trying to write a formula to count the number of calls for the first meeting from two separate spreadsheets. I was able to count the total calls for all the meeting but I can figure out how many calls for the first meeting and 2nd meeting and so on.
My first Spreadsheet is the meeting sheet and I have customer column, created date. the second sheet is the phone call sheet with customer name and the date (each call create one date)
I used countif formula to count if the customer exist in the phone list then count the number of call but this formula only gave me the total then I added additional count if formula to say if the phone call date less than the meeting created date then count those number but all I got an error value. Can you help?
Thank you,
LE
Hello,
Please I want to group items but want to write a function so that all those who qualify are assigned 1 and those who do not qualify are assigned 0. Please help
Does Countif work with Frequency? I've found an example to count how many different values there are in a large array as the following
= SUM( --(FREQUENCY(A1:A1000,A1:A1000)>0))
so I thought that COUNTIF should work to
= COUNTIF(FREQUENCY(A1:A1000,A1:A1000),">0")
However, the formula is not accepted. Do you know if there is a limitation in the type of argument?
Is it possible to use countif function in whitch criteria is text in comment attached to the cell?
Greetings, Svetlana!
First let me tell you how impressed I am with the clarity of your explanations. Your written English is more lucid than that of most native speakers— seriously! My hat’s off!
Let me try to explain what I want to do here, and please bear in mind that I’m a novice.
I’m in the midst of trying to create a calculator in Excel (2010) that will enable our sales support personnel in a large financial services brokerage agency to efficiently and accurately return guaranteed/non-guaranteed lifetime annual income results from our brokered line of fixed indexed annuity products, given varied investment input, and each product’s individual growth and payout parameters. This would allow us to give very accurate and definitive advice to our contracted agents about which annuity contracts would be most appropriate for given clients.
The four unwieldy IF/AND statements which are copied and pasted below result from each of 4 possible value output combinations obtained from two binary decision points (which are interfaced with two independent groups of two form control radio buttons). I have tested each of the four IF/AND statements separately and they return correct output.
1)
IF(AND(F2=1,I2=1,C5<=44),"NA",IF(C5<=54,0.040,IF(C5<=59,0.045,IF(C5<=64,0.050,IF(C5<=69,0.055,IF(C5<=74,0.060,IF(C5=80,0.070))))))))
2)
IF(AND(F2=2,I2=1,C5<=44),"NA",IF(C5<=54,0.035,IF(C5<=59,0.040,IF(C5<=64,0.045,IF(C5<=69,0.050,IF(C5<=74,0.055,IF(C5=80,0.065))))))))
3)
IF(AND(F2=1,I2=2,C5<=44),"NA",IF(C5<=54,0.030,IF(C5<=59,0.035,IF(C5<=64,0.040,IF(C5<=69,0.045,IF(C5<=74,0.045,IF(C5=80,0.055))))))))
4)
IF(AND(F2=2,I2=2,C5<=44),"NA",IF(C5<=54,0.025,IF(C5<=59,0.030,IF(C5<=64,0.035,IF(C5<=69,0.040,IF(C5<=74,0.050,IF(C5=80,0.060))))))))
Let me add that each successive statement after the first simply reduces each of the whole series of nested IF outputs by .05.
Here are my two questions with regard to all the foregoing:
1) How do I integrate the four IF/AND statements into a single statement that will correctly function in concert with the radio buttons and return a single correct output?
2) Does Excel provide some function or other way of reducing the complexity of the nested IF statements?
If you can help me with those questions, I’d be much obliged.
With kind regards,
Bill Hunter
Hello Bill,
Thank you very much for your kind words! For me to understand the task better, please reply to my email with a small sample of your data, formulas and expected results. (I've removed your email address from this blog for security reasons).
When are you gonna add windows 11
Thank you!
… Here is what I am trying to do:
=COUNTIF(H1179:H3396,TODAY())
This is my current formula I use to determine how many units are processed for the day…Fortunately / Unfortunately I processed 87 installs yesterday from 3 ICSB locations so my formula doesn’t provide me with a quick answer to Marks daily question of “How many do we have done today” so I sit here and count them manually soooo I want to add to it:
(D1179:D3396,”Carol Stream”)
Basically I want a formula that I can utilize for each location that only counts the installs done for that location and not all installs done within a range that are dated for TODAY.
If you can help it would be appreciated!!
Thanks
Good day all hope someone can help me
ok here it goes hope it makes sense
I need a line written for a worksheet of mine that does the following
i have items that are being sold call it a orange
then i have a date that it has been delivered
now what i want to be able to do is have excel calculate how many of oranges how many apples how many grapes etc. there are 7 different items that i have still needs to be delivered based on a text insert "to be delivered"
Thanks let me know hope this is enough info
Hello,
I want to know formula to count cells that does not contain some values...more than one.
Hi,
I have a spreadsheet where I want to count yields on investments between various rates (i.e. >=1% and 1")-countif(p8:p29,">2").
this returns 0.00%. Please advise. Thanks!!
Please suggest formula -
If in Column A I have names (Names are repeating) & In Column B Status against name like Yes & No.
So If I want to count how many Yes are there against any particular name than how to do it. Pls help
Hello,
assuming, that you want to count "Yes" against "Peter" use the following formula:
=COUNTIFS(A:A,"Peter",B:B,"Yes")
Just replace the name in the formula with the one from your data.
Hop it helps!
Thank you so much. Incredibly helpful!