Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4538 comments

  1. Hi guys!

    I have a struggles to make the formula to check the schedules in the way that there can not be more than 6 working days in a row. The biggest problem is probably a format which is:

    06:00-14:30 09:00-17:30 sl. 15:30-24:00 15:30-24:00 15:30-24:00 sl.

    06:00-14:30 are the formats of the shifts and sl. are free days. How to make the formula to find the mistakes if there is more than 6 shifts in a row?

    Thank youu :)

    • Hello!
      The formula returns TRUE if there are 7 consecutive business days in the range of cells.

      =ISNUMBER(SEARCH("1111111",CONCAT((--(A1:Z1<>"sl.")))))

      The results of the comparison are combined into a string using the CONCAT function. The number 1 corresponds to the working day.

  2. IF A1 > B1 by 1-3 then score 3 in cell C1
    IF A1 > B1 by 4-6 then score 2 in cell C1
    IF A1 >B1 by 7-9 then score 1 in Cell C1

  3. Hello,

    I'm looking for TAT formula . there are 3 stages sales bucket ,credit bucket and disbursement bucket .

    i want cal TAT and if i change the status it should to go the previous bucket. from there it should again cal the TAT

    • Hello,
      I've looked through the blog and the posts and cannot find an answer, so I appreciate any help you can give.

      On my sheet, there is one column (A) that has one of 3 different categories- Urgent, Non-urgent, For awareness.

      A second column (C) contains the number of minutes that it took to respond to the above categories.

      SLA is 15 mins for Urgent, 30 mins for Non-urgent, and 45 mins for For Awareness.

      I am trying to calculate whether the response time meets the service level agreement.

      Here's the formula that I wrote, but it only works for the Urgent SLA evaluation:

      =IF(AND(A3="Urgent", C3<=15, AND(A3="Non-urgent", C3<=30), AND(A3="FYSA", C3<=45)), "YES", "NO")

      Would you please explain how I can correct this?

      Thank you.

  4. Hi all,

    I am struggling to create a formula that will only show the date increased by 28 days if the cell has a value

    so,

    G4 has 16/05/2022 + 28 days (=SUM($G4+28) showing H4 - 13/06/2022

    but if G5 is empty, the H4 should remain empty

  5. I tried the multiple if and it says too many arguments

  6. Hi, I would like to know how to use the IF statement in the below situation

    If value of Column A in Sheet 1 matches a value in Column A of Sheet 2 then print a statement ex "True".

    TIA.

    Ps: Anyother function than IF is also welcome.

  7. Hi I need help with a formula to see if this is possible.
    I want to have A1>5 it is Yes, if A1<5, then it is NO and if A1 id empty or blank then it should be left blank,

    I tried using : =IF(A1<5,"NO",OR IF(ISBLANK(A1),"BLANK", "")))
    But it returns with NO even when A1 cell is empty instead of returning as blank

    • =IF(ISBLANK(A5),"",IF(A5<5,"NO","YES"))

      • Sorry I used A5 instead of A1. The formula still holds true though. Just a note though, if the cell contains anything other than blank or 0-5 it will say "YES".
        If a cell contained "a" the result would be YES

  8. I am trying change the value of a cell based on another value depending on if it is a multiple of a specific number.

    So, I want C1 to change to "1" if G1 is a multiple of 8. And to "0" if G1 is not a multiple of 8

    Not sure if anybody has commented this before but I have spent hours trying to figure it out.

    • Hello!
      If the remainder of the division of numbers is zero, then the first number is a multiple of the second. You can determine the remainder of a division using the MOD function.
      Please try the following formula:

      =IF(MOD(G1,8)=0,1,0)

  9. Hi, I have a problem with the formulas I am using for an analysis.

    I have made a drop down, with 4 options:
    1.) 0-2
    2.) 3-6
    3.) 7-10
    4.) 11+

    I have also made a short table where this option got a value to calculate with:
    0-2 = 5
    3-6 = 10
    7-10= 15
    11+ = 20

    To calculate I use the formula: =LOOKUP(Cell of the option 1 to 4; {"0 to 2";"3 to 6";"7 to 10";"11+"};{5;10;15;20})

    This is going good untill i need the vallue of the last option 4 (11+), because it shows the value 5, and it has to be 20.

    What am I going wrong in the formula?
    Or do I need to use an IF formula?

    • Hello!
      The second argument to the LOOKUP function, [Lookup_vector], must be sorted in ascending order. Your formula doesn't have it. The fourth value is less than the third.
      You can learn more about LOOKUP syntax in Excel in this article on our blog.

  10. Hi I need some help with IF statements,

    Im using the following formula which so far works great but not sure if what I want to happen can actually work.
    =IF(Y17="A","Awesome job.",IF(Y17="B","great work")) ect. all the way through to F.

    however I want it to try and give more than one option to pick from as I am doing this for a lot of kids and what different options. For example if they get an A randomly pick out of 3 different comments for example "awesome job" or "Amazing" or "Fantastic work". can I have this many options? even a choice of 2 options would be great.

    Also I have the example comments written in example Cell C21-C24. Can I get it to pick and copy one of those 3 cells instead of typing out the whole text comment I want?

  11. Could you help me to write a formula for IF B2 is YES, then it should consider the data present in A2,if B2 is No, then it should be blank

      • No,I Could not find answer in the mentioned link. Kindly help me on the below
        Example:In A2 column document number has given, In B2 cell if document is closed then closed date has mentioned, If document is open then cell is blank, In C2 cell if document is in closed status (date updated)mentioned as YES if it’s open (B2 is blank) C2 shows as No.
        Now I need the formula for D2 cell, if C2 is yes then it should consider the date which is mentioned in B2, if C2 is no then D2 cell should be blank.

          • Perfect! It’s working thank you so much ☺️

  12. Hi,

    I'm looking at trying get a yes/ no answer for a column that has "yes" or "no" data entered.

    If the column is all "yes" the statement is true and the result should be "yes". Is there a way to do this?

    E.g.

    A1 Yes

    A2 Yes

    A3 Yes

    A4 Formula gives the answer "Yes"

    However, if A2 had "No", the formula in A4 would give the answer as "No"

    Any help would be appreciated as I have been researching for a few months on and off now.

    • Hello!
      I hope you have studied the recommendations in the tutorial above. It contains answers to your question.

      =IF(AND(A1="Yes",A2="Yes",A3="Yes"),"Yes","No")

  13. I need a formula that will do the following:

    =IF(F2*60%)/32)2, I want 3 for my answer, If >1 and < 3 I need 2 as my answer. thanks kindly

    • It dropped something from my question:
      =IF(F2*60%)/32) >2 I want 3, <2 I want 1 and 1 I want 2.

      • Hi!
        Please re-check the article above since it covers your case. However, your second and third conditions can be met at the same time. It's not allowed in the formula.

  14. the "," does not work! it has to be ";" to work

  15. Hi! Is it possible that I can have two values if my logical test is true?

    Example:
    If(A1>0, B1-A1 and at the same time C1-A1, "")

    I hope I explained it well. Thank you.

  16. Hi,
    Required to identify credit / debit ( contain with "-" after number that is credit, otherwise debit

    my data as below

    84.03
    0.05
    0.58-
    131,429.79
    209,489.24
    239,999.90
    145,599.21
    0.44
    0.43
    170,989.70
    4,666.29-
    0.98-
    0.39

  17. Hi

    A1=100
    A2=50
    =sum(A2-A1) WILL = -50
    How do I make it show 0

  18. Hi, can you please help me write an IF formula/statement that alerts users of a chart that the total nett profit after tax is less than 10% of the total sales?

  19. If I calculate 12 rolls of different yardings in one cell and i want to know the quantity of rolls in different cells. Then what formula should i apply?

  20. If my amount of 20001 more is 5%.

    Rate monthly GP
    3% 20000
    5% 20,001 - 40,000

    Margin* Cons Margin* %
    3,131.20 3,131.20 3%=IF(Cons Margin<20000,3%,5%)
    1,844.40 4,975.60 3%
    2,720.00 7,695.60 3%
    2,604.00 10,299.60 3%
    2,620.80 12,920.40 3%
    3,633.00 16,553.40 3%
    2,856.00 19,409.40 3%
    2,155.33 21,564.73 5%
    1,890.00 23,454.73 5%
    2,204.00 25,658.73 5%
    3,192.00 28,850.73 5%
    1,920.00 30,770.73 5%
    1,817.60 32,588.33 5%

    When 3% to 5% then 3% on 20001 but what happen here it is calculate 2,155.33 (21,564.73) on 5% this is not correct.

    So Can you please help me it how to calculate my Exact 20001 on 5%?
    I know it's really hard to explain but please let me if you have any suggestions.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)