Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4538 comments

  1. I have a condition kindly provide me the formula

    upto 10 KM a company charges $20
    above it per km a have additional charges is $2 per KM

    if a person travel following km what was the formula

    A B C D E F
    1 18
    2 10
    3 24

    Then what is the formula I put in B1

    • Hello!
      If I understand your task correctly, the following formula should work for you:

      =MAX(A1-10,0)*2+20

      I hope it’ll be helpful.

  2. Sorry meant that I wish the span of normal to be between 53.

    My initial thought was fx= IF(A1>=71, "hypertension, IF(A1<=53, "hypotension, IF(A1=53, "normal"))))

    • Hello!
      Your terms change with every comment. Your conditions A1 <= 53 and A1 = 53 cannot be met at the same time. Perhaps this formula will suit you

      =IF(A1>=71,"hypertension",IF(A1<=53,"hypotension","nornal"))

      Pay attention to the following paragraph of the article above — Multiple IF statements in Excel

  3. Hello!
    Perhaps you can help me. I am hoping to write a IF + AND statement with multiple results.
    A171 is "2" and A1 >53 AND <71 is "0". Thanks!

      • I wish to write fx where A1>71= hypytension, A153=71, "hypertension, IF(A1<=53, "hypotension, IF(A1=53, "normal"))))

        However this does not work for me. Thanks

        • I wish to write fx where A1>71= hypytension, A153=71, "hypertension, IF(A1<=53, "hypotension, IF(A1=53, "normal"))))

          However this does not work for me. Thanks

  4. Condition:1
    Marks >=20 & Marks =20 & Marks =41 & Marks =41 & Marks <=60
    % Marks 110 & Above
    Eligible for Rs.3000/- reward

  5. Hi

    Can any one apply the formula for given 2 conditions please.

    Condition-1
    Marks 20 to 40
    Marks 41 to 60
    Marks 61 to 80
    Marks 81 to 100

    Eligible Marks 30
    Score (Marks) 30
    % of Marks 100
    Award for 1500

    Eligible Marks 30
    Score (Marks) 35
    % of Marks 117
    Award for 2500

    Condition-2
    Marks 20 to 40
    Marks 41 to 60
    Marks 61 to 80
    Marks 81 to 100

    Eligible Marks 45
    Score (Marks) 45
    % of Marks 100
    Award for 2000

    Eligible Marks 45
    Score (Marks) 55
    % of Marks 122
    Award for 3000

    • Hello!
      Sorry, I do not fully understand the task. ould you please describe it in more detail? What result do you want to get? Thank you!

  6. Hi can anyone spot the error in the following formula? Thanks.

    =IF(C$7<=55,"37%", IF(55<C$7<=60,"26%", IF(60<C$765,"12.5%"))))

    It gives either 37% (for 55) as outcome.

  7. Hello, I am attempting to forecast employee availability based upon a singular calendar date.

    Through conditional formatting I’ve created cells to be filled if they align with the start and end dates based upon a singular employee being able to forecast 10 different start and end dates columns.

    I was able to get all 10 to feed into a singular cell based on a IF(OR(AND statement, however I will only get a 1 if true and 0 if false. For the entirety of the formula...

    My end-state is that I would like to create a data validation that doesn’t allow any date to overlap any of the other dates.

    My thought was if a cell yielded 1, great! If the cell went greater than 1, then the user would get an error message stating the date overlaps with another.

    Unless you know a better solution? I am all ears, Grand Master Yoda :)

    Please Help
    Warm Regards, Michael

    • Hello!
      Unfortunately, without seeing your data it is impossible to give you advice.

      I'm sorry, it is not very clear what result you want to get. Could you please describe your task in more detail and send us a small sample workbook with the source data and expected result to support@ablebits.com? Please shorten your tables to 10-20 rows/columns and include the link to your blog comment.

      We'll look into your task and try to help.

  8. Hi Friends

    Could you please help me to get the excel formula?

    c11 = 50% of b11 or 100000, which one is lower

    Thanks
    Manik

  9. Good morning Svetlana,
    I really need some help on this,
    How do i write a formula to convert every 0.30 to 1.
    Assuming cell a1 contains 100, how do i count very 30 as 1.

    I hope this makes sense and I really appreciate the assistance!!
    Thank you in advance for the help!!
    Kind regards,

    Samuel

  10. Hello
    i have a list of names, scores, sex and statuses and here's my assignment:

    if the "status" of the customer is "Faculty" then give it a value with "Dr. " plus a space plus First Name plus a space plus Last Name.
    if the "status" of the customer is "student" and the "sex" is "M" then give it a value with "Mr. " plus space plus first name space plus last name
    if the "status" of the customer is "student" and the "sex" is "F" then give it a value with "Ms. " plus a space plus first name plus space plus last name

    please help me out with that one i am completely clueless on how to do it..

  11. Hi would you be able to help me with the below. I have 2 formulas that work separately however want to merge them into one formula.

    =IF(OR(AND(SUM(W3:X3)>=100,Y3>=0), AND(SUM(W3:X3)<=100, Y3<=0)), "Yes", "No")

    =IF(W3="","N/A", IF( X3= "", "N/A", IF(Y3="", "N/A")))

    I would like to add into the first formula that if W3 or X3 or Y3 are blank, then it should return "N/A"

  12. If you write 5 column like this

    A.Name
    B. Source (broker,ref and direct)
    C .product value
    D. commission %
    E. Commission amount( need formuls this column)

    1 ) if any broker(column B) sale 1 product
    Get commission (product value* 2%)=

    2 ) any existing buyer through his refrence sale 1 product to any customer
    Get commission 3 types
    * 1 st deal = 10k
    * 2 nd deal = 20k
    * 3 rd deal = 30k

    And

    3) if direct sale any product
    Get 0 commision

    How to codition formula in one cell

    • Hello!
      Your task is not completely clear to me. Explain condition 2 using your table data as an example. Give an example of the source data and the expected result.
      It’ll help me understand it better and find a solution for you.

  13. Hi, i want determine the latest date for this:
    If: a1=complete, c1=complete, e1=complete,g1=complete, i1=complete, if all of these are in "complete status" i want to get the latest date: b1=2/1/2020,d1=3/2/2020,f1=4/2/2020,h1=5/1/2020,j1=6/1/2020,j1=7/1/2020

  14. Please can someone help me with an excel formula? I have a cell E6 which has a drop down (Not Applicable, Fully Implemented, Mostly Implemented, Partly Implemented and Not Implemented). I want cell E7 to output 100%, 100%, 75%, 50% and 0% when E6 is Not Applicable, Fully Implemented, Mostly Implemented, Partly Implemented and Not Implemented respectively.

  15. I want to have solution of the following, if some one can help me:

    Cell A1 = Professional
    Cell A26 = sum of figures from cell A2 to A25
    I want to have results in A30 that if cell A1 is equal to "Professional" and results of A26 is less than or equal to 400 than it should display the results of A26 otherwise 400 should be there,

    Hope anyone of you can understand my query

    Naeem Sabir

  16. Is there a way to make this Countif statement work?

    =COUNTIF(C11:C112,"Low", AND D11:D112,"Work in Progress")

    • Hello!
      Unfortunately, without seeing your data it is difficult to give you any advice. I am assuming you have not one but several conditions to count. Therefore, I recommend using the COUNTIFS function. Read this detailed instruction.
      I hope this will help, otherwise please do not hesitate to contact me anytime.

  17. guys i've spend 5 hours. I just can't figure this out, so i seek help from you and god himself.
    I want to make an IF statement between theese numbers.
    7% $1,000.00
    8% $10,000.00
    9% $50,000.00
    9.50% $100,000.00

    how do I make if between 1000 and 9999 then show 7% or between 10000 and 49999 then show 8% etc.. etc...

    all my love

    • Hello!
      I hope you have studied the recommendations in the tutorial above. It contains answers to your question

      =IF(A1>=100000,9.5%,IF(A1>=50000,9%,IF(A1>=10000,8%,7% ) ) )

      Hope this is what you need.

      • Thx for your fast reply. I just figured it out my self.
        the "=IF" functions does not work. I ahve to use an "=IF(And(" function.
        so the code gonna look like this
        =if(and(K14=F12,K14=F13,K14=F14,K14=F15,K14=F16,K14=F17,K14=F18),E18,"Forkert beløb i j14"))))))))

        Thx for helping it's much appreciated

      • I have another great question which is even harder to figure out.
        I got this cummulative calculations which starts with
        5% of all up to 10,000.00 $
        10% of all between 100001 and up to 20,000.00 $
        12% of all between 20001 up to 50,000.00 $
        etc. etc..

        how do I make that calcualtion so it won't keeping make 5% of all after 10k but still SUM the all the differnet percentages?

        thx for your time and help. how can I share your knowledge with the community?

        • Hello!
          You have not described all the conditions and the expected result, but I think the following formula will suit you:

          =MIN(A1,10000)*5% + MAX(0,A1-MIN(MAX(0,A1-20000),30000) - MAX(0,A1-50000)-10000)*10% + MIN(MAX(0,A1-20000),30000)*12% + MAX(0,A1-50000)*12%

          I hope it’ll be helpful.

  18. I was looking all over on how to code the IF AND OR formula for different shifts base on a time and your example on the grades showed me the way.
    =IF(ISBLANK(D1),"",IF(AND(D1>=TIME(6,0,0),D1=TIME(14,0,0),D1<TIME(22,0,0)),"2nd Shift","Night Shift")))
    There may be a better way, but this is working
    Thanks

  19. I was wondering if you could help me? I am trying to figure out what is wrong with this formula. I keeping getting the #VALUE! error.

    =IF((AND(G2=OR("AF","SA"),(F2="R"))),"5.0%",IF(AND(G2=OR("AF","SA"),(F2=OR("S","F"))),"6.0%",IF((AND(G2=OR("NA","EU","AS","OC"),(F2=OR("R","S","F")))),"6.0%")))

    Thanks in advance!

    • Hello!
      Your formula is incorrect. Pay attention to how to write the AND and OR conditions correctly. See above Example 3 - Using IF with AND & OR functions.

      G2=OR(“AF”,”SA”) - incorrect

      OR(G2=“AF”,G2=”SA”) - correct

  20. Hello,

    I have a table with multiple columns - Gift, Type, Date, Year Since Gift & Exempted.

    Under Type there is a 2 option dropdown menu. - Charity and BPR.

    I have got the Year since gift to automatically calculate the years.

    What I would like to be able to do is have the Exempt column show "yes" or "no" if the gift is exempt.

    If the Type column shows "Charity" it is exempt, so the exempt column would need to show Yes.
    If the Type column shows "BPR" and it has been more than 2 years in the years since gift column it would be exempt, so would need to show "Yes". If its not exempt, I would like the column to show "No".

    This is the formula that I have used, but it does not work correctly.

    =IF(OR(AND(F14="BPR",H14>2),OR(F14="Charity",H14>=0)),"Yes","No")

    Please can you advise.

    Thank you!

    • Hello!
      If I understand your task correctly, the following formula should work for you:

      =IF(OR(AND(F14="BPR",H14>2),AND(F14="Charity",H14>=0)),"Yes","No")

      I hope this will help.

      • Hi,

        Thank you for this!

        I am however having the same problem. It works correctly for the BPR output but if I change the dropdown to Charity it does not change.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)