Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4538 comments

  1. Hi! I hope you can help me with this.

    I have the following data:

    Employee A:
    Starting salary - 500
    Had a promotion on 3/1/2022, salary will be 600

    Employee B:
    Starting salary - 400
    Increased salary on 2/1/2022 at 420
    Promoted on 8/1/2022, salary will be 500

    Employee C:
    No increase in salary at 450

    I need formulas for the months Jan-Dec showing salaries of employees for each month. There are only 2 instances where employees get salary increase which can happen in a year: salary increase and promotion.

    Table should show these (with months in columns):

    Employee A: (Jan) 500, (Fed) 500, (Mar) 600, (Apr-Dec) 600
    Employee B: (Jan) 400, (Feb-Jul) 420, (Aug-Dec) 500
    Employee C: (Jan-Dec) 450

    Thanks in advance

  2. I tried to do it in a lot of ways but failed. If I have suppose 10 number in a cell and a -5,-3,-2 as a credit then I have to match it manually. Is there any way that the cells which are becoming zero automatically get highlighted or actual one? And this zero's are getting's on the reference Id basis. Any number should not get zero by matching other reference Id value .So,is there any better ways to do it?

    I have tried the solver also but its has a range of 200 line items only and I have the data of 50000 thousand line item.

  3. Hello sir
    I want two condition match with formula
    Plz help me
    Example
    A B C
    ITEM NAME SHADE NAME CD
    22SLK02907 4A/NAVY NA 15%
    22SLK02907 4A NAVY 15%

    I want A:B match same condition another sheet Match and find CD value

  4. Hello Sir,

    My Data is like this

    Column
    M1
    A2
    B5
    M2
    B55
    A15
    M54
    A25

    I want to sort or filter that data to this

    Column 1 Column 2 Column 3
    M1 A2 B5
    M2 A15 B55
    M54 A25

    Please suggest Excel Formula for this.

    Thanks in Advance.

  5. Data Base-
    A B C X Y output-1 output-2
    12 24 10 3 1 11 36
    24 12 8 2 3 19 27
    12 24 8 2 2 5 35
    24 12 8 2 0 1 -5
    30 9 12 4 2 22 19

    and so on......

    Result (conditions which to be matched from data base)
    A B C X Y output-1 output-2
    30 9 12 4 2 ? ?
    24 12 8 2 3 ? ?

    any suggestion, how do i get output-1 & output-2 from data base by verifying different conditions given in Result range

    i have tried DGET() this works fine for 1st row of Result but not for rest of rows in Result range.

    Thanks

      • Hello, need a quick help with the if condition along with concatenate function.
        I have this data as mentioned below in column A. Now, wherever "AA" appears in column A, I want to concatenate the column A with F1 and wherever "XA" appears in column A, I want to concatenate the column A with F2. How could i do this?

        AA,FS
        AA,FS
        AA,FS
        XA,GP,FT
        XA,GP,FT
        XA,GP,FT

  6. I need one small help here

    Rather than showing as a data I need results as Match-1,Match-2,Match-3,Match-4,Match-5

    For below formula:

    =IFERROR(VLOOKUP(AA3, Visa!AA:A, 1,0),IFERROR(VLOOKUP(AB3, Visa!AB:AB,1,0),IFERROR (VLOOKUP(AC3, Visa!AC:AC,1,0),IFERROR (VLOOKUP (AD3, Visa!AD:AD,1,0), VLOOKUP(AE3, Visa!AE:AE,1,0)))))

  7. I have a column of cells that say either "Buy", "Sell", "Hold".
    I'm looking for a formula that at the end of the column automatically populates which ever word populates the most in the column. Any help with a formula is appreciated!

    • Hello!
      To find the most frequently occurring value in a range, use this array formula with the COUNTIF function.

      =INDEX(A1:A40, MATCH(MAX(COUNTIF(A1:A40,A1:A40)), COUNTIF(A1:A40,A1:A40),0))

      This is an array formula and it needs to be entered via Ctrl + Shift + Enter, not just Enter.

  8. Dear Alexander Trifuntov, I hope you can help me
    I have the following data

    year condition
    A1 1991 B1 =IF((A1={1991,1994,1998}),1,0)
    A2 1992 B2 =IF((A2={1991,1994,1998}),1,0)
    A3 1993 .
    A4 1994 .
    A5 1995 .
    . . .
    A9 1999 B9 =IF((A9={1991,1994,1998}),1,0)
    A10 2000 B10 =IF((A10={1991,1994,1998}),1,0)

    I need that if the evaluated cell is equal to a group of values {1991,1994,1998}, I get 1, otherwise 0, I have tried with the AND/OR function and I have not been able to obtain the result I am looking for. Could you give me a hint on how to search with more than one criteria using the IF function?
    Thank you very much for your help.

  9. Hello i m hoping someone will help me with this formula

    I have 5 set of criteria data based this I m doing iferror vlookup in one shot same column then I found the results but I want to know results matched with which criteria out of 5 whether criteria 1 or 2 or 5 for this how to check in same formula.

    My formula is :

    =IFERROR(VLOOKUP(AA3,Visa!AA:AA,1,0), IFERROR(VLOOKUP(AB3,Visa!AB:AB,1,0),
    IFERROR(VLOOKUP(AC3,Visa!AC:AC,1,0),
    IFERROR(VLOOKUP(AD3,Visa!AD:AD,1,0),
    VLOOKUP(AE3,Visa!AE:AE,1,0)))))

    • Hi!
      An Excel formula cannot return 2 values at once - the search result and the criterion number. You can combine these values if that suits you.

      =IFERROR(VLOOKUP(AA3,Visa!AA:AA,1,0)&"1", IFERROR(VLOOKUP(AB3,Visa!AB:AB,1,0)&"2",
      IFERROR(VLOOKUP(AC3,Visa!AC:AC,1,0)&"3",
      IFERROR(VLOOKUP(AD3,Visa!AD:AD,1,0)&"4",
      VLOOKUP(AE3,Visa!AE:AE,1,0)&"5"))))

  10. Hello,

    I do have an Excel Sheet with multiple tabs (For Hiring Process)

    I want to link the first tab (Manpower Requisitions) with the second tab (Applicant Tracker).

    whenever I mark in the first tab - against in any requisition that it is “closed”, it will reflect in the second tab against the candidate name that (joined).

    Which formula will be good for use?

  11. Hi, I am looking for a solution.

    I want to get a result as "Graduated" if "Persons name or employee" and a "particular code" (code is a typology) and if the result says pass (we have the result as pass or fail in the data already) and if there is consecutive 5 "pass" or more "pass".
    If not the result must say "Pending" if there is only 4 "Pass" or less "Pass"

    EXAMPLE:

    Name Code Result Final outcome
    XYZ SO04 Pass
    Pass
    Pass
    Pass
    Pass "GRADUATED" If it has 5 consecutive result as "pass" or
    more than 5 consecutive result as "Pass" then
    the outcome must be "GRADUATED" .

    Name Code Result Final outcome
    XYZ SO04 Pass
    Pass
    Fail
    Fail
    Pass "PENDING" If it does not have 5
    consecutive Pass" the final
    outcome must be "Pending"

    PLEASE HELP ASAP

    • Column A is Name which is XYZ Column B is Code which is SO04 Column 3 is Result which is Pass or Fail. Need outcome in Column D which is FINAL OUTCOME header. If Column 3 has 5 consecutive PASS the FINAL OUTCOME must be "Graduated" If not FINAL OUTCOME must be "Pending"

      Data dump has Difference names (In column A) and different code (Typology) in Column B

      For each employee (Name) based on audit for the Code. Result is already given as Pass or fail in the data dump

  12. sShare
    sLoan
    sShare
    sLoan
    sShare
    sShare
    sInterest
    sLoan
    sShare
    sLoan
    sShare
    sLoan
    sInterest
    The above information is column N, I want to report in column O the above remarks inform of codes i.e., S shares to be 1, sInterest to be 2, sLoan to be 3 and so on which formular is the best?

  13. Hello!
    I want to select a cell from two where if there is 0 in one cell then select another cell where there are values. like if in cell O22 is equal to zero then take zero overall but if not then take O23 there is an average of some cells.

  14. I am trying to write a formula. I have 3 cells that have either YES or NO, I need a formula to look at the 3 cells and return a value of 1 if only 1 out of 3 is a YES or 1.5 if 2 out of 3 are YES or 2 if all 3 are YES.

    YES
    YES
    YES
    =Would equal 2
    YES
    YES
    NO
    = Would equal 1.5
    YES
    NO
    NO
    = Would equal 1

    Any help would be greatly appreciated.

  15. HI ,

    Need help to validate/lookup for a text(Predeifned text) in 2 Columns and return value if both columns satisfy the conditions

    State Reason Result
    Active Accepted Imp
    Proposed Accepted
    Active Accepted
    Active Accepted

    • Please ignore above msg before entering it is submitted
      HI ,

      Need help to validate/lookup for a text(Predeifned text) in 2 Columns and return value if both columns satisfy the conditions.
      could you please share the formula? Any help would be greatly appreciated.

      Column1 Column2 Column3(Result)
      Active Accepted Implemented
      Proposed Complete Analyze
      Closed Rejected Invalid

      If column1 ="Active" and Column2="Accepted", then set Column 3 as "Implemented"
      If column1 ="Closed" and Column2="Rejected", then set Column 3 as "Invalid"

  16. I have been struggling with this formula for days. Thanks so much!

    I want to do a vlookup on another sheet first, if the data is not listed on the other sheet I want the data to be taken from another cell, however, if the cell selected is blank, then return with a text. This is what I have so far and it is not working.

    IF(ISNA(VLOOKUP(A1,'Cargoo New Shipments'!$B:$AD,29,FALSE)),E1,IF(E1="","Lookup ETA","Lookup ETA"))

    Lookup value from the other sheet first - VLOOKUP(A1,'Cargoo New Shipments'!$B:$AD,29,FALSE))
    If the data is not listed, then take the data from cell E1
    If cell E1 is "" (blank) then return with a text, "Lookup ETA"

    I hope this makes sense, thanks so much!!

    • Hello!
      I recommend using the IFERROR function to handle the lookup error.
      I can't check the formula that contains unique references to your workbook worksheets.
      Here is an example formula. Change external links as you need

      =IFERROR(VLOOKUP(A1,$B:$AD,29,FALSE),IF(E1="","Lookup ETA",E1))

  17. Hello there.
    been days trying to figure this out and so far no sucessful, hope somebody can help.
    This is a Crypto trading journal Excel sheet.

    Sometimes you open a trade and you exit it in multiple transactions at different sell prices,

    Bellow are my columns, hopefully this is understandable

    | Take Profit # 1 | Take Profit # 2 | Take Profit # 3 |
    C E G H J K L M N O
    Profit/Loss |Type |Position Size |Price | Exit Size | Exit Price | Exit Size |Exit Price |Exit Size |Exit Price
    $5,800.00 |Short| 15,000 |0.950 |10,000.00 | $0.8450 |5,000.00 |$1.0240 |

    entered a position of 15K shares, now first sold 10K shares on one transaction TP#1 and then sold the remaining 5K shares on the next transaction TP#2 and nothing on TK#3

    so far i have this formal and it works fine for Take Profit #1 , my problem is to calculate TP#2 and add it to TP#1 in Column C and if there is a TP#3 to also add it to column C

    =IF((ISBLANK(J9)),,(IF(E9="Long",-1,1))*((H9*G9)-(K9*J9)))

    Any help would be greatly appreciated.
    Thank you

    • Hi!
      Unfortunately I don't quite understand what you want to do. Please describe your problem in more detail. Give some examples of the results you want to get.

  18. Hello,
    I have 5 conditions that result in the correct corresponding value - it's purpose is to evaluate a set of criteria to come up with the standard Budget $ amount - but none of the equations involve math functions.

    If A2=P2 and B2=Q1 then R50; OR if A2=P2 and B2=P2 then R51, ...this goes on for 5 conditions (meaning B2=Q1 through Q5 each resulting in a value in R50 through R55.

    The values in A2 are words. They are not calculating numbers but just the reasoning of the association of values selected from a drop down box

    I hope that makes sense!

    Thanks for your help - I looked through the instructions but didn't see something exactly like this and I can't seem to get the OR OR OR OR OR right!

  19. Can you help me write a formula? Essentially, I want the formula to look at a data set 1 to extract the last transaction (date essentially). If data set 1, does not have the required data (maybe the last transaction happened between a different date range), I then want the formula to look at the second data set for the nearest transaction date.

    • Hello!
      To find the maximum value in a date range, use the recommendations and examples in this article: Excel INDEX MATCH with multiple criteria.
      If the desired value is not found, use the IFNA function to search in a different range. Here's an example of a formula:

      =IFNA(INDEX(A1:A10,MATCH(1,(MAX(A1:A10)=A1:A10)*(A1:A10 > E1)*(A1:A10 < F1),0)),INDEX(C1:C10,MATCH(1,(MAX(C1:C10)=C1:C10)*(C1:C10 > E1)*(C1:C10 < F1),0)))

      I hope I answered your question. If something is still unclear, please feel free to ask.

  20. Hello
    Can you assist in creating formula to the following conditions
    I have two columns A has numbers from 0 to 100 and Column B has one of the following text ( Low- LoAvg- Avg- HiAvg- High)
    - Condition 1: IF column A is more than 61 And Column B is either Avg or HiAvg or High then result is 5
    IF Column A is more than 41 And Column B is high then result is 5
    - Condition 2: IF Column A is more than 41 And Column B is Either Avg or HiAvg then result is 4
    - Condition 3:IF Column A is between 31 to 40 and Column B is either Avg or HiAvg or High then result is 3
    - Condition 4:IF Column A is between 21 to 30 And Column B is either Avg or HiAvg or High then result is 2
    IF Column A is between 10 to 20 and Column B is High then Result is 2
    - Condition 5:If Column A is less than 21 and Column B is either Low orLoAvg or HiAvg then result is 1
    IF Column A is between 21 to 30 and Column B is low then result is 1

    • Hi!
      If I understand your task correctly, try the following formula:

      =(A1 > 61)*((B1="High")+(B1="HiAvg")+(B1="Avg"))*5+(A1 > 41)*(A1 < 61)*(B1="High")*4+(A1 > 31)*(A1 < 41)*((B1="High")+(B1="HiAvg")+(B1="Avg"))*3+(A1 > 21)*(A1 < 31)*((B1="High")+(B1="HiAvg")+(B1="Avg"))*2+(A1 > 10)*(A1 < 21)*((B1="Low")+(B1="LoAvg")+(B1="HiAvg"))*1

      You can also use nested IF function. Use the recommendations in the article above, as well as this instruction: Excel nested IF statement - multiple conditions in a single formula

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)