by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
Need help,
I am trying to return true statement with two cells (C4,C5) equaling Y and every other combination equaling a false statement. Tried this and it did not work
=IF(OR(AND(C4=Y,C5=Y), AND(C4=N,C5=N),(C4=Y,C5=N),(C4=N,C5=Y)),"TRUE","FALSE")
Hi Svetlana,
I am trying to make a formula to pull students that passed all classes.
If I use the example above:
I need to know that every time they are listed in column B they received a "pass" in E
Adam Pass
Adam Fail
Fred Pass
Fred Pass
So it would only pull Fred.
Thank you!!!
Hi Svetlana Cheusheva,
If Sheet1 A2:A20= Jim AND Sheet1 B2:B20= dolar AND Sheet1 M2:M20= Paid Then M2= " Full Paid"
If Sheet1 A2:A20= Jim AND Sheet1 B2:B20= dolar AND Sheet1 M2:M20= Not Paid Then M2= "Partially Paid".
Date Name Currency Status
02-Feb Jim Dollar Partially Paid
12-Feb Jim Dollar Partially Paid
20-Feb Jim Dollar Partially Paid
20-Feb Richard Dollar Partially Paid
31-Feb Jim Dollar Full Paid
I want to sort out finally who is Fully Paid or Partially Paid to another sheet.
Please help me to short out this.
Thanks-
Md Wahid
Hi I am looking to pull a value from a row but if there are more than two values in the row then needs to show error, and the only values that should be there are a "Y" or an "N". if there is another value besides a Y or an N then it needs to pull an error. This is what I have so far but its not working.
=IF(COUNTIF(K2:U2,"Y"),"Y","N")
I have the date in one cell and in the next using the text formula it just shows the year and month. when I drag this formula down the colum I want it to be blank until I fill the necessary cell - can you help me with the formula. I have had a stab at it but not sure if I am even starting in the right place!
=if(text,B2,"yyyy-MM")>0,text,B2,"YYYY-MM"," ")
How to check invoices has been paid or not in excel file. if i have paid invoices details.
hi
I want to know how to create a formula that "if the value is greater than 1 then use "this" formula, otherwise use "that" formula"
thanks
How to make a formula, If column B is less than column A you must add 24 plus column A ( in a new column).
please help:
i need
if a>=15000,a*12%, if (a+b)>=15000, (a+b)*12%, if(a+b+c)>=15000, (a+b+c)*12%
Good morning
Need help with a formula. If C5 is<=10, C7 = 6 & 1, IF 1015 , C7= 8&1. This is for staffing (C7 is number of staff required based on C5 number) . Thank you in advance
dear sir / mam
in excel we given tax rate 12%,18%,28% etc that tax amount should go to particular column please tell madam condition formula
Sorry if this has been asked already. I did try to scroll through to find the answer. I put information into columns K and L. If I put something I to column A, that matches column K, I need column B to pull it from column L. Does that make sense? I know it's an IF, but is it more than one?
Iteam Price Use if function
-10 -14
22 20
-40 33
24 -13
Condition
Iteam Price Result
-ve -ve A
+ve +ve B
-ve +ve C
+ve -ve D
Pls help out with above mentioned criteria
Good Day I need to be able to do a IF but i don't know if it can be done
So i Have a if already
=IF(OR(C6="cow",C6="dog"), "+", "-")
SO i Get answer of lets say +
then i want to say a1 a2 A3
A1 is 1
A2 is now the answer of +
A3 is 2
so B3 should give me a answer of 3
IF the answer was not cow or dog i should get a answer of -1
So how do I make a1 and a2 sum with the +- that is choosen in A2
If cell B4:B40= "Amy" and cell c4:c40= "Rich" and cell d4:d40= "Done" then "Done".
Else "On Process"
Note that number of "On process" has but only one is "Done". If all "On Process" found show "On Process".
If just one "Done" found with number of "On Process" then show "Done".
when utilizing if and, how can i have the result be the data in the cell, for example, my criteria is if the name in worksheet 1column A matches the name in worksheet 2 and the number in column N is greater than 1, place that number here (where I am inputting the formula). Hopefully I explained that, I can get a result of yes or no but I want the number that is greater than 0 to be put in the spot. Thank you
Hi I am looking a formula that captures different values for multiple line items:Can some one help
For example:
Cleveland to Akron 4 miles
Cleveland to Akron 8 miles
Akron to Cleveland 6 miles
Columbus to Cleveland 900 miles
Akron to Cleveland 13 miles
Cleveland to Akron 10 miles
I would like the outcome to be
Akron to Cleveland =6 miles and 13
Columbus to Cleveland 900 miles
Cleveland to Akron 4, 8 and 10 miles
Hello,
I want to get the formulae for the cell content verification that starts with fixed digit middle some variable then last also some fixed digit e.g. if Cell A2 contains ABC123AA & Cell A3 contains ABC567AA then in B2 it should show true & B3 also shows true (in example Starting "ABC" is fixed and ending "AA" is fixed where as middle three number is variable)
Pickup EUR 55.00 < 100kg
EUR 70.00 < 200kg
EUR 80.00 < 300kg
EUR 100.00 < 400kg
base on kg, how to set the formula by different column
Hi. I need a way to determine if members in a household satisfy certain conditions. Forexample I have mutliple households, each with multiple members and I need to determine if anyone in each household earns above a certain amount.