by The tutorial explains how to use COUNTIFS and COUNTIF formulas with multiple criteria in Excel based on AND as well as OR logic. You will find a number of examples for different data types - numbers, dates, text, wildcard characters, non-blank cells and more.
Of all Excel functions, COUNTIFS and COUNTIF are probably most often mixed up because they look very much alike and both are purposed for counting cells based on the specified criteria.
The difference is that COUNTIF is designed for counting cells with a single condition in one range, whereas COUNTIFS can evaluate different criteria in the same or in different ranges. The aim of this tutorial is to demonstrate different approaches and help you choose the most efficient formula for each particular task.
Excel COUNTIFS function - syntax and usage
The Excel COUNTIFS function counts cells across multiple ranges based on one or several conditions. The function is available in Excel 365, 2021, 2019, 2016, 2013, Excel 2010, and Excel 2007, so you can use the below examples in any Excel version.
COUNTIFS syntax
The syntax of the COUNTIFS function is as follows:
- criteria_range1 (required) - defines the first range to which the first condition (criteria1) shall be applied.
- criteria1 (required) - sets the condition in the form of a number, cell reference, text string, expression or another Excel function. The criteria defines which cells shall be counted and can be expressed as 10, "<=32", A6, "sweets".
- [criteria_range2, criteria2]… (optional) - these are additional ranges and their associated criteria. You can specify up to 127 range/criteria pairs in your formulas.
In fact, you don't have to remember the syntax of the COUNTIF function by heart. Microsoft Excel will display the function's arguments as soon as you start typing; the argument you are entering at the moment is highlighted in bold.
Excel COUNTIFS - things to remember!
- You can use the COUNTIFS function in Excel to count cells in a single range with a single condition as well as in multiple ranges with multiple conditions. If the latter, only those cells that meet all of the specified conditions are counted.
- Each additional range must have the same number of rows and columns as the first range (criteria_range1 argument).
- Both contiguous and non-contiguous ranges are allowed.
- If the criteria is a reference to an empty cell, the COUNTIFS function treats it as a zero value (0).
- You can use the wildcard characters in criteria - asterisk (*) and question mark (?). See this example for full details.
How to use COUNTIFS and COUNTIF with multiple criteria in Excel
Below you will find a number of formula examples that demonstrate how to use the COUNTIFS and COUNTIF functions in Excel to evaluate multiple conditions.
How to count cells with multiple criteria (AND logic)
This scenario is the easiest one, since the COUNTIFS function in Excel is designed to count only those cells for which all of the specified conditions are TRUE. We call it the AND logic, because Excel's AND function works this way.
Formula 1. COUNTIFS formula with multiple criteria
Suppose you have a product list like shown in the screenshot below. You want to get a count of items that are in stock (value in column B is greater than 0) but have not been sold yet (value is column C is equal to 0).
The task can be accomplished by using this formula:
=COUNTIFS(B2:B7,">0", C2:C7,"=0")
And the count is 2 ("Cherries" and "Lemons"):
Formula 2. COUNTIFS formula with two criteria
When you want to count items with identical criteria, you still need to supply each criteria_range / criteria pair individually.
For example, here's the right formula to count items that have 0 both in column B and column C:
=COUNTIFS($B$2:$B$7,"=0", $C$2:$C$7,"=0")
This COUNTIFS formula returns 1 because only "Grapes" have "0" value in both columns.
Using a simpler formula with a single criteria_range like COUNTIFS(B2:C7,"=0") would yield a different result - the total count of cells in the range B2:C7 containing a zero (which is 4 in this example).
How to count cells with multiple criteria (OR logic)
As you have seen in the above examples, counting cells that meet all of the specified criteria is easy because the COUNTIFS function is designed to work this way.
But what if you want to count cells for which at least one of the specified conditions is TRUE, i.e. based on the OR logic? Overall, there are two ways to do this - by adding up several COUNTIF formulas or using a SUM COUNTIFS formula with an array constant.
Formula 1. Add up two or more COUNTIF or COUNITFS formulas
In the table below, supposing you want to count orders with the "Cancelled" and "Pending" status. To have it doen, you can simply write 2 regular Countif formulas and add up the results:
=COUNTIF($C$2:$C$11,"Cancelled") + COUNTIF($C$2:$C$11,"Pending")
In case each of the functions is supposed to evaluate more than one condition, use COUNTIFS instead of COUNTIF. For example, to get the count of "Cancelled" and "Pending" orders for "Apples" use this formula:
=COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Cancelled") + COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Pending")
Formula 2. SUM COUNTIFS with an array constant
In situations when you have to evaluate a lot of criteria, the above approach is not the best way to go because your formula would grow too big in size. To perform the same calculations in a more compact formula, list all of your criteria in an array constant, and supply that array to the criteria argument of the COUNTIFS function. To get the total count, embed COUNTIFS inside the SUM function, like this:
In our sample table, to count orders with the status "Cancelled" or "Pending" or "In transit", the formula would go as follows:
=SUM(COUNTIFS($C$2:$C$11, {"cancelled", "pending", "in transit"}))
In a similar manner, you can count cells based on two or more criteria_range / criteria pairs. For instance, to get the number of "Apples" orders that are "Cancelled" or "Pending" or "In transit", use this formula:
=SUM(COUNTIFS($A$2:$A$11,"apples",$C$2:$C$11,{"cancelled","pending","in transit"}))
You can find a few more ways to count cells with OR logic in this tutorial: Excel COUNTIF and COUNTIFS with OR conditions.
How to count numbers between 2 specified numbers
By and large, COUNTIFS formulas for numbers fall into 2 categories - based on several conditions (explained in the above examples) and between the two values you specify. The latter can be accomplished in two ways - by using the COUNTIFS function or by subtracting one COUNTIF from another.
Formula 1. COUNTIFS to count cells between two numbers
To find out how many numbers between 5 and 10 (not including 5 and 10) are contained in cells C2 through C10, use this formula:
=COUNTIFS(C2:C10,">5", C2:C10,"<10")
To include 5 and 10 in the count, use the "greater than or equal to" and "less than or equal to" operators:
=COUNTIFS(B2:B10,">=5", B2:B10,"<=10")
Formula 2. COUNTIF formulas to count numbers between X and Y
The same result can be achieved by subtracting one Countif formula from another. The first one counts how many numbers are greater than the lower bound value (5 in this example). The second formula returns the count of numbers that are greater than the upper bound value (10 in this case). The difference between the first and second number is the result you are looking for.
- =COUNTIF(C2:C10,">5")-COUNTIF(C2:C10,">=10") - counts how many numbers greater than 5 and less than 10 are in the range C2:C10. This formula will return the same count as shown in the screenshot above.
- =COUNTIF(C2:C10, ">=5")-COUNTIF(C2:C10, ">10") - the formula counts how many numbers between 5 and 10 are in the range C2:C10, including 5 and 10.
How to use cell references in COUNTIFS formulas
When using logical operators such as ">", "<", "<=" or ">=" together with cell references in your Excel COUNTIFS formulas, remember to enclose the operator in "double quotes" and
add an ampersand (&) before a cell reference to construct a text string.
In a sample dataset below, let's count "Apples" orders with amount greater than $200. With criteria_range1 in cells A2:A11 and criteria_range2 in B2:B11, you can use this formula:
=COUNTIFS($A$2:$A$11, "Apples", $B$2:$B$11, ">200")
Or, you can input your criteria values in certain cells, say F1 and F2, and reference those cells in your formula:
=COUNTIFS($A$2:$A$11, $F$1, $B$2:$B$11, ">"&$F$2)
Please notice the use of absolute cell references both in the criteria and criteria_range arguments, which prevents the formula from being broken when copied to other cells.
For more information about the use of an ampersand in COUNTIF and COUNTIFS formulas, please see Excel COUNTIF - frequently asked questions.
How to use COUNTIFS with wildcard characters
In Excel COUNTIFS formulas, you can use the following wildcard characters:
- Question mark (?) - matches any single character, use it to count cells starting and/or ending with certain characters.
- Asterisk (*) - matches any sequence of characters, you use it to count cells containing a specified word or a character(s) as part of the cell's contents.
Tip. If you want to count cells with an actual question mark or asterisk, type a tilde (~) before an asterisk or question mark.
Now let's see how you can use a wildcard char in real-life COUNTIFS formulas in Excel. Suppose, you have a list of projects in column A. You wish to know how many projects are already assigned to someone, i.e. have any name in column B. And because we are learning how to use the COUNTIFS function with multiple criteria, let's add a second condition - the End Date in column D should also be set.
Here is the formula that works a treat:
=COUNTIFS(B2:B10,"*",D2:D10,"<>"&""))
Please note, you cannot use a wildcard character in the 2nd criteria because you have dates rather that text values in column D. That is why, you use the criteria that finds non-blank cells: "<>"&""
COUNTIFS and COUNTIF with multiple criteria for dates
The COUNTIFS and COUNTIF formulas you use for dates are very much similar to the above formulas for numbers.
Example 1. Count dates in a specific date range
To count the dates that fall in a certain date range, you can also use either a COUNTIFS formula with two criteria or a combination of two COUNTIF functions.
For example, the following formulas count the number of dates in cells C2 through C10 that fall between 1-Jun-2014 and 7-Jun-2014, inclusive:
=COUNTIFS(C2:C9, ">=6/1/2014", C2:C9, "<=6/7/2014")
=COUNTIF(C2:C9, ">=6/1/2014") - COUNTIF(C2:C9, ">6/7/2014")
Example 2. Count dates with multiple conditions
In the same manner, you can use a COUNTIFS formula to count the number of dates in different columns that meet 2 or more conditions. For instance, the below formula will find out how many products were purchased after the 20th of May and delivered after the 1st of June:
=COUNTIFS(C2:C9, ">5/1/2014", D2:D9, ">6/7/2014")
Example 3. Count dates with multiple conditions based on the current date
You can use Excel's TODAY() function in combination with COUNTIF to count dates based on the current date.
For example, the following COUNTIF formula with two ranges and two criteria will tell you how many products have already been purchased but not delivered yet.
=COUNTIFS(C2:C9, "<"&TODAY(), D2:D9, ">"&TODAY())
This formula allows for many possible variations. For instance, you can tweak it to count how many products were purchased more than a week ago and are not delivered yet:
=COUNTIFS(C2:C9, "<="&TODAY()-7, D2:D9, ">"&TODAY())
This is how you count cells with multiple criteria in Excel. I hope you will find these examples helpful. Anyway, I thank you for reading and hope to see you on our blog next week!
2039 comments
Hi,
I have data that shows me how many times different projects pass or fail, but I want to count how may times a project fails on different days, i.e. not to count it twice if it failed twice on the same day. See simplified data below; I want to return Project 101 as 'Failing' 3 times, i.e. on 3 days, not 4 individual occasions.
A B C
Date Project Result
01 Jan 101 Fail
01 Jan 101 Fail
02 Jan 102 Fail
02 Jan 101 Fail
03 Jan 101 Pass
03 Jan 101 Fail
04 Jan 103 Pass
Thanks in advance
Paul
Hello!
If I understand your task correctly, the following formula should work for you:
=IFERROR(ROWS(UNIQUE(FILTER($A$1:$A$8, $B$1:$B$8=$D$1))), 0)
where $D$1=101.
You can learn more about count unique values with criteria in this article.
I hope it’ll be helpful.
I'd appreciate any help or insight.
Use Case: Get count of multiple criteria from different columns
Criteria1: =COUNTIFS('Sales Report'!$G:$G,"Damy Dams",'Sales Report'!$H:$H,"Nov",'Sales Report'!$I:$I,{"Movies","Music"}),
Criteria 2: 'Sales Report'!$E:$E, {"Offline","Onsite","Podcast"})
My formula returned the count for Criteria 1 BUT does not return the count for Criteria 2
How can I combine all into one statement?
For example: =SUM(Criteria1,Criteria2)
AND NOT
=SUM(Criteria1+ SUM(COUNTIFS(Criteria2)…. this gives a much higher count value and is not the requirement.
Hello!
Use the formula for Criteria2
=SUM(COUNTIFS('Sales Report'!$E:$E, {“Offline”;”Onsite”;”Podcast”}))
I hope it’ll be helpful.
Hi,
I need following assistance from you guys.
In my data table column A = code number and column B = name.
If code number in column A is same, that has to be count as one only.
Count result should be Reza = 2, Jonny = 1, Rony = 2 & Bony = 1.
Code Name
438 Reza
438 Reza
438 Reza
438 Reza
438 Reza
438 Reza
438 Reza
438 Reza
438 Reza
438 Reza
439 Jonny
440 Reza
441 Rony
442 Bony
443 Rony
Thanks in advance for you assistance .
Warm regards,
Hamid
Hi, I am trying to count non text items listed in one column. These items belong to each patients who can have a cardiovascular risk that could be "<10%", "10 - <20%", "20 - <30%", "30 - 40%". How do I use countif formular for these to create how many patients for each CVR category?
Hi, I am trying to set up a spreadsheet to check whether colleagues are completing specific tasks (that are recorded on a different spreadsheet), at least once within each 28 day period and to count how many of the task they did within the period. The best way I can think of it to to pull the count for each date and then have a separate tab that then works off that count to be certain the colleague is competent over the year. But I'm struggling to get the correct formula. What I need is: the count if column M on spreadsheet A is equal to cell A2 on spreadsheet B AND the date within column Q on spreadsheet A is equal to B1 on spreadsheet B - spreadsheet A being the one that contains the original data and spreadsheet B being the new one I am setting up
How to combine following two formula..?
if(and(f2>=d25,i2<=e25),b25,"")
if(countifs(ar3:ar6,i24),"",b25)
I have a file with some numerical grading,i need the lowest grading ...
how can i calculate the same
Row Labels- 2 3 4 5 1 6
Hi,
May be this is a silly question, but i cant figure it out the solution. Here's the data:
A1 Korea
A2 Indonesia
A3 Indonesia
A4 Singapore
A5 Malaysia
A6 Indonesia
A7 Malaysia
A8 Indonesia
I want to calculate what is the most showed up country. Do you have any solutions? Thank you in advance
Hey I want to concatenate names in excel ..but the conditon is
In coloum A
A1 is having an I'd and then second I'd number is present in another cell suppose A6 .. so I want excel to concatenate name from A1 to A5 ..and excel can do the same ..for entire sheet .with varying range of cells with I'd number
I would like to find out how to group values using COUNTIFs in excel. For example, i have a grade sheet of students with the student name, subject and grade.
Student Subject Grade
Ann English A
Ann Math A
Joe English B
Ann Science B
Joe English A
I want to group by the Student and the grade
Student Grade Total
Ann A 2
Ann B 1
JOE B 1
Joe A 1
A1 09:00:10 , A2 Medical , A3 11:03:25 , A4 blank
what can I show B1 is 1 , B2 is 0 , B3 1 , B4 0 .
Hi,
Please describe the logic behind your calculations. What do you want to count? Why B1 = 1? Please specify what you were trying to find, what formula you used and what problem or error occurred.
this has been helpful
Is it possible to take this a step further and incorporate date range to this?
Each sheet contains a column with a date that something was completed...column R
The criteria in each sheet needed to be counted is column T
In a new "summary" sheet is where calculations would occur using "SUMPRODUCT(COUNTIF(INDIRECT"
In this "summary" sheet, column "A" contains the dates representing a week where the specific criteria occurred.
Columns Row 1 in column B, C and D have the criteria needing to be counted based during the week listed in column A.
Unfortunately limited in formatting in the forum
Column A
Row 1 Week Of
Row 2 11/15/2020
Row 3 11/22/2020
Row 4 11/29/2020
Column B
Row 1 "Missed"
Row 2 5
Row 3 12
Row 4 11
Column C
Row 1 "Caught"
Row 2 7
Row 3 11
Row 4 13
Column D
Row 1 "Disconnect"
Row 2 11
Row 3 1
Row 4 5
I hope this makes sense. I have been unsuccessful in getting anything to work.
Thanks in advance.
Hello!
Sorry, I do not fully understand the task.
Describe in detail the conditions for counting.
Assuming I have a table with two columns J and K with entries of rows either, row1 ,(J=No,K= Yes), row2(J=yes,K=No), row 3 (J=Yes,K=Yes) ROW 4, (J=No,K=No), row5 ,(J=No,K= Yes), row6 (J=yes,K=No), row 7 (J=Yes,K=Yes) ROW 8, (J=No,K=No),...onwards for different documents.
Whenever a No appears on either column J or K or both columns it should be termed error. What formula can I use to help me analyze a large data with the above scenarios. Analysis can be done on another sheet.
Hello!
If I got you right, the formula below will help you with your task:
=IF((COUNTIF(J:J,"No") + COUNTIF(K:K,"No"))>0,"Error","Ok")
I hope my advice will help you solve your task.
I'm trying to do countif to get results from different cells not ranges.
A1 table
A2 chair
A3 table
A4 leg
I basically need countif (A1,A3, "table") but that doesn't work.
I've tried this indirect formula but it still doesn't work =SUM(COUNTIF(INDIRECT({"a1:a1","a3:a3"}),"table"))
Any ideas?
Hello!
The COUNTIF function can only work with one range. Therefore your formula is not possible. Try
=SUM(--(A1="table"),--(A3="table"))
I hope it’ll be helpful.
I want know how is count last 2 days continuous absent
I want to know about . the person who absent last 2 days continuously. if he continuously 2 days did not come to the job his salary should deduct. i want know how is count in excel his continuously absent day ….please help me....
Hello!
I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you.
The response that you sent to me earlier in the day was =IF(COUNTIFS(A:A,A2,B:B,"received")>0,1,""). I do know just how to specify the ranges in this formula. When I attempted it various ways =IF(COUNTIFS(F2:F309,F2,J2:J309,"received")>0,1,"") no error resulted ,but then no count appeared. The count should be 1.
I am trying to develop an Excel formula to obtain a count.
If an ID number appears multiple times in one column and the result “received” appears in a different column, what is the formula to count only 1 instance of the occurrence of the ID and “received”?
For example:
Column Column
F J
5596326 attempted
5596326 delivered
5596326 received
5596326 received
5596326 sent
5596326 Wrong Number
The ID number appears 6 times in column F, and “received” appears twice in column J. With a correct formula, the result should be 1.
What is the formula? And please specify the row ranges in the formula.
Both columns may contain 1,000 or more rows.
Thank you for any assistance.
I have three sheets
Sheet 1
Sheet 2
Sheet 3
I need to count values from Sheet 2 while matching criteria's from Sheet 1 & 2 both.
I want to get these results on sheet 3.
Since this record is for entire month for around 900 names.
Please help & suggest why am I not able to get the results if using countifs formula.
SUMPRODUCT(COUNTIFS(Roster!J5:J444,Sheet1!A1,Roster!K5:K444,Sheet1!B1,Attendance!S5:S444,"P"))
Why am I not able to get the count on sheet 1 with this formula.
Please help me out with this
Hello!
The COUNTIFS function works with data from different sheets. Unfortunately, without seeing your data it is difficult to give you any advice. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. It’ll help me understand it better and find a solution for you.
Hi, I have this data
S/N YEAR MONTH DAY DATE FULL NAME
1 2020 SEPTEMBER TUESDAY 09/01/2020 STEPHEN TAYO
2 2020 SEPTEMBER TUESDAY 09/01/2020 FADE OGUNRO
3 2020 SEPTEMBER TUESDAY 09/01/2020 FADE OGUNRO
4 2020 SEPTEMBER TUESDAY 09/01/2020 FADE OGUNRO
5 2020 SEPTEMBER TUESDAY 09/01/2020 MRS WUNMI OGUNBIYI
6 2020 SEPTEMBER TUESDAY 09/01/2020 MRS WUNMI OGUNBIYI
7 2020 SEPTEMBER TUESDAY 09/01/2020 MRS WUNMI OGUNBIYI
8 2020 SEPTEMBER TUESDAY 09/01/2020 LANRE KUYE
9 2020 SEPTEMBER TUESDAY 09/01/2020 LANRE KUYE
10 2020 SEPTEMBER TUESDAY 09/01/2020 KOME AJEGBO
11 2020 SEPTEMBER TUESDAY 09/01/2020 TIWA SAVAGE
12 2020 SEPTEMBER TUESDAY 09/01/2020 MS ASMAH WILLIAMS
13 2020 SEPTEMBER TUESDAY 09/01/2020 AISHA
14 2020 SEPTEMBER WEDNESDAY 09/02/2020 LANU AGUSTO
15 2020 SEPTEMBER WEDNESDAY 09/02/2020 MS FATIMA
16 2020 SEPTEMBER WEDNESDAY 09/02/2020 TIWA SAVAGE
17 2020 SEPTEMBER WEDNESDAY 09/02/2020 TIWA SAVAGE
18 2020 SEPTEMBER WEDNESDAY 09/02/2020 MR JIDE
19 2020 SEPTEMBER WEDNESDAY 09/02/2020 MR JIDE
20 2020 SEPTEMBER WEDNESDAY 09/02/2020 MR KEVIN JOHNSON-AZUARA
21 2020 SEPTEMBER WEDNESDAY 09/02/2020 MR KEVIN JOHNSON-AZUARA
22 2020 SEPTEMBER THURSDAY 09/03/2020 MRS HADIZA
23 2020 SEPTEMBER THURSDAY 09/03/2020 TOYIN SUBAIR
24 2020 SEPTEMBER THURSDAY 09/03/2020 MR YINKA
25 2020 SEPTEMBER THURSDAY 09/03/2020 MR YINKA
26 2020 SEPTEMBER THURSDAY 09/03/2020 FADE OGUNRO
27 2020 SEPTEMBER THURSDAY 09/03/2020 FADE OGUNRO
28 2020 SEPTEMBER FRIDAY 09/04/2020 MR SAM
29 2020 SEPTEMBER FRIDAY 09/04/2020 EMMANUEL
30 2020 SEPTEMBER FRIDAY 09/04/2020 MR IFEOLUWA BAKARE
31 2020 SEPTEMBER FRIDAY 09/04/2020 MR IFEOLUWA BAKARE
32 2020 SEPTEMBER FRIDAY 09/04/2020 MRS EBI WILLIAMS
33 2020 SEPTEMBER FRIDAY 09/04/2020 ETHEL OKOSUN
34 2020 SEPTEMBER SATURDAY 09/05/2020 SEGUN AWOLOWO
and i want to identify the number of transaction each customer does in a month, a customer can only do one transaction in a day, and multiple transactions in subsequent days whenever they come into the store. Please how do I go about this?
Hello!
Pay attention to the following paragraph of the article above COUNTIFS formula with multiple criteria.
=COUNTIFS(B:B,B1,C:C,C1,F:F,F1)
I hope it’ll be helpful.
I have to calculate attendance for 5 periods in different sheets. Using countif how can i calculate attendance
Hello!
You need to use the COUNTIFS function for each sheet and then sum the 5 results. In doing so, you can use external references to sheets. COUNTIFS does not work with 3D links.