by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
Hello, sir. What if I want the if condition to look value in multiple cells.
Eg.
=IF(A1=any value from the (B1,B2,B3), TRUE, FALSE)
How can I achieve this?
Hello, I'm really struggling with this. I think the function that I need to use is IF but I'can make it to work properly.
I have 4 different categories [A] [B] [C] [D] and those categories can be scored as 1, 2 ,3. But one particular [D] category if the score is 1 I need to have more impact in the end. I was thinking in if score is 3 : 40%,40%,10%,10%, if score is 2 : 35%,35%,10%,20% and if score is 1 : 30%,30%,10%,30%.
I came to
=IF(E10="3","((E7-40%)+(E8-40%)+(E9-10%)+(e10-10%)/4)",IF(E10="2","((e7-35%)+(e8-35%)+(e9-10%)+(e10-20%)/4)",IF(E10="1","((e7-30%)+(e8-30%)+(e9-10%)+(e10-30%)/4)")))
But is not working and this is driving me crazy,
If you maybe help me I would be very grateful
Thank you in advance,
David Lopes
Hi! The information you provided is not enough to understand your case and give you any advice, sorry. Explain your source data and the result you want to get.
I can assume that your formula does not need quotation marks.
=IF(E10=3,((E7-40%)+(E8-40%)+(E9-10%)+(E10-10%)/4),IF(E10=2,((E7-35%)+(E8-35%)+(E9-10%)+(E10-20%)/4),IF(E10=1,((E7-30%)+(E8-30%)+(E9-10%)+(E10-30%)/4))))
Thank you so much that really help me, I don't know why I was using quotation marks... I was just looking at some tutorials and gave me the wrong idea. For my formula to work and give back a result between 1 and 3 I just add one more () and it worked just fine!
like this:
=IF(E10=3,(((E7-40%)+(E8-40%)+(E9-10%)+(E10-10%))/4),IF(E10=2,(((E7-35%)+(E8-35%)+(E9-10%)+(E10-20%))/4),IF(E10=1,(((E7-30%)+(E8-30%)+(E9-10%)+(E10-30%))/4))))
Thank you so much!!!! You really solved my problem!!!
Hell Alexander, I continue receiving error messages when attempting to write “IF” formula with multiple conditions
=IF(AND(‘D7=”Kick-Off Training”, ‘M7>=DATEVALUE(“4/30/2023”), "0", "1")))
Cell D7 value = required training title
Cell M7 value = later than date hired (those hired Q2 or later)
“0”, “1” = determines if counted in subtotal formula
Read the manual above carefully and do not use unnecessary brackets and quotation marks.
Check the formula below, it should work for you:
=IF(AND(D7="Kick-Off Training", M7>=DATEVALUE("4/30/2023")), "0", "1")
Alexander, thank you so much. That correction worked perfectly!
Little Help in the following formula
=IF(OR(A6="Equity",A6="MFs",F5>365*1),"LT","ST"),IF(OR(A6="Debt",A6="Sec-UL",F6>365*3),"LT","ST"), the result of which shows as "#value" instead of LT or ST as case may be, Plese help
Hi! If I understand your task correctly, the following formula should work for you:
=IF(OR(OR(A6="Debt",A6="Sec-UL",F6>365*3),OR(A6="Equity",A6="MFs",F5>365*1)),"LT","ST")
For more information, please read: Nested IF OR statements
Thank you so much Sir. That correction worked perfectly
=IF(OR(OR(A6="Debt",A6="Sec-UL",F6>365*3),OR(A6="Equity",A6="MFs",F5>365*1)),"LT","ST"),
PLEASE check once again, the result from the above formula always as "LT" instead of "ST", even if the days in some case less than 365 days.
My original formula as later which had been modified by you as former one above
=IF(OR(A6="Equity",A6="MFs",F5>365*1),"LT","ST"),IF(OR(A6="Debt",A6="Sec-UL",F6>365*3),"LT","ST"), the result of which shows as "#value" instead of LT or ST as case may be,
The formula I suggested to you uses the conditions you described in your formula. If you have described them incorrectly, the formula will not work properly. Note that the OR function returns TRUE if at least one condition out of three is true. For example, if A6="Equity", it doesn't matter what number is written in F5 and F6.
Hi
Trying to create a formula for 0.33 "Present" and blank cell (so no result) "Not evaluable".
Any help appreciated!
Please re-check the article above since it covers your task.
Worked on multiple IF functions with AND and OR and THEN but nothing is working.
My issue:
B14=9 then 100
B14=6 then 350
B14=1 then 500
no matter what I've put in I keep getting errors.
IF(OR(B14=9 THEN true_value 100 ELSE IF B14=6 THEN true_value 350 ELSE IF B14=1 THEN true_value 500)
Please help.
Hi! The answer to your question can be found in this article: Nested IF in Excel – formula with multiple conditions
=IF(B14=9,100,IF(B14=6,350,IF(B14=1,500,"")))
You can also use the IFS function instead of multiple IF:
=IFS(B14=9,100,B14=6,350,B14=1,500)
I hope you may help me with this situation.. i have 3 sheets with Cust name in column A and warehouse name in rows B to F. 1st sheet is called SUMMARY. now in SUMMARY sheet, i need to show the total value of all the warehouses (from sheet 1 & 2) according the customer name.
SHEET 1 LOOKS LIKE THIS:
WAREHOUSE
CUST NAME F G H I J
A 1 2 3 4 5
B 2 2 3 4 5
CD 3 2 3 4 5
DE 4 2 3 4 5
E 5 2 3 4 5
SHEET 2 LOOKS LIKE THIS:
WAREHOUSE
CUST NAME F G H I J
A 6 7 8 9 10
AB 7 7 8 9 10
B 8 7 8 9 10
CD 9 7 8 9 10
DE 10 7 8 9 10
SUMMARY MUST ADD THE WAREHOUSE VALUES OF SHEET 1 & 2 ACCORDING TO THE CUSTOMER NAME
WAREHOUSE
CUST NAME F G
A SHEET 1+2 SHEET 1+2
AA SHEET 1+2 SHEET 1+2
DE SHEET 1+2 SHEET 1+2
B SHEET 1+2 SHEET 1+2
CD SHEET 1+2 SHEET 1+2
thank you so much
sorry that content rumbles and i cant paste screen shots
Hello
the content was really helpful and useful
thanks a bunch
Hi, am trying to create an expense sheet, so if a cell has a drop down with three values Needs, Wants and Savings and if I add Rs 200 to a cell and select option "need" from the drop down, Automatically value from my cell where percentage of total earnings which is allocated to needs must be subtracted.
For example, My total earnings is 30K and from that I have allocated 30% to my needs which will be 10K , if I enter house rent = 5K and select "Needs" from drop down automatically the cell which has 10K should be 10k - 5K. This formula must be applied to atleast 10 rows so I can track my needs, wants and savings.
I have derived with this formula =IF(J3="Needs",D33-H3,D33) where J3 is the drop down cell, D33 holds the 10K , H3 holds the 5K, but this formula works only for 1 cell , I want this formula to work on a range of cells say from H3 to H13.
Kindly help on this formula
Hi! To find the sum of the cells according to a certain criterion, use the SUMIF function:
D33-SUMIF(J3:J13,"Needs",H3:H13)
Hello! I was hoping you could help.
If A2 = Male and B2 = RTK then C2*15% If A2 = Female and B2 = RTK then C2*20% If A2 = Male and B2 = MDK then C2*25% If A2 = Female and B2 = MDK then C2*30% Else C2=0
Hi! Pay attention to the following guide: Nested IF with OR/AND conditions.
For example:
=IF(AND(A2 = "Male",B2 = "RTK"), C2*15, IF(AND(A2 = "Female",B2 = "RTK"), C2*25,0))
But you can't use the formula to set C2=0
Hi,
Hope you could help me this.
If K721 is equals to "VAT" then (amount) divided into 1.12
Hi! All the necessary information is in the article above. For example,
IF(K721="VAT",J721/1.12,J721)
Hi,
I have a below data, where column E is the result column.
Trying to come up with a formula, that gives me the expected result in column E.
Any help on this is greatly appreciated.
Thanks in Advance.
ID Helper 1 Helper 2 Customer Expected Result
A-01-A1 A-01-A 1 Sliver 1
A-01-A1 A-01-A 1 Sliver 0
A-01-A1 A-01-A 1 Sea Blue 1
A-01-A3 A-01-A 3 Sea Blue 0
A-01-A4 A-01-A 4 Sliver 0
A-01-A5 A-01-A 5 Sea Blue 1
A-01-A7 A-01-A 7 Sliver 1
A-01-A9 A-01-A 9 Sliver 0
A-01-B1 A-01-B 1 Sliver 1
A-01-B1 A-01-B 1 Sliver 0
A-01-B3 A-01-B 3 Sliver 0
A-01-B6 A-01-B 6 Sliver 1
A-01-B6 A-01-B 6 Sliver 0
A-01-B8 A-01-B 8 Sliver 0
A-01-C1 A-01-C 1 Sliver 1
A-01-C2 A-01-C 2 Sliver 0
A-01-C3 A-01-C 3 Sea Blue 1
A-01-C6 A-01-C 6 Sea Blue 1
A-01-C9 A-01-C 9 Sea Blue 0
A-01-D1 A-01-D 1 Sea Blue 1
A-01-D4 A-01-D 4 Sliver 1
A-01-D5 A-01-D 5 Sliver 1
A-01-D6 A-01-D 6 Sliver 0
A-01-D7 A-01-D 7 Sliver 0
Hi! I can't guess at the logic of getting a result. Your question is not entirely clear, please specify.
Hello. I'm trying to create this:
IF E2=1 then the value is 400. But I want this for more numbers. But somehow I am unable to combine them.
Endgoal:
E2=1, then value 400...... =IF(E2=1;400;0)
E2=2, then value 200...... =IF(E2=2;200;0)
E2=3, then value 150...... =IF(E2=3;150;0)
E2=4, then value 75........ =IF(E2=4;75;0)
E2=5, then value 50........ =IF(E2=5;50;0)
How should my formula look like?
Kind regards,
Tommy
In your case, we can recommend using the CHOOSE function. The following tutorial should help: CHOOSE function in Excel with formula examples.
=CHOOSE(E2,400,200,150,75,50)
You can also use the IFS function for many conditions.
=IFS(E2=1,400,E2=2,200,E2=3,150,E2=4,75,E2=5,50)
Thank you for your reply. Unfortunately your formule doesn't work.
"There's a problem with the formula''
Not trying to type a formula?
When the first character is an equal ("=") or minus ("-") sign, Excel thinks it's a formula:
• you type: =1+1, cell shows: 2
To get around this, type an apostrophe ( ' ) first:
• you type: '=1+1, cell shows: =1+1
Hi! The formula I sent to you was created based on the description you provided in your first request.This formula has been tested and works with your data. Why are you telling me how to enter the formula correctly? You need it, not me. What delimiters do you use in your formulas - commas or semicolons? What is the value in cell E2?
I've just copy pasted your formule, hoping it could work. Once copy pasting it, the text below have been directly copy pasted from Excel. Wasn't trying to be rude. I am really thankful for your help.
I'm using semicolons. Currently is the value of E2 3.
Hi! Replace the commas in the formula with semicolons. Use your regional settings in the formulas.
=IFS(E2=1;400;E2=2;200;E2=3;150;E2=4;75;E2=5;50)
Hi Sir,
I am trying to use below excell function but it doesnt works. Please help
=IFS(D4=1,1.1,D4=2,1.1,D4=3,1.2,D4=4,1.3)
Hi! Without seeing your data, it is difficult to give you any advice. Check the data in cell D4.
If there are 32 days in any cell, zero will be added after 33 days at the rate of 10 rupees per day.
excel formula making
Hi! Your question is not very clear, but I think this instruction will help: Using IF function with dates.
Hello,
I'm trying to create a formula that says "If cell D8 equals In Progress or Not Started AND cell G8 is earlier than today, then mark the field with either OVERDUE or NOT DUE". I have tried several different things and can't get it to work properly. Any suggestions?
Thank you!
Hi! All the necessary information is in the article above. The formula might look like this:
=IF(AND(OR(D8="In progress",D8="Not started"),G8<TODAY()),"overdue","")
please help with the formula
i want to Calculate the Tax for Whisky at 8% of the TOTAL
and GIN at 6% of the TOTAL For the drinks not requiring tax to
paid insert "NO TAX"
col a col b col c col d col e col f
Drink Tax Band Price Sales Total Tax
Whisky B 12.90 8,000.00 103,200.00 8,256.00
Brandy C 14.50 6,890.00 99,905.00 FALSE
Gin A 8.65 12,896.00 111,550.40 6,693.02
Vodka D 9.95 12,356.00 122,942.20 6,147.11
Rum B 11.30 7,896.00 89,224.80 0
Port D 13.90 2,300.00 31,970.00 0
Hi! Please re-check the article above since it covers your task.
If I understand correctly, here is an example formula:
=IF(A2="Whisky",F2*8%,IF(F2="Gin",F2*6%,"No tax"))
Hi! I need to add the results of a nested if together to give me a number to source for a further if query - I'm really struggling to get it work and I'm getting very frustrated!
To ensure clear understanding of your task, can you provide an example of the source data and the desired result you are aiming for?
I am asked to do this:
"In column H find Discount. Where discount is 10% of the total Sales for Item Type “Clothes”
and “Total Sales” greater than 500000. Otherwise, the discount is 0."
what is the correct way to write the function?
Hi! I don't have your data, so I can't offer an exact formula. Look for the detailed instructions and example formulas here: Excel INDEX MATCH with multiple criteria - formula examples
Im looking for a formula that will provide me with a result only if two conditions are met and are on the same line of the table
From one spreadsheet i need to search another table made up of follows Column A - PO Number / Column B - Item No. & Column C - Value
How can i make sure that the PO and Item No are the same in both tables before i can call in the value (Column C).
In the data table, PO number and Item Numbers can be duplicated but only one line will contain the correct PO and Item number together.
Hi! You can find the examples and detailed instructions here: Excel INDEX MATCH with multiple criteria - formula examples. The formula might look like this:
=INDEX(C2:C13, MATCH(1, (G1=A2:A13) * (G2=B2:B13), 0))
Hi!
I have a question about the following formula:
=IF(F2="MONTH";DATE(YEAR(C2);MONTH(C2)+D2;DAY(C2));IF(F2="";DATE(YEAR(C2)+D2;MONTH(C2);DAY(C2));IF(F2="YEAR";DATE(YEAR(C2)+D2;MONTH(C2);DAY(C2)))))
What I am doing here is creating a date calculation from Starting date, so if the cell F2 contains MONTH as the unit, then add the number present in D2 to the MONTH (in the formula). If the F2 cell contains YEAR unit, then add number in D2 to the YEAR (in the formula). If the F2 cell does not contain any unit, assume it is YEAR and add the number from D2.
Now I want to add an additional condition into the formula - if the Starting date (column C) is empty, how do I show the result as "0" instead of it just being #VALUE! error?
Here is a quick example of the table I have:
1 C D F
2 empty 20 empty
3 empty 20 YEAR
4 2025-02-28 15 YEAR
5 2022-03-24 1 MONTH
Thank you for the help!
Hi! To replace the error with another value, use the IFERROR function. The following tutorial should help: Excel IFERROR function with formula examples.
Thank you!