by The tutorial explains how to use COUNTIFS and COUNTIF formulas with multiple criteria in Excel based on AND as well as OR logic. You will find a number of examples for different data types - numbers, dates, text, wildcard characters, non-blank cells and more.
Of all Excel functions, COUNTIFS and COUNTIF are probably most often mixed up because they look very much alike and both are purposed for counting cells based on the specified criteria.
The difference is that COUNTIF is designed for counting cells with a single condition in one range, whereas COUNTIFS can evaluate different criteria in the same or in different ranges. The aim of this tutorial is to demonstrate different approaches and help you choose the most efficient formula for each particular task.
Excel COUNTIFS function - syntax and usage
The Excel COUNTIFS function counts cells across multiple ranges based on one or several conditions. The function is available in Excel 365, 2021, 2019, 2016, 2013, Excel 2010, and Excel 2007, so you can use the below examples in any Excel version.
COUNTIFS syntax
The syntax of the COUNTIFS function is as follows:
- criteria_range1 (required) - defines the first range to which the first condition (criteria1) shall be applied.
- criteria1 (required) - sets the condition in the form of a number, cell reference, text string, expression or another Excel function. The criteria defines which cells shall be counted and can be expressed as 10, "<=32", A6, "sweets".
- [criteria_range2, criteria2]… (optional) - these are additional ranges and their associated criteria. You can specify up to 127 range/criteria pairs in your formulas.
In fact, you don't have to remember the syntax of the COUNTIF function by heart. Microsoft Excel will display the function's arguments as soon as you start typing; the argument you are entering at the moment is highlighted in bold.
Excel COUNTIFS - things to remember!
- You can use the COUNTIFS function in Excel to count cells in a single range with a single condition as well as in multiple ranges with multiple conditions. If the latter, only those cells that meet all of the specified conditions are counted.
- Each additional range must have the same number of rows and columns as the first range (criteria_range1 argument).
- Both contiguous and non-contiguous ranges are allowed.
- If the criteria is a reference to an empty cell, the COUNTIFS function treats it as a zero value (0).
- You can use the wildcard characters in criteria - asterisk (*) and question mark (?). See this example for full details.
How to use COUNTIFS and COUNTIF with multiple criteria in Excel
Below you will find a number of formula examples that demonstrate how to use the COUNTIFS and COUNTIF functions in Excel to evaluate multiple conditions.
How to count cells with multiple criteria (AND logic)
This scenario is the easiest one, since the COUNTIFS function in Excel is designed to count only those cells for which all of the specified conditions are TRUE. We call it the AND logic, because Excel's AND function works this way.
Formula 1. COUNTIFS formula with multiple criteria
Suppose you have a product list like shown in the screenshot below. You want to get a count of items that are in stock (value in column B is greater than 0) but have not been sold yet (value is column C is equal to 0).
The task can be accomplished by using this formula:
=COUNTIFS(B2:B7,">0", C2:C7,"=0")
And the count is 2 ("Cherries" and "Lemons"):
Formula 2. COUNTIFS formula with two criteria
When you want to count items with identical criteria, you still need to supply each criteria_range / criteria pair individually.
For example, here's the right formula to count items that have 0 both in column B and column C:
=COUNTIFS($B$2:$B$7,"=0", $C$2:$C$7,"=0")
This COUNTIFS formula returns 1 because only "Grapes" have "0" value in both columns.
Using a simpler formula with a single criteria_range like COUNTIFS(B2:C7,"=0") would yield a different result - the total count of cells in the range B2:C7 containing a zero (which is 4 in this example).
How to count cells with multiple criteria (OR logic)
As you have seen in the above examples, counting cells that meet all of the specified criteria is easy because the COUNTIFS function is designed to work this way.
But what if you want to count cells for which at least one of the specified conditions is TRUE, i.e. based on the OR logic? Overall, there are two ways to do this - by adding up several COUNTIF formulas or using a SUM COUNTIFS formula with an array constant.
Formula 1. Add up two or more COUNTIF or COUNITFS formulas
In the table below, supposing you want to count orders with the "Cancelled" and "Pending" status. To have it doen, you can simply write 2 regular Countif formulas and add up the results:
=COUNTIF($C$2:$C$11,"Cancelled") + COUNTIF($C$2:$C$11,"Pending")
In case each of the functions is supposed to evaluate more than one condition, use COUNTIFS instead of COUNTIF. For example, to get the count of "Cancelled" and "Pending" orders for "Apples" use this formula:
=COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Cancelled") + COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Pending")
Formula 2. SUM COUNTIFS with an array constant
In situations when you have to evaluate a lot of criteria, the above approach is not the best way to go because your formula would grow too big in size. To perform the same calculations in a more compact formula, list all of your criteria in an array constant, and supply that array to the criteria argument of the COUNTIFS function. To get the total count, embed COUNTIFS inside the SUM function, like this:
In our sample table, to count orders with the status "Cancelled" or "Pending" or "In transit", the formula would go as follows:
=SUM(COUNTIFS($C$2:$C$11, {"cancelled", "pending", "in transit"}))
In a similar manner, you can count cells based on two or more criteria_range / criteria pairs. For instance, to get the number of "Apples" orders that are "Cancelled" or "Pending" or "In transit", use this formula:
=SUM(COUNTIFS($A$2:$A$11,"apples",$C$2:$C$11,{"cancelled","pending","in transit"}))
You can find a few more ways to count cells with OR logic in this tutorial: Excel COUNTIF and COUNTIFS with OR conditions.
How to count numbers between 2 specified numbers
By and large, COUNTIFS formulas for numbers fall into 2 categories - based on several conditions (explained in the above examples) and between the two values you specify. The latter can be accomplished in two ways - by using the COUNTIFS function or by subtracting one COUNTIF from another.
Formula 1. COUNTIFS to count cells between two numbers
To find out how many numbers between 5 and 10 (not including 5 and 10) are contained in cells C2 through C10, use this formula:
=COUNTIFS(C2:C10,">5", C2:C10,"<10")
To include 5 and 10 in the count, use the "greater than or equal to" and "less than or equal to" operators:
=COUNTIFS(B2:B10,">=5", B2:B10,"<=10")
Formula 2. COUNTIF formulas to count numbers between X and Y
The same result can be achieved by subtracting one Countif formula from another. The first one counts how many numbers are greater than the lower bound value (5 in this example). The second formula returns the count of numbers that are greater than the upper bound value (10 in this case). The difference between the first and second number is the result you are looking for.
- =COUNTIF(C2:C10,">5")-COUNTIF(C2:C10,">=10") - counts how many numbers greater than 5 and less than 10 are in the range C2:C10. This formula will return the same count as shown in the screenshot above.
- =COUNTIF(C2:C10, ">=5")-COUNTIF(C2:C10, ">10") - the formula counts how many numbers between 5 and 10 are in the range C2:C10, including 5 and 10.
How to use cell references in COUNTIFS formulas
When using logical operators such as ">", "<", "<=" or ">=" together with cell references in your Excel COUNTIFS formulas, remember to enclose the operator in "double quotes" and
add an ampersand (&) before a cell reference to construct a text string.
In a sample dataset below, let's count "Apples" orders with amount greater than $200. With criteria_range1 in cells A2:A11 and criteria_range2 in B2:B11, you can use this formula:
=COUNTIFS($A$2:$A$11, "Apples", $B$2:$B$11, ">200")
Or, you can input your criteria values in certain cells, say F1 and F2, and reference those cells in your formula:
=COUNTIFS($A$2:$A$11, $F$1, $B$2:$B$11, ">"&$F$2)
Please notice the use of absolute cell references both in the criteria and criteria_range arguments, which prevents the formula from being broken when copied to other cells.
For more information about the use of an ampersand in COUNTIF and COUNTIFS formulas, please see Excel COUNTIF - frequently asked questions.
How to use COUNTIFS with wildcard characters
In Excel COUNTIFS formulas, you can use the following wildcard characters:
- Question mark (?) - matches any single character, use it to count cells starting and/or ending with certain characters.
- Asterisk (*) - matches any sequence of characters, you use it to count cells containing a specified word or a character(s) as part of the cell's contents.
Tip. If you want to count cells with an actual question mark or asterisk, type a tilde (~) before an asterisk or question mark.
Now let's see how you can use a wildcard char in real-life COUNTIFS formulas in Excel. Suppose, you have a list of projects in column A. You wish to know how many projects are already assigned to someone, i.e. have any name in column B. And because we are learning how to use the COUNTIFS function with multiple criteria, let's add a second condition - the End Date in column D should also be set.
Here is the formula that works a treat:
=COUNTIFS(B2:B10,"*",D2:D10,"<>"&""))
Please note, you cannot use a wildcard character in the 2nd criteria because you have dates rather that text values in column D. That is why, you use the criteria that finds non-blank cells: "<>"&""
COUNTIFS and COUNTIF with multiple criteria for dates
The COUNTIFS and COUNTIF formulas you use for dates are very much similar to the above formulas for numbers.
Example 1. Count dates in a specific date range
To count the dates that fall in a certain date range, you can also use either a COUNTIFS formula with two criteria or a combination of two COUNTIF functions.
For example, the following formulas count the number of dates in cells C2 through C10 that fall between 1-Jun-2014 and 7-Jun-2014, inclusive:
=COUNTIFS(C2:C9, ">=6/1/2014", C2:C9, "<=6/7/2014")
=COUNTIF(C2:C9, ">=6/1/2014") - COUNTIF(C2:C9, ">6/7/2014")
Example 2. Count dates with multiple conditions
In the same manner, you can use a COUNTIFS formula to count the number of dates in different columns that meet 2 or more conditions. For instance, the below formula will find out how many products were purchased after the 20th of May and delivered after the 1st of June:
=COUNTIFS(C2:C9, ">5/1/2014", D2:D9, ">6/7/2014")
Example 3. Count dates with multiple conditions based on the current date
You can use Excel's TODAY() function in combination with COUNTIF to count dates based on the current date.
For example, the following COUNTIF formula with two ranges and two criteria will tell you how many products have already been purchased but not delivered yet.
=COUNTIFS(C2:C9, "<"&TODAY(), D2:D9, ">"&TODAY())
This formula allows for many possible variations. For instance, you can tweak it to count how many products were purchased more than a week ago and are not delivered yet:
=COUNTIFS(C2:C9, "<="&TODAY()-7, D2:D9, ">"&TODAY())
This is how you count cells with multiple criteria in Excel. I hope you will find these examples helpful. Anyway, I thank you for reading and hope to see you on our blog next week!
2039 comments
Hi,
Im facing a problem. I have automated a sheet and there I have used countifs. However, eg. I have given a cell range i.e I:I and further condition. But when i checked the data for the next month the column changed from I to B and it keeps changing constantly. Can i Have a "&" condition before count if function. E.g if 1:1 contains text "status" then countif the column.
Thanks in advance,
Soheb.
appreciated it really help me and done my job
Thank you for this formulas. Do you know if it is possible to combine 2 arrays of OR conditions, with a AND between ? It seems impossible
For example something like
=SUM(COUNTIFS($A$2:$A$11,{"apples","Bananas"},$C$2:$C$11,{"cancelled","pending","in transit"}))
doesn't work
I have an excel summary table that is referencing other table to return a yes or no response. The summary table is 10 contiguous cells in a row that I want to get an average of yes' (out of ten). I tried doing countifs, but now I am not sure if this would be the best function to use.
ex: C8:L8 have a non numerical result referenced to return "yes" or "no". in M8 I want to display the average number of yes' not just the count.
any help is greatly appreciated. thank you
I need help with a spreadsheet on google sheets
I am trying to write a formula. I have a large spreadsheet with a range of dates and tasks that employees have completed that day. All of these dates are at random and the employees enter their name once something has been completed by them.
I need to write a formula that will search for example the name *aaron* on date 16/09/2019 and count the amount of times *aaron*has been entered and show for example 7.
Can anyone help ?
I have this query to be sloved i have two or more lines in single row in excel how can i split the same in two different rows below are in single row now i want to split them
eg
1 Unit Fodder Grass Bijankur-BB2 50 gm Rs. 335 1 Unit Humic Acid Roota 500 gm Rs. 430
11 Unit Drumstick PKM 1 50 gm Rs. 2401 Unit Fodder Grass Bijankur-BB2 50 gm Rs. 335
B1/A1-1
how i can count multiple criteria in a single range based on other two conditions using countifs??
Please help – I have a working formula that’s counting three specific criteria from a report (see formula below). I have hundreds of different specific criteria combos that I’ll be counting and would like to avoid having to type all the different criteria combos directly into each formula.
How can I use cell references instead of typing them? I tried several different things, but unable to get it to work.
Company1 – Names will be in a fixed cell on the results page – D1
Department1 – Names will be in a fixed cell on the results page – E1
Account Type1 – The results page is by account type and all the account types are in the column – A3, A4, A5 (type one is A3)
=COUNTIFS('Report'!$C:$C,"=Company1",'Report'!$K:$K,"=Department1",Report'!$J:$J,"=Account Type1")
Thank you so much for your tutorials, it's really very much useful in work life.
Date Person Unit Summary
19 June 2019 Rakesh 32 19-Jun-19 20-Jun-19
19 June 2019 Rakesh 65 Person U.Count T.Unit U.Count t.Unit
19 June 2019 Kranti 15 Kamlesh
19 June 2019 Kranti 25 Kranti
19 June 2019 Kamlesh 35 Pradeep
19 June 2019 Kamlesh 48 Rahul
19 June 2019 Rahul 38 Rakesh
19 June 2019 Rahul 65 Sagar
19 June 2019 Sagar 25
19 June 2019 Sagar 44
19 June 2019 Pradeep 52
19 June 2019 Pradeep 35
20 June 2019 Rakesh 12
20 June 2019 Rakesh 24
20 June 2019 Kranti 12
20 June 2019 Kranti 24
20 June 2019 Kamlesh 42
20 June 2019 Kamlesh 35
20 June 2019 Rahul 48
20 June 2019 Rahul 38
20 June 2019 Sagar 65
20 June 2019 Sagar 25
20 June 2019 Pradeep 12
20 June 2019 Pradeep 24
How this data is create accoding to date person bill count and sum of units
Hi,
I need some formula to get the below result. Looking formula to get the unique list with conditions & count based on condition.
Input
A B C
Engine Body Status
Done Painting WIP
Done Done Wash
Done Painting WIP
Done Done
Done Denting WIP
Done Done
Done Body Work
Done Body Work
Done Done
Done Body Work
Expected Result
F G
Yet to GO Job Count
Painting Wip 2
Denting WIP 1
Body Work 3
Thanks in advance...
Regard,
Anand
=IF(I5"",IF(T5"",T5-I5),IF(I5"",-T5,"nopre"),IF(I5"","")
I neeed help gettin this formular to work. I want to subtract cell values return different value if particular cell is blank and no value if both are blank.
I am trying to calculate students who take only online classes from my data set. I don't want to include students who may take a mix of classes such as online and face to face, or online and hybrid class.Any thoughts how to do this.
I want to count different 17 digit number. Example:
1. 55554440100000000
2. 55554440299999999
3. 55554440178999990
4. 55554440220000001
5. 55554440123456789
Result: 5555444010000000 to 55554440199999999=3 and
55554440200000000 to 55554440299999999=2
Please help me to solve this problem.
I'm trying to figure out if two dates in two separate columns are less than today, then they are considered backlogged; however, if a patient was seen on one date for something, then they are not backlogged on the other? How would i figure this out?
How to solve
F2<150 *3.5 otherwise *6.5
Note :- * = Multiply
Reply please send my Email
Thank you
in col A are student name, col B are Marks, How to around 1000 students are there. I want to find how many students having marks above 500 and how many are below 500. plz help
Hello
I have a excel sheet for feedback Report and I want to count each faculty feedback with specific alphabet for count separate like:
Faculty 1 A= 50
B= 35
C= 15
D= 7
E= 8
Faculty 2 A= 35
B= 40
C= 14
D= 25
E= 10
Same as per above :
Condition 1: all data calculate in 1 sheet
Hi, this formula counts all apples that falls between two dates. How can I change the formula so that the apples that occurs on weekends between these two dates doesn’t get counted. thanks
=COUNTIFS(A1:A500,"apples",B1:B500,">="&D1,B1:B500,"<="&D2)
Column A has names of fruits
Column B has dates
D1 is cell with date
D2 is cell with date