by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
what is the formula if one column contains text and we want to copy that in next column and below it until another word appears in the some column within excel?
E.g
1- Next Company Model Management
2- NO TOYS DE
3- Nur Management
Above data needs to be converted into folowing in next coloumn:
Next Company Model Management
Next Company Model Management
Next Company Model Management
Next Company Model Management
Next Company Model Management
Next Company Model Management
NO TOYS DE
NO TOYS DE
NO TOYS DE
Nur Management
Nur Management
Nur Management
Nur Management
IF(A3=70,A3=75,A3=85,A3=95,"C3*2"))
can someone correct this formula for me
HI
QUESTION.. IS THERE AN EASIER WAY THAN: =IFS(AG21=0,"+3",AG21=+1,"+3",AG21=+2,"+3",AG21=+3,"+3",AG21=+4,"+3",AG21=+5,"+3",AG21=+6,"+3",AG21=+7,"+3",AG21=+8,"+3",AG21=+9,"+3",AG21=+10)
THANKS FOR YOUR HELP
=IF(A1=0,0,IF(AND(A1=1, B1=3,1)
Tried this formula for the above but it is not working. Can someone please check? Thank you.
Column A is lates
Column B is minutes of lates
If Lates is 1 and minutes is less than 15, Warning
If Lates is 1 and minutes are more than 15, 50%
If Lates are 2, 50%
If Lates are 3 or more, 100%
I'm trying to use a nested IF function using specific ranges of dates but I can't get it to display each answer separately in the same column. For example, I want to display "30 Days" if the condition cell has a date within 30 days out from today, "60 Days" if the date is within 30 and 60 days out, and so on... This is what I have:
=IF(H15-TODAY()>=30,"30 Day",IF(H15-TODAY()>=60,"60 Day",IF(H15-TODAY()>=90,"90 Day",IF(H15-TODAY()>=180,"6 Mo",IF(H15-TODAY()>=270,"9 Mo","12 Mo")))))
Morning
can you please assist in calculating a if then formula in excel 2016.
I am trying to say if D48+D49>=C40 then D50=E40, if D50 is less than C40 then keep the sum of D48+D49 in cell D50
I need a formular that will either give me
1)Lost Customer
2)New Customer
3)Down-Trders
4)Up_traders
Have tried below but it is not working our
Please help
=IF(D53<1;"Lost Customer";IF(E53D53;"Downtrader";"Uptrader")))
Need to calculate accrual / accumulated leave for current year . Please guide with the “ If condition” :
Sick Leave Prev. Yr Bal. = X
Sick Leave Alloted Current Yr. =Y
Capping for Sick Leave =Z
Below Z to be considered on actual & Above Z will lapse.
Anyone please help.!!!
Hiya,
Trying to create a formula that I can then conditional format based on the result.
Basically:
If >75% of of a column say Yes in a different worksheet, I want it to return a value of Green
If 25-75% of a column say Yes in a different worksheet, I want it to return a value of Amber
If <25% of a column say Yes in a different worksheet, I would like it to return a value of Red
Then I will conditional format these so we can see at a glance how much has been received (I know how to do this so can do this bit).
Thank you in advance for your help.
Trudie
Hi,
I want to calculate the sum of the cells if in column B have text "paid" then calculate values from Column A in respective cell and if Column B have text "Un-Paid" then the values from Column A will not calculated... reference list is below...
Rs 3,000.00 Paid
Rs 30.00 Paid
Rs 50.00 Paid
Rs 5,000.00 Paid
Rs 10,000.00 Un-Paid
Rs 10,000.00 Un-Paid
Rs 5,000.00 Un-Paid
Rs 330.00 Un-Paid
Rs 650.00 Paid
Rs 785.00 Un-Paid
Looking forward for prompt response please...
Thanks
If you want something simple you can have another column that determines if column b says paid.
=IF(B1="PAID",A1,0) - this goes in column c
Sum values in column c.
Just realized you can use sumif here
=SUMIF(B1:B10,"PAID",A1:A10)
Change the range as needed.
Mam kindly give formula to calculate pass or fail for 6 subjects in which marks of 4 subjects is more than 40 and subjects are present in different cell such as a2, e2, j2 , l2, m2 and p2.
Looking for help with: ie. if d43 - 3.75 is <= 0 then equal blank if not then equal d43 - 3.75
=IF(d43-3.75<=0,"",d43-3.75)
Hi,
I weekly table set up and I want to track if someone does a certain task for consecutive days. What would I use to give 4 points if they did it 4 consecutive days and NOT just for 4 days during that specified time frame? Thank you
there are so many man or women then how can i find man with help of if formula please let me know
help me to calcute my commission my commission is .5% but condition is minimum 2 rs and maximum 12 rs
=IF(and(A1>2,A1<12),A1*0.5%,"")
1. i like to minus Coulmn 1 (1st ship date) to column 2 (2nd ship date) & out come should be in number
2. after that i like to find the max value number in the column.
If there is two dates in a1 and b1
If 0 to 3 months, c1 is yes
If 3 to 6 months, d1 is yes
If 6 to 12 months, e1 is yes
If 0 to 1 year, f1 is yes
Please suggest formula
I think I just found heaven!