Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4538 comments

  1. I need a formula for below
    This calculation need to get the incentive for employees. If an Employee Achieve his target than incentive will be 1% as follow
    Achievement = 1% of Incentive
    95% and above = 100% of 1
    90%-94.99% = 85% of 1
    80%-89.99% = 75% of 1
    70%-79.99% = 50% of 1
    60%-69.99% = 30% of 1
    Below 60% = 0% of 1
    And also one more clause if the collection amount collect on time or as follow :
    No of Days = Commission %
    01-60 Days = 100%
    61-90 Days = 75%
    91-120 Days = 50%
    121-150 Days = 30%
    151-180 Days = Penalty 1%
    Above 180 Days = 1.5%
    Please help me out for calculation
    For Example (Guy Collection 100 Dollar if he achieve and collect on time than will get 1 Dollar) But i want as below
    Calculated Amount = 100
    Achievement % = 85%
    And Collection day = 95 days
    Than he will get = Result 0.375 Cent

  2. I need a formula, which calculate the difference between the maxmum and minimum chainage values provided that the chainage grouped are of the same name which is in column A.
    Name of drift (ID) - column A
    Chainage from (m)- column B
    Chainage to(m) - column C

  3. when i put no 1 in A1 IT REPRESENT AS ABSENT IN B1
    when i put no 2 in A1 IT REPRESENT AS ABSENT IN C1
    when i put no 3 in A1 IT REPRESENT AS ABSENT IN D1
    when i put no 4 in A1 IT REPRESENT AS ABSENT IN E1
    HOW CAN I PUT ABSENT IN ALL FOUR CELLS(B1, C1, D1, E1)AND ANY THREE CELLS USING A FORMULA

  4. hey i have this table
    NAMES RANK
    ali 30
    moses 10
    mo 25
    eyali 30
    and i want to know for example who is the name with the highest rank and his name contain "li" and his rank

    in another words, if i have string (like "mo" ) and i want to know who is the name that have highest rank that include this string ( in out example we have "mo" in 2 names, 'moses' with rank 10, and 'mo' with 25, the formula give me the answer 25)

    thanks!

  5. HELP !!!
    Driving me mad, Im trying to auto add a percentage,
    i.e
    £0.00 to £10.00 = 50%
    £10.00 to £50 = 30%
    £100 up = 20%
    So B2 is 6.99 and I want E2 to display eather 3.49 or 10.48.
    Is this possable? ive tryed in E2
    =IF(B2>=10.00, B2+50%, IF(B2>=50.00, B2+30%, IF(B2>=100.00, B2+20%, "")))
    Many thanks

  6. i have been trying but cant figure out a formula for my current need
    i have 4 different codes FA or W or D or T each one if code is used has a different amount that is needed to be added
    i have this formula but need to add the other letters incase the referenced cell is one of the other codes. i know i'm on the right track but can figure out how to add the other codes in incase the code changes then that nuber in cell O35 will be added to the value associated with the letter for the code
    =IF(P35=O70,O35+M70)

  7. Hello! I have been having a hard time trying to figure out how to write a formula to tell me if a football play was successful or not.
    Any one know how I would write something that can tell me the following;
    On 1st down, we need 40% of necessary yardage to be successful
    On 2nd down, we need 70% of necessary yardage to be successful
    On 3rd and 4th down, we need 100% of necessary yardage to be successful.

  8. Hi.

    I am trying and can't find the way of having the following:
    I provide a cell and look for in a column that has the name partiallym and need to return the full value of the cell i am looking for on another column, additionally if the value is found on other cells to get all the cells value into a single cell...

    I know it is a tricky one :)

    Thanks in advance, BTW awesome excel skills!!

  9. I need a formula if 3rd row values can be "solved" then it should return me "0".Else return "1".

  10. Can anyone help me getting this solved
    If >150 A
    If <100 C
    If 120-150 B
    If 100-110 c

  11. Value in a Cell (eg: K2) : 3/13/2019 19:18:26
    Condition should be followed as:
    Morning (6AM-3PM)
    Afternoon (2PM-11PM)
    Night (10PM-7AM)

  12. I want the formula TAT,
    if a2 is <= 5, give me 5, or give me the same cell count,
    like its the a2 = 6 then give 6 if its 7 give me 7

  13. I want to display Remark in students mark list having following conditions:
    Marks >=420 then "Excellent",
    Marks Between 360 and 419 then "V. Good",
    Marks upto 359 and if pass in all subjects then "Good",
    If fails in 1 or 2 subjects then "Average" and
    Fails in 3 or more subjects Then "Poor".
    All subjects are of 100 marks each. Total 6 subjects and passing marks 35 and above.
    How can I display Remark for the above conditions?

  14. Hi - Can you help me solve this formula? Thank you
    If Column H >= 100%, then Column N = Column F; if Column G >= 100% and Column H >= 100%, then column N = Column F*2

  15. Hello,
    I am trying to do a formula to highlight cells a certain color based on a name, that are equal to certain calendar days. Could anyone help with this?

    • I am looking for the same formula. Were you able to figure this one out? Please let me know. Thank you!

  16. I am trying to improve my Excel skills. I am stuck on this:
    I have a column retrieving data via VLOOKUP. If the result is a blank cell, I would like to have a particular text returned, but if the result is an error, I want a different text. I am guessing this will involve nesting an IF and an IFERROR, but I'm not sure - any help that can be offered is appreciated. Thank you!

  17. I have an actions table where each action has a deadline and a status of whether that action is 'opened' or 'closed'. I am trying to highlight / or colour a row for actions which are still open and have passed the deadline. I tried using combination formulas in conditional formating. But nothing is working for me. Any suggestions?

  18. Hi, I know this is probably something stupid, but so am I lol.

    I have data in Cell A and Cell B. If Cell B is greater than 0, then the data in Cell A & B has to be copied to Cell A & B on another sheet?

    • Hi Riaan,

      You can use the following formulas on another sheet:

      For cell A: =IF(Sheet1!B1>0, Sheet1!A1)
      For cell B: =IF(Sheet1!B1>0, Sheet1!B1)

      Where Sheet1 is the sheet with the original data.

  19. find a formula for the percentage of the given items.All are in out of 100.
    86
    98
    88
    75
    92
    Exempt
    99
    73
    87
    45
    Exempt

  20. kindly help me, what is the formula for my below condition

    * if i entered in B cell as credit then only C cell will allow to enter the value and D cell
    will be Empty.
    * if i entered in B cell as debit then only D cell will allow to enter the value and C cell
    will be empty.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)