by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
I am in need of a formula that would allow for the following in one cell:
If field 1=A, and field 2=I, then field 3=Low, or, If field 1=A, and field 2=II, then field 3=Low, or, If field 1=A, and field 2=III, then field 3=Low, or, If field 1=A, and field 2=IV, then field 3=Moderate, or, If field 1=A, and field 2=V, then field 3=High
My issue is there are 5 data possibilities. How do I write that in a formula?
I II III IV V
A Low Low Low Moderate High
B Low Low Moderate High Unacceptable
C Low Moderate Moderate High Unacceptable
D Low Moderate High High Unacceptable
E Moderate Moderate High Unacceptable Unacceptable
Sir.,
I want to find a formula for gradeing
Using 4 subject marks and total ‰age
For example
Sub1=30
Sub2=85
Sub=80
Sub4=85
Now %age is 70
If we use IF function it show "A" grading
But fail in sub 1
So i want to show in result FAIL
PLZ
=IF(IF($AI278>0,(IF(MONTH(AO$21)MONTH($AI278),0)))),$AF278),IF(MONTH($J278)>MONTH(AO$21),0,IF(MONTH($J278)<=MONTH(AO$21),$AF278)))
this FORMULA show FALSE I NEED TO SHOW 0
WHAT IS MISSING
=IF(And(Sheet1!F30>0,Sheet1!F30<=1)),1,0) is it correct
great explanation.
How do I create a formula that returns a projected date value based on more than one other set of data? Example: current formula is =IF(G5"",G5+60,""), but I want to include in this if another cell is YES, then the formula changes to G5+65.
How will you explain =IF(DAY(H18)=1;H18;"")
Formula .. We have an excel kalendar that needs to be revised for leap year
Help! Can I change all instances of say, "October", in column I, to "November", only if column B says Traffic Stops?
=IF((Z18-AA18-AB18)>(AC14-AC11),(AC14-AC11),(Z18-AA18-AB18))
My Answer In Negative
But I want Answer In positive
*Minimum Answer is Zero Not less Then Zero
So Can you Help?
Hi, I want to check if the 2 values i have in tab 1 has also in tab 2. example, in column A I have numbers.. 1, 2, 3 ……, in column B i have letters A, B, C ……….. I want to check if I have the same digits in other tab, eg. 1A, 2A, 3A etc... thank you.
Hi: Svetlana Cheusheva (Ablebits.com Team)
i am marking participants Hours: as =IF(C3>=1,"Present","Absent")
I want it to show no value if the cell (C3) is empty or has no value instead of "Absent"
whatsapp +92-345-6165677
Good Evening,
I am hoping that you could help me with understanding what formula to use. I am very new to excel so this is probably pretty easy. But i would greatly appreciate if you could assist. Thank you!
Two columns of numbers (Column A and B). I need to add up the sum of the numbers in column B, however, if the number in Column B is greater than the corresponding number in Column A, it needs to count column A's number for that line instead.
example:
A B looking for sum
725 454 = 454+65+1+4+"15"+8+"5", etc.
86 65
45 1
45 4
15 45
45 8
5 31
45 28
41 1
4 84
5 45
123 8
456 52
45 8
15 5
78 8
45 4
7 8
96 45
13 7
79 84
7456 87
4 5
8789 754
76 8
78 4
76 8
4 48
89789 1
45 82
8
978 8
5 74
8 8
78 4
8 8
7 45
7 48
I'm trying to construct a spreadsheet that has an input of several measurements, and M or F and based upon that calculates a value. But I'm can figure it out.
=IF(U2="M",359.34+0.265*(R2*S2*T2), (U2="F",296.4+0.275*(R2*S2*T2)
Thank you
Hi,
I need a formula for my report. I need to get the result for the trace level column. If Clearing has number, result should be "Cleared" in Trace Level Column. But if Clearing column has no number, and Aging column is Over 120Days, Trace Level should be Trace 5. Below is the sample. Hope you can help me with this.
Clearing Aging Trace Level
1123456 Over 120 Days
5846821 91-120 Days
31-61 Days
5846821 1-30 Days
0 Day
Good day
Can you Please be so kind as to help me out
I am trying to do a formula where if I enter a number from 1-10 each number will represent a differt total in another cell
1=25
2=38
3=47
4=63
5=71
6=82
and so on, This is not the correct numbers.
How would I Formulate say if I put 1 in CELL A1 then the Total that represents 1 Should apear in CELL C3 for instance?
Hi,
I have both "number" and "text" in the same cell. Like "A123". In such case comment should reflect as "Invoice received". Please help
Regards,
Prashanth N B
1000 TO 2000=50
2001 TO 2500=60
2501 TO 3000=70 PLEASE CONVERT TO EXCEL FORMULA
Hi,
I am trying to use the IF,AND function to calculate what tariff should be applied.
Three types of rates: Standard, Out of Hours and Bank Holiday
Three Type of Van: Small, Transit LWB
I have tried the following: =IF(AND(C4="Standard",C5="Small),£23,IF(AND(C4="Standard",C5="Transit", £25.....
OOH = Standard x 1.5
BH = Standard x 2
Any ideas
which formula we can use if our value is 30 then multiply by 2, if 31-60 then multiply 4 and if value is grater than 60 then multiply by 5
I am trying to find a way to make this all work so that it will give me the new value.
if value is between 0 and 3999 multiply by 3% if value is between 4000 and 5999 then multiply by 10% if value is grater than 6000 multiply by 14%
=IF(AND(A1>=0,A1=4000,A15999,A1*0.14,"")))
Swap A1 for the cell which contains the value you wish to multiple.
"=IF(AND(A1>=0,A1=4000,A15999,A1*0.14,"")))"
The first formula didn't post correctly