Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4538 comments

  1. Im trying to put values based on country... But I want to be able to change them in one worksheet and they reflect in another... Now is there a way I can make a command/statement which can make excel automatically add a row or column in another worksheet if I input a new country that was not originally specified??

  2. Hi, I am trying to write a formula for the following:

    Cell A1 is a Number ranging between 0 & 400. I want Cell A3 to display the following:
    If Cell A1 is between 0 - 99 = "Text 1"
    If Cell A1 is between 100 - 249 = "Text 2"
    If Cell A1 is 250+ = "Text 3"

    I can make it work for Text 1 & Text 2 but adding a third, breaks the formula...

    If anyone can help me with this, that would be great.

    Thanks,

    Ash

    • IF(AND(A1>=0,A1=100,A1=250,"TEXT 3","")))

  3. hi, i am trying to use OR & AND operator in the following condition but it is not working so please help me in writing the formula
    conditions
    if (A1>0), A1*5*100, OR (B1>0), B1*100 AND (A1>0,B1>0),A1*5*100+B1*100, and if (C1>0) add 0 to previous result or if (D1>0), add 0 and if (C1>0,D1>0) add 0 to the above result
    i tried many times to write the formula by myself but still error message is showing. please kindly help me

    with regards
    singh

  4. Hi kindly help me to do this.
    I have a value in Cell A1. I needs to do that When I put value as "Yes" in cell B1 then the cell C1 pick the value of cell A1 automatically. And if I put value as "No" in cell B1 then the cell C1 pick 0 as a value automatically.

    • In cell C1 enter the following:
      If(b1="Yes",a1,if(b1="No",0))

      • Thanx alot....

  5. Hi kindly help me to do this.
    I have a value in Cell A1. I needs to do that When I type "Yes" in cell A2 then the value of A1 shows as a result in Cell A3.

  6. Add 10000 if 1.98% of the principal is greater than 2000 if not less 1000

  7. Hi,
    i want to convert sign of calculation values like in one cell i have these values "=-4896.71-190+3613.39+90+5086.71" and i need "=+4896.71+190-3613.39-90-5086.71" how i change their signs.

    Thanks in advance

  8. Hi
    I have question if the condition as follow then how the if formula will be transit
    If the total portfolio is 600000 and the condition say that
    From 0 - 300000 you get $1.5/1000 then
    From 300001 - 500000 you get $2/1000 then
    Above 500001 you get $2.5/1000.
    For example if I bring total portfolio $600,000 then for first $ 300,000 I will get (300000/1000*1.5) = 450. Then rest $100,000 I will get (100000/1000*2) = 200 and last $100,000 I will get (100000/1000*2.5) = 250. So total I get = 450 + 200 + 250 =900. How can I do the above in if statement?

  9. Hi
    i am new to excel but i want the value in a cell to be either 7 or 12

  10. hi, i am trying to write a formula for the following:

    1) if R49 is less then 1825 days then M49*50% and if R49 is greater then 1825 days then M49*100%.
    2) and if between these two so pick 50% and 100% Proportionate basis.

    Kindly help

  11. Hello Can someone please help me. I need to trun this formula to a 4 clause insted of 3
    =IF(D274>31.99,"5%",IF(AND(D274>=20,D274<=32),"3%","0%"))

    I need to change it to...

    0$ to 24.99 0%.... 25 to 34.99 3%...... 35 to 41.99 5%.... 42+ 8%

  12. Hello, i have a something to ask. :)
    What will be my formula if I will write
    Always and on the other column and it will automatically respond "5"?
    Example:
    Always - 5
    Most of the Time 4
    Sometimes - 3
    Seldom - 2
    Never - 1

  13. I have two Special Handling Codes one is 6YU and another 6ZO
    We have 3 customers
    6YU APD SHENZHEN DK INC, ASIAN POWER DEVICES INC
    6ZO SENERGY TECHNOLOGY(SHENZHEN)CO.,LTD
    If I choose 6YU SPH answer should be either this APD SHENZHEN DK INC, or this ASIAN POWER DEVICES INC customer
    If I choose 6ZO SPH answer should be SENERGY TECHNOLOGY(SHENZHEN)CO.,LTD
    Can you please help me out of this by using IF formula

  14. Hi Friends,
    Could you help me with the below example.
    if we have 1000 in one column which is splitted in many values in another column with 20000, how to total only 10000.
    In the below example you may see, for each day, we have same amount in two columns but these amount are splitted in third column, how can we match these. Any suggestions.
    Example:
    Monday 1000 2000 500
    Monday 1000 2000 500
    Monday 1000 2000 500
    Monday 1000 2000 500
    Monday 1000 2000 500
    Monday 1000 2000 250
    Monday 1000 2000 250
    Tuesday 2900 1100 750
    Tuesday 2900 1100 750
    Tuesday 2900 1100 600
    Tuesday 2900 1100 500
    Tuesday 2900 1100 500
    Tuesday 2900 1100 450
    Tuesday 2900 1100 450
    Wednesday 1500 2500 750
    Wednesday 1500 2500 750
    Wednesday 1500 2500 1000
    Wednesday 1500 2500 1000
    Wednesday 1500 2500 250
    Wednesday 1500 2500 250
    Thurday 2250 2750 1000
    Thurday 2250 2750 750
    Thurday 2250 2750 250
    Thurday 2250 2750 2000
    Thurday 2250 2750 1000
    Friday 8450 1550 450
    Friday 8450 1550 550
    Friday 8450 1550 2000
    Friday 8450 1550 3000
    Friday 8450 1550 1000
    Friday 8450 1550 1000
    Friday 8450 1550 2000
    Please help.

    • use sumif formula for that.

  15. Hi,
    I am trying to convert to date format from column A "20190520" to column B "05/20/2019"
    please advise. Thanks in advance.

    • highlight column, click "text to columns" in the data tab. Then bubble in delimited, click "next" twice, bubble in Date and use "YMD" in the dropdown and click finish.

  16. Hi
    I have three suppliers like A B C,the three suppliers given material price ,i should format three column now i want least supplier name in new column, how to i calculate this format in excel

  17. I wish to know how to use IF formula for conditions as under:
    1: M-W:I/II T-S:III/IV =1
    2: M-W:I/II =.5
    3: M/T:I W/T:II F/S III =1
    4: M/T:I =.5

  18. I'd like to create a formula for a calculation:

    Up to $100,000 total price, the cost is $5.75 per $1,000 of price.

    Above $100,000 total price, the cost is $575 plus $5.00 per $1,000 of price.

    Thank you!

  19. Hi Everybody,
    I have a problem in if function with following conditions:
    1. I have 4 words in C3, C4, C5 & C6 and each word has condtion 1 and otherwise condition 2 if not returns false
    2. I want to add both conditions againt each word in a single formula
    I.e. if(C3="a", condition 1, condition 2, if(C3="b", condition 1, condition 2, if(C3="c", condition 1, condition 2, if(C3="d", condition 1, condition 2))))

    But it does not help me out.

    Requested to please help me in this regards

    Waiting

    • if(C3="a", condition 1, if(C3="b", condition 1, if(C3="c", condition 1, if(C3="d", condition 1, condition 2))))

  20. Hi,can you write a formula for the follow these question for me,
    IF cell A1 = JENNIFER then value will be 2000
    IF cell C1 is less than 40 multiply it by 2
    IF cell C1 is grreater than or equal to 40 but less than 100, then multiply it by 4

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)