by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
hi,
i want a formula so that i come to know that if a particular cheque issued then amount of that cheque will appear in next cell,
for example
AMOUNT CHQ NO STATUS DATE OF ISSUE DATE OF CLEARENCE Amount(if cleared)
2977 54808 issued 21.04.2016 25.04.2016
as above mentioned i want to next cell which is blank shows the amount if a particular cheque has cleared from bank and also i've given the clearance date of cheque
please guid
Thanx & Regards
Ghayas Ahmad
I am trying to make an If then statement for the following:
If box F5 = 100, then box F6 = 3000
if box F5 100, then box F6 = 5 x every number over 100 + 3000
(example if F5 = 105, the box F6 would need to be (5*5)+3000
Could you help me make a formula? Please?
it cut off part of my formula:
also add in: if box F5 < 100, than F6 = 3000
Hi Emily,
Try the following formula:
=IF(F5<=100, 3000, 5*(F5-100)+3000)
I have a spreadsheet that has a due date in column j, and a status of open or closed in column K.
I need Column L to calculate if the date is after today's date, and the status is open, then it says On Track, if the date is after today's date and the status is closed, then it says completed, and if the date is before today's date and the status is either open or closed then it shows Delayed... I've figured out how to get it to show On Track, Completed and Delayed based on just the date in column j, but I can't figure out how to get the status involved.
Hi Kayla,
Please use the below function,
=IF(AND(J14>TODAY(),K14="Open"),"On Track",IF(AND(J14>TODAY(),K14="Close"),"Completed",IF(AND(J14<TODAY(),OR(K14="Open",K14="Close")),"Delayed","")))
Thanks,
Prabath
Hi,
I have scenario,
I am trying to get all the blank fields from the column, for ex- if I have this column.
13 years 6 months 0 days
34 years 5 months 0 days
10 years 9 months 0 days
14 years 0 days
6 years 8 months 0 days
5 years 11 months 0 days
23 years 6 months
6 years 9 months 0 days
8 years 9 months 0 days
30 years 9 months 0 days
7 years 7 months 0 days
15 years 4 months 0 days
45 years 3 months 0 days
40 years 10 months 0 days
33 years 2 months 0 days
13 years 9 months 0 days
30 years 2 months 0 days
29 years 10 months 0 days
25 years 6 months 0 days
14 years 9 months 0 days
41 years 3 months 0 days
10 years 11 months 0 days
30 years 3 months 0 days
15 years 11 months 0 days
27 years 0 days 6 years
As you can the column has the blank fields, I need to get the blank fields out from the column, also it has "NUM" error and 0, which I also need need to take out.
Can you please tell me how to construct the formula for that.
Thanks,
Saurabh
Hello Saurabh,
I recommend you to use filter. So you can select blank rows and remove them.
https://support.office.com/en-us/article/Add-or-remove-table-rows-and-columns-in-an-Excel-table-4d6585be-4292-444c-b86b-71cb4e5d3e16#bmremoveblankrows
Similarly you can choose the rows with errors and remove them.
Hi can you help me with the conditions for this !
If age is between 0 - 12 months then 0.5 to 1.8 µmol/L
If age is between 1 - 6 years: then 0.7 to 1.5 µmol/L
If age is between 7 - 12 years: then 0.9 to 1.7 µmol/L
If age is between 13 - 18 years:then 0.9 to 2.5 µmol/L
If age is ≥ 18 years:then 1.5 - 3.5 µmol/L
Hi,
use this function,
=IF(A2<1,"0.5 to 1.8 umol/L",IF(A2<6,"0.7 to 1.5 umol/L",IF(A2<12,"0.9 to 1.7 umol/L",IF(A2<18,"0.9 to 2.5 umol/L","1.5 to 3.5 umol/L"))))
Thanks,
Prabath
Hi Sam!
Use the following formula to calculate a months count
=(YEAR(NOW())-YEAR(A1))*12+MONTH(NOW())-MONTH(A1)
So your formula is:
=IF((YEAR(NOW())-YEAR(A1))*12+MONTH(NOW())-MONTH(A1)>18*12,"1.5 - 3.5 µmol/L",IF((YEAR(NOW())-YEAR(A1))*12+MONTH(NOW())-MONTH(A1)>13*12,"0.9 to 2.5 µmol/L",IF((YEAR(NOW())-YEAR(A1))*12+MONTH(NOW())-MONTH(A1)>7*12,"0.9 - 1.7 µmol/L",IF((YEAR(NOW())-YEAR(A1))*12+MONTH(NOW())-MONTH(A1)>1*12,"0.7 - 1.5 µmol/L","0.5 to 1.8 µmol/L"))))
Please note A1 should be contain a birth date.
Hi,
If above once is not clear. Please assist me by using this one.
Invoice # Value
MYEX0455477 10.00
MYEX0456058 5.00
MYAE0154262 8.00
MYEX0456603 8.00
MYEX0456601 7.00
MYAE0154534 2.00
MYEX0457138 11.00
MYEX0457438 9.00
MYAI0069730 14.00
MYEX0457318 6.00
Matching Amount 20.00
Combinations
MYEX0455477 10.00
MYAE0154262 8.00
MYAE0154534 2.00 20.00
MYEX0455477 10.00
MYEX0456603 8.00
MYAE0154534 2.00 20.00
MYEX0456058 5.00
MYAE0154262 8.00
MYEX0456601 7.00 20.00
MYEX0456058 5.00
MYEX0456603 8.00
MYEX0456601 7.00 20.00
MYEX0457138 11.00
MYEX0457438 9.00 20.00
MYAI0069730 14.00
MYEX0457318 6.00 20.00
Thanks,
Regards,
Prabath
Hi all,
I have 10 Invoices & 10 Invoice value as below. I want to get all possible combinations of Invoices which value is equal to 20. How is it possible to get it by using excel? I have mentioned the possible combination for easy reference.
Invoice # Value Matching Amount 20
MYEX0455477 10 Combinations
MYEX0456058 5
MYAE0154262 8 MYEX0455477 10
MYEX0456603 8 MYAE0154262 8
MYEX0456601 7 MYAE0154534 2 20
MYAE0154534 2
MYEX0457138 11 MYEX0455477 10
MYEX0457438 9 MYEX0456603 8
MYAI0069730 14 MYAE0154534 2 20
MYEX0457318 6
MYEX0456058 5
MYAE0154262 8
MYEX0456601 7 20
MYEX0456058 5
MYEX0456603 8
MYEX0456601 7 20
MYEX0457138 11
MYEX0457438 9 20
MYAI0069730 14
MYEX0457318 6 20
Thank you,
Regards,
Prabath
Hi Svetlana,
I need some help on below issue.
Below function has been created to get the status of Customer Statement of Account as mentioned below. As per my function, If there are no details in C4, I'm getting the status as "Unapplied". But I need it to be zero. How can I write this function.
=IF(RIGHT(C4,1)="I","Invoice",IF(RIGHT(C4,1)="C","Credit Note",IF(AND(C4="NULL",A4="Unidentified"),"Unidentified","Unapplied")))
Thanks for you guidance in all the time.
Thank You,
Regards,
Prabath
Hi Prabath,
If "no details in C4" means "if C4 is blank", then you can simply add one more IF statement to your formula:
=IF(C4="", 0, IF(RIGHT(C4,1)="I","Invoice",IF(RIGHT(C4,1)="C","Credit Note",IF(AND(C4="NULL",A4="Unidentified"),"Unidentified","Unapplied"))))
Hi Svetlana,
Thank you very much. This is exactly what i want.
Thanks,
Regards,
Prabath
Good afternoon,
how could i round down a number when its decimals are smaller than 0,5 and if not it stays the same?
Hi Bocirnea,
Please use this function,
=ROUNDDOWN(B3,1)
Thanks,
Regards,
Prabath
Hi there, how can I make this less complicated or shorter. If a cell is =IF(OR(A1=B1:B250,C1,IF(A1=B251:265,C2))
CURRENTLY I HAVE IT AS - =IF(F6=D217,A285,IF(F6=D218,A285,IF(F6=D219,A285,IF(F6=D220,A285,IF(F6=D221,A285,IF(F6=D222,A285,IF(F6=D223,A285,IF(F6=D224,A285,IF(F6=D225,A285,IF(F6=D226,A285,IF(F6=D227,A285,IF(F6=D228,A285,IF(F6=D229,A285,IF(F6=D230,A285,IF(F6=D231,A285,IF(F6=D232,A285,IF(F6=D233,A285,IF(F6=D234,A285,IF(F6=D235,A285,IF(F6=D236,A285,IF(F6=D237,A285,IF(F6=D238,A285,IF(F6=D239,A285,IF(F6=D240,A285,IF(F6=D241,A285,IF(F6=D242,A285,IF(F6=D243,A285,IF(F6=D244,A285,IF(F6=D245,A285,IF(F6=D246,A285,IF(F6=D247,A285,IF(F6=D248,A285,IF(F6=D249,A285,IF(F6=D250,A285,IF(F6=D251,A285,IF(F6=D252,A285,IF(F6=D253,A286,IF(F6=D254,A286,IF(F6=D255,A286,IF(F6=D256,A286,IF(F6=D257,A286,IF(F6=D258,A286,IF(F6=D259,A286,IF(F6=D260,A286,IF(F6=D261,A286,IF(F6=D262,A286))))))))))))))))))))))))))))))))))))))))))))))
Hi Svetlana,
Need your help
I want a formula for these conditions
If the labour take leave more than 5 days the value should be "no. of leave days".
If the labour take leave less than 5 days the value should be "0".
ex.
8 days leave means ans should be "8".
4 days leave means ans should be "0".
Hi Saravana,
You can use a formula similar to this:
=IF(A1>=5, A1, 0)
where A1 is the cell containing the number of leave days.
Hi Svetlana,
Need your help
i was trying the formula unfortunately something wrong can you pls help
Name Start time log in time
12:30 12:40 late login
12:30 12:30 on time
12:30
=IF(C2-B2>0,"late login","on time")
when the third column is nil i have put the fourmula
=IF(C4-B4>0,"late login","on time",if(c4="","leave")).
Thanks and regards
Giriraj
Hi Giriraj,
Try the following syntax:
=IF(C2="","leave", IF(C2-B2>0,"late login","on time"))
Hi,
I need a formula to calculate the below conditions.
if 800 is 160% of 500, first 100% should be calculated in .1% and next 50% should be calculated in .2% and remaining 10% should be calculated in .25%.
Please help
I'm trying to merge multiple workbooks/sheets into 1 master. I have a template that someone made (who know who) that works but only to a certain row and not through out the workbook so when I copy and paste or when I consolidate the formula/condition doesn't transfer so I wanted to create one from scratch.
Here's the criteria:
The row will highlight yellow if at least one of the grades in either column E or F is less than 73.
The row will highlight red if both grades are less than 73.
Help please! I've Googled, YouTube, and even taken a a short course and nothing.
I have a tool size range and I'd like to determine if a given measurement falls within the range.
Column A is the RANGE (.7"-1.4")
Column C is a TOLERANCE such as (+/- .0001)
Column D is a target such as .75
Column E is the ACTUAL READING such as .1200
What would the formula be to determine if the value of Column E (ACTUAL READING) falls into the (RANGE) while taking the TOLERANCE into consideration? In this example .1200 does NOT fall within the range listed in Column A, but .80 DOES fall within the range.
Please help. Your answers look beautifully simple, but I'm not sure how to use them to solve my particular situation.
Thanks. so much!
Hi,
Can you help figure out what formula i'm going to use? i want to get the sum of the whole column with the same equivalent in other column. for example a1 to A10 has different value let say 2,3,4,5,6 and in B1 to B10 has its equivalent value like 100,123,121,333 etc. i want to get the sum of row with 2 value in B column and its total sum.
Hello Manny,
If my understanding is correct, you need to sum only those cells in column B, that have 2 in the same row in column A. If so, you can use the following SUMIF formula:
=SUMIF(A1:A10, 2, B1:B10)
Hi
Value in cell A3 is 10
I want to check this value tn 4 Different Criteria
1)Less than 20
2)Greater than 20 but less than 50
3)Greater than 50 but less than 80
4)greater than 80
Please help
Regards
Venkat
Hello!
I want to only bring back a value when column A shows "Project". I want to multiply 2 different columns together but the tricky part is that sometimes those fields are blank and it's returning a #Value! error which I would like to remove and show as a blank field.
Column A: "Project" Verbiage needed
Column B: Value 1 for multiplication (can be blank sometimes)
Column C: Value 2 for multiplication (can be blank sometimes)
If Column A = "Project", multiply column B x column C and if it returns a #Value error (from at least 1 field being blank), return an empty cell.
Thoughts? Thank you in advance!
Hello,
I am having trouble displaying multiple matches from nested IF statements.
As an example:
I have a meal planner with QUICK, CASUAL, EXTRAVAGANT. QUICK = =15 but 30.
Now say meal 1 takes 13-18 minutes, which puts it in Quick and Casual, but the validation stops after it meets the <15 logic, how can I get it to check the rest of the specifications to check the Casual block also?
Thanks for any help.
Sam
Something didn't post right.
Quick: first IF is less than or equal to 15, "QUICK" next IF equal or greater than 15 but less than equal to 30, "CASUAL", third IF equal to or greater than 30 "EXTRAVAGANT". The rest is correct as I put in a meal that takes 13-18 minutes, how to I have the formula block identify it as a Quick Casual Meal.
Thanks
Hi Sam,
You can use the following nested If functions:
=IF(A1>=30, "EXTRAVAGANT", IF(A1>=15, "CASUAL", "QUICK"))
Hi,
I need help combining 3 individual IF formulas into one. All work correctly as individual formulas but I can't figure out how to combine the 3 formulas into one. The individual formulas are as follows:
=IF(OR(ISNUMBER(SEARCH("TAMPA BAY*",C2)),ISNUMBER(SEARCH("TAMPA TRIBUNE*",C2)),ISNUMBER(SEARCH("TAMPA BAY NEWS*",C2)),ISNUMBER(SEARCH("LEDGER*",C2)),ISNUMBER(SEARCH("NEIGHBORHOOD*",C2)),ISNUMBER(SEARCH("OBSERVER*",C2))),"PN","NO")
=IF(OR(ISNUMBER(SEARCH("out*",C3)),ISNUMBER(SEARCH("CLEAR*", C3)),ISNUMBER(SEARCH("LAMAR*",C3))),"O","NO")
=IF(OR(ISNUMBER(SEARCH("Bright*",C4)),ISNUMBER(SEARCH("Com*", C4)),ISNUMBER(SEARCH("Via*",C4))),"C","NO")
Thanks for the help!
Mary