by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
I need a formula that essentially says the following:
if a2 is " a" and b2 is "no" c2 is 1
if a2 is "a" and b2 is "yes" c2 is 2
if a2 is "b" and b2 is "no" c2 is 3
if a2 is "b" and b2 is "yes" c2 is 4
I tried if(or(and) but I can only get two results with that formula. Can someone help?
=IF((AND(A2="A",B2="NO")),1,IF((AND(A2="A",B2="YES")),2,IF((AND(A2="B",B2="NO")),3,IF((AND(A2="B",B2="YES")),4,0))))
=IF(A2="a", IF(B2="no",1,2), IF(A2="b", IF(B2="no",3,4)))
Should be typed in C2
=IF(OR(AND(A2=a,B2=no)),"1",IF(OR(AND(A2=a,B2=yes)),"2",IF(OR(AND(A2=b,B2=no),"3",IF(OR(AND(A2=b,B2=yes)),"4"))))
Hello,
If we understand your task correctly, you need to create a few helper columns:
- Column G: G1 - "a", G2 - "a", G3 - "b", G4 - "b"
- Column H: H1 - "no", H2 - "no", H3 - "yes"
- Column I: I1 – 1, I2 – 2, I3 – 3, I4 – 3
Then enter the following array function into C1:
=INDEX($I$2:$I$5, MATCH(A2&B2, $G$2:$G$5&$H$2, $H$5, 0))
Press Ctrl + Shift + Enter for this array function to work and copy this formula down the column. Hope this solution will work for you.
Sir, Please write this formula in C2.
=IF(AND(A2="A",B2="NO"),1,IF(AND (A2="A",B2="YES"),2,IF(AND(A2="B",B2="NO"),3,IF(AND (A2="B",B2="YES"),4,""))))
I am trying to do a formula:
Column j minus column L but only if there is a value in L if there is no value then it equals 0.
Hi! I need to show "Retained" if 3 or more failed, "Conditionally Promoted" if 1 or 2 failed and "Promoted" if no failed. I used this formula but it only shows two arguments and I'm having difficulties inserting the other argument.
=IF(COUNTIF(M25:N39,"Failed")>=3,"Retained","Promoted")
Please help. Thank you!
I want to do a vlookup between 2 workbooks and the if the values match then I need to output a cell value from workbook 2 into workbook 1. For example: If W1.A1=W2.A2:A1000 then populate with W2.appropriate cell value in column D. I have the vlookup working but having a hard time getting it work with the if statement and outputting the appropriate cell value.
Hi!
In using Data Validation, I'm trying to include that text should be in UPPER case when using the formula below:
=IF(F3=''",TRUE,IF(ISERROR(SUMPRODUCT(SEARCH(MID(F3,ROW(INDIRECT("1:"&LEN(F3))),1),"0123456789abcdefghijklmnopqrstuvwxyz"))),FALSE,TRUE))
Any help would be appreciated.
Hi!
I'm trying to find a formula for a kid to practice the irregular verbs on excel, it makes me practice excel formulas too..!
I'd like to have a formula that says: if the content of 2 cells (the one with the correct answer and the one which needs to be filled out by the kid) is equal AND the next 2 others are equal too etc... (the whole line made up of 4 cells has to match the line with the correct answers). If it does, then display "correct", if not, display "Wrong".
I've tried this one but it's obviously wrong
=IF((AND("B4"=G4, "C4"="H4", "D4"="I4", "E4"="J4")), "Correct", "Wrong")
I hope this was clear enough ... Any help would be much appreciated!
Thanks,
Emma
good tips, but pls. note that this is wrong: "=IF((AND(C2>=20, D2>=30))"
it works only with ; instead of , like this: =IF((AND(C2>=20;D2>=30))
Hi Bácskai,
That depends on which List Separator is set in your Regional Settings: in North America it's the comma, in most European countries - semicolon.
i HAVE THIS WORKING BUT RETURNS #VALUE! IF AP2 IS BLANK
=IF(AND(AP2>0,C2="DIRECTOR"),SUM(AS2*0.035)/12*AP2,SUM(AS2*0.0575)/12*AP2)
i WANT IT TO ALSO RETURN BLANK IF AP2 IS BLANK - NEED HELP
I'm trying to make a formula so that one cell reads 10, 5 or 0 depending on what's in the cell before it. However, the cell before it would have text or phrases that determine the 10, 5 or 0 score. Here is what I have so far:
=IF(B13="Gravel","10",IF(B13="Grass","5","0"))
In addition to Gravel=10, I'd like Bare Soil, Fallow Land, and Poor Farm to also equal 10. How can I add these phrases?
How I make if condition aganist below article.
A2 row have some time appear data.[A2 row is also set formula{=}].
Above mentioned formation as showing A2 Row.(60-62-2038-11011K-N).
When data appear in A2 row then I want to show 1st row(A1) will appear "Line list".A2 haven't data then A1 is also doesn't appear data.
How can I set this , could you please help me.
Please help me and suggest a solution.
How I make if condition aganist below article.
A1 row have some time appear data.[A1 row is also set formula{=}].
Above mentioned formation as showing A1 data.(TP-66-67-U144-114-WF-A5R-0003).
When data appear in A1 row then I want to show 3rd row(A3) will appear "C".A1 haven't data then A3 is also doesn't appear data.
How can I set this , could you please help me.
Can someone help me with a formula to show if learner has passed or failed a Grade, whereby to pass a learner has to meet the following subject requirements
Home Language >= 50%
First additional Language >=40%
Any other 3 subjects >=40%
Any other 2 subjects >=30%
Thanks
I am trying to put together the following functionality but have no idea where to start. Is there a way to tie all this functionality together to produce a result in one cell based on the following criteria?
IF B2>0 then AD2*.0075
IF C2>0 then AD2*.0025
IF D2>0 then AD2*.0025
IF B2 & C2>0 then AD2*.01
IF B2 & D2>0 then AD2*.01
IF C2 & D2>0 then AD2*.005
IF B2 & C2 & D2>0 then AD2*.0125
Hi...
one of the excell cell showing text like"Direct Billing - 35% of deal value" but in formula bar same cell is showing only "35%". how is it possible
Hi,
IF C1="Personal" is there a way to get excel to display certain rows? so if C1="Personal" rows B3:B6 will display.
Thanks
if type a text in A1 cell "A", in A2 cell the value i want is "0" so what formula should i use , please help
How I calculate using the condition of 25% of old salary ,if qualification is MA and sex Female, 15% of old salary ,if qualification is BA or BSC, 17% of old salary ,if qualification is MA or MSC and 20% of old salary, otherwise
Hello Kassahun,
Please try the following formula:
=IF(AND(C2="Female", B2="MA"), 25%, IF(OR(B2="BA", B2="BSC"), 15%, IF(OR(B2="MA", B2="MSC"), 17%, 20%)))
Just copy this formula down the column if necessary.
PLEASE HELP CHECKING THE VALUE of another sheet those have "1JR" text value and with the lower age value 5 and below.. if satifies both cell value then will get the particular cells surname or firstname of that person in the sheet.
sample but not working..the formula below
=IF('Competition Entry'!D4 ="1JR",'Competition Entry'!F4<=5,'Competition Entry'!C4)
Is there a way to write a formula with multiple IF AND functions that will go to a VLOOKUP? I need to match a table with up to 20 entries up with two different criteria, i.e. "IF condition 1 is A, AND condition 2 is C, then VLOOKUP table E. IF condition 1 is B, AND condition 2 is C, then VLOOKUP table F".
Thank you in advance
Hi
I'm working on a points generating spreadsheet for a dance school...
I need to know the best formula to use if I have a "key" of points (eg. straight final = 0 bonus points, semi final = 1 bonus point, quarter final = 2 bonus points etc.)
Eg CELL C2 = QUATER so D2 should = 2.... but the administrator should only have to fill in the rounds danced (C2) - D2 should be a calculation.
Thank you
Carlyn