by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
Need help with formula
if D3=x,v4>120,"RED", "YELLOW"),If D4="Active", "BLANK")
trying to day if D3 = Active and V4 Greater than 120 then RED otherwise Yellow. But if D3 is not equal to Active then leave it blank.
Thanks
Anna
Hello Anna!
If I understand your task correctly, the following formula should work for you:
=IF(AND(D3="Active",V4 > 120),"RED", IF(D3 <> "Active","","YELLOW"))
I hope it’ll be helpful.
not sure why, but the post is not displaying the entire formula as I am pasting it,
=IF(AND(B25>A15,B25A16,B25A17,B25A18,B25A19,B25A20,B25*C16)
updated but still not correct
=IF(AND(B25>A15,B25A16,B25A17,B25A18,B25A19,B25A20,B25*C16)
=IF(AND(B25>A15,B25A16,B25A17,B25A18,B25A19,B25A20,B25*C16)
Hello Keith!
Please describe your problem in more detail. The IFOR function does not exist. What does the B25A16 mean? It’ll help me understand it better and find a solution for you. Thank you.
I am trying to compare a sales amount in a cell to a commission schedule and based on teh sales figure it will bring multiply the sales times the correct commission %. I know this is not correct but I am not sure where I am going wrong
=IFOR((AND(B25>A15,B25A16,B25A17,B25A18,B25A19,B25A20,B25*C16)
Hello,
Just want to say thank you , you doing great job, lord shower grace on you.
I was writing my problen but suddenly answer clicked, thank you again.
Thank you so much!
Hi,
I'm trying to write an "If" statement if 3 variables in different cells match up with each other then "Y" else "N"
If [A2]=[C2]=[D2]THEN "Y" ELSE "N" ENDIF
Hello Michelle!
Please try the following formula
=IF(A2=B2,IF(B2=C2,"Y","N"),"N")
I hope it’ll be helpful.
I'm stuck, wonder if someone can help me:
I need ranges-
if cell value is =1500 and =3000 and =5000 "5000+"
I know it's where I'm putting the () but I can't seem to get it right?
Hello Cindy!
I’m sorry but your task is not entirely clear to me. I hope you have studied the recommendations in the above tutorial. For me to be able to help you better, please specify which formula you mean and describe the problem in more detail. Thank you.
sorry, it didn't type out correctly
If h2 is less than 1500, then "<1500", if h2 is greater than or equal to 1500 AND less than 3000, then "1500-2999", if h2 is greather than or equal to 3000 AND less than 5000, then "3000-4999", if h2 is greater than 5000, then "5000+"
Hello Cindy!
Please try the following formula:
=IF(D2 < 1500,"<1500", IF(D2 < 3000,"1500-2999",IF(D2 < 5000,"3000-4999", "5000+" ) ) )
The second way:
Write your values in columns A, B, C. A1 - 0 B1 - 1499 C1 - <1500 A2 - 1500 B2 - 2999 C2 - 1500-2999, etc. If the final value is written in D1, then the formula for determining the output will be as follows:
= VLOOKUP (D1, A1: C4,3,1)
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hello,
I'm hoping to add a calculated field to my pivot table and need a little help.
A B C calc field
1 "A only"
1 1 "A & B"
1 "C only"
1 "B only"
1 1 1 "All 3"
1 1 "B & C"
1 1 "A & C"
Hello, how do write a formula for this? If total is between .01%-.99%, output should be $40, if between 1% and 1.99% - output should be $210. I tried IF and also IF(AND with , but I can't get it to work...help please. Thank you so much!
0.01% ---> 0.99% $40.00
1% ---> 1.99% 210.00
2% ---> 2.99% 240.00
3% ---> 3.99% 270.00
4% ---> 4.99% 300.00
5% ---> 5.99% 330.00
6% ---> 6.99% 370.00
7% ---> 7.99% 410.00
8% ---> 8.99% 450.00
9% ---> 9.99% 490.00
10% ---> 10.99% 540.00
11% ---> 11.99% 590.00
12% ---> 12.99% 640.00
13% ---> 13.99% 690.00
14% ---> 14.99% 740.00
hello Phatima!
Write your values in columns A, B, C. A1 - 0.01% B1 - 0.99% C1 - 40.00, etc. If the final value is written in F1, then the formula for determining the output will be as follows:
=VLOOKUP(F1,A1:C15,3,1)
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hi,
Great article!
In my example below, is it possible to add to the formula so that results in column 'C' would also take into consideration the value in column 'B' and (subtract 10 if 'B'=1) or (subtract 20 if 'B'=2)
Hope this makes sense, thank you!
A B C
1 35 1 150
2 33 150
3 40 2 200
4 41 200
=ifs(and(A1>=30,A1=38,A1<42),200)
Hello!
Your formula does not work. I did not understand what result you want to get. If there are already numbers in column C, then they cannot be changed by the Excel formula. Please describe your problem in more detail. It’ll help me understand it better and find a solution for you. Thank you.
thanks for the response.
I didn't realize I pasted wrong the formula
here is the correct one I use:
=ifs(and(A1>=30,A1=38,A1=" and "<") from Column 'A' which are size values. Now I want to add additional criteria (Column 'B') which is a quality grade (A,B,C or can be switched to numbers 1,2,3) so the calculated value (price) in column 'C' would be less by 10 if 'B=1', less by 20 if 'B=2', less by 30 if 'B=3', if 'B=blank' leave it as it is.
Hope this makes sense and thank you for all your help!
Alex
...here it is again, for some reason when I publish the comment it changes the formula pasted.
I'll try again with no "=" sign
ifs(and(A1>=30,A1=38,A1<42),200)
ifs(and(A1>=30,A1=38,A1<42),200)
...Never mind, the forum messages will change the formula every time I submit it.
ifs(and(A1>=30,A1<38)=38,A1<42),200)
I'll put it in words:
if "A1" is "greater than or equal to" 30 and "less" than 38, than 150, if "A1" is "greater than or equal to" 38 and "less" than 42, than 200
hope this makes sense as it won't let me paste the formula in the chat correctly.
Hello Alex!
If I understand your task correctly, the following formula should work for you:
=IF(B1<>"", (IF(AND(A1>=30,A1<38),150, IF(AND(A1>=38,A1<42),200,""))) - (B1*10), IF(AND(A1>=30,A1<38),150, IF(AND(A1>=38,A1<42),200,"")))
I hope this will help, otherwise please do not hesitate to contact me anytime.
Yes! That's it!
Thank you sooooo much!
Appreciate all your help!
Hi,
I order supplies for my company and have created a sheet that has 13 tabs, one for each 4 week period and a Summary tab at the end. On each tab I have:
ItemOrdered Qty Item# Supplier Cost$ DateOrdered DateReceived QTY/CS
I need to create a formula where IF a certain item is ordered (say triggered by Item#), THEN, the value in the Qty column is tallied as a sum on my Summary tab. Does that make sense?
Thanks in advance!
Matt
Hello,
I need the following formula:
if in column A I have the word "Revision", I need to put it in column B but not at same level (-1 level).
Exemple: if A4=Revision: 2.1--> put all content in B3
Thank you very much
Hello Pascale!
If I understand your task correctly, the following formula should work for you:
=IF(SEARCH("Revision",A4,1)>0,A4,"")
If there is anything else I can help you with, please let me know.
if the 1st row is greater than the other row then the answer is 1
if the 1st row is lesser than the other row then the answer is 0
if the 1st row is 0 than the other row is 0 then the answer is 1
if the 1st row is equivalent to the other row then the answer is 0
Hello Vincent!
I’m sorry but your task is not entirely clear to me. Do you want to compare rows or cells? What does "row is greater than the other row" mean? Could you please describe it in more detail? Thank you!
I am trying to work out an IF formula for the following. I have a spreadsheet that details stock and whether it is in date, out of date or expiring soon. I need the cell to show whether an item expires one month from today, is in date or out of date. I am struggling to work out the IF formula - this is what I have come up with so far, but am unable to get any further. Any help would be greatly appreciated by this newbee to Excel
=IF(E3<TODAY()*AND(-365-335),"Exp 1 mth",IF(E3<TODAY()-365,"Out of date","In date"))
Hello Sarah!
If I understand your task correctly, the following formula should work for you:
=IF(E3>TODAY(),"In date",IF(E3 > EDATE(E3,1),"Exp 1 mth","Out of date"))
I hope this will help, otherwise please do not hesitate to contact me anytime.
HI,
Please suggest how automate in sheet B
Sheet A.
01-05-2020 02-05-2020 03-05-2020
Branch Cash Transfer Cash Transfer Cash Transfer
A 200 90 500 152 5165 2132
B 500 100 700 515 6516 98
C 700 930 785 515 212 19
Sheet B.
Date 02-05-2020
Branch Cash Transfer
A ? ?
B ? ?
C ? ?
Hello Anoop!
I’m sorry but your task is not entirely clear to me.
For me to be able to help you better, please describe your task in more detail. Please let me know in more detail what you were trying to find, what formula you used and what problem or error occurred. It’ll help me understand it better and find a solution for you. Thank you.
WHAT SHOULD BE FORMULAE CONSIDERING BELOW CONDITIONS:
- Cell is greater than equal to 5 = P-HOME
- Cell is less than 5 = HLWP
- Cell is "0" OR "NULL" OR "#N/A" = LWP
Hello!
If I understand your task correctly, the following formula should work for you:
=IFERROR(IF(B1 >= 5,"P-HOME", IF(B1=0,"LVP","HLWP") ),"LWP")
Hope this is what you need.
How do I extend this formula to retrun "Agency" if employer column does not = J Smith Ltd.
Employer Source Fomula
J Smith Ltd Direct =IF(C4="J Smith LTD","Direct")
ABC Recruit Agency
XYZ Recruit Agency
Hello Tim!
If I understand your task correctly, the following formula should work for you:
=IF(ISERROR(SEARCH("J Smith LTD",C4)),"Agency","Direct")
Hope this is what you need.
Gud day Sir, please I have a large document that is up to 20 pages & maybe more. I want the heading which is in row 1,2,3,4,5 to show at the top of each page, I used the print title option and it worked perfectly. Now I want the bottom note which is up to eight rows to show at the bottom of each page. How can I make that work?
Please I need help on that.
Thanks.
Formula is =IF(OR(AND(G16="D",Q16>300000),AND(G16="V",Q16>300000),AND(G16="I",Q16>1000000),AND(G16="ORC",$L$5>600000)),"Y","")
It's returning the first two conditions "D" & "V" correctly but not the last two conditions. What am I missing? Please help. Thank you.
Hello Luisa!
I copied the formula from a blog in Excel and made sure that it works. Write in detail what results you want to get. For me to be able to help you better, please describe your task in more detail. It’ll help me understand it better and find a solution for you. Thank you.
Thank you for your reply.
What I'm trying to accomplish has several conditions, so if:
Service column has "D" and total of more than 300K the result should say "Y" for yes.
OR
Service column has "I" and total of more than 300K the result should say "Y" for yes.
OR
Service column has V and total of more than 1M the result should say "Y" for yes.
OR
"H" total column is more than 600K the result should say "Y" for yes.
I hope this is clear explanation. Thank you so much for your help.
Hello Luisa!
Based on your explanations, the formula needed to make very small changes
=IF(OR(AND(G16="D",Q16 > 300000),AND(G16="I",Q16 > 300000),AND(G16="V",Q16 > 1000000),AND(G16="H",Q16 > 600000)),"Y","")
Hope this is what you need.
Formula is= if(and(T3>3,U3>=9,v3<2,w3="NO",X<25),"eligible","ineligible")
If result come ineligible then I want to know that due to which column this result came.
Please guide
Regards