by The tutorial explains how to use COUNTIFS and COUNTIF formulas with multiple criteria in Excel based on AND as well as OR logic. You will find a number of examples for different data types - numbers, dates, text, wildcard characters, non-blank cells and more.
Of all Excel functions, COUNTIFS and COUNTIF are probably most often mixed up because they look very much alike and both are purposed for counting cells based on the specified criteria.
The difference is that COUNTIF is designed for counting cells with a single condition in one range, whereas COUNTIFS can evaluate different criteria in the same or in different ranges. The aim of this tutorial is to demonstrate different approaches and help you choose the most efficient formula for each particular task.
Excel COUNTIFS function - syntax and usage
The Excel COUNTIFS function counts cells across multiple ranges based on one or several conditions. The function is available in Excel 365, 2021, 2019, 2016, 2013, Excel 2010, and Excel 2007, so you can use the below examples in any Excel version.
COUNTIFS syntax
The syntax of the COUNTIFS function is as follows:
- criteria_range1 (required) - defines the first range to which the first condition (criteria1) shall be applied.
- criteria1 (required) - sets the condition in the form of a number, cell reference, text string, expression or another Excel function. The criteria defines which cells shall be counted and can be expressed as 10, "<=32", A6, "sweets".
- [criteria_range2, criteria2]… (optional) - these are additional ranges and their associated criteria. You can specify up to 127 range/criteria pairs in your formulas.
In fact, you don't have to remember the syntax of the COUNTIF function by heart. Microsoft Excel will display the function's arguments as soon as you start typing; the argument you are entering at the moment is highlighted in bold.
Excel COUNTIFS - things to remember!
- You can use the COUNTIFS function in Excel to count cells in a single range with a single condition as well as in multiple ranges with multiple conditions. If the latter, only those cells that meet all of the specified conditions are counted.
- Each additional range must have the same number of rows and columns as the first range (criteria_range1 argument).
- Both contiguous and non-contiguous ranges are allowed.
- If the criteria is a reference to an empty cell, the COUNTIFS function treats it as a zero value (0).
- You can use the wildcard characters in criteria - asterisk (*) and question mark (?). See this example for full details.
How to use COUNTIFS and COUNTIF with multiple criteria in Excel
Below you will find a number of formula examples that demonstrate how to use the COUNTIFS and COUNTIF functions in Excel to evaluate multiple conditions.
How to count cells with multiple criteria (AND logic)
This scenario is the easiest one, since the COUNTIFS function in Excel is designed to count only those cells for which all of the specified conditions are TRUE. We call it the AND logic, because Excel's AND function works this way.
Formula 1. COUNTIFS formula with multiple criteria
Suppose you have a product list like shown in the screenshot below. You want to get a count of items that are in stock (value in column B is greater than 0) but have not been sold yet (value is column C is equal to 0).
The task can be accomplished by using this formula:
=COUNTIFS(B2:B7,">0", C2:C7,"=0")
And the count is 2 ("Cherries" and "Lemons"):
Formula 2. COUNTIFS formula with two criteria
When you want to count items with identical criteria, you still need to supply each criteria_range / criteria pair individually.
For example, here's the right formula to count items that have 0 both in column B and column C:
=COUNTIFS($B$2:$B$7,"=0", $C$2:$C$7,"=0")
This COUNTIFS formula returns 1 because only "Grapes" have "0" value in both columns.
Using a simpler formula with a single criteria_range like COUNTIFS(B2:C7,"=0") would yield a different result - the total count of cells in the range B2:C7 containing a zero (which is 4 in this example).
How to count cells with multiple criteria (OR logic)
As you have seen in the above examples, counting cells that meet all of the specified criteria is easy because the COUNTIFS function is designed to work this way.
But what if you want to count cells for which at least one of the specified conditions is TRUE, i.e. based on the OR logic? Overall, there are two ways to do this - by adding up several COUNTIF formulas or using a SUM COUNTIFS formula with an array constant.
Formula 1. Add up two or more COUNTIF or COUNITFS formulas
In the table below, supposing you want to count orders with the "Cancelled" and "Pending" status. To have it doen, you can simply write 2 regular Countif formulas and add up the results:
=COUNTIF($C$2:$C$11,"Cancelled") + COUNTIF($C$2:$C$11,"Pending")
In case each of the functions is supposed to evaluate more than one condition, use COUNTIFS instead of COUNTIF. For example, to get the count of "Cancelled" and "Pending" orders for "Apples" use this formula:
=COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Cancelled") + COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Pending")
Formula 2. SUM COUNTIFS with an array constant
In situations when you have to evaluate a lot of criteria, the above approach is not the best way to go because your formula would grow too big in size. To perform the same calculations in a more compact formula, list all of your criteria in an array constant, and supply that array to the criteria argument of the COUNTIFS function. To get the total count, embed COUNTIFS inside the SUM function, like this:
In our sample table, to count orders with the status "Cancelled" or "Pending" or "In transit", the formula would go as follows:
=SUM(COUNTIFS($C$2:$C$11, {"cancelled", "pending", "in transit"}))
In a similar manner, you can count cells based on two or more criteria_range / criteria pairs. For instance, to get the number of "Apples" orders that are "Cancelled" or "Pending" or "In transit", use this formula:
=SUM(COUNTIFS($A$2:$A$11,"apples",$C$2:$C$11,{"cancelled","pending","in transit"}))
You can find a few more ways to count cells with OR logic in this tutorial: Excel COUNTIF and COUNTIFS with OR conditions.
How to count numbers between 2 specified numbers
By and large, COUNTIFS formulas for numbers fall into 2 categories - based on several conditions (explained in the above examples) and between the two values you specify. The latter can be accomplished in two ways - by using the COUNTIFS function or by subtracting one COUNTIF from another.
Formula 1. COUNTIFS to count cells between two numbers
To find out how many numbers between 5 and 10 (not including 5 and 10) are contained in cells C2 through C10, use this formula:
=COUNTIFS(C2:C10,">5", C2:C10,"<10")
To include 5 and 10 in the count, use the "greater than or equal to" and "less than or equal to" operators:
=COUNTIFS(B2:B10,">=5", B2:B10,"<=10")
Formula 2. COUNTIF formulas to count numbers between X and Y
The same result can be achieved by subtracting one Countif formula from another. The first one counts how many numbers are greater than the lower bound value (5 in this example). The second formula returns the count of numbers that are greater than the upper bound value (10 in this case). The difference between the first and second number is the result you are looking for.
- =COUNTIF(C2:C10,">5")-COUNTIF(C2:C10,">=10") - counts how many numbers greater than 5 and less than 10 are in the range C2:C10. This formula will return the same count as shown in the screenshot above.
- =COUNTIF(C2:C10, ">=5")-COUNTIF(C2:C10, ">10") - the formula counts how many numbers between 5 and 10 are in the range C2:C10, including 5 and 10.
How to use cell references in COUNTIFS formulas
When using logical operators such as ">", "<", "<=" or ">=" together with cell references in your Excel COUNTIFS formulas, remember to enclose the operator in "double quotes" and
add an ampersand (&) before a cell reference to construct a text string.
In a sample dataset below, let's count "Apples" orders with amount greater than $200. With criteria_range1 in cells A2:A11 and criteria_range2 in B2:B11, you can use this formula:
=COUNTIFS($A$2:$A$11, "Apples", $B$2:$B$11, ">200")
Or, you can input your criteria values in certain cells, say F1 and F2, and reference those cells in your formula:
=COUNTIFS($A$2:$A$11, $F$1, $B$2:$B$11, ">"&$F$2)
Please notice the use of absolute cell references both in the criteria and criteria_range arguments, which prevents the formula from being broken when copied to other cells.
For more information about the use of an ampersand in COUNTIF and COUNTIFS formulas, please see Excel COUNTIF - frequently asked questions.
How to use COUNTIFS with wildcard characters
In Excel COUNTIFS formulas, you can use the following wildcard characters:
- Question mark (?) - matches any single character, use it to count cells starting and/or ending with certain characters.
- Asterisk (*) - matches any sequence of characters, you use it to count cells containing a specified word or a character(s) as part of the cell's contents.
Tip. If you want to count cells with an actual question mark or asterisk, type a tilde (~) before an asterisk or question mark.
Now let's see how you can use a wildcard char in real-life COUNTIFS formulas in Excel. Suppose, you have a list of projects in column A. You wish to know how many projects are already assigned to someone, i.e. have any name in column B. And because we are learning how to use the COUNTIFS function with multiple criteria, let's add a second condition - the End Date in column D should also be set.
Here is the formula that works a treat:
=COUNTIFS(B2:B10,"*",D2:D10,"<>"&""))
Please note, you cannot use a wildcard character in the 2nd criteria because you have dates rather that text values in column D. That is why, you use the criteria that finds non-blank cells: "<>"&""
COUNTIFS and COUNTIF with multiple criteria for dates
The COUNTIFS and COUNTIF formulas you use for dates are very much similar to the above formulas for numbers.
Example 1. Count dates in a specific date range
To count the dates that fall in a certain date range, you can also use either a COUNTIFS formula with two criteria or a combination of two COUNTIF functions.
For example, the following formulas count the number of dates in cells C2 through C10 that fall between 1-Jun-2014 and 7-Jun-2014, inclusive:
=COUNTIFS(C2:C9, ">=6/1/2014", C2:C9, "<=6/7/2014")
=COUNTIF(C2:C9, ">=6/1/2014") - COUNTIF(C2:C9, ">6/7/2014")
Example 2. Count dates with multiple conditions
In the same manner, you can use a COUNTIFS formula to count the number of dates in different columns that meet 2 or more conditions. For instance, the below formula will find out how many products were purchased after the 20th of May and delivered after the 1st of June:
=COUNTIFS(C2:C9, ">5/1/2014", D2:D9, ">6/7/2014")
Example 3. Count dates with multiple conditions based on the current date
You can use Excel's TODAY() function in combination with COUNTIF to count dates based on the current date.
For example, the following COUNTIF formula with two ranges and two criteria will tell you how many products have already been purchased but not delivered yet.
=COUNTIFS(C2:C9, "<"&TODAY(), D2:D9, ">"&TODAY())
This formula allows for many possible variations. For instance, you can tweak it to count how many products were purchased more than a week ago and are not delivered yet:
=COUNTIFS(C2:C9, "<="&TODAY()-7, D2:D9, ">"&TODAY())
This is how you count cells with multiple criteria in Excel. I hope you will find these examples helpful. Anyway, I thank you for reading and hope to see you on our blog next week!
2039 comments
I imported two separate reports into either same sheet or different sheets. Each report have in separate columns, b and ac, matching and unmatching number values. I need to identify a formula to return matching value from Report 1 (column b) Report 2(Column ac) to calculate total amount from Report 2 (Column ad if column b and column ac then match column e to column v and place total amount in column w) that matches the value from table array (column v match column e). As you can see below, in the table array (column v, data 3) matches from Report 1(column b, rev 3 and rev 7) with Report 2(Column ac, rev3) where the table array (data 3) calculates the total value to match all the criteria's of table 1 and table 2 and places the total amount from Report 2 (Column ad, $1.00 and $4.00). I hope this makes sense as this is difficult to explain.
Report 1 Table Array Return Value Report 2
Column b Column e Column v Column w Column ac Colum ad
rev1 Data1 data1 ($0.00) Rev3 $1.00
Rev2 Data6 data2 ($0.00) Rev4 $3.00
Rev3 Data3 data3 ($5.00) Rev5 $10.00
Rev4 Data4 data4 ($3.00) Rev7 $4.00
Rev5 Data2 data5 ($0.00) Rev10 $1.00
Rev6 Data1 data6 Rev12 $2.00
Rev7 Data3 data7 Rev15 $3.00
Hello!
Your request goes beyond the advice we provide on this blog. This is a complex solution that cannot be found with a single formula. If you have a specific question about the operation of a function or formula, I will try to answer it.
Hey,
I'm trying to use COUNTIF to look at 2 different collums and if both of the values are true to count, this is my formula but it is not working;
=COUNTIF('2021 Requests'!C6:C440, "Granted",'2021 Requests'!D4:D440,"07/01/2022")
Any help would be appreciated.
Needs to be COUNTFS not COUNTIF
also the range of C should be the same size as the range of D
so EX.
=COUNTIFS('2021 Requests'!C4:C440, "Granted",'2021 Requests'!D4:D440,"07/01/2022")
I have three colms
A B C
Loss amnt reason
Yes 100 Retrun
i have tried countifs( B1:B10,"<100",C1:C10,"return") but actual picture will be on the basis of Loss ( Yes or No). what is the formula for that.
Hi!
If you want to calculate the amount of losses, then use the SUMIFS function.
=SUM(COUNTIFS(D24,"*P*"),(COUNTIFS(D55,"*P*")),(COUNTIFS(D104,"*P*")))
I'M TRYING TO GET THE SUM OF DIFFERENT CELLS IN SAME COLUMN THAT IS MY SAMPLE FORMULA HOW CAN I SHORTEN IT IF I HAVE MORE THAN 20 LIST.. FOR THE FORMULA ABOVE THAT IS FOR MY FOREMAN THEY ARE "P" BECAUSE THEY ARE PRESENT I WANT TO COUNT THE PRESENT NO NEED FOR THE ABSENTS BUT MY HELPER IS 20 AND MORE I WANT TO TRY AND SHORTEN IT . I ALSO HAVE A FORMULA FOR MY 11 CARPENTERS
=SUM(COUNTIFS(D30,"*P*"),(COUNTIFS(D35,"*P*")),(COUNTIFS(D39,"*P*")),(COUNTIFS(D40,"*P*")),(COUNTIFS(D67,"*P*")),(COUNTIFS(D68,"*P*")),(COUNTIFS(D70,"*P*")),(COUNTIFS(D75,"*P*")),(COUNTIFS(D76,"*P*")),(COUNTIFS(D85,"*P*")),(COUNTIFS(D106,"*P*")))
IF YOU CAN HELP ME THAT WOULD BE A BIG HELP
TIA
ANW I ALREADY GOT THE ANSWER TYVM <3
=COUNTIFS(D21:D118,"P",C21:C118,"CARPENTER")
Hello!
If your data is written in separate cells, you need to specify each cell separately. To reduce the formulas, you need to change the data table.
Thank you ! I did it by using countifs with multiple criteria
I did it by reading your article word by word haha thank you !
Hello there! First I'm working on a spreadsheet where there are sometimes multiple rows for a single machine, and sometimes there is only one, I'm trying to get a function that works in a similar way to the countifs, but instead of resulting the number of cells it gives me the "name" or "address" of the cell, Example: =countifs(J61423:J61463;J61460; K61423:K61463;K61460) -> It results "2" but what I want is "(J61459; J61460)" which are the cells that I need.
For extra clarity: I'm asking if it is possible to do this by any function or mean, not necessarily using countifs, this function would simply work in a similar way to it. Is there something like that that I can use?
Hello!
You can get the cell address using the ADDRESS function. You can find the examples and detailed instructions here.
Can you please help? I am working from two tables. First table has a list of student group codes and the course department codes. The second table has a list of all the student names/their student group codes/course/department/course department codes, all in different columns. From table 2, I'm trying to do a count of total students in each student group codes in table 1 that shows up in each course department codes. Same student group code can belong to different dept codes.
Raw data is in Table 2 in different columns. Example of columns header below
Table 1
Stu_Grp Dept Dept Codes Dept
106100 2 Org_2200 Business
107100 2 Org_2201 Management
105100 4 Org_2400 Law
102100 6 Org_2600 Marketing
102200 8 Org_2800 Finance
104200 4 Org_2400 Law
104300 2 Org_2200 Business
104400 2 Org_2201 Management
105100 7 Org_2700 Accounting
Table 2
Student NameStud_Grp Dept 2 Codes Dept Description Dept 4 Codes Description Dept 6 Codes Descript
Hello!
Unfortunately, without seeing your data in Table 2, it is difficult to give you any advice. I think you need to use the COUNTIFS function. If you have specific questions about the formula, I will try to answer them.
Hello! I'm in need of a bit of help please :)
In my worksheet, I have a drop down list in row G10:CK10 for "Completed", "Ongoing", "Cancelled".
In the column G17:Y50, I have names of speakers, some of which are repeating names.
I would like to count the number of "Completed" events for each speaker. I have tried the COUNTIFS function, but unfortunately using the formula below it keeps returning as a VALUE error:
=COUNTIFs(G10:CK10, "Complete", G17:Y50, "Linda").
I would if you would be able to help?
Many thanks!
Hello!
You have different range sizes for the criterion and for the count, so the COUNTIFS function cannot be used.
If I got you right, the formula below will help you with your task:
=SUM(($B$10:$J$10="Complete")*($B17:$J50="Linda"))
I hope it’ll be helpful.
This is absolutely perfect! Thank you very much for your help!!
hello,
I need a little help :)
I have a excel file with some documents with bill ID and Dealer ID. I want to count number of dealer who has sold each product. Can you help me find a formula as detail below:
Date dealerID Bill Number Product ID Amount
23-03-21 68345307 21016501146004 5 1500
23-03-21 68345307 21016501146004 6 500
23-03-21 68345307 21016501146004 7 1000
23-03-21 68345307 21016501146004 8 1000
23-03-21 68345307 21016501146004 9 1000
24-03-21 963949731 21016601151003 0 100
24-03-21 963949731 21016601151003 2 100
24-03-21 963949731 21016601151003 5 100
24-03-21 963949731 21016601151003 7 100
24-03-21 963949731 21016601151003 9 100
25-03-21 99336636 21016701145002 0 2000
Product ID Total Amount No. Bill No. Dealer
0 2100 2 ?
1 0 0 ?
2 100 1 ?
3 0 0 ?
4 0 0 ?
5 1600 2 ?
6 500 1 ?
7 1100 2 ?
8 1000 1 ?
9 1100 2 ?
Hello!
I recommend using the information in this article: Count unique values with criteria.
The formula is something like this:
=IFERROR(ROWS(UNIQUE(FILTER(B2:B12,D2:D12=H2))), 0)
H2 -- Product ID
B2:B12 -- Dealer ID
Hi,
please see below, i have 2 columns, first one are the jobs working on, second column is phases in the job, how i can sum, count each phase for this job repeating in the column? different jobs may have same phases, so need phase column be dependant on job column... please help
job phase
3156 112
3156 541
3137 541
3156 99020
3156 99020
3137 541
3137 541
3156 99020
wip wip
Hi!
I do not quite understand what you want to calculate. How to calculate the number of phases for each job is described in this article above. If you need to calculate an amount with multiple conditions, use the SUMIFS function.
Hello, I've searched multiple threads and cannot find a combination that might help my scenario. I'm using COUNTIFS successfully. Ex. =COUNTIFS(A:A,"employee",C:C,"product") But how can I add a third criteria that counts ''repair order" only once if it is replicated? I think the correct term is 'Distinct'.
Here is a small sample where the result = 6
However Repair Order 206189150 is duplicated so the desired result is = 5
employee repair order product
318 206188973 ABLAST
318 206189055 ABLAST
318 206189150 ABLAST
318 206189150 ABLAST
318 206189160 ABLAST
318 206189188 ABLAST
I hope this is clear and I'm sorry about formatting.
Thanks in advance! - Craig
Hello!
I recommend reading this guides: Count unique rows in Excel and How to count unique values in Excel with criteria. Use a formula like this:
=ROWS(UNIQUE(FILTER(A1:C6,A1:A6=318)))
I hope it’ll be helpful.
Hi there,
second day in a row, sorry about that.
Is there a way to search across multiple sheets (i know that is a VLOOKUP) but to return values from the search?
In this case I have data from various cities, (all sheets are the same layout) and i want to look up the Sector (coloum D) for say "Construction" and return the total cost across all sheets (column F)
Hello!
If the “Construction” value is written in different positions on each sheet, then I recommend using the Consolidate Sheets tool.
You can use the SUMIF function for each sheet and then summarize the results.
Hi there, Im trying to return a result if one 'phrase' is met, and then one do have a difference result if one of 5 others.
I had a try but seem to have failed miserably with the second criteria/calculation
please help
IF(SUM(COUNTIF(E3,{"*In work as a result of LVP*"})),B3,""),(SUM(COUNTIF(E3,{"*In work through other means*","*Awaiting a start date*", "*Out of work*", "*Health Condition*", "*Other*"})),(B3-(B3*2)),"")
Hi,
if I understood the problem correctly, try this formula:
=IF(SUM(--ISNUMBER(SEARCH("In work as a result of LVP",E3))),B3, IF(SUM(--ISNUMBER(SEARCH({"In work through other means","Awaiting a start date", "Out of work","Health Condition","Other"},E3))), (B3-(B3*2)),""))
Hi there,, Thankyou SSOOO much, thats amazing
I am trying to use the Countifs to count the number of cells that fall within a specific date range and are between two values.
Example: If I want to know how many cells are between 40 and 60 (Cell E) and between the dates of 3/1/21 and 3/31/21 (Column A)
Formula I have been trying to get to work is
=COUNTIFS($A$4:$A$1000000, ">="&G5, $A$4:$A$1000000, "<="&H5,$E$4:$E$1000000, "&=40")
however, its returning over 27K as the count. I know I only have 1365 cells in this date range.
Any help would be appreciate.
Thanks
Hi!
Please use the following formula:
=COUNTIFS($A$4:$A$1000000, “>=”&G5, $A$4:$A$1000000, "<="&H5,$E$4:$E$1000000, ">="&40,$E$4:$E$1000000, "<="&60)
I have a need for a 3rd criteria. Using your example I would want it to countif Susan has a project, with a start date, but no end date. The example I am looking at is under "How to use COUNTIFS with wildcard characters".
Hi Bryan,
Simply, use 3 range/criteria pairs:
=COUNTIFS(B2:B10, "susan", C2:C10, "<>"&"", D2:D10,"")
if having a range of cells (D3:M37) where certain cells contain text: Yes, No, Maybe, how to return a result in another cell as the Yes or No or maybe correspond to a name in column B, for example, cell F3 has a NO the result (wanted to appear in P4) should be B3 name.
Hope this make sense
Thank you.
Hi, I've been stuck at this for hours.
I'm supposed to Input either a "Yes" or "No" or blank for 12 columns in a single row.
However I need a formula to Prioritize "NO" over the other answers.
But:
1. if there isn't "NO", but there's "YES" and blanks, then the cell should reflect "YES"
2. If there isn't "NO" or "YES", the cell should be blank
I tried Match and CountIF formula but i can't get the result i need.
Any help would be greatly appreciated!
Could you please help me
If in One Column I have Y 2,Y 1,Y 6, N3 is there a way that i can sum the Numbers only
Hello!
If I understand your task correctly, the following formula should work for you:
=SUM((IF(ISNUMBER(--MID(CONCATENATE(A1,A2,A3,A4),ROW($1:$100),1)),--MID(CONCATENATE(A1,A2,A3,A4),ROW($1:$100),1),"")))
or
=SUM((IF(ISNUMBER(--MID(CONCAT(A1:A4),ROW($1:$100),1)),--MID(CONCAT(A1:A4),ROW($1:$100),1),"")))
I hope it’ll be helpful.
Hi,
I've been spending days on getting the formula right, but still uncertain how to get the right info.
I've got two columns with different dates: Start Date (A) & Resignation Date (B).
Currently using =COUNTIFS(A3:A143, "=",B3:B143,"=>1-90" but doesn't seem to give the right answer.
I would like to calculate how many people are resigning within 3 months, between 3-6 months, between 6-12 months. Any idea how the formula will look like?
Thanks.
Hello!
To calculate how many people are resigning within 90 days, use the formula
=SUMPRODUCT(((B1:B15-A1:A15)<90)*((B1:B15-A1:A15)>0))
I hope it’ll be helpful.
Hi Alexander,
Thank you so much, this is definitely working!! :)
Regards,
Cindy
=SUM(COUNTIFS('SACE stg 2 2017'!F:F,OR('SACE stg 2 2017'!$F$1253,'SACE stg 2 2017'!$F$1256,'SACE stg 2 2017'!$F$1478,'SACE stg 2 2017'!$F$1484,'SACE stg 2 2017'!$F$1490,'SACE stg 2 2017'!$F$1495,'SACE stg 2 2017'!$F$1502),'SACE stg 2 2017'!G:G,'Lingustics subject'!A3), COUNTIFS('SACE stg 2 2017'!F:F,OR('SACE stg 2 2017'!$F$1253,'SACE stg 2 2017'!$F$1256,'SACE stg 2 2017'!$F$1478,'SACE stg 2 2017'!$F$1484,'SACE stg 2 2017'!$F$1490,'SACE stg 2 2017'!$F$1495,'SACE stg 2 2017'!$F$1502),'SACE stg 2 2017'!G:G,'SACE stg 2 2017'!$G$55))
This is my formula, I used the or statement to select a wide range of data that could include in a range, but it seems to didn't work. How can I fix this?
Hi!
It is very difficult to understand a formula that contains unique references to your workbook worksheets. Hence, I cannot check its work, sorry.
Hi,
I have following large set of data.
Catalogue Lot Count
HBI66545 1320000531 2
HBI66545 1320000531 2
HBI66545 1320000531 2
HBI66545 1319000101 2
HBI66545 1320000531 2
HBI66545 1320000531 2
HBI66545 1319000101 2
I have used this formula to count.
=SUM(B2=$B$2:$B$18,(1/COUNTIFS($A$2:$A$18,$A$2:$A$18,$B$2:$B$18,$B$2:$B$18,$C$2:$C$18,$C$2:$C$18)),0)
But my problem is I would need sum of Catalogue and Lot which should be 5 for 1320000531 and 2 for 1319000101. Could you help me solving this?
Thanks heaps
Hi!
Your explanations are not very clear. I am assuming that you want to count the number of occurrences of a value. For example 1320000531.
A simple COUNTIF formula is suitable for this, as described in this article.
If this is not what you wanted, please describe the problem in more detail.