Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4538 comments

  1. I have a table sheet (CMT) with formula. it was created to monitor patient clinic attendant. I want to create other sheets that will extract data from my original table sheet (CMT). For example, I want to have a sheet that will show list of patient due for clinic appointment for the present month base on the table formatting.
    What excel techniques will I use to create such automated sheets from my table sheet?

  2. (+/-) 6 - 10% (+/-) 1 - 5% 100%
    1,000 1,500 2,000
    how to create formula that should result into this
    90% 1,000.00
    91% 1,000.00
    92% 1,000.00
    93% 1,000.00
    94% 1,000.00
    95% 1,500.00
    96% 1,500.00
    97% 1,500.00
    98% 1,500.00
    99% 1,500.00
    100% 2,000.00
    101% 1,500.00
    102% 1,500.00
    103% 1,500.00
    104% 1,500.00
    105% 1,500.00
    106% 1,000.00
    107% 1,000.00
    108% 1,000.00
    109% 1,000.00
    110% 1,000.00

  3. Hi,
    could some one help me to create a formula - if my loss is less than 2%, 100 marks, if my loss is between 2.1 to 2.5, 80 marks, if my loss is more than 2.4 - 0 marks

  4. hello, 1st I'd like to say I found this site very interesting; so great that you're willing to help !

    here's my question.. I have 2 lists in a column, for example, 8,6,2,-2,-4 and the second list 5,3,-2,-4,-6. now if I multiply by rows I get 40,18,-4,8,24. The issue here is that the list a ranking of points in game for 5 people. based on the 3rd column, the dude with -4 and -6 is ranked 2nd while he's actually 5th. one way to get around this is to multiply by (-1) if both values are negative. I wanted to know if there is a IF statement I can use such that (if a2<0 and b2<0 then multiply by (-1), else just multiply as usual) . I'm aware that another way to get around it is to just add the values then both negative values would remain negative; I just wanted to know if I could multiply by (-1) . that's it ! thanks for reading this. hope to hear from you this week.

  5. Thank you!!!

  6. Hello, i want to make a formula that shows me a number of 13 rows based on two criteria. One of them is
    " =IF(M3="monofazat",(R10) " and i want to put that 13 rows in " R10 " place. In the same row i want to make another criteria that sound like this " =IF(M3="trifazat",(T10) "and also shows e another 13 rows. When i write in "M3" this texts ( "monofazat" or "trifazat") i want that rows to appear in the one i write the formula. I want to make some ofertation table, to be more simple to make an offer to a client. It's possible? Thanks, i m waiting for an answer!! Have a nice day!

    • Hi!
      Based on your description, it is hard to completely understand your task. However, I’ll try to guess and offer you the following formula:

      =IF(M3="monofazat",A2:A15,"")

      If this is not what you wanted, explain in more detail, write an example of the result.

  7. There will be a given data of a person with their Height, Weight and Mid upper arm circumferance , from that we have to derive whether the child is Severe Accute Malnutrition or Moderate Accute Malnutrition or Normal or Obese. What will be the formula in Excel . Length (cm) "SAM
    < –3""MAM ≥ –3 to +2 to ≤ +3" "Obesity> +3"
    Weight (kg)
    45 0–1.8 0–1.9 1.9 2.0–3.0 > 3.3
    46 0-1.9 2.0–2.1 2.2–3.1 3.2–3.5 > 3.5
    47 0–2.0 2.1–2.2 2.3–3.3 3.4–3.7 > 3.7
    48 0–2.2 2.3–2.4 2.5–3.6 3.7–3.9 > 3.9
    49 0–2.3 2.4–2.5 2.6–3.8 3.9–4.2 > 4.2

  8. I need a formula that can look at value in B column (there will be up to 10 different values in this column)
    and return a different result in the next cell of column C IE: cell b1 = text then c1 = text2

  9. Hi There!
    Looking for some help.

    I have a scoring card and need to calculate points on a ranking scale. What would be the correct formula for the below.

    Score is 20 or less receive top points, if score is higher than 20 subtract point. (-2)

    =IF(D920,$F$34,(D9*F$34)/20-2))
    OR
    =IF((D820,$F$34,(D8*F$34)/20),-2))

    Thanks

    • Hi!
      Unfortunately, without seeing your data it is impossible to give you an exact formula. Your conditions are not entirely clear to me. But you can do this if you carefully study the instructions in this article above.

      • Hello,

        We need to check value of two column and IF BOTH ARE POSITIVE "LB",if 1st is negative and 2nd is positive "SB",if both are negatie "LU" else "SC")
        1st 2nd
        -1.62% 169.90% LB
        2.01% 44.29% SB
        -0.78% 15.46% SB
        -0.74% 7.80% SB
        -0.10% 4.16% LB
        1.95% 2.91% SB
        -0.19% -1.32% SB
        0.89% 1.92% LB
        3.11% 1.33% SC
        -1.47% -7.96% SC
        2.25% 3.83% SC
        -0.85% -2.97% SB
        0.41% -3.17% SC
        0.05% 0.42% SC
        -0.07% -3.88% LU
        -0.61% -3.52% SB
        0.49% -2.44% SC
        -0.95% -0.84% LU
        -2.37% -5.69% SC

        Please help me with correct formula.

  10. I want to put the "statements in column 2" when I select "items in column 1" from menu bar in another sheet.

    Column 1 Column 2
    item1 sample for statement1
    item2 sample for statement2

    I tried pivot table, but it provides statement upto some extent, I need to display the whole statement in column 2, no matter how bigger it is. Please help!

  11. I had read all the examples, and maybe I miss it but I can't figure it out a formula:

    If the value of cell A1 is equal or more than 10% the amount will be $500.00 but if the same cell is less than $500.00 it will be 10% less. Can you please help me? I do appreciated

  12. Hi,
    I have a spreadsheet with a Table tab and a Data tab. In the Table I have a persons name and then columns for each different inspections that are completed - I'm trying to work out whether a VLookup or a some sort of IF or SUMIFS variation can be used to search the information in the 'Data' tab. Colum C in Data is the names and D is the type of inspection. The Data is C3 : C20 (names) and D3 : D20 Inspection type (example 'Assurance - Task Inspection') I need the table to have = QTY of John Smith's Task Inspections. Ideally I would like to include in the formula 'name' and 'inspection type' as the report evolves and we include more people or inspections all that would need to be changed is the formula 'name' reference or 'inspection type' reference.
    Note: The data tab will be copied from a system report and pasted into those rows everytime

      • Thanks Andrew,
        I managed to work out a SUM and COUNTIF combination and trial and error the formulas until it worked out.

  13. Thank you very much guys, this article was very helpful in getting me to complete an urgent caluclation.

    well explained and simple.

    Many thanks

  14. Hello ,

    Could you please help me on the below formula? I'm trying to define the below rule:
    The formula that I have defined is this =IF(K2>=I2,"Achieved",IF(K2<I2,"Not Achieved"))
    but I need to add another condition so if the method of meeting colum2 is Phone Call whatever value it might have not to be calculated as Achieved.

    2 Meeting 1 Not Achieved
    1 Meeting 0 Not Achieved
    6 Meeting 6 Achieved
    6 Meeting 6 Achieved
    6 Meeting 2 Not Achieved
    6 Meeting Not Achieved
    1 Meeting Not Achieved
    0 Phone Call Achieved

    • Hello!
      If I understood correctly, add the condition to the formula

      =IF(J2="Phone Call","Achieved",IF(K2>=I2,"Achieved",IF(K2<I2,"Not Achieved")))

  15. Hi, i have been trying very hard to display the length of service for some vouchers. Appreciate your help!

    Category > = 2 Years < 2 Years
    Manager 70.00 50.00
    MT & ASM 50.00 40.00
    FT SA 40.00 30.00
    PT SA 30.00 20.00

    and it depends on the category and less than 2 years or more than 2 years.

  16. Hello I need a formula that can display multiple argument
    For example let say the display cell is C1 and what to be displayed in it is in relationship with other two cell let say A1 and B1 such that if A1 is IP and and B1 is 1.0 then C1 is 0.036 but A1 has 9 different possible conditions while B1 has 8 different possible conditions.

    • Hello!
      This information is not enough to write a formula. However, you will be able to describe all the conditions in the formula if you carefully read the recommendations in the article above.

  17. Hello,
    I'm trying to come up with a formula that will give me the same return as the following, but include more room numbers and more sections of the facility:
    for example this formula in column A returns "North" or blank "=IF(AND(B14>209,B14<227),"North","")"

    What I would like is to have the following:

    If the value in Column B = between 202-208, and 232, Column A = North East
    If the value in Column B = between 210-226, Column A = North
    If the value in Column B = between 234-242, and 258-274, Column A = East
    If the value in Column B = between 244-256, Column A = West
    If the value in Column B = between 280-294, Column A = South

    I don't need it to return blank.

    I thank you ever so much for any help you can offer!

  18. If value of C2 (in excel cell) is 210000. Take value greater than 150000 but less than 200000 in C5 (in excel cell) and if value of C2 is equal to 150000 or less than 150000 take as zero.
    Kindly enlighten with formula.

  19. Hello guys
    I have a problem that i cant solve for days. Can't find an answer on web. So here is what i wanna do;
    There are almost 250 pieces of products i have and all have names and codes
    (e.g name:15cm silver furn. leg and code: ob0001)
    I want to enter the name of one products in a random cell and excel will automatically enters the code in the next cell.

    Its all but i cannot make it work. im about to smash my computer (:

    Is there a solution? Please help me!
    thanks in advance

      • Thank you very much.. Im gonna try this function.

  20. I'm looking for a function that will change the end date based on the number of days delayed. However, it's not as simple as merely adding the number of days to the start date. There are two stakeholders involved such that if stakeholder "A" has a delay of 30 days, stakeholder "B" or the result is only impacted by 12 days. Would you please suggest a function for this and tell me how to use it? Thank you.

    • Hello!
      I am not sure I fully understand what you mean. Explain in more detail, give an example of the source data and the desired result.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)