by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
Hi,
Kindly I need help in this please, I need to count the cells that contain a value x bigger than y and less or equal z.
Many thanks
Hi There,
I need your advise on the following. I have 3 siblings. Everytime any payment made by either one of our siblings for our parents' affair, we will split the bill. But everytime different sibling will pay the bill first. Therefore, I would like to find a solution which I just need to key in the payment amount and payment by which sibling and it auto calculate each share and who needs to top up their payment and who needs to collect from other siblings. I need to attach a screenshot to show if you can't understand my question.
Hi question, using the data below
particulars date received due date date paid action remarks
water 01 jan 2019 31 jan 2019 29 jan 2019 paid w/ deadline
electric 01 jan 2019 31 jan 2019 02 Feb 2019 paid beyond
Dues 01 jan 2019 31 jan 2019 not yet paid
using IF function how to formulate
result if "paid" or "not yet paid"
remarks if "paid" and "within the due date" or "paid but beyond due date"
thank you
Hi I am using the following formula =MAX(0,C105-C106)so that I do not get results with a negative answer (e.g. -356). However if cell 106 is blank i would like to have a zero returned. How do I amend the current formula to include this perameter?
Figured it out myself.
=IF(AND(ISNUMBER(C105),ISNUMBER(C106)),MAX(0,C105-C106),"")
Works a treat.
My policy is to give Incentive based on year of service of my staffs. For example: I would like to give Rs. 750/- to those staffs who have year of service between 1 & 3 years and Rs. 1,000/- to those staffs having service above 3 years. In addition, if they achieve a Per Vehicle Incentive of > Rs. 500/- only they will be eligible for the above mentioned Incentive. Will u please help me to resolve this?
I need a formula that will return the following:
8 or lower = Pre Contemplation
8-11 = Contemplation
12-14 = Preparation
14 and above = Maintenance
I have a running total cell that will give me the number. Based upon the result of that cell I need it to return the text that corresponds. The below examples shows the column B totaled then averaged. The average equates to 12 therefore based upon the above table should return "Preparation"
Column A. Column B
1 2
2 4
3 6
4 Total 12
5 Preparation
Thank you!
Nevermind...figured it out
I need a formula to do the following:
There is a list of cells in column B. If column B contain text ending with "hba0" or "P0",
Indicate SW1 on column A, next to the row cell in column B. If column B contain text ending with "hba1" or "P1", Indicate SW2 on column A, next to the row cell in column B.
Also to ignore blank or empty cell for the list in column B, thanks.
I need a formula to do the following;
If "X" is present in A1 - A10 & "Y" is present in B1-B10 (in the same row) what is C1-C10 in the same row.
eg. A2=X & B2=Y what is C2
Can you please help?
Hello
I would like some help with adjusting this formula:
=IF(ISERROR(AVERAGE(G3,K3,N3,Z3,AF3,AO3,AT3,BD3,BF3)),"", IF(DO3<2,AVERAGE(G3,K3,N3,Z3,AF3,AO3,AT3,BD3,BF3), "Invalid"))
I would like the average of the scores above to be calculated based on two conditions.
BOTH DL=1 and DO<2. If both of these conditions are not met then it should read "invalid"
Is this possible? is there another way to write this? (I have included the ISError as I do not want blank cells to produce errors)
Very very Thanks
Hi,
Is there any formula for: if the text(Name) comes 2 times in a column take the text to a specific cell if the text(Name) comes 3 times in the column take the text to another cell?
Hi,
Hoping to get some help with a formula. Currently I have this formula:
=IF(AND(DL3>=0, DL3=4.1, DL3=4.26), 2, FALSE)))
I also want to add another condition: If 5 or more cells in a range are blank then return "2"
Can this be added to this formula? Or how would you write that?
Here is the range of cells E3:BF3
Hi,
Hoping to get some help with a formula. Currently I have this formula:
=IF(AND(DL3>=0, DL3=4.1, DL3=4.26), 2, FALSE)))
I also want to add another condition: If 5 or more cells in a range are blank then return "2"
Can this be added to this formula? Or how would you write that?
Here is the range of cells E3:BF3
Hi all again,
Just to say I resolved it with the following, you have to imagine that it reads =IF(AND(A1lessthangreaterthan"", etc. as it'll probably strip the signs out again.
=IF(AND(A1"",C1""),CONCATENATE(A1,B1,C1),IF(AND(A1="",C1""),C1,A1))
Best, Trevor
Just realised that when posting it seems to be stripping the greater and less than symbols from my formula above which should be immediately after A1. Not sure why but I'll give it another go here just to see if I was really remiss and forgot to include them in my original emails. So far I've tried the formula below, hopefully the greater and less than symbols after A1 will be apparent as I've typed them in this time rather than pasted them, but this returns A1,B1 not just A1. And I haven't even got to the C1 part of the equation yet!
=IF(A1"",CONCATENATE(A1,B1,C1),IF(C1="",A1))
Best, Trevor
Sorry, the above should have read adjacent columns A,B,C not A1,B1&C1 and the basic concatenate formula without the additional conditions is actually
=IF(A1"",CONCATENATE(A1,B1,C1))not A1"",CONCATENATE(A1,B1,C1)) as above.
Thanks again, Trevor
Hi, I have a question if that's okay. I have three adjacent columns with values, lets say for the sake of argument A1,B1&C1, some of which have values in A, some of which have values in C, and all of which have values in B.
A basic formula for my purpose, if there's a value in column A, would be something along the lines of:
=IF(A1"",CONCATENATE(A1,B1,C1))
However, here's where it gets tricky, as I'd only wish it to concatenate A1,B1,C1 if there's also a value in C1. Otherwise I'd like it to return a value of A1. Similarly if there's a value in C1, but not in A1, I'd like it to return a Value of C1.
I've managed in the past to concatenate A1,B1 or return a blank value if there's no value in A1, but what I can't seem to do is return A1 rather than concatenate all three cells if there's no value in C1.
Many thanks for any help anyone can offer in this matter. As a more concrete means of expressing it, let's say that A1 = Dog, B1 = -, C1 = Cat. The result of the formula would be to read Dog - Cat, with or without the space between the hyphens.
However, if A2 = Dog, B2 = -, C2 is blank, the result of the formula would be Dog.
And if A3 is blank, B3 = -, C3 = Cat the result of the formula would be Cat.
Best, Trevor
I recieve False when I entered this function help pls
If(B3>=10,IF((OR(C3>=10,D3>=10)),"PASSED","FAILED"))
Hello-
I am trying to add additional data to an existing If Is formula:
=IF(@O:O<=-3,"25% DISCOUNT - PCS OVER",IF(@P:P<=-3,"25% DISCOUNT - PCS SHORT"," "))
I would like to add the Number (value) of pcs into the formula. The numbers are in columns O (over) and P (short). How would I do this?
Anyone Help For below mention Problem
I have This 3 Same Am mount but percentage is different different,
500 70%
500 80%
500 90%
now what i want i am trying to fix formula in next coalum
Target % Result
500 70% 0 if % below 70 % amount should be 0
500 80% 300 if % between 80 to 85 Result come Automatic 60% From target
500 85% 800 if % between 85 to 90 Result come Automatic 80% From target
500 90% 500 if % Above 90 Result come Automatic 100% From target