by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
Thank you that worked perfectly. The calculating cell contains FALSE until all conditional are met. Is there a way FALSE can be blank until all conditions are me?
Thanks you
Hello!
If I understand your task correctly, You can use something like this formula —
=IF(A1>B1,A1,"")
Use "" instead of FASLE.
=IF(A4="big creek",“Karen”,IF(A4="vista AOR","Jim",IF(A4="alhambra","Martin")))
I know I can't use * for remaining characters with IF function. Is there a way to use multiple IF statements with partial texts and not case sensitive? The above did not work.
Really appreciate the help!
Hello!
Instead of the "* big *" condition, you can use the formula to find the value in the text
ISNUMBER(SEARCH("big",A4,1))
I hope my advice will help you solve your task.
=IF(K:K="published","Live-API",IF(K:K="blocked","",IF(K:K="published","Live")))
Can I use the OR condition here?
Live-API or Live
Hello!
There are 2 conditions in your formula
K:K=”published”,”Live-API”
and
K:K=”published”,”Live”
The information you provided is not enough to understand your case and give you any advice, but this is wrong.
Good afternoon,
I am having great difficulty trying to fix some else's spreadsheet...this never happens of course. They are gardeners so the fact that they managed to fire up a computer and enter the data is pretty impressive and not in their wheelhouse....nor is Excel in mine.
The problem. I am needing to do a secondary sort on data. The parameter is "soil conditions" is the secondary column header.
The range are currently all text values entered individually in several hundred cells:
dry
dry - avg
average
avg - moist
moist
avg - wet
wet
submersed
I need to be able to assign a numeric value based on the range in this order, 1 through 8. The IFS argument does not appear to work, nor does IF in series.
Any help you can give would be greatly appreciated.
Cheers,
Richard
Hello!
If I got you right, the formula below will help you with your task:
=VLOOKUP(A1,{"dry",1;"dry – avg",2;"average",3;"avg – moist",4;"moist",5;"avg – wet",6;"wet",7;"submersed",8},2,0)
The VLOOKUP function selects the desired condition from the array.
Column A Column B Return
aa p P and H
aa h P and H
aa p P and H
aa p P and H
bb h H
bb h H
bb h H
I have a sheet like this above, Column A has ID#s and column B has different values for tht same ID, in column C i want to combine the values of Column B for each ID in column A and return those values in Column C. PLEASE HELP ME WITH THIS.
Thank you
Hello!
I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail.
It is not entirely clear what data is in each column. Explain what is the identifier in your data?
Please provide me with an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you.
Hello, i have three equations.
In sales team monthly target assigned, if salesman achieve less than 60% comm. will b zero, if 60-80% 2.5% comm. & more than 80% 2.5+1.5%(team leader1.5%)
Please help me !!!!!
Hello!
I’m sorry but your task is not entirely clear to me. Could you please describe it in more detail?
What is "2.5% comm"? What does "2.5 + 1.5% (team leader1.5%)" mean?
Lemme explain you again ... we have a sales team with monthly commission assigned, if salesman achieve less than 60% of his target then commission will b zero, if he achieve 61-80% of his target will 2.5% of commission on same, if he achieve more 81% and above will get 2.5% commission & his team leader will get 1.5% commission ...
hope its clear, pls help urgently
Hello!
If cell D1 contains the monthly sales target, and cell G1 contains the total sales of the seller, then the commission formula might be:
=IF(G1/D1<0.6,0,G1*0.0025)
For the team leader -
=IF(G1/D1<0.8,0,G1*0.0015)
Hi, Im trying to create a formula using the IF Function with multiple conditions.
My scenario is that if
Q1= Yes and Q2, Q3, Q4, Q5 and 6 = Yes or No the outcome = Significant.
But if Q1 = No and Q2 or Q3 or Q4 = Yes the outcome = High (it doesnt what Q5 and Q6 equal)
And if Q1, Q2, Q3 or Q4 = No but Q5 or Q6 = Yes then the outcome = medium
And if all questions = no then outcome = low
Thank you
Hello!
I hope you have studied the recommendations in the above tutorial.
Please try the following formula:
=IF(AND(Q1="Yes",OR(Q2="Yes",Q2="No"),OR(Q3="Yes",Q3="No"), OR(Q4="Yes",Q4="No"),OR(Q5="Yes",Q5="No"),OR(Q6="Yes",Q6="No")),"Significant", IF(AND(Q1="No",OR(Q2="Yes",Q3="Yes",Q4="Yes")), "High",IF(AND(OR(Q5="Yes",Q6="Yes"), OR(Q1="No",Q2="No",Q3="No",Q4="No")),"Medium", IF(AND(Q5="No",Q6="No",Q1="No",Q2="No",Q3="No",Q4="No"),"Low",))))
Hi! I am trying to create a royalty % using the IF formula with multiple conditions.
My scenario is that I have 5,000 patients in this 5 year plan. I am trying to come up with a 2 formulas broken out in two Tiers. The first tier or formula is 1,000 patients onboarded in Year 1 receive a 20% royalty. The second tier is royalty percentage for cumulative onboarding or remaining 4,000 patients receive a 3% royalty. BUT if we add new patients in year 3, those patients receive the 20%.
I need specific formula for this problem
I check attendance 3 times: 1st , 2nd, 3rd
Now I would like my excel to mark LATE if the student:
Got the 2nd and 3rd attendance but not the 1st
and
Got the 1st and 3rd attendance but not the 2nd
and
Got the 1st and 2nd attendance but not the 3rd
Hello!
I assume that if the attendance is negative, then the cell is empty. You can use the formula
=IF(SUM(--ISBLANK(A1:A3))=1,"Late","")
I hope it’ll be helpful.
Hi! I am trying to create an IF formula with multiple conditions.
My scenario is that I have 5,000 patients in this 5 year plan. The first 1,000 patients onboarded in Year 1 receive a 20% royalty. After that, the remaining 1000 patients onboarded receive only a 3% royalty. BUT if we add new patients in year 3, those patients receive the 20%. Let me know if I explained it correctly.
To add: I am looking for a royalty % using the IF formula with multiple conditions.
I am trying to come up with a 2 formulas broken out in two Tiers.
The first tier is a royalty percentage the moment patients get enrolled in the model.
The second tier is royalty percentage for cumulative onboarding of patients.
Hello!
Unfortunately, without seeing your data it hard to give you advice.
For the condition in the IF function, I recommend using the COUNTIFS function. With COUNTIFS, you can count the number of patients in a given time. I recommend examples of using COUNTIFS.
Hi! No problem, would the below data be helpful? Here is a financial model with the following scenario
Contract value: $30,000,000
Years: 5 year model
Number of patients: up to 6,000
Revenue per patient: 5,000
Royalty to patients: Right now its fixed at 20% but I would like to base it on patients enrolled
Gross Margin per patient: $2,062
COGS: $2,938 (includes a 20% fixed royalty)
Gross Margin: $12,373,920
Gross Margin %: 41.2%
I am struggling with coming up with a COUNTIFS formula for "royalty to patients"
Hi there
I#m trying several nests in my formula, but something is not working... And I'm not sure what can it be
=IF( (D52>2); (if(2900>I52>5000); (if(J52="FC");"yes";"no");"no"))
Sorry, this is the one I think should be ok
=IF( ((D52I52>5000); (if(J52="FC");"yes";"no");"no");”no”)
Hello!
Please describe your problem in more detail. It’ll help me understand it better and find a solution for you. Thank you.
Hi,
please help me out
i have so many column from A to N
i want to add value from A C D F H J L N
COLUMN B E G I K M CONTAIN DIGIT 1 TO 4
IF VALVE 1 OR 4 COME THEN IT ADD A AND C OR STOP TO ANOTHER COLUMN
IF VALUE 3 OR 2 COME THEN ADD A C D AND AGAIN SEARCH VALUE.
ONLY 1 OR 4 COME MEAN IT WILL STOP ADDING NEXT COLUMN OTHERWISE 2 OR 3 COME MEAN IT ADD ANOTHER COLUMN AND SEARCH FOR NEXT COLUMN.
Hello!
I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you.
a b c d e f g h i j k
19 3 15 2 11 2 16 1 16 3 15
i want to add 19+15+11+16 when 2 or 3 come after any number.
if 1 or 4 come then stop adding another column
Hello!
Explain the phrase "i want to add 19 + 15 + 11 + 16 when 2 or 3 come after any number." Why are these cells selected? Where do you enter 2 and 3?
Hello, i have three set of data inputted manually. I have another column for the set of data to be copied if i input a character corresponding to that set of data.
Example:
A , B , C , D
1 Q , R , S ,
2 10, 19 , 7
3 5 , 11 , 66 ,
4 1 , 9 , 3 ,
5 23 , 3 , 8 ,
i want to type into D1 "1" for all the data under Q (i.e A2:A5) and it will copy that data into column D. If i type in "2" into D1, i want all the data under R to be copied in the column D. And if i type in "3" into D1, it will copy all the data under S into column D.
Is this possible?
Thank you in advance
Hello!
Column D in your case already contains data. Therefore, you can only replace this data with values from other cells using a VBA macro.
Your phrase "And if i type in“ 3 ”into D1, it will copy all the data under S into column D." looks strange since this data is already written to column D
Thanks for your response.
D is meant to be a blank column. I think the spacing is making it look like it has data. D1:D5 is all empty. I want to put my formula in E1 so that the data will be copied onto column D.
A , B , C , D , E
1 Q , R , S ,
2 10, 19 , 7
3 5 , 11 , 66 ,
4 1 , 9 , 3 ,
5 23 , 3 , 8 ,
Hope this is clearer.
Thank you in advance for your time.
HI,
Please help me with formula using ifs
Total marks is = 30
Time limit to complete the exam is 10 mins , prior to which following deductions will be made :
If the person completes the exam in 11 mins, 15% marks will deduct
from the total marks.
If the person completes the exam in 13 mins, 30% marks will deduct
from the total marks.
If the person completes the exam in 15 mins, 50% marks will deduct
from the total marks.
If the person exceeds 15mins, the marks will be nil.
Hello!
I hope you have studied the recommendations in the above tutorial.
If I understand your task correctly, the following formula should work for you:
=IFS(B1>15,0,B1>13,C1*0.5,B1>11,C1*0.7,B1>10,C1*0.85,B1<=10,C1)
A+A+A=3.How is possible in MS Excel work sheet
How to distribute numbars according to slabs, and short upto 100 with different rates as well
Hello!
I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you.
Hello,
Below is column A, B & C and in column D I need is.. if A1 is equal to "UKB" and then if B1 is equal to C1 the field should be blank or it should say "PLS CHECK" and if A is not equal to UKB then Column D field should be blank.
UKB M07595448 M07595448
UKB M07595448 M07595448
UKB M07748431 M07748431
UKB M07744464 M07744464
UKB M07744464 M07744464
UKB M07685293 M07685293
UKB M07685293 M07685293
UKB M07685293 M07685293
UKB M07794223 M07794223
UKB #N/A M04787723
UKB #N/A M04395096
UKB #N/A M04395096
UKB #N/A M04395096
UKB #N/A M04395096
UKB #N/A M02083964
UKB #N/A M02083964
UKB #N/A M02083964
UKB #N/A M01861464
UKB #N/A M01861464
UKB #N/A M01861464
UKB #N/A M01861464
UKB #N/A M01861464
UKB #N/A M01861464
UKB #N/A M04802877
301219 #N/A M02731841
301219 #N/A M02731841
301219 #N/A M02731841
301219 #N/A M02731841
290120 #N/A M08189356
Hello!
If I understand your task correctly, the following formula should work for you:
=IF(A1="UKB",IF(B1=C1,"PLS CHECK",""),"")
I hope this will help
Actually, I have multiple conditions. Firstly, if A1 is equal to "UKB" then it should check whether B1 is also equal to C1 and B1 & C1 matches then the D1 field should be blank and if B1 & C1 does not match then it shoudl display as "PLS CHECK" and suppose if A1 is not equal to 'UKB" then the field should be blank.
Hello!
The formula I sent to you was created based on the description you provided in your first request. Why couldn't all the conditions be described at once? I think that you yourself can add all the conditions that you have to my formula.
I tried but not able to get it. Pls help me.
If a1 contain 60 and I input any value in a2 which cannot be divided by A1 as a whole number (eg. 120/60=3) as correct and (140/60=2.33 or 30/60=0.5) as wrong. How can I check for these and then advise person entering the a2 data that his value does not fall into the allowable multiples of 60 lots
Hello!
You can use this formula for Data Validation or to check a condition
=IF(MOD(A1,60)=0,TRUE,FALSE)
I hope it’ll be helpful.
I have a spreadsheet with 10 years and am trying to blend in raises over that time to figure an amount we can afford each year. Current Wage versus what they should be at (new wage). So, if current wage is 10 and new wage is 15, he is 50% behind. I have 100 employees and have 4 tiers to try to catch them up depending on how far behind whereby those that are further behind will get a bigger pay increase. My problem is they need to be more than tier 1 behind but less than tier 2 and, if the percentage increase brings them over the new wage, they should only get up to that new wage. G3 is the current rate and N3 is the new rate. O3 is the percentage behind they are. Q1,R1,S1,T1 are where I'm figuring the percentage behind is what will give them the % raise (which is Q2, R2, S2, T2). Help please?
G=IF(OR(G3>N3,G3),IF(OR(O3=$Q$1,O3=$R$1,O3=$S$1),(G3*$S$2)+G3,IF(OR(O3>=$T$1),(G3*$T$2)+G3,G3))))))
Hello!
I’m sorry but your task is not entirely clear to me. Could you please describe it in more detail? What do you want to calculate with this formula? What result do you want to get? Give an example of the source data and the expected result.
Thank you!
hi
I want to set a criteria when met by three scenarios e.g. if extraction % is greater than 80%,waste % is greater than 60% and status is ready, Give me Sample the Area.
Hello!
I’m sorry but your task is not entirely clear to me. Could you please describe it in more detail? What result do you want to get? Thank you!
Never mind this one