by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
i am using formula which is below mentioned but the result is for "yes" ok but for "#n/a" result is same #n/a but i need to show the result is "NO" which is base on formula.
example: =IF(I1="#N/A","NO","YES")
regards,
ABAS
Hello! I need a formula to display a scholarship.
These are the conditions:
if final_grade < 8 print “No receive”;
• if 8 ≤ final_grade < 9 print 300 ;
• if 9 ≤ final_grade < 9,5 print 400 ;
• if final_grade ≥ 9,5 print 600 .
of course, I have a column where final grades are placed.
I wish I was clear with my commnet... I can't wait for an answer!
Thank you, All the best!
my difficulty is to use more conditions in "IF" syntax... I don't know how to do that...
I tried to use more '' IF '' in Formula Bar ( like in Progamming for example - elseif ... ... ...) but it doesn't work and I don't think it's possible something like that.
C6=GRADE
=IF(C6<8,"NO RECEIVE", IF(C6<9, 300,IF(C6<9.5, 400, 600)))
Hello!
Please re-check the Nested IFs example since it covers your task.
If cell C2 is greater than 50000, then give 20% discount, if less than 50000 give nil discount. Please assist me with the correct IF Function
Hi,
I hope you have studied the recommendations in the tutorial above. It contains answers to your question.
Please have a look at this article — How to use IF function in Excel
Thank you for this page. I used to work in an office and now use Excel to calculate my marks as a teacher but it's been a while since I've used the IF formula. So grateful to have found your summary!
Hello, Can you please help me with the below formula , I want to set an Active, Non Active status relating an end date of a contract based on today date.
Thank you,
Hello,
Column A has names of people ( repititions are also present )
Column B has multiple codes names with which they are called
example -
column A(names) column B( code name) Column (pocketmoney) --------- sheet 1
James Jamie ?
James Jam ?
nick Nicky ?
john jonny ?
derek D ?
thomas Tom ?
derek D dog ?
thomas TIM ?
a different sheet is same excel has data as below -- sheet 2
Column A(fathers name) column B(mothers name) Column C ( pocket money ) Column D(code nam)
ABC AAA 1$ Jamie
XYZ BBB 2$ Jam
XXX CCC 3 Nicky
YYY DDD 4 jonny
ZZZ EEE 5 D
ZXZ FFF 6 TOM
ZZY GGG 7 D Doog
AZZ HHH 8 TIM
My condition is as below
If same names have multiple code names in sheet 1, then allocate the pocket money for children( column A in sheet ) based on their codes names in Column D of sheet 2
example -
James has 2 code names ( jamie and jam) , so the one with code name jam should get 2 $ as pocket money and jamie should get one
i need a formula to write in column C of sheet 1 to retrieve the pocket money of the children having same name but different nick name
Hi,
Here is the article that may be helpful to you: Vlookup multiple sheets with INDIRECT.
I hope I answered your question. If something is still unclear, please feel free to ask.
I am creating a spreadsheet for a darts score card. I want to display "winner" in a cell when a player's score reaches zero and Loser in another cell at the same time for the opposing player. I also want to display Game on in both cells whilst the game is in progress, i.e. when both players score is greater than zero,
I have managed to display winner when either player reaches zero, and Game on when they have a score greater than zero, but I am struggling to achieve displaying loser in the opposing cell which will still display Game on.
Hi,
Sorry, it's not quite clear what you are trying to achieve. Could you please describe it in more detail? What result do you want to get? Give an example of the source data and the expected result.
I required a formula
Name factory Name invoice type Qty
A Rawal Plant GST 478
B AJK Plant without GST 325
C Rawal Plant without GST 843
D AJK Plant GST 275
E AJK Plant GST 564
F Rawal Plant without GST 528
G AJK Plant without GST 362
H AJK Plant GST 358
Required data separately Qty
AJK Plant GST ?
AJK Plant without GST ?
Rawal Plant GST ?
Rawal Plant without GST ?
Hi!
I can't guess what you wanted to calculate - quantity or amount. Therefore, I recommend the manual for the COUNTIF function and the instruction for the SUMIF function.
I have to measure the height of the balls in a a ball mill to determine how many balls to feed example
Say I measure 100 cm from the height in the ball mill , there is another table that I have that gives ranges that 95 cm to 100 cm you add 1 kg of balls into the mill ,
My question is how do I add my table that gives the ranges so that when I do the measurements and put them into my excel sheet it automatically looks at the ranges and automatically tells me add 1kg or 2kg etc... not sure if you get me but if you do I just need a formula to use
Hello!
I guess you can use the VLOOKUP function with an approximate match for searching. If you ask a more specific question, I will try to help.
I know how to reference cells on other sheets, but I'd trying to point to a cell on another sheet IF the date at the beginning matches the date I input.
For example: I have dates running down the A column on Sheet1, and total sales running down the B column also on Sheet1.
On Sheet2, I'd like to enter a date into A1 and, on A2, I'd like it to tell me the total for that day, as already listed on Sheet1.
---
Sheet1:
Dates:
A1 - 01/04/21
A2 - 02/04/21
A3 - 03/04/21
etc.
Total sales:
B1 - 7
B2 - 4
B3 - 8
etc.
---
Sheet 1:
B:B - I can input the total sales for the day in A:A
Sheet 2:
A1 - I can input any date.
A2 - show me the total sales for that date.
---
I've tried using =IF on Sheet2 and manually nesting formulas for each cell in each row I want to reference on Sheet1, instance by instance.
Eventually, I'd end up nesting over 100 formulas in a single cell on Sheet2.
Is there a way to do this more generally?
Hello!
If I understood the problem correctly, the SUMIF function can be used in cell A2. You can learn more about SUMIF in Excel in this article on our blog.
I hope my advice will help you solve your task.
Hi Alexander,
That's exactly what I needed. Perfect! Thanks for that :)
Hi
I hope you can help.
I am looking to automate a cash flow forecast using figures from a separate 'Budget' tab, so that payments are listed on the specific day that they are due.
I need to cater for various different suppliers, some of which are paid at the end of the month and others at various days during the month.
I have a separate column which displays the payment due date, which will be listed as '31' for end of month (to help identify those that need adjusting for shorter months), and the specific day of month for all others.
In short, I need the budget figure 'Budget K16' to only show on the specific day confirmed on each line ('B24') for that supplier, and if not due, to show as zero/empty.
Budget K16 = Payment amount from other tab
B24 = Day of month that payment is due
D3 = Date
I have come up with the following formula to ensure that the payments are displayed on the day that they are due to be paid, but the IF statement is not working.
=IF(AND(OR(B24="31"), AND(D3=EOMONTH),'Budget '!$K$16,0),OR(DAY(D3)=$B$24,'Budget '!$K$16,0)
Are there any obvious errors with this? Any help would be much appreciated.
Kind regards
Dave
Hello!
It is very difficult to understand a formula that contains unique references to your workbook worksheets. Correct me if I’m wrong, but I believe the formula below will help:
=IF(OR(AND(B24=31, D3=EOMONTH(MONTH(D3),0)),DAY(D3)=$B$24),$K$16,0)
Use external links to other sheets in your workbook. I cannot do this.
I have to use single cell as a condition for the whole column.. How can i use it?
For example in the below formula i have to use cell Formula!A2 for all the cells in the column W in the workings spreadsheet.
=IF(Workings!W2=Formula!A2,CONCATENATE("V2",".",A3),CONCATENATE("I2",".",A3))
Hello!
If I understood the problem correctly, you need to use an absolute reference. I recommend reading this guide: Relative and absolute cell reference.
I hope I answered your question. If you have any other questions, please don’t hesitate to ask.
Hello,
Needing some help with a formula that will produce my values that might have a letter at the end of it. IE.
=IFERROR(IF(OR(VALUE(B90)7000),"",VALUE(B90)),"") this works perfectly fine when I am doing only numbers like 1000 or 4000, but when I have a 3429G, this formula will obviously leave my cell blank. I need to get my cells that might have inventory letters and numbers together to post in that cell. Is there a formula to help identify if there is text within numbers?
Sorry it messed the formula up for some reason. Here is my current formula:
=IFERROR(IF(OR(VALUE(B86)7000),"",VALUE(B86)),"")
Hi,
If there are no letters in a cell, it can be converted to a number. If this is not possible, then there are letters in the cell.
For example:
=IF(ISNUMBER(--(B1)),"Number","Text")
I hope my advice will help you solve your task.
I'm looking to do a mail merge from an excel sheet to a word document/contract. I need a formula that will basically say any time you see "One (1)" in the document then "First (1st)" will appear throughout where needed. If "Two (2)" is written, then "Second (2nd)" would appear when needed. I would like to have this up to "Ten (10)" if possible.
Any ideas for a formula?
However I need to add EQ07 in to the above formula where as the condition is different
IF(A5="EQ07",IF(AF<=70,"70")
I need to have only one formula that reads value of Column A and accordingly reviews the condition and provides result in column B
Hi,
Based on your description, it is hard to completely understand your task. However, I’ll try to guess and offer you the following formula:
=IF(A5="EQ07",IF(AF<=70,70,""),"")
Please have a look at this article — Nested IF in Excel – formula with multiple conditions
Good Day! Need assist!
I have a formula: =IF(I2>64,IF(J2<=$O$20,TRUE),IF(I2$O$20,TRUE),IF(I2>64,IF(J2>$O$20,FALSE),IF(I2<64,IF(J2<=$O$20,FALSE)))))
O20 is a particular criteria near the table that I am changing.
Currently I am receiving everything correctly, where True is that my system results (column J) predicted the results from column I and False appears when the system provided a wrong result. However, there is an exception that I need to add IF(I2<64,IF(J2<=$O$20,FALSE) I want to see in this case in the cell "EXCEP"
Please, comment if I do not described the question correctly?
Hello!
Try the following formula:
=IF(I2>64,IF(J2<=$O$20,TRUE,
IF(I2<$O$20,TRUE,
IF(I2>64,IF(J2>$O$20,FALSE,
IF(I2<64,IF(J2<=$O$20,FALSE)))))),IF(J2<=$O$20,FALSE))
I'm not sure if this will work. There is already a condition IF(I2<64 in your formula.
I can’t check the formula, because I don’t know the conditions and I don’t have the source data.
HELLO i need help please.
i need a formula that says
if in a cell there is the word- red then return a 3 if it says blue then return a 2 and if yellow then return a 1
Hello!
If I understand your task correctly, the following formula should work for you:
=IF(ISNUMBER(SEARCH("red",B1,1)),3, IF(ISNUMBER(SEARCH("blue",B1,1)),2, IF(ISNUMBER(SEARCH("yellow",B1,1)),1,"")))
You can learn more about SEARCH function in Excel in this article on our blog.
im looking for a formula for 2 pages to look up if the account number is the same it would add up the totals in the totals column for that account number and give me one total Can you help please.
Please share if its says YES than add no value anf if it says NO than add value formula in excel
AS EXAMPLE.
A1 A2 A3
YES 500 FORMULA PLEASE
NO 100
Hello to all,
I really need your help about this formula. I've tried everything I know about excel...
When I use this formula to check the field A30 (could be a date OR text Always On):
=IF(OR(A30="Always On";A30>=TODAY());"ACTIVE";"NOT ACTIVE")
If I put a date in A30, the result is correct, ACTIVE if higher or NOT ACTIVE if lower.
But with any text in A30, it gives me always ACTIVE, instead of only recognizing Always On.
I have tested the same formula but choosing different fields (A30 and B30):
=IF(OR(A30="Always On";B30>=TODAY());"ACTIVE";"NOT ACTIVE")
And in this case, it recognize either the date AND the correct or wrong text.
Do you know why it is happening when it is the same field?
Thank you for your help!
Hello!
Add a condition to the formula: if the date is checked, then A30 must be a number.
=IF(OR(A30="Always On",AND(ISNUMBER(A30),A30>=TODAY())), "ACTIVE","NOT ACTIVE")
I hope it’ll be helpful.