The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
Hi all,
How to get different statement in one cell based on the different date ,
For example:
I have 5 document received date and 6 document sent date.
from that once document sent from my side i need statement automatically "Sent"
from my side document is pending statement should come " Pending"
and if i entered any date in completed column statement should come " completed"
Hello Jaybal!
I’m sorry but your task is not entirely clear to me. Excel cannot automatically indicate the status of a document. How does he know that you sent the document? It’ll help me understand it better and find a solution for you. Thank you.
I will receive document from vendor for review and once documents are okay i will approve that doc, if document rejected they will resubmit.
In my tracker Approved mean i will enter code "A"
if document reject i will enter code "C"...
These sequence will happen more than 7 to 8 times.
My requirement is Once i entered in C / A code i need result Approved /rejected in any one cell
Exampple:
(I need status automatically)
First time doc received A2= C Status "Rejected"
2nd time doc received C2= C Status "rejected"
3rd time doc received E2=A Status " Approved"
like this i have to check based on the code
Hello Jayabal!
If I understand your task correctly, the following formula should work for you:
=IF(COUNTIF(A2:E2,"A")>0,"Approved ","Rejected")
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hi I need to do a calculation total. I have a column called Quote/Won with one word in each row. I have a Labour £ column. I need to create a total of all labour revenue won. So if any figure in work labour column is won, the revenue figure shows in the total field. (single combined total field)
eg.
Total Labour revenue won £ 200
Won/Quoted Column---- Work Labour £ Column
Won £100
Quoted £150
Won £100
Hello Deb!
If I understand your task correctly, the following formula should work for you:
=SUMIF(A2:A7,"won",B2:B7)
You can learn more about SUMIF in Excel in this article on our blog.
Hope you’ll find this information helpful.
Please I need help on this;if B1"", it should give me the value of K1,"", if C1"", it should give me the value of L1,"", if D1"", it should give me the value of L1,"" and so on to about fifteen arguments. But when I input the formula, the Excel is telling me that I have input too many arguments. How can I resolve this please.
Thanks.
I have this formula =IF((AND($F2>=VLOOKUP($C2&""&F$1,Sheet3!$C$5:$E$1200,2,FALSE),$F2=VLOOKUP($C2&""&G$1,Sheet3!$C$5:$E$1200,2,FALSE),$G2=VLOOKUP($C2&""&H$1,Sheet3!$C$5:$E$1200,2,FALSE),$H2=VLOOKUP($C2&""&I$1,Sheet3!$C$5:$E$1200,2,FALSE),$I2=VLOOKUP($C2&""&J$1,Sheet3!$C$5:$E$1200,2,FALSE),$J2=VLOOKUP($C2&""&K$1,Sheet3!$C$5:$E$1200,2,FALSE),$K2=VLOOKUP($C2&""&L$1,Sheet3!$C$5:$E$1200,2,FALSE),$L2=VLOOKUP($C2&""&M$1,Sheet3!$C$5:$E$1200,2,FALSE),$M2=VLOOKUP($C2&""&N$1,Sheet3!$C$5:$E$1200,2,FALSE),$N2=VLOOKUP($C2&""&O$1,Sheet3!$C$5:$E$1200,2,FALSE),$O2=VLOOKUP($C2&""&P$1,Sheet3!$C$5:$E$1200,2,FALSE),$P2=VLOOKUP($C2&""&Q$1,Sheet3!$C$5:$E$1200,2,FALSE),$Q2=VLOOKUP($C2&""&R$1,Sheet3!$C$5:$E$1200,2,FALSE),$R2=VLOOKUP($C2&""&S$1,Sheet3!$C$5:$E$1200,2,FALSE),$T2>=VLOOKUP($C2&""&T$1,Sheet3!$C$5:$E$1200,2,FALSE),$T2=VLOOKUP($C2&""&U$1,Sheet3!$C$5:$E$1200,2,FALSE),$V2>=VLOOKUP($C2&""&V$1,Sheet3!$C$5:$E$1200,2,FALSE),$V2=VLOOKUP($C2&""&W$1,Sheet3!$C$5:$E$1200,2,FALSE),$X2>=VLOOKUP($C2&""&X$1,Sheet3!$C$5:$E$1200,2,FALSE),$X2=VLOOKUP($C2&""&Z$1,Sheet3!$C$5:$E$1200,2,FALSE),$Z2<=VLOOKUP($C2&""&Z$1,Sheet3!$C$5:$E$1200,3,FALSE))), "", 1)
It is working normally but it is very long, Is their any way to make it easier.
My apologies if you answered this already. I have a spreadsheet with Monday-Sunday in each column (A-G). State Names in Columns H-O. Unique People names in P column and their phone number in column Q.
Monday
Monday
Monday
Monday
Monday
Monday
I want to know who is available to travel on Monday to Utah.
I want the formula to provide me with a list of people and their phone number
Hello Sylvia!
I think that in your case the simplest and the most convenient way is to make use of Advanced Filter in your table instead of formulas. Please find advice on applying filters on our blog:
how to add filter, about advanced filter, highlight duplicates
Set a filter in the table and indicate criteria (what values you would like to see) in the necessary columns.
how to connect two condition under each have some conditions?
Hello!
See above Example 1. Using IF & AND function in Excel
I am trying to Populate a Date cell in L7 and I have two cells to choose from T7 and U7. I want L7 to be T7 if T7 has a date if not I want it to be U7 since that will always have a date. The Date in T7 will change due to plan optimization.
Hello Blaise!
If I understand your task correctly, maybe the following formula should work for you:
=IF(T7<>"",T7,U7)
If there is anything else I can help you with, please let me know.
I am trying to get a formula as per condition below:
Condition 1 - 0<A6<=2
Condition 2 - 0<B6<=2
Condition 3 - N/A
"OK" if criteria as below met.
A6 B6
1 1
1 2
2 1
2 2
N/A 1
1 N/A
N/A N/A
"Not OK" if criteria as below met.
A6 B6
1 3
2 3
3 1
3 2
3 3
N/A 3
3 N/A
Need help. Thanks
Hi, I am looking for a formula to build where if the answer in cell E10 = Yes, then populate information in cell D10. As an example, if Yes, then it would populate YM-SL. The information in column D is various sizes. Or I could create a formula in column E, that if Yes, populate with answer from D. Either formula would be helpful. Thank you
Hello Robin!
I’m sorry but your task is not entirely clear to me. Do you want to fill in cell E or D? Maybe this is a formula =IF(E10="Yes",D10,"")? Could you please describe it in more detail? Thank you!
hello, iam trying to counts pages based on if formaula, but i am not getting the answerer
If pages are 1 to 5 my answer should be 1
if more than 5 pages and less than or equal to 14 should be 2
If anything more than 14 pages my answer should be 3 - but this i am not getting
Here is my formula which i applied, can anyone suggest me on this
=IF(B25,"2",IF(B215,"3")))
Hello Ratheesha!
Please try the following formula:
=IF(B2>=1,(IF(B2<=5,1, (IF(B2<=14,2,3)))),0)
Hope you’ll find this information helpful.
I am trying to create a formula that will calculate the LTV (loan to value) I can use. Here is what I have so far.
=IF(D3>=850000, "75%", IF(D3>=500001, "80%", IF(D3<=500000, "85%")))
However, I want to add another two IF conditions that will increase each percentage by 5% if they have 740+ credit AND $120000 annual salary. Thanks in advance for the assistance!
Hello Yixo!
If I understand your task correctly, maybe the following formula should work for you:
=IF(AND(D4>=740000,D5>=120000), IF(D3>=850000, "80%", IF(D3>=500001, "85%", IF(D3<=500000, "90%"))),IF(D3>=850000, "75%", IF(D3>=500001, "80%", IF(D3<=500000, "85%"))))
Hope you’ll find this information helpful.
Hi,
Would the if function work for this?
Port/City Vancouver Montreal
Shanghai 27 34
Shenzhen 28 35
Guangzhou 35 42
Example:
Select: Shanghai, Vancouver
Time: 27 days
Select: Shanghai, Montreal
Time 34 days
Hello Jesse!
Please try the following formula:
=INDEX(B2:C4, MATCH("Shanghai",A2:A4,0), MATCH("Vancouver",B1:C1,0))
or
=INDEX(B2:C4, MATCH($E$2,A2:A4,0), MATCH($E$1,B1:C1,0))
I hope this will help, otherwise please do not hesitate to contact me anytime.
I want to put this equation in cell H57
1) if cell I54 value is = or than 20 and than 40, then multiply (I54 X N44)
so please advise how to right this equation
Hi there,
I have a total of "overtime and regular hours". I want my regular to show the hours in total cell of OV and RE, but not exceed over 40.
for example:
Total of overtime and regular is 32.
Regular cell show the 32.
but when the overtime and regular cell is > 40, the regular cell show only 40.
Can you please help me with a formula?
Hello Aimal!
If I understand your task correctly, the following formula should work for you:
in B21:
=IF(SUM(A1:A20,B1:B3)>40, 40, SUM(B1:B20))
where A1: A20 is overtime, B1: B20 is a regular time.
If that's not what you wanted, please describe your task in more detail. It’ll help me understand it better and find a solution for you. Thank you.
1)If= first month(1 Jan to 31 Jan) all floors commission 2%
2)If= second month (1feb to 29 Feb) floor wise commission
Lower floor - 3%
Middle floor - 3.5%
Higher floor - 4 %
3) if = third month ( 1 March onwards) onwards floor wise commission
Lower floor - 2 %
Middle floor - 2.5%
Higher floor -3%
Please help how to create formula in 1 cell in excel
Hello Swapnil!
if you write data -
A B C D E
Month 1 2 3 2/10/2020
Lower floor 2 3 2 Middle floor
Middle floor 2 3.5 2.5
Higher floor 2 4 3
Please try the following formula:
=INDEX(B2:D4,MATCH($E$2,A2:A4,0), MONTH(E1))
I hope this will help, otherwise please do not hesitate to contact me anytime.
sorry I do not understand of this
A1 - Month, A2 - Lower floor, A3 - Middle floor, A4 - Higher floor, B1 - 1, B2 - 2, B3 -2, B4 - 2, C1 - 2, C2 - 3, C3 - 3.5, C4 -4 and so on. E1 - 2/10/2020 , E2 - Middle floor
Thank you very much it's working
but one more problem one Month Condition was changed. Condition is Date of period so formula not working...
*Date of period
1 ) 1 Jan 2019 to 2 Feb 2020 -commission all floors 2%
2 ) 3 Feb 2020 to 29 Feb 2020 - commission floor wise( L, M, H) 3 %, 3.5%,4%
3 ) 01 March 2020 to 31 march 2021* commission floor wise (L, M, H) 2%,2.5%,3%
Can you please help .....
Hello Swapnil!
Please try the following formula:
=IF(E1 < DATE(YEAR(TODAY()),3,31), (INDEX(B2:D4,MATCH($E$2,A2:A4,0), IF(E1 < DATE(YEAR(TODAY()),2,3),1,IF(E1 <= DATE(YEAR(TODAY()),2,29),2, IF(E1 <= DATE(YEAR(TODAY()),3,31),3,0))))), "Date out of range")
Hope you’ll find this information helpful.
Formula not working on pending period 01 april 2020 to 31-03-2021 ...working only march 2020 ..
Third condition not completed.. Please help.
And one more condition add
3 types of sources in this
X, y, z
X and z eligible for all condition commission
But y not eligible for all. Only eligible 2% commission in all types of condition
Please help....
Please can someone help me with an excel formula?
3 sources of get commision
1)Comany
2) Customer ref
3) Direct sale
1) If multiple company commission for 2 %
2)if customer ref commision
*first ref commission rs 10k
*Second ref commission 20k
And
*Third ref commission 30 k
3) Direct commission "0%"
How to get commission formula in one cell
Hello!
I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you.
please help its very urgent
Hello!
If you want to learn something, try to understand how the formula works, and not ask for help all the time.
=IF(E1 < DATE(YEAR(TODAY()),3,31), (INDEX(B2:D4,MATCH($E$2,A2:A4,0), IF(E1 < DATE(YEAR(TODAY()),2,3),1,IF(E1 <= DATE(YEAR(TODAY()),2,29),2, IF(E1 <= DATE(2021,3,31),3,0))))), "Date out of range")
If you write table
Column a : name of customer
Column b : source
Column c : source name
Column d : value
Column e : commission %(2%)
Column f : need formula this column
Source type 3
* broker
* Ref
* direct sale
Commission type
1)If broker sale 1 product get 2% commission ( value * 2%)
2 ) if any existing sale his ref through 1 product get amount benefit
* sale 1nd product deal get 10000 rs
*sale 2nd prduct deal get 20000 rs
* sale 3 rd product deal get 30000rs
And
3) if direct sale get 0% commission
Please help me how to merge in one cell (f column) formula
Hello!
Your request goes beyond the advice we provide on this blog. This is a complex solution that cannot be found with a single formula. If you have a specific question about the operation of a function or formula, I will try to answer it.
=If(and(A2="A",B2="A" or "B"),"Yes","No")
Using like this in excel, if A2 value is A, and B2 value is A or B, the result I want as Yes.. Please clarify
Hello
Please try the following formula:
=IF(A2="A",IF(OR(B2="A",B2="B"), "Yes","No"),"No")
Hope you’ll find this information helpful.
=If(and(A2="A",B2="A" or "B"),"Yes","No")
Using like this if A2 value is A, and B2 value is A or B, the result I want as Yes.. Please clarify
I need a formula that says if cell "M" is "true" and Cell "N" is "yes" then sum cells Q & T but if cell "M" is "false" and "N" is "no" the cell T but if cell "m" is "false" and cell "n" is "yes" cell T
I have been working on a formula for an movie list of 1500 Dvds, Blu-rays, and 4ks that I'm backing up on 3 HDDs, 1 for each type. Now all the movies have a "type" column C2 which will only be a value "SD", "SD/HD", "HD", "HD/UHD", "UHD". A "on HDD" column I2 which will only be a value "Y", "N", "Y/Y", "Y/N", "N/Y", "N/N". These represent if the movie was copied to hard drive/s (some have read errors), I have 3 more columns 1 for each drive L2 = drive 1 SD, M2 = drive 2 HD, N2 = drive 3 UHD. Now if I have a DVD/Blu-ray movie (SD/HD) the Y/Y part matches the type so if the DVD SD did not make it to hard drive but the blu-ray did it would be "N/Y" my ? Is if I just want a "X" in columns L,M,N if the movie made it to the coralating HDD =IF(AND(OR(C2="SD",AND(I2 ="Y",OR(C2="SD/HD",AND(I2="Y/Y",OR(I2="Y/N", "X","") I know I'm on the right track, I will do that for each drive column changing out "Type" but I need help with the correct way to write out the formula, Please Help, Thanks.
Hello Ryan!
If I understand your task correctly, the following formula should work for you:
=IF(OR(
AND(C2="SD",I2 ="Y"),
AND(
C2="SD/HD",OR(
I2="Y/Y",I2="Y/N",I2="X",I2="")
)
),TRUE,FALSE)
For me to be able to help you better, please describe your task in more detail. Your explanation of the formula is very difficult to understand. It’ll help me understand it better and find a solution for you. Thank you.
=IF((B5+C5)<=25400,"900"(B5+C5)<=29900,"1100"(B5+C5)<=30400,"1300"(B5+C5)<=33400,"1500"(B5+C5)<=35400,"1700",IF((B5+C5)<=37300,"1800",IF((B5+C5)<=41100,"2300",IF((B5+C5)<=44500,"2600",IF((B5+C5)<=50200,"2900",IF((B5+C5)<=51600,"3100",3200))))))
how can use these conditions in a formula excel doesnot allow morethan 8