The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
Can someone please help, if is score in 6 boxes 60 or more to add additional 30 on final result but if is 59 and below to have exact score. Thanks
hello, i am trying to get a if statement to work, here is my scenario:
IF(COUNTIF(Data!J:J,"R")>=50%,"R",IF(COUNTIF(Data!J:J,"A")>=70%<95%,"A","G"))
i have a list of R/A/G entries that get updated regularly, so the count will always change, i am trying to say if the "R" count is greater than 50%, but lower than 70% give an "R", if the count is between 70% and 94% Return an "A" and if the Count is greater than 94% than return a "G", these counts are based on the total amount of rows that are populated.
i also need to have another formula that states that if they are all under 50%, sort of like 33%R, 35%A and 32%G, to return the highest amount, with the numbers presented it would be "A". i have found this challenging to figure out and hope someone there can help
thank you
Need help with creating a formula based off this statement,
If Gross profit <= 15,000, then taxes = Gross profit X 20%, Otherwsie taxes + Gross Profit x 39%
the cells i am currently using is Gross profit is G12 and my Taxes cell is B24
Thanks
Pls guide I’ve 2 vehicles (Vehicle 1 & 2) in Column C, both mileages in column E should multiply by different values and need answers in column F. Please advise the formula?
How can i write - (minus values in nested if functions
whats the formula if i want to calculate the total QTY that has a value only. Currently i have qty with number but no value, so i want to only count qty with actual value
I want to write a simple Conditional format rule -
If column H contains either texts - VTA or ADI or SBI , value in column P should be a difference of (Value in Column O - Value in Column G)
Please help or guide me where to look
Hi Abhay,
Here goes the formula for P2:
=IF(OR(H2="vta", H2="adi", H2="sbi"), O2-G2, "")
Just copy it down to as many cells needed.
How to make formula. If Cell4 = Cell1, but if Cell2 has data then Cell4 = Cell2, like wise if Cell3 has data then Cell4 = Cell3. So in short Cell 2 and 1 will not be shown or be read if the Cell3 has data. More likely an updating formula. Please help Thanks
Hi
Please solve this problem
80% -90% 1
91% -99% 2
100%-110% 3
111%-120% 4
>120 5
Hi need formula below mentioned
i want result 1 2 3 45
80% 90%
91% 99%
100% 110%
111% 120%
>120
Hi,
I need a formula IF value in J8 is less than 0 add J8 & G9, IF more than 0 add J8 & C9.
Hi,
I have a number of figure ranges that have corresponding different values. What is the formula to automatically calculate the value applicable when given a figure within one of the ranges?
Ranges and their corresponding values are:
0.005 - 0.025 = 5
0.025 - 0.05 = 7.2
0.05 - 0.1 = 16.3
Thanks.
Hi,
if b2 equals 1 I need the calculation to = 4 and if b2 is 2 then I need the calculation to = 8
I'm trying to write an logical statement to do the following:
Assume the statement is in Range Name "Question"
If Value in Range Name Value = 3
Then Question = Value
and
Range Name Result = Value
The first part is ease [If(Value=3,Value)]
But if I try [IF(Value=3,AND(Value, Result=Value)] it doesn't work.
Is there a way to set value in a named range from a statement in a cell/range not where the value should go?
Thanks
Hi,
I want to compare vales in two cells and assign a value in 3rd column with multiple conditions, e.g.,
If (I4="H" & K4="H") OR (I4="M" & K4="H") OR (I4="H" & K4="M"), assign number 1 to L4
OR
If (I4="M" & K4="M") OR ( I4="M" & K4="L") OR (I4="L" & K4="M"), OR (I4="L" & K4="H"), OR (I4="H" & K4="L), assign number 2 to L4
OR
If (I4="L" & K4="L"), assign number 3 to L4.
Thanks.
Humbly,
manju
=IF(($D2="legendary",RANDBETWEEN(500001,1000000),IF($d2="veryrare",RANDBETWEEN(5001,50000),IF($d2="rare",RANDBETWEEN(501,5000),IF($d2="uncommon",RANDBETWEEN(101,500))))))
I am trying to make a shop pricing algorithm for my D&D campaign that will generate random prices based off of item rarity. so far I have a list of about 500 items each assigned a rarity uncommon, rare, veryrare, and legendary, in the D column. I am using column F to generate the costs for each item using the formula above. anyone have any ideas why this is creating an error and how to fix it?
I need a formula to fill a cell with text (5 possible text outcomes).
I need several cells to be checked to decide which of the text options are filled, (5 different cells to check).
eg, if cell b=No fill with 'text a', if = yes check cell c, if c = no fill with 'text b', if = yes check cell d and so on.
IF(A1>0 THEN A1/B1,A1/C1,A1/D1)
RESULT SHOULD SHOW FIRST DEVIDING RESULT AND IF FISRT DEVIDING RESULT BE 0 THEN SHOULD SHOW SECOND DEVIDING RESULT IF SECOND DEVIDING RESULT BE
ALSO 0 THEN SHOULD SLOW THIRD DEVIDING RESULT.
HOW CAN I MEET FOLLOWING CONDITION IN A SINGLE CELL
Hello Community!
Would really appreciate if someone can help.
My case is:
I have 3 columns of varying data points.
I need to scan through the first two columns - and if both rows of data match - I need to run a secondary function where I say compare the values of the 3rd column - and give me the largest number.
Example (not necessarily what I am attempting to do):
Column A contains all First Names
Column B contains all Last Names
Column C contains all ages
I need to find every instance of "John" (column A) "Smith" (column B) and then return me the "oldest" age (column C).
Thank you everyone for your help! Greatly appreciated.
Can I use excel to start the second operation only after completion of the first. Also note, the operations are in test form and not numbers.