Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4538 comments

  1. If a column has values as A2=product price,A3=Service price,A4=List Price and A5=Contract Type 1, A6=Contract Type 2,A7=Contract Type 3.What is the formula to populate Pricing as a value in cloumn B2,B3,B4 & Contract as a value in column B5,B6,B7.

  2. How would I write the IF statement for the following? Or maybe it's something else.
    Sheet 1.
    Column A (name)
    Jay
    Sam
    Grant
    Dave
    Column B (LVL)
    Cell B2 = 1
    Cell B3 = 3
    Cell B4 = 2
    Cell B5 = 3
    Column C (Stage)
    Cell C2 = 1
    Cell C3 = 3
    Cell C4 = 2
    Cell C5 = 3
    Column D (Price)
    Cell D2 = 500
    Cell D3 = 300
    Cell D4 = 350
    Cell D5 = 10,000
    I need to pull this data to another sheet (Sheet2), Sheet2 has three results; Column A-Name B-Safe (LVL and Sage =1), C-Commit (LVL and Stage =2), D-longshot (lvl and Stage = >3)
    If LVL and Stage equal 1, then I need row B Safe.
    If LVL and Stage are 2 then put D in Sheet2 Column C (Commit), if the Stage is not equal to 2 Than the results in C a placed in Longshot.
    My issue is pulling the Price (Column D)
    Any help would be great.
    Thanks,
    Jay

  3. I need assistance with the formula.
    Eg:
    If I write "Pass"in Cell J2 then I need Cell J3 updated with number value like "5"

  4. Sir,
    I have question.
    Suppose there are 3 columns in excel. If column-1 contains data or value, then column-3 will be column B*10% either B*15%.

  5. Need some help, have been trying to figure this out for awhile. How would a formula look:
    If a cell has 1 it would be $7 if more than 1 $6?

    need some help

    • =if(A1=1,7,6)

  6. A1, C1, E1 and G1 >=1 IF TRUE RESULT "PASS" IF FALSE RESULT "FAIL"
    B1, D1, F1 and H1>=1 IF TRUE RESULT "PASS" IF FALSE RESULT "FAIL"
    EACH CELL MUST >=1 SO PASS, IF ONE OF THEM 0 RESULT "FAIL"
    Please help me. How can I solve the problem?

    • =IF(SUBTOTAL(6,A1:H1)=0,"FAIL","PASS")

  7. How would I combine these 3 formulas
    Basically I need to look at the amount in B5 and if it's greater than 98 return 200.00 if between 90-97 return 100.00 and if under 90.00 return 0.00
    I have the 3 separate formulas but can't seem to get them into one formula.

    IF(B5>98%,"200.00",0)
    IF(AND(B590%),"100.00","-")
    IF(B5<90%,"0.00",0)

  8. Please help me.
    In two different rows with two columns. The first column (A) will contain the value and the next column (B) will contain the calculated value (formula). A formula has been entered in the first row of the second column (B1) and it has been extended down to the second row (B2) using the fill handle tool. (Say if A1 is 50, a student has "passed", and if not the student has "failed"). No values have been entered in either of the cells that should contain the data. By this the cells containing the formula will show "failed" since no value has been entered in the columns containing the the data.
    I want a formula if I enter a value in A1, it will show the results in the next column but the whole row of row 2 containing any data should go off/clear off including the calculated results "failed".

  9. Hi,
    I have different currency rates which I want have an IF function to link the correct rate to a different tab depends on what currency on that tab is. Below is my example
    CAD USD
    FX Rate 1.3036 1.1198

    If my next tab currency is CAD, I would like the rate for it to automatically equal 1.3.36, otherwise, it will be 1.1198.

    Can someone help me with a formula for it?
    Thanks in advance

  10. I have a complex if statement to create a dashboard that I need to amend to use data from other worksheets. When I select 'Cats' or 'Dogs from the drop down, the relevant information SHOULD be displayed in the dashboard 'feed plan' eg:
    =IF(AND($J$1"All Pets",$J$1Q4),0,OFFSET(Cats!$B$1,'feed plan'!$I3,'feed plan'!J$3))
    Where 'All Pets' and 'Cats' are tables. I want to update this to use the data in table 'Dogs'. Every time I change 'Cats' to 'Dogs in the IF..statement the information in 'feed plan' that should stay as 'cats' is updated with 'Dogs'. What am I doing wrong?

  11. Kindly help with suitable formula for C=A-B but should not exceed 15000

    • Hi Praveen,

      And if A-B exceeds 15000, what is a C cell to display?

  12. I need to get the formula for below
    I have 3 scenario's as below

    1 Night = $ 8.5
    2 Night = $ 17
    3 Night & Above = $ 22
    My report comes with the number of nights guest stayed I want to to pick the total amount if guest stayed for 1 night then to pick $8.5, if for 2 nights then $ 17 and if for 3 night& above $22

  13. I want to write a formula:

    If column B2 is higher than 10000 and lower than 20000, put 100 in column c2

    • Hi Laya,

      Here goes the formula for C2:

      =IF(AND(B2>10000, B2<20000), 100, "")

  14. I have been trying to nest an IF formula with 5 rage but 6 of them are not working out. Please let me know if you have the same issue.
    =IF(H104>15,"E",IF(H104>11,"D",IF(H104>8,"C",IF(H104>4,"B", "A"))))
    Vlookup Table
    1-3
    4-7
    8-10
    11-14
    15+
    Thanks

  15. HOW DO I AUTOMATICALLY COLOR A CELL BASED ON THE FIRST 2 LETTERS OF A TEXT?

    • Use conditional formatting and format rule if text start with

  16. I trying to apply the if formula but i was failed every time please help me out.
    my concern is that i need if value is less than 12000 than i get result 2% of value otherwise get 25% .please give me solution

  17. I have a question if I have
    A1 = keep the change
    B1 = 0.50

    I would like a formula for whenever I have keep the change it's will always give me the next cell reference for example in Sheet 2. A1 = same and B1 = equal the same number. What formula should I use to get that. Please let me know thanks.

  18. Hi, can someone help me to create formula according to below condition??
    Table 1
    Type>> 6-800 6-500 6-100 6-200
    Item<<
    Book $10.00 $15.00 $- ??
    Table $100.00 $- $200.00 ??
    Copy $5.00 $10.00 $30.00 ??
    Pen $7.00 $8.00 $- ??
    Pencil $2.00 $3.00 $- ??
    Paper $1.00 $2.00 $5.00 ??

    Table 2
    Item Type Price
    6-800 Book $10.00
    6-800 Table $100.00
    6-800 Copy $5.00
    6-800 Pen $7.00
    6-800 Pencil $2.00
    6-800 Paper $1.00
    6-500 Book $15.00
    6-500 Copy $10.00
    6-500 Pen $8.00
    6-500 Pencil $3.00
    6-500 Paper $2.00
    6-100 Table $200.00
    6-100 Copy $30.00
    6-100 Paper $5.00
    6-200 Book $100.00
    6-200 Pencil $50.00
    6-200 Paper $10.00

    I want the formula which will fill the Table 1 with data from Table two.
    Condition are if Type & Item from Table 1 matches with single column(Item Type) of Table 2 than return value form Price column.
    Thank you,

  19. Can someone help me write a formula that searches a list of data to see if the word Holiday is in there, if it is it sums all the other data together except that cell. If it doesn't find the word then it sums all the data in the column. If all cells are empty it returns an empty cell.

    Thanks

  20. Hi Svetlana
    Need your help and guidance to solve the following problem

    I have set of 85 readings of at test done on a unit taken from DAQ (Data acquisition system), and i have populated in a table in excel. Now i need to insert a condition in the cell, specifying that if any five consecutive readings taken from the 85 readings surpasses number "100" than the test is failed , if no five consecutive readings surpasses number "100" than test is " Passed"

    Hope the above info is enough for you to solve the problem.

    Best Regards
    Aditya

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)