Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4538 comments

  1. I want to see if the below formula is correct
    IF(J42="Station with 3 Teams (All 3 Team)",IF(OR(Y42>=100%,AE42>=100%,AK42>=100%),Inputs!$L$24,IF(J42="Station with 3 Teams (All 3 Team)",IF(AND(Y42>=100%,AE42>=100%,AK42>=100%),Inputs!$L$25,Inputs!$L$27))))

    • Hi!
      I don't know what data you are using and what result you want to get. I can't check the formula that contains unique references to your workbook worksheets, sorry.

  2. Hello,

    I'm looking to add criteria to the following COUNTIF formula. I use this formula [=(COUNTIF($A$2:[@ColumnA],[@ColumnA)=1)+0] to identify unique values. It returns a 1 the first time a unique value appears in the cell referenced and 0 every time that value is repeated. It is meant to assign a 1 or 0 to each row in a table. Where it says "ColumnA" the name of the column referenced appears. As you can see all references are to the same column and cell.

    I need to add criteria to this equation. Ideally the equation would recognize the cell in another column and consider it if it says "Yes", not consider it if it says "No." The final result would be an output of 1 if one cell says "yes" and another has a unique value. If the cell says "No" OR if the value is not unique, the equation would return a 0.

    Any idea on how to do this?

    Thank you!

  3. thank you so much!

  4. Hi,
    I am trying to do automated marking coming out of a MS Forms. I am trying to do a quiz answer that has multiple answers say "Red", "Blue", "Green"
    when recorded in a spreadsheet these answers can come out in any order is there an IF function that will ignore the order of the answers? at the moment I am writing a +IF for every combination ?

    Thank you

  5. I try to work below if function but it doesn't work, kindly help me

    =IF(OR((I50637=1),IF(AND(J50637<=249.99,K50637250,K50637<=5),"ON TIME"),IF(OR(I50637=3),IF(AND(J50637<=249.99,K50637250,K50637<=72),"ON TIME"),IF(OR(I50637=5),IF(AND(J50637<249.99,K50637<=12),"ON TIME",IF(AND(J50637<250,K50637<=24),"ON TIME","LATE"))))))))

    Priority 1 - less than 250 KM need to deliver within 2 days "ON TIME", more than 250 KM within 5 days "ON TIME" else "LATE"
    Priority 3 - less than 250 KM need to deliver 24 Hours "ON TIME", more than 250 KM need to deliver within 72 hours "ON TIME" else "LATE"
    Priority 5 - less than 250 need to deliver 12 Hours "ON TIME", more than 250 KM need to deliver 24 Hours "ON TIME" else "LATE".

    • Hello!
      If I understand your task correctly, the following formula should work for you:

      =IF(OR(AND(I1=1,J1 < 250,K1 < = 5*24), AND(I1=3,J1 < 250,K1 < =24),AND(I1=3,J1 > 250,K1 < =72),AND(I1=5,J1 < 250,K1 < =12),AND(I1=5,J1 > 250,K1 < =24)),"ON TIME","LATE")

      Combine conditions with the IF AND fotmula. Also, read all the necessary recommendations in the article above.

      • Thank You Alexander ?, It's working fine.

  6. Good evening,
    I need your help. Is there a formula for this statement in excel?
    The value of a cell is 15 less than the value cell of any other cells. If true, change to color of that cell.
    A1=10 B1=15 C1=20 D1=26
    The formula should return with cell A1 to highlight a different color, since A1 is the only one that is 15 less than any other cells (D1).
    Thanks in advanced

  7. Hello!

    Hoping someone may be able to assist - I am working towards calculating an amount to be paid up to a cap.

    This is what I have so far (and could possibly be using the incorrect type of formula), but this formula needs to show up to 23568 and no higher.... even if the calculation works out more. I am just unsure how to get this into the formula - each way I have tried to date has failed.

    IIF([Base_ANN]<={&SALARY_SUPER_CAP}, ([Base_ANN]*[Super_Contribution]/100), {&SALARY_SUPER_CAP}*[Super_Contribution]/100)

    Any help would be appreciated.

    • Hi!
      It is very difficult to understand a formula that contains unique references to your workbook worksheets. Hence, I cannot check its work, sorry.
      Give an example of the source data and the expected result. It’ll help me understand it better and find a solution for you.

  8. Hi I am trying to create an inventory sheet. I have three different lumber companies I'd like to track. I also have 22 different lumber types each from these different companies. Each company has their own price based on the lumber type. The formula I would like to create is one where I can enter the company name and the lumber type and it automatically picks up the price. I have already been able to do a simplistic version of this by setting only two logical tests and the true value but is it possible to create a formula that would encompass all these variations? Thank you in advance.

  9. If a1=$200.35 and b2=agree give me “paid in full”

  10. I'm trying to figure out how to create a formula that will review whether 3 of 4 conditions are present, and return a value of "Yes" or "No."

    Ex*. The presence of 3 of the following 4 criteria must be met: (*not actual clinical diagnostic info; just an idea of what I'm looking for)

    1. Persistent anxiety about topic: Yes (Yes or No will be derived from a Questions sheet, with an IF formula [to obtain information from multiple cells] or = formula)
    2. Persistent problems with sleep: No
    3. Distressing nightmares: No
    4. Lack of enjoyment in activities: Yes

    In this case, the formula would return "No," as the client doesn't meet at least 3 of the 4 criteria. But if 3 of the 4 were answered Yes, then it would return a "Yes."

    Not sure if I'm overthinking this as it's late, or if I'm just stuck here. Thanks!

      • OMGosh! You're a life and time saver!! Thank you! I was thinking it was going to take all kinds of nested IF formula's! LOL.

      • I may have thanked you too soon. I didn't mention in my example that the cells are not in a range. For example, there are cells (with further questioning to give a "yes" or "no" answer to the headings; i.e 1a, 1b, 1c, 2a, 2b, 3a...). Is there a way to do this without the range? I've tried a few different things, but it doesn't seem to be working.

          • The data that the formula needs to look through looks like this:

            i4
            i8
            i15
            i24

            There is other data in the cells in between that provide the answers of "Yes" or "No" in the cells listed above.

            So it would look something like this:

            i4 - 1. First set of criteria for diagnosis (at least 1 of the following must be endorsed).
            i5 - 1a. symptom
            i6 - 1b. symptom
            i7 - 1c. symptom
            i8 - 2. Second set of criteria for diagnosis (at least 4 of the following must be endorsed).
            i9 - 2a. symptom
            i10 - 2b. symptom
            i11 - 2c. symptom
            i12 - 2d. symptom
            i13 - 2e. symptom
            i14 - 2f. symptom
            i15 - 3. Third set of criteria for diagnosis (at least 2 of the following must be endorsed).
            i16 - 3a. symptom
            i17 - 3b. symptom
            i18 - 3c. symptom
            i19 - 3d. symptom
            i20 - 3da. symptom
            i21 - 3db. symptom
            i22 - 3dc. symptom
            i23 - 3e. symptom
            i24 - 4. Fourth set of criteria for diagnosis (at least 1 of the following must be endorsed).
            i25 - 4a. symptom
            i26 - 4b. symptom
            i27 - 4c. symptom
            i28 - 4d. symptom
            i29 - 4e. symptom
            i30 - 4f. symptom
            i31 - 4g. symptom

            Each of the sub-sets must be endorsed (or not) in some way to generate the answer in those 4 cells. In order for Criterion A to be endorsed, any 3 of the 4 cells i4, i8, i15, or i24 must be answered with yes, otherwise, Criterion A is not met, and the diagnosis is not made. So there is no range of cells like i4:i24, and it appears COUNTIFS only uses a range.

            I hope that clarifies it. What else can I use instead?

            Thanks!

            • Hi!
              In cells i4, i8, i15, i24, use the formula previously recommended to you.
              Then use the IF function for those four cells.

              =IF((A4="Yes")+(A8="Yes")+(A15="Yes")+(A24="Yes")>0,TRUE)

              Hope this is what you need.

              • I'm not really sure how that will work. I only need any 3 of those cells to return yes, not all 4.

              • Hi!
                If you need 3 "Yes" answers, replace 0 with 3 in the formula

                =IF((A4="Yes")+(A8="Yes")+(A15="Yes")+(A24="Yes") > = 3,TRUE)

              • NVM, I figured out an alternative. Thanks!

  11. I have a problem too :) I have 30 cells and some of them are not numbers but "GO". As a result, I want Excel to summarise every "GO" as number 8 at the end. So, if I have 3 "GO" in this 30 cells, result I expect should be 24. Thank you :)

      • You are a genius :) Thank you. I already understand better how this actually works. COUNTIF helped me for my problem. Thanks again

  12. Hi, I am trying to work out a problem with nested IF functions. I have the following table which i need to return values on based on the number in a cell see below. I have got all the way up to >250 with nested IF functions but need another formula to work out the problem for every 100 greater than 250 add the relevant amount. e.g. 450 = 7.

    1-50= 1
    51-100= 2
    101-150= 3
    151-200= 4
    201-250= 5
    >250= Add 1 per 100

    Here is the formula i have so far: =IF(B7=51,B7=101,B7=151,B7=201,B7=251,B7=351,"7",0)))))))

    Is this something you could help with?

  13. Can someone please help with providing a formula for the below problem:

    If C2 is <=500000 then C2*1.6%
    If C2 is <=1500000 then 500000*1.6% + the remaining value * 1.78%
    If C2 is <=3000000 then 500000*1.6% + 1000000*1.78% + the remaining value * 3.25%

    I have the first two conditions satisfied as mentioned below but cannot figure out the 3rd condition.

    =IF(C2<=500000,C2*1.6%,IF(C2<=1500000,((500000*1.6%)+((C2-500000)*1.78%))))

  14. ABC Material used in W,X,Y.Z FG Product , how i find that ABC material used in which FG Product.

  15. Hi I'm looking for a formula in this following condition:

    Name exact-age. estimate-age
    John Doe

  16. I want to take Unique name in duplicate entry with choiced date or current date. =like counta(Unique,"21.02.2022")

    Neeed to solve
    20.02.2022 R
    20.02.2022 A
    21.02.2022 R
    21.02.2022 R
    21.02-2022 A

    Need to count for date 21.02.2022
    Count 02 only

  17. =IF(K9="ABC", "do this","do that")

    hi guys ,
    the above formulae is not working
    May i know how to use IF function if text involved

    • You could name a different cell (for example A1) ABC and then refer to A1 instead of using the actual text "ABC"

  18. Hello,

    I'm looking for if formula for following condition

    if lower salary bracket achieve upper target he/she will get upper slab incentive but upper salary bracket not achieve his/her target or sale lower slab he/she will get 0% incentive

    Salary bracket Part + Labour Sale in Lacs Incentive %age
    Upto 16 k gross & below 400000 to 475000 L 1%
    16.01 k to 18 k gross 475001 to 550000 L 1.50%
    18.01 k to 20 k gross 550001 to 625000 L 1.75%
    20.1 k to 22 k gross 625001 to 700000 L 2%
    22.01 k to 25k gross 700001 to 775000 2.25%
    25.01 k gross & above 775001 & above 2.50%

    Please Help in this matter

    Thanks & Regards

    Vipul

    • =IF(AND(O34>=25001,N34>=775001),2.5%,IF(AND(O34>=22001,N34>=700001),2.25%,IF(AND(O34>=20001,N34>=625001),2%,IF(AND(O34>=18001,N34>=550001),1.75%,IF(AND(O34>=16001,N34>=475001),1.5%,IF(AND(O34=400001),1%,0))))))

      I'am trying this formula but not works properly it gives 20K Salary Bracket and sales 522329 it gives 1.5% actually it shows 0%

      Thanks,

      Vipul

  19. Ive to create a condition where there are 3 subjects (s1, s2, s3) . conditions are s1>5, and if s1+s2+s3>20 then 100 reward, if s1+s2+s3>40 then 200 reward

    • apologies, i got it

  20. Hey Guys,

    I am trying to set up an automatic status formula where if I put data in the cells that require action, then status cell would say "closed". Otherwise, it would say "open" if any of the required cells needing data dont have anything. For example, I am trying to say =IF(ISTEXT(E1,E2,E3,E4)),"CLOSED",OPEN") Is this something possible to do? I keep getting the error message no mater what way I do it.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)