Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4538 comments

  1. Hello,

    I need a formula for a variance analysis with the following conditions
    If % change is greater than + or - 20% AND $ change is greater than + or - $20,000 then Yes if not, No.

    I can't seem to get the formula right to capture the +/- for % change and $ change without it picking up everything.

  2. : 13% of Gsal if it Gsal is more than 20000 need formula for this in excel

  3. please help..
    if we type a same name in difference character i.e muneer , munir" the how to identify it in excel. because it is same name but differ in character.

  4. I have made the right formula for the 1st rows..but when I tried to copy it to other rows the result is different I tried using.thesame values to check the result is different.

  5. This seems a bit more complicated than previous posts. I have a Spreedsheet that I am trying to link several different cells with different values to auto populate the sum of all the cells in a column that coincide with an account number in another column. For example
    Column C= Account number (rows 3-60)
    Column F= Amount payed out of that account for an individual transaction
    Column A Separate sheet (same workbook)= Sum of moneys paid out of each account
    I want column A to reflect the sum of all amounts (Column F) associated with each account number (column C) from all rows that include that account number, and not include those with a different number in column C. I cannot figure out how to write a multi condition If formula for this.

  6. Hi Svetlena,
    Could you please help by which farmula suould be used to count total for many currenceies not in order in one sheet?
    Regards

  7. I'm trying to do an IF(AND multiple times but the results continue to come back as #N/A. I know they are correct because I have individually taken them out and tested it line by line.

    =IFS(AND(D7="Active",$J$9="30"),TODAY()+30,AND(D7="Active",$J$9="60"),TODAY()+60,AND(D7="Active",$J$9="90"),TODAY()+90,AND(D7="Active",$J$9="120"),TODAY()+120,AND(D7="Active",$J$9="150"),TODAY()+150)

    Is there a correct way to structure this? I would appreciate any help on this! Thanks.

  8. I have problem with application of % formula for student concession. My school data has unique parent numbers(repeating itself if he has more kids studying). If a parent has more than 2 kids he is charged 75% and on 4th onward 50%. Concession criteria is first given to lowest class to highest( I have classes 1-12). If any idea for solution it will be great.

  9. Please help, you write formula
    If In Time = 12:00 AM and Out Time=12:00 AM and Off Day,Gazette Day,Leave Day=0
    Result = 1
    If In Time = 12:00 AM and Out Time=12:00 AM and Off Day,Gazette Day,Leave Day=1
    Result = 0
    If In Time = have time and Out Time=not have time and Off Day,Gazette Day,Leave Day=0
    Result = 0.5
    If In Time = not have time and Out Time=have time and Off Day,Gazette Day,Leave Day=0
    Result = 0.5
    ( Result is Absent Days).
    Thank a lot!

  10. Good day
    I am battling to write this formula:
    info available as follows
    I3 req del date
    J3 actual del date
    current formula:
    =IF(J3=I3,"on time",IF(J3I3,"late")))
    and it is working all over the spreadsheet.
    now I want to add : if J3 has no date, what do I have to do to the formula to have the status column be "none"

    • =IF(J3=I3,"on time",IF(J3I3,"late")))

  11. Dear Sir/ Madam

    I want to write formula in excel to increase the cell value by 4 but if sum exceed to more the 10, same will be reduced to maximum 10 as 10 is considered as maximum values.

  12. I want to add no 4 with all the cell elements but if sum exceed 10 it will reduced to 10 as 10 is the maximum value to be increased. Kindly send formula for the same

  13. Sir, how to calculate bonus for Engineering department, we have in 6 departments, accounts, finance, production, maintenance, marketing and engineering. How to use if function for each department and pay bonus, below rs 17000/- we are planing to pay every weekend pay one department

  14. I am looking for a formula to calculate the following
    I have an order form. ie a1 = cmilk b1 = wmilk c1 = cost
    I would like to write a formula to indicate that if either a1 or b1 are not blank (indicating that a choice was made) then calculate the cost and enter this amt in c1 the total cost in this instance is $20. I can't seem to get any formulas to work with both a1 and b1

    Any suggestions? Thanks

  15. =IF(BD153="NO",IF(AW153>7,"R",IF(AW153>6,(AD153*(AW153-6)%),IF(BD153="YES",IF(AW153>6.5,"R",IF(AW153>5,(AD153*(AW153-5)%),0))))))

    plz help i have tow Text in One BD153 Cloum 1 No and 2 Yes
    if NO entered in Cloum than come this Condition - IF(AW153>7,"R",IF(AW153>6,(AD153*(AW153-6)%)

    if Yes Entered in Cloum than come this Condition - IF(AW153>6.5,"R",IF(AW153>5,(AD153*(AW153-5)%),0))))))

    i am entered in bd153 colum yes than both condition are working
    plz Give Answer

  16. Hi help mi with excel I want to create a mls excel which can portray the mark sheets say MTC if ali scores 79 I give him D2 but wat I want is to make a system wic can portray the aggregate say D2,F9,C4 such wic formula should I use to do it and how should I do I it Sam help .....whats up mi on 0704598204 for help bambiiiiiii

  17. Hi I have a problem and hope someone can help. I want a cell to increase in percentage depending on what the other cells percentage is. This is what I have so far but it only works for 8%, 11% and 15% but not for the rest of the formula.
    =IF(C21=11%,I18*120%,IF(C21>=15%,I18*130%,IF(C21>=20%,I18*140%,IF(C21>=30%,I18*150%,I18)))))
    Can anyone help? Thanks

  18. Hi Svetlana, Great to see so many people are being helped. My problem is very small and basic but don't know how to solve it. I have 2 cells A1 = value of Kg, B1 = Value of Manns (Kg/40). I want both the cells to have formula and if the value of one For example B1 is entered then A1 should automatically convert it into kg (Manns*40). and same in the other case, if value of A1 is entered then B1 should be automatically convert the Kgs to Mann (Kg*40). I hope you understand my point. Please help! Thanks! :)

  19. If a=2, if b=6, if c=8 then formula to calculate average of a,b,c

    • =SUM(D15+E15+F15)/3

      would this do it?

  20. Hi there,
    Help please!!
    I need to get the value of last week's report copied into this weeks report.
    The report looks like this, for example:

    Column A: The client name
    Column B: The client type of funding
    Column C: The client risk value

    One client can have 1, 2 or 3 types of funding.

    Then, on the right I copied this week's report:

    Column D: The client name
    Column E: The client's type of funding
    Column F: The client's risk value.

    What I need is a formula for column G to look within all the data set for a matching client (of client in column D), and then display the value for last week's risk IF the type of funding matches.

    If this possible?

    Dan

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)