by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
Hello
Rate Quantity Result
2 2 4
2 Text Text
Text 2 2
Text1 Text2 Text2
I need the result like this help me with the formula please
2*2 = 4
2*Text = Text
Text*2 = 2
Text1*Text2 = Text2
All possibilities should be in one formula
Hello!
I'm having a bit of a challenge on this issue. I have a list of 2 columns, A and B.
Column A has duplicates that I need to remove, but I need to "Textjoin" column B first.
> Forgive extra Parenthesis, I need them to be able to read it better.
Currently using "=IFS((A2=A3), (TEXTJOIN(", ",TRUE,B2,B3)))
However, the problem is that it leads to duplicate text joins, and it has a limit to how many values it's joining. I have it set as the first function of the column to start things out.
Formula #2 I came up with:
=IF((A2=A3), (TEXTJOIN(", ",TRUE,B2,B3)), (IFS((A2=A1), (TEXTJOIN(",",TRUE,E1, B2)))))
However, even this doesn't work as I want it to because it's merging cells multiple times. Not all of the groupings are by two. Some are 5 cells, some are 3, etc.
Formula #3 I came up with:
For this one to work I had to put in a value for the first cell in Column C. (I just set it =A2).
"=IFS((A3=A2), (TEXTJOIN(", ",TRUE,C2,B3)), (A3=A4), (TEXTJOIN(", ",TRUE, B3, B4)))"
Formula #3 produced the best results, but still adding cells incorrectly.
The reason for this; there are roughly 12K rows and I need to reduce it as much as possible. However, I don't have a month to go cell by cell confirming it joined correctly.
Hopefully you can pass on some assistance!
Hello!
Unfortunately, without seeing your data it is difficult to give you any advice. In which cells do you write these formulas? Please provide me with an example of the source data and the expected result.
Could you please describe your task in more detail and send us a small sample workbook with the source data and expected result to support@ablebits.com? Please shorten your tables to 10-20 rows/columns and include the link to your blog comment.
We'll look into your task and try to help.
English Punjabi Hindi Math Science SST Comp Sci BELOW40% 90%&ABOVE
16 24 40 8 8 12 20 0 108 45.0 ENG,MAT,SST
24 28 40 10 18 12 26 0 132 55.0 ENG,PUN,MAT,SCI,SST HIN
12 6 6 8 10 12 14 0 54 22.5
16 22 10 4 10 4 22 0 66 27.5
18 20 30 14 16 18 16 0 116 48.3
14 22 30 14 16 18 16 0 114 47.5
WHICH FORMALUA APPLYED IN EXCLE TO GET ANSWER. PLEASE HELP ME
Hi! A non-techy person here and I need help for the formula for this please. (If B2 and C2 is blank then 0, if B2 and C2 has a value then D1+B2-C2) Thanks in advance!
Hi,
I hope you have studied the recommendations in the tutorial above. It contains answers to your question. Please use the following formula
=IF(AND(B2="",C2=""),0,D1+B2-C2)
or
=IF(ISBLANK(B2:C2),0,D1+B2-C2)
I hope it’ll be helpful.
Please i need a formula for the following:
If "Abbasia" then add 30 minutes to the time (The time is in another cell) and if Maadi Please write the time as it is (The time is in another cell)
Hello!
I hope you have studied the recommendations in the tutorial above. It contains answers to your question about IF function.
To add 30 minutes to the time, use the formula
A1+TIME(0,30,0)
I hope I answered your question. If something is still unclear, please feel free to ask.
I want to apply a formula to print purchase order status is active or if print purchase order status is cancel then print cancel. please guide me what is the formula i need to apply to get result
Hi,
An Excel formula can change the value of a cell. But she cannot start printing the document or cancel printing. To do this, you need to use a VBA macro.
hi all
i have some data like column a column b column c column d column e
a1 b1 c1 d1 e1 f1 g1 h1 i1 j1
1 2 3 4 5 6 7 8 9 10
if b1="a", then c1 should 2 d1 3 e1 3 like series should continue
if a1="a", b1="a", then c1 shoud start with 1, d1 2, e1 3 4 5 6 like
if f1 "a", g1 should start with 6,7,8,9,10............
A letter it may repeat and continues , but series should be continue.
ple provide the formula for above logic.
I'm getting a FALSE status on the one logic.
=IF(AND(V8=1,Q8>7/31/2020,Q8<9/1/2020),R8,"")
Q8 is the date 9/17/2020
R8 is a dollar amount
Logic 3 keeps returning FALSE, but I can't figure out why.
I'll be copying this down a column where some of the dates fit the parameters.
Hello!
Here is the article that may be helpful to you: Using IF function with dates
Please try the following formula:
=IF(AND(V8=1,Q8 > DATE(2020,7,31), Q8 < DATE(2020,9,1)),R8,"")
or
=IF(AND(V8=1,Q8 > DATEVALUE("7/31/2020"), Q8 < DATEVALUE("9/1/2020")),R8,"")
I hope I answered your question.
They both worked! Thank you so much!!!
From looking through your site, I had tried the DATEVALUE, but missed using the " marks.
Thank you again!
I have issues producing a function to fit in my amount cell.
Ok.
I have income from 3 sources Beans, Rice and Garri and I can only spend within the income received from each of these items. So I have an income section where I record income received from these items and their totals are in cell (A5, C5, E5 respectively). So For example, if I received 10,000frs as income from Beans, I cannot spend above the 10,000frs.
I now have an Expenditure section where I have a date column, a searchable list column where I can select the source of income (Beans, Rice, or Garri) i want to spend from at the time being and then a column for amount.
I want an IF function that when the amount of Expenditure of a particular item is more than the income received for that item, it should give an error message.
For example. If I received 10,000frs for Beans, and I put the first Expense in the amount of Expenditure section, 5,000frs, choosing Beans as source of income and now if I want to put the second Expenditure on a different date say 6,000frs still choosing Beans as source of income. It should return an error message because is more than 10,000frs income received from that item (Beans)
Please can someone help me out
Hi,
Your request goes beyond the advice we provide on this blog. This is a complex solution that cannot be found with a single formula. If you have a specific question about the operation of a function or formula, I will try to answer it.
Ok. Thanks for the reply Sir. Please How can I get to you may be privately for help in this.
Hello Ma'am
how can i summary all the fail and pass in the same sheet? I want to separate all the fail and pass after using if function please help. I don't want to manual copy and paste the name the selected fail or pass thank you and GOD bless.
Okay, I have a question. I am trying to pull data from one cell that has a lot of data. IF the data were consistent, I believe it would be easy. But it is not.
So, I have cell A2 for example the data in the cell is something similar to this:
Persons Cell Phone Number: 123-456-7890 (not everyone enters it that format and I can't 'force' it to be that way)
Persons Personal E-Mail Address: (again, not everyone types it out the same)
-Variations could be Persons Personal E-Mail Address: with or without a space before the start of the email
Persons E-Mail Address: with or without a space before the start of the email
All I want to do is easily pull out the persons email address and cell phone number. Here is an actual example of some of the data that could be in ONE cell (the data is not always in this order):
PERSONS E-MAIL ADDRESS: PERSONS.EMAIL@OUTLOOK.COM
________ (SM INITIALS)
PERSONS CELL PHONE #: (XXX) XXX-XXX
________ (SM INITIALS)
WHERE ASSIGNED TO (SSSSSS) : MR JIMMY SMITS
OFFICE/CELL PHONE NUMBER: (XXX) XXX-XXXX / (XXX) XXX-XXXX
E-MAIL ADDRESS: ANOTHER PERSONS EMAIL@OUTLOOK.COM
IF I AM UNABLE TO CONTACT MY OFFICE, I WILL CONTACT THE HELP DESK AT 1-800-XXX-XXXX.
Hello!
To extract e-mail from the text, use the formula:
=MID(A2,SEARCH("PERSONS E-MAIL ADDRESS:",A2,1)+23, (SEARCH("_",A2,SEARCH("PERSONS E-MAIL ADDRESS:",A2,1)+23+1)) - (SEARCH("PERSONS E-MAIL ADDRESS:",A2,1)+23))
To extract a phone number from text, use the formula:
=MID(A2,SEARCH("PERSONS CELL PHONE #:",A2,1)+21, (SEARCH("_",A2,SEARCH("PERSONS CELL PHONE #:",A2,1)+21+1)) - (SEARCH("PERSONS CELL PHONE #:",A2,1)+21))
I hope this will help, otherwise please do not hesitate to contact me anytime.
Thanks, the problem is that only works if the data is all exactly the same. If the way they enter the title of the persons email address is PERSONS E-MAIL ADDRESS then it might work if all of the other data was in the same location, character wise, in each cell. Sometimes, however, they enter the title of the persons email address as PERSONS PERSONAL E-MAIL ADDRESS: sometimes they enter it as PERSONS E-MAIL ADDRESS: and then to top it off, if they put spaces after the : it throws it off even more.
Hello!
You can remove extra spaces using any of the methods indicated in this article. But if they enter data in the wrong place, the program cannot fix it.
However, by changing these formulas, you can extract any part of your text.
If there is anything else I can help you with, please let me know.
Hi,
I need to help do this correction and needed to add more like this???
=IF(C4,(G4*H4*2+G4*J4*2)*L4),IF(C5,((((I5+H5)/2)*G5)*2+(G5*J5+0.141*K5))*L5)
Hi, need help to create a formula that can add 7 numbers (my own given numbers) to generate 5 number combinations between 1 and 36.
hello Team, I'm a bit stuck I need your help. So what I'm trying to do is to put 'if' formula in this way:
I have 10 persons and 8 cars, when I put a person to work i want to be assign to a car, but when that person is off I want another person to be on that car. The problem that I have is that if I put the first person off the second person will take the car but the will double up.
My formula is in this way: =if(B=1, A, B=0, C). I also tried =if(B=1, A, B=0, C, C=1, D)
I think I would need a 'but' somehow but I don't get the hang of it.
Any ideas would be very helpfull
thank you
Hello Team, I want to know the formula if 35Km, 45Km, 65KM is their and I want to fixed $7 for 5Km per ride then what was the formula
I have to add 'if A2>=200,B2=200,B2<=0)),"999",A2/B2)
But, Can I make this formula in IFERROR form ? because in 'value in false' shows #DIV/0!
Thank you very much in Advance.
Sean
Hello!
The purpose of your formula is not entirely clear to me. However, your conditions B2=200 and B2<=0 cannot be met at the same time. If B2=0 you will get # DIV/0 error!
I have multiple sheets with similar information; students fill in one of the sheets but I want the last sheet to look at all the other sheets (at a specific cell) to see which one(s) are filled in and enter that number in the formula cell. The number will be the same regardless of the sheet information entered in. So regardless of which sheet the information was entered on, it should return a specific number.
This is one of the formulas I tried; but I received an error (#value!) - =IF((OR(AP!E5:S5=1, OA!G5:S5=1)), "1", "0"). I am looking at a range of cells in each sheet for a response.
Trying to write a formula for calculation of: 25% of the quantity or (quantity x rate = ) Rs.5000 whichever is more
Hey Ablebits.
Thx for this amazing page. i've been using you so much. I'm unsure on how I post a question in a new topic. so feel free to move me in the right Direction.
I have this Formula
=if(and(D16=C4,D16=C5,D16=C6,D16=C7,D16=C8,D16=C9,D16=C10),B10,"Forkert beløb i D16"))))))))
How do I fast make changes to this, so that all the times it says "D16" I will change it to "K30"
Cheers
Hello!
Based on your description, it is hard to completely understand your task. However, I’ll try to guess and offer you the following formula:
=IF(AND(K30=C4,K30=C5,K30=C6,K30=C7,K30=C8,K30=C9,K30=C10),B10,"Forkert beløb i K30")
Hi
is it possible to use VLOOUP function in multiple IF statements as below? already try cannot work.
need your advice if have another way to solve it.
thanks in advance.
=IF(EXACT(G5,"AGENT"),VLOOKUP(E5,MASTERLIST!C:G,2,FALSE), IF(EXACT(G5,"MINI AGENT"), VLOOKUP(E5,MASTERLIST!C:G,3,FALSE)), IF(EXACT(G5,"DROPSHIP"), VLOOKUP(E5,MASTERLIST!C:G,4,FALSE)))
Hello!
It is very difficult to understand a formula that contains unique references to your workbook worksheets. Hence, I cannot check its work, sorry.
However, the formula contains an error. Try to change it.
=IF(EXACT(G5,"AGENT"),VLOOKUP(E5,MASTERLIST!C:G,2,FALSE),
IF(EXACT(G5,"MINI AGENT"),VLOOKUP(E5,MASTERLIST!C:G,3,FALSE),IF(EXACT(G5,"DROPSHIP"),VLOOKUP(E5,MASTERLIST!C:G,4,FALSE))))
I hope it’ll be helpful.
Thank sir, formula work perfect!!