by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
Hi Svetlana..
In Excel Solver, my variable cell output should be either 0 or 20.
how to add this constraint please.
I have an IF formula =IF(D8="X","1","") and now I want to add up the lines that have a 1 in them .. what type of formula will I need?
Hi Brad did you get any solution for that? I am also looking for the same.
Try =COUNTIF([Your Desired Range],"1")
Take the quote out:
=IF(D8="X",1,0)
Is it possible to write a formula for a whole column?
IE, Currently column 'C' divides 'D' but i need a formula that If C>D divide D by C.
Hi Gary,
Usually, you write a formula for the first cell using relative references (without $ sign), and then drag it down to as many cells as needed. This will copy the formula across the column and adjust the references for each row. For example, if your data begins in row 2, enter this formula in any cell in that row:
=IF(C2>D2, D2/C2, "")
And then, double-click the fill handle (a small square at the lower right-hand corner of the cell) or drag it over the cells where you want to copy the formula.
For more information, please see How to copy formula in Excel.
This is the formula I am trying to calculate - here are the criteria https://i.imgur.com/S3u7NJC.png
1 - this is the cell where I need the formula to calculate my cost price.
2 = "Paid" or "Traded" and
3 = the Transaction Type is "Transfer" then
4 - take the value from the cell in column "Adj EUR to AUD Rate" and divide it by
5 - (on the same row as he cell to calculate the cost price)
However only take the value in "4" if on the same row as "4"
6 = FX Transfer
7 = Xfer_Receipted
8 = the date matches the date in the same column as the row of the cell for "1" (the cost rate we are calculating" and
9 does not equal "0"
I hope that makes sense and appreciate any help
@Svetlana Cheusheva are you able to help with my query please?
Dear sir/mam
If sales value is =10 lakh then % incentive will be 4%.how we solve this with the help of nested if function
Hi there - this article is very helpful but I am struggling to create a formula to calculate a cost-price based on various criteria but not sure if these comments are being monitored still and if so should I upload an excerpt from my spreadsheet to show what I am trying to achieve?
=IF(AND(E6="FP",M6>=2,AND(A6>=$K$1,B6=2),AND(A6>=$K$1,B6<=$L$1)),"VD Promo","No Promo")
please help me to run the statement
=IF(AND(E6="FP",M6>=2,AND(A6>=$K$1,B6<=$L$1)),"VD","No Promo")
This is the correct one please help me to run the statement.
date 1 2 3 4 5 6
name total bonus normal
james 300 360 400 370 403 360 2193 393 1800
ken 340 350 334 342 401 359 2126 326 1800
geff 350 370 336 420 389 349 2214 414 1800
brian 300 390 337 436 376 57 1896 96 1800
robert 400 340 361 340 369 367 2177 377 1800
peter 365 366 352 345 346 301 2075 275 1800
nicholus 333 358 369 368 352 300 2080 280
judith 420 309 345 369 323 326 2092 292 1800
muati 440 470 321 370 310 326 2237 437 1800
19090 2890 16200
i need a formula to calculate the sum of any amount in excess of 300 from day 1 to day 6
e.g day 1 (x-300)+day 2(y-300) till the sixth day.remember the sum should not be affected by a negative value i.e if x is less than 300
Hi,
I'm trying to make the logic
if A1=B1 then true; A1=C1 then true; A1 not=B1 & C1 then False.... nested functions OR functions nt working. kindly advice.
Regards
may I know the excel formula if value below 10 and I need to plus 2.
eg. =<10+2
I am trying to create a formula using criteria in the same column which could be either a number or a word. Example 7230 or "Store". I want the formula to return the word "Direct" if the answer is true or "Overhead" if the answer is false. Hope you can help
I want a formula for comparing end date to decide the application.
if start date = end date,replay 0
if start date = 1-end date,replay 0 or else 1
=IF((LEFT(F10,2))=29,"-",G10*18%)
Need a formula that says...
If cell A1 is has the text "Oshkosh","NEW Oshkosh", or "Shumaker", put 36,500 for the text Oshkosh, 37,500 for NEW Oshkosh, or 37,500 for Shumaker.
Can you help me.
Hi Bob,
I believe this is the formula you are looking for:
=IF(A1="Oshkosh", 36500, IF(A1="NEW Oshkosh", 37500, IF(A1="Shumaker", 37500, "")))
Thank you. That is actually what I needed. Just couldn't wrap my head around it.
correction
=IF(AND($C$9E2,$B$9=0.2),0.8
For fertigation no problem i use this
=IF(AND($C$9E2,$B$9=0.2),0.8,"-"))
where C9= Harvest date
E2= Application date
B9= Area
from this when C9=E2 no fertigation the same is true for irrigation the difference is one day less than the harvest date.
Hello! I have been having a hard time trying to figure out how to write a formula which tell assume that the produce will harvest on 3/20/2020 so irrigation is applicable each month to grow. However; irrigation is not applicable between 3/19/2020 and 3/20/2020.So any help is much appreciated .
Hi,
I cannot get my function to work even following all the examples above. My scenario
B3=Amount that can change
Where the amount is under $50000, cell will equal B6*B16
Where the amount is equal or over $50000, cell will equal B6*B17
TIA
Please give the formula for the below condition.
REFUND AMOUNT UPTO RS.25L-OUR CHARGES 5% WITH MIN RS.5000/- WHICH EVER IS HIGHER
i having two Excel Files with similar data and need to compare our data in
Excel File - A is having correct information comparing with Excel file B ,
require Your support to find formula to compare EXCEL file A & B
EXCEL file A Column A = 1234 Then 1245 ,1256 and So on in every Column .
EXCEL file B Column A = 1234 Then 1245 ,1256 and So on in every Column .
EXCEL file A Column B and EXCEL file B Column B Having Multiple Bandwidth example (1 MB , 2 MB , 3 MB ,4 mb etc ) ,
how to mention All bandwidth Associated with EXCEL file B Column A = 1234 WITH in EXCEL file A Column C