Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4538 comments

  1. Can I use this formula for Attendance usage? I am trying to locate a specific word (or) in time in a cell (in column A) and assign a value out time to that cell in column B. Here is my formula, but the error message says I have too many arguments entered. Please help!

    Need for three contain - Present, Absent & Leave, how to use the formula

    =IF(AND(A2="",B2=""),"","P",")

      • i need extra A (Absent) or L (Leave) add that formula???

        • Hi!
          For each of the values, you need to specify a condition. You didn't. See the examples in this article above for how the IF function works with multiple conditions.

  2. HELP! its true, if you don't use it, you'll lose it. I'm trying to say if J4-D4 is >9.5 then "Y" and if not then "N". It sounds simple but I'm so frustrated. Can anyone help me please?

  3. I'm trying to find the gender and housing status (Single or paired) in a list of animals, (this could be my data information: 7-01/001-002F or 7-001/001-002M or 7-01/001F or 7-01/001M).
    I've combined the Housing and gender in to one cell already, then I use the "IF" "OR" formulas below to find them but I would like to know if I can combine formula A with B in one cell (currently I use each formula in separate cells)
    Formula A =IF(OR(U:U="7-01/001-002F"),"1PF","1PM")
    Formula B =IF(OR(U:U="7-01/001F"),"1SF","1SM")

    • Hi!
      Your formulas A and B cannot be combined as they contradict each other.
      The value "7-01/001F" according to formula A returns ”1PM”, and according to formula B - ”1SF”.

  4. Please advise the formula to return the value, lets say if A1*A2 is higher than 100, return value as 100 and if A1*A2 is less than 50 return value as 50 if not A1*A2.

  5. Trying to find a formula for: IF Cell A1 = X show Cell B1, but IF Cell A1 > X show B3-(B2*A1)

  6. My question is that how I can use IF with "OR" "AND" to give me the result like:
    Admin dept "yes"
    HR dept. "No"
    Securityguard " under consideration"
    Or you can suggest another logical formulas..thanks

  7. I need to find an excel formula that will take a number in a cell (example "a1") and rounds up to the nearest hundredth. It's for product increases and the number has to be even. Like $3.28, not $3.27. If I have the number $3.333 I need it to round up to $3.34. Can this be done in Excel?

  8. Hi! I could have sworn I've been to this site before
    but after browsing through some of the posts I realized it's
    new to me. Nonetheless, I'm definitely happy I came across it and I'll be bookmarking it and checking back regularly!

  9. =IF((AND(I3="No",N3="Good IMU")),"Action - Feeds",""),IF((AND(I3="Yes",N3="Low IMU")),"Action - IMU")

    Can someone please help - I need 2 different return values based on 2 different and statements. help!! I can get one or the other, but I don't know how to combine into one formula!

    • Hello!
      You can learn more about nested IF and multiple conditions in a single formula in this article on our blog.

      =IF((AND(I3="No",N3="Good IMU")),"Action - Feeds",IF((AND(I3="Yes",N3="Low IMU")),"Action - IMU",""))

  10. Hi,
    I need some help, what I`m trying to achieve is based on 4 cells. the first being a salary amount and then the next two cells (1 x figure and 1 x %) with the forth being the grand total.

    So If I wanted to give an employee a salary increase, for example; rather than give £5k in the second cell, I just enter a % in the third cell. However I would like the total salary amount to calculate the total increase whether it be a £ or % increase.

    Hope the above makes sense

  11. Hi, is it possible to generate percentage on excel with multiple arguments based on the data populated each day?

  12. I need if formula with logic if A1 column is blank data pick from A2 column
    Thanks in advance for supporting

  13. hi, is it possible to put number 1 or 2 in c1 while i used this formula in the same cell =IF((C1)=1,"I",IF((C1)=2,"II",IF((C1)=3,"III","blank")))

    i just want to put number then its automatically change or convert to text which i want it, Help me pls

  14. How do I check if Column A has different values in Column B.

    E. G Apples in Column A has both fruit and veg in column B.

    Thanks

  15. I would like to create an IF statement saying in effect if a certain cell or range) is black then add it(or range) and if it is another color then deduct it.

  16. Hi there,

    I am looking to do an IF function to display a percentage. So if Cell A1 is less than 5,000 then its 8%, if its bewteween 5000 and 15000 its 10%, if its between 15000 - 40000, then its 15% and so on and so forth.

    How do I do this?

  17. HOW COULD I DO AN EQUATION THAT STATES "IF B6 IS BETWEEN 0 AND 10, THEN MULITPLY B6 BY .20,, IF B6 IS BETWEEN 10 AND 20, THEN MULTIPLY B6 BY .22,, IF B6 IS BETWEN 20 AND 30, THEN MULTIPLY B6 BY .24, ETC.....

  18. Hi,

    I am looking for an if, else function formula in excel that can identify who will "win", or "loss" in the sample situation below?
    Score
    Player #1 - 5
    Player #2 - 1
    Player #3 - 8

    In the result, Player #3 should be "win", and Player #1 and #2 should be "loss" . Is there a possible if, else formula for this? Thank you.

    • I'm trying this formula (where H is the column in excel) ,data in H3 is 5, H4 is 1, H5 is 8
      but the result is not correct , it resulted to win, where it should be loss.

      =IF(H3>H4,"win",IF(H3>H5,"win","loss"))

      Thank you, appreciate your reply.

  19. Hello,
    can you help me to write formula that if cell B6 is:
    between 1201 to 3200, write in cell B20 number 125
    between 3201 to 10000, write in cell B20 number 200
    between 10001 to 35000, write in cell B20 number 315
    between 35001 to 150000, write in cell B20 number 500

    Appreciate your help.
    thank you
    Milan

  20. A formula for if N13=** OR * SHOW 'Y' AS RETURN VALUE

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)