by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
Hi,
I would liek to come up with a formula to calculate the completion rate of an action plan,I have 3 dates : Date whan the action added to the list, the target date(due date) and the completion date.
If the completion date is empty(action not completed) and the target date inferior of the today's date the result is 100%
If the completion date inferior or equal to target date the result is 100%.
If the completion date superior to target date the result is (completion date- target date) / (Completion date-date added).
Can you please help
Thanks
Hi guys,
Need help, basically I need to add 15% to a cell value based on the value of another cell. its to do with weight, so for every 1000 "pounds/kilograms", I need to add 15% to the fuel consumption.
=IF(AND(B16>=1000),B5*15/100,IF(AND(B16>=2000),B5*30/100))
This is the formula I have, any advise/support/help will be greatly appreciated. happy to share the sheet if that will help
Hi Mark,
Please try the following formula to solve your task:
=ROUNDDOWN(B16/1000, 0) * 15/100 * B5+B5
Is there a formula for:
If Column A contains the letters "REQ" and column B contains the word "Accepted", then column C shows "Status w/ Acceptance"?
And if Column A does not contain the letters "REQ" and column B does not contain the word "Accepted", then column C shows "Status w/out Acceptance".
Thanks!
Hi Crystal,
Here is the formula for you:
=IF(IFERROR(FIND("REQ", A1, 1)*FIND("Accepted", B1, 1), 0) > 0, "Status w/ Acceptance", "Status w/out Acceptance")
My Mean If any one subject get below 40 marks get fail and dont show any thing in cell, if get good marks show A-1, A, B, grades.
S.No Name F Name Eng Maths Science Social Total % Rank Grade
1 Sam David 84 85 85 85 339 84.75 Pass A
2 Frank Joseph 100 60 50 80 290 72.50 Pass A
3 Mark Tom 99 42 85 40 266 66.50 Pass B
4 Dave Smith 40 42 40 40 162 40.50 Pass C
5 Jhon Gill 40 25 40 40 145 36.25 Fail Blank Cell Required
Question:I want to put in this cell with Vlookup formula a new formula with above formula for If Pass Show Grade If Fail Don’t Show any thing (Blank)
using =VLOOKUP(G6;K$1:L$5;2)
i am looking for a formula where a letter appears in A11, (A to E)
depending what that letter is determines which cell i want data for.
-If A11 equals "A", then A41
-If A11 equals "B", then A42
-If A11 equals "C", then A43
-If A11 equals "D", then A44
-If A11 equals "E", then A45
whats the best way to do multiple arguments for the data?
Hello Steve,
It looks like the following formula will do the trick:
=IF(A11 = "A", A41, IF(A11 = "B", A42, IF(A11 = "C", A43, IF(A11 = "D", A44, A45))))
Hi,
I am looking for a formula which will autopopulate value of "Primary" if the time start is 8:00 to 17:00 and 'Non-Primary' if the value is set to the other part of the clock, primarily 17:00-24:00 and 0:00 to 8:00.
Any pointers would be awesome!
Thanks in advance!
Christina
Hi Christina,
Please try to apply the following formula:
=IF(AND(HOUR(A1) >= 8,HOUR(A1) <= 17), "Primary", "Non-Primary")
Where A1 is the cell that contains the time.
Respected,
I hope you are doing well. I have stuck in a problem and I hope you will solve my this issue.
I have a sheet of employees of an organization which include their salary designation etc. I have to search a designation which give me the full details of all employees (at the same position) .
I hope you have understood what I want to ask
Hello Folks,
Kindly advise how to do this excel formula correctly.
Cell B1 has Data Validated with list of (A,B,C,D)
Cell E5 has a number to be multiplied with
Cell F5 has formula i.e. =IF(B1<=A,(E5*0),IF(B1<=B,(E5*7),IF(B1<=C,(E5*21),IF(B1<=D,(F5*30),(E5*21)))))
Your guidance if much appreciated.
Test - 1 Marks - 70
Test - 2 Marks - 65
Test - 3 Marks - 78
if a student gets more than 70 in any two tests from the above then he/she will get A otherwise F. Then what will be the formula??
Thanks in advance.
Hi Nik,
=IF(COUNTIF(A2:C2, ">70")>=2, "A", "F")
Where A2:C2 are the test marks.
It’s hard to come by experienced people about this subject, but you seem like you know what you’re talking about, keeping the good work up! Thanks
I have one doubt
I am making result I wanted to do if a student fails in 1 subject then excel shows supply if he fails in 2 subjects then excel shows 2 supply but if he fail in 3 or more than 3 subjects then excel shows it Fails Whats the formula I can apply?
I am trying to use the IF Function (or any formula) to SUM for a particular date depending on if the date also has the exact name attached to it. For instance, I want a cell to calculate how many hours a person "John Doe" participated on a seperate sheet for a calendar month to populate on a calendar on a seperate sheet. It is only dependant upon the date and name, nothing else. How do I do this?
the values has to be in specification, if it is entered between the specification values have to accepted by column. If values are exceeded or lowered it would be "0" or highlighted. How to do this in excel by using VLOOKUP or IF CONDITION? eg;spec: 50-80 if I enter 65 it has to be the same, if I enter 81 it has to be noted by excel
Dear Expert,
I have to use a formula for retrieving the value based on multiple cells, I have tried multiple options using IF, AND but I cant achieve the results.
Let me try to add the query to explain (only few examples) however this has to be replicated until last line.
I already tried different formula as below but I can achieve the result maximum upto 2 values, not nested upto last lines.
=IF(IF((AND(H5>=2,I5>=4)),"V2","V1"),(IF((AND(H5>=4,I5>=8)),"V3","V2")))
=IF(OR(AND(I5>6),AND(H5>=2,I5>=4),AND(H5>=4,I5>=8)),"V3","V1")
- if Value in the "vC" cell is 2 and value in "Me" cell is 4 then category should come as "V2"
- if Value in the "Me" cell is more than "6" because that is maximum limit then category should come as "V2"
- if Value in the "vC" cell is 4 and value in "Me" cell is 8 then category should come as "V3"
Default Size Max size
Category vC Me vC Me
V1 1 2 2 6
V2 2 4 4 20
V3 4 8 8 40
V4 8 16 16 32
V5 16 32 32 96
V6 16 64 16 192
V7 32 128 64 128
V8 64 128 64 384
V9 64 256 64 256
HI, I could really use some help making an if/then equation:
-If A2:F2 equals 0, then "1"
-If A2 > 1, and B2:F2 1, and C2:F2 1,then "3"
-If C2 > 1, and D2:F2 1,then "4"
-If D2 > 1, and E2:F2 1,then "5"
-If E2 > 1, and F2 1,then "6"
-If A2:E2 > 1, and F2 > 1, then "7"
Thanks!
hi
i need 6 contion in same cell
=IF((AND(AW8<0,AY8(AZ8*AW8)-AY8)))
can you please correct it
How do I nest multiple IF statements + AND in this case.
Columns C1 = 2000; C2=1500; C3=2000
Row H1 = 1250; H2=3000; H3=1400;
Row S1=1; T1=0; U1=1; V1=1; W=0
Formula I am trying to fill Row AA1 BB1 CC1
AA1- I want this cell to be filled with 0 if S1=1 and H1C1 as well as S1=0 and H1<C1.
I want the cell to be filled with 0 ONLY for S1=1 and H1<C1. If S1=0, I don't need to check for H1<C1. We can by-pass and fill the cell with text "NF". Please help me out on this.
Can you change it to "you performed well" instead of "you performed good?"
Done, thank you!